New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/UKMO/2015_CO6_CO5_zenv_wr_direct_dwl_temp/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/2015_CO6_CO5_zenv_wr_direct_dwl_temp/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90 @ 5418

Last change on this file since 5418 was 5418, checked in by deazer, 9 years ago

Removed SVN KEYWORDS ready for adding code changes before fcm merges

File size: 27.9 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting                   
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   sbc_init       : read namsbc namelist
20   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
21   !!----------------------------------------------------------------------
22   USE oce              ! ocean dynamics and tracers
23   USE dom_oce          ! ocean space and time domain
24   USE phycst           ! physical constants
25   USE sbc_oce          ! Surface boundary condition: ocean fields
26   USE sbc_ice          ! Surface boundary condition: ice fields
27   USE sbcdcy           ! surface boundary condition: diurnal cycle
28   USE sbcssm           ! surface boundary condition: sea-surface mean variables
29   USE sbcapr           ! surface boundary condition: atmospheric pressure
30   USE sbcana           ! surface boundary condition: analytical formulation
31   USE sbcflx           ! surface boundary condition: flux formulation
32   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
33   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
34   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
35   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
36   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
37   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
38   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
39   USE sbccpl           ! surface boundary condition: coupled florulation
40   USE sbcssr           ! surface boundary condition: sea surface restoring
41   USE sbcrnf           ! surface boundary condition: runoffs
42   USE sbcisf           ! surface boundary condition: ice shelf
43   USE sbcfwb           ! surface boundary condition: freshwater budget
44   USE closea           ! closed sea
45   USE icbstp           ! Icebergs!
46
47   USE prtctl           ! Print control                    (prt_ctl routine)
48   USE iom              ! IOM library
49   USE in_out_manager   ! I/O manager
50   USE lib_mpp          ! MPP library
51   USE timing           ! Timing
52   USE sbcwave          ! Wave module
53
54   IMPLICIT NONE
55   PRIVATE
56
57   PUBLIC   sbc        ! routine called by step.F90
58   PUBLIC   sbc_init   ! routine called by opa.F90
59   
60   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
61     
62   !! * Substitutions
63#  include "domzgr_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
66   !! $Id$
67   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE sbc_init
72      !!---------------------------------------------------------------------
73      !!                    ***  ROUTINE sbc_init ***
74      !!
75      !! ** Purpose :   Initialisation of the ocean surface boundary computation
76      !!
77      !! ** Method  :   Read the namsbc namelist and set derived parameters
78      !!                Call init routines for all other SBC modules that have one
79      !!
80      !! ** Action  : - read namsbc parameters
81      !!              - nsbc: type of sbc
82      !!----------------------------------------------------------------------
83      INTEGER ::   icpt   ! local integer
84      !!
85      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx,  ln_blk_clio, ln_blk_core,           &
86         &             ln_blk_mfs, ln_apr_dyn, nn_ice,  nn_ice_embd, ln_dm2dc   , ln_rnf,   &
87         &             ln_ssr    ,  nn_isf , nn_fwb    , ln_cdgw , ln_wave , ln_sdw, nn_lsm, nn_limflx
88      INTEGER  ::   ios
89      !!----------------------------------------------------------------------
90
91      IF(lwp) THEN
92         WRITE(numout,*)
93         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
94         WRITE(numout,*) '~~~~~~~~ '
95      ENDIF
96
97      REWIND( numnam_ref )              ! Namelist namsbc in reference namelist : Surface boundary
98      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
99901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
100
101      REWIND( numnam_cfg )              ! Namelist namsbc in configuration namelist : Parameters of the run
102      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
103902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
104      IF(lwm) WRITE ( numond, namsbc )
105
106      !                          ! overwrite namelist parameter using CPP key information
107      IF( Agrif_Root() ) THEN                ! AGRIF zoom
108        IF( lk_lim2 )   nn_ice      = 2
109        IF( lk_lim3 )   nn_ice      = 3
110        IF( lk_cice )   nn_ice      = 4
111      ENDIF
112      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
113          ln_ana      = .TRUE.   
114          nn_ice      =   0
115      ENDIF
116     
117      IF(lwp) THEN               ! Control print
118         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
119         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
120         WRITE(numout,*) '           Type of sbc : '
121         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
122         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
123         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
124         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
125         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
126         WRITE(numout,*) '              coupled    formulation (T if key_oasis3)   lk_cpl      = ', lk_cpl
127         WRITE(numout,*) '              Multicategory heat flux formulation (LIM3) nn_limflx   = ', nn_limflx
128         WRITE(numout,*) '           Misc. options of sbc : '
129         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
130         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
131         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
132         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
133         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
134         WRITE(numout,*) '              iceshelf formulation                       nn_isf      = ', nn_isf
135         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
136         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
137         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
138         WRITE(numout,*) '              n. of iterations if land-sea-mask applied  nn_lsm      = ', nn_lsm
139      ENDIF
140
141      ! LIM3 Multi-category heat flux formulation
142      SELECT CASE ( nn_limflx)
143      CASE ( -1 )
144         IF(lwp) WRITE(numout,*) '              Use of per-category fluxes (nn_limflx = -1) '
145      CASE ( 0  )
146         IF(lwp) WRITE(numout,*) '              Average per-category fluxes (nn_limflx = 0) ' 
147      CASE ( 1  )
148         IF(lwp) WRITE(numout,*) '              Average then redistribute per-category fluxes (nn_limflx = 1) '
149      CASE ( 2  )
150         IF(lwp) WRITE(numout,*) '              Redistribute a single flux over categories (nn_limflx = 2) '
151      END SELECT
152      !
153#if defined key_top && ! defined key_offline
154      ltrcdm2dc = (ln_dm2dc .AND. ln_blk_core .AND. nn_ice==2)
155      IF( ltrcdm2dc )THEN
156         IF(lwp)THEN
157            WRITE(numout,*)"analytical diurnal cycle, core bulk formulation and LIM2 use: "
158            WRITE(numout,*)"Diurnal cycle on physics but not in passive tracers"
159         ENDIF
160      ENDIF
161#else
162      ltrcdm2dc =  .FALSE.
163#endif
164
165      !
166      !                              ! allocate sbc arrays
167      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
168
169      !                          ! Checks:
170      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
171         ln_rnf_mouth  = .false.                     
172         IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' )
173         nkrnf         = 0
174         rnf     (:,:) = 0.0_wp
175         rnf_b   (:,:) = 0.0_wp
176         rnfmsk  (:,:) = 0.0_wp
177         rnfmsk_z(:)   = 0.0_wp
178      ENDIF
179      IF( nn_isf .EQ. 0 ) THEN                      ! no specific treatment in vicinity of ice shelf
180         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
181         fwfisf  (:,:) = 0.0_wp
182         fwfisf_b(:,:) = 0.0_wp
183      END IF
184      IF( nn_ice == 0  )   fr_i(:,:) = 0.e0        ! no ice in the domain, ice fraction is always zero
185
186      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
187                                                   ! only if sea-ice is present
188 
189      fmmflx(:,:) = 0.0_wp                        ! freezing-melting array initialisation
190     
191      taum(:,:) = 0.0_wp                           ! Initialise taum for use in gls in case of reduced restart
192
193      !                                            ! restartability   
194      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
195          MOD( nstock             , nn_fsbc) /= 0 ) THEN
196         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
197            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
198         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
199      ENDIF
200      !
201      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
202         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
203      !
204      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) )   &
205         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
206      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) )   &
207         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' )
208      IF( nn_ice == 4 .AND. lk_agrif )   &
209         &   CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' )
210      IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 )   &
211         &   CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' )
212      IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) )   &
213         &   WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3'
214      IF( ( nn_ice == 3 ) .AND. ( lk_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) )   &
215         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
216      IF( ( nn_ice == 3 ) .AND. ( .NOT. lk_cpl ) .AND. ( nn_limflx == 2 ) )   &
217         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' )
218
219      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
220
221      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) )   &
222         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
223     
224      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
225         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
226
227      IF ( ln_wave ) THEN
228      !Activated wave module but neither drag nor stokes drift activated
229         IF ( .NOT.(ln_cdgw .OR. ln_sdw) )   THEN
230            CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' )
231      !drag coefficient read from wave model definable only with mfs bulk formulae and core
232         ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) )       THEN       
233             CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core')
234         ENDIF
235      ELSE
236      IF ( ln_cdgw .OR. ln_sdw  )                                         & 
237         &   CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but     &
238         & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ')
239      ENDIF 
240     
241      !                          ! Choice of the Surface Boudary Condition (set nsbc)
242      icpt = 0
243      IF( ln_ana          ) THEN   ;   nsbc = jp_ana    ; icpt = icpt + 1   ;   ENDIF       ! analytical      formulation
244      IF( ln_flx          ) THEN   ;   nsbc = jp_flx    ; icpt = icpt + 1   ;   ENDIF       ! flux            formulation
245      IF( ln_blk_clio     ) THEN   ;   nsbc = jp_clio   ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk       formulation
246      IF( ln_blk_core     ) THEN   ;   nsbc = jp_core   ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk       formulation
247      IF( ln_blk_mfs      ) THEN   ;   nsbc = jp_mfs    ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk       formulation
248      IF( lk_cpl          ) THEN   ;   nsbc = jp_cpl    ; icpt = icpt + 1   ;   ENDIF       ! Coupled         formulation
249      IF( cp_cfg == 'gyre') THEN   ;   nsbc = jp_gyre                       ;   ENDIF       ! GYRE analytical formulation
250      IF( lk_esopa        )            nsbc = jp_esopa                                      ! esopa test, ALL formulations
251      !
252      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
253         WRITE(numout,*)
254         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
255         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
256         WRITE(numout,*) '                     We stop'
257         nstop = nstop + 1
258      ENDIF
259      IF(lwp) THEN
260         WRITE(numout,*)
261         IF( nsbc == jp_esopa )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
262         IF( nsbc == jp_gyre  )   WRITE(numout,*) '              GYRE analytical formulation'
263         IF( nsbc == jp_ana   )   WRITE(numout,*) '              analytical formulation'
264         IF( nsbc == jp_flx   )   WRITE(numout,*) '              flux formulation'
265         IF( nsbc == jp_clio  )   WRITE(numout,*) '              CLIO bulk formulation'
266         IF( nsbc == jp_core  )   WRITE(numout,*) '              CORE bulk formulation'
267         IF( nsbc == jp_cpl   )   WRITE(numout,*) '              coupled formulation'
268         IF( nsbc == jp_mfs   )   WRITE(numout,*) '              MFS Bulk formulation'
269      ENDIF
270      !
271                               CALL sbc_ssm_init               ! Sea-surface mean fields initialisation
272      !
273      IF( ln_ssr           )   CALL sbc_ssr_init               ! Sea-Surface Restoring initialisation
274      !
275      IF( nn_ice == 3      )   CALL sbc_lim_init               ! LIM3 initialisation
276
277      IF( nn_ice == 4      )   CALL cice_sbc_init( nsbc )      ! CICE initialisation
278      !
279      IF( nsbc   == jp_cpl )   CALL sbc_cpl_init (nn_ice)      ! OASIS initialisation. must be done before first time step
280
281   END SUBROUTINE sbc_init
282
283
284   SUBROUTINE sbc( kt )
285      !!---------------------------------------------------------------------
286      !!                    ***  ROUTINE sbc  ***
287      !!             
288      !! ** Purpose :   provide at each time-step the ocean surface boundary
289      !!                condition (momentum, heat and freshwater fluxes)
290      !!
291      !! ** Method  :   blah blah  to be written ?????????
292      !!                CAUTION : never mask the surface stress field (tke sbc)
293      !!
294      !! ** Action  : - set the ocean surface boundary condition at before and now
295      !!                time step, i.e. 
296      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
297      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
298      !!              - updte the ice fraction : fr_i
299      !!----------------------------------------------------------------------
300      INTEGER, INTENT(in) ::   kt       ! ocean time step
301      !!---------------------------------------------------------------------
302      !
303      IF( nn_timing == 1 )  CALL timing_start('sbc')
304      !
305      !                                            ! ---------------------------------------- !
306      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
307         !                                         ! ---------------------------------------- !
308         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
309         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
310         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
311         ! The 3D heat content due to qsr forcing is treated in traqsr
312         ! qsr_b (:,:) = qsr (:,:)
313         emp_b(:,:) = emp(:,:)
314         sfx_b(:,:) = sfx(:,:)
315      ENDIF
316      !                                            ! ---------------------------------------- !
317      !                                            !        forcing field computation         !
318      !                                            ! ---------------------------------------- !
319      !
320      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
321                                                         ! (caution called before sbc_ssm)
322      !
323      CALL sbc_ssm( kt )                                 ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
324      !                                                  ! averaged over nf_sbc time-step
325
326      IF (ln_wave) CALL sbc_wave( kt )
327                                                   !==  sbc formulation  ==!
328                                                           
329      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
330      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
331      CASE( jp_gyre  )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
332      CASE( jp_ana   )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
333      CASE( jp_flx   )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
334      CASE( jp_clio  )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
335      CASE( jp_core  )   ;   CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
336      CASE( jp_cpl   )   ;   CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! coupled formulation
337      CASE( jp_mfs   )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
338      CASE( jp_esopa )                               
339                             CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
340                             CALL sbc_gyre    ( kt )                    !
341                             CALL sbc_flx     ( kt )                    !
342                             CALL sbc_blk_clio( kt )                    !
343                             CALL sbc_blk_core( kt )                    !
344                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
345      END SELECT
346
347      !                                            !==  Misc. Options  ==!
348     
349      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
350      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
351      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
352      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
353      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
354      END SELECT                                             
355
356      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
357
358      IF( nn_isf   /= 0  )   CALL sbc_isf( kt )                    ! compute iceshelves
359
360      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
361 
362      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
363
364      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
365
366      IF( nn_closea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
367      !                                                           ! (update freshwater fluxes)
368!RBbug do not understand why see ticket 667
369      !clem-bugsal CALL lbc_lnk( emp, 'T', 1. )
370      !
371      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
372         !                                             ! ---------------------------------------- !
373         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
374            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
375            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
376            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
377            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
378            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
379            ! The 3D heat content due to qsr forcing is treated in traqsr
380            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
381            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
382            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
383            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
384               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
385            ELSE
386               sfx_b (:,:) = sfx(:,:)
387            ENDIF
388         ELSE                                                   !* no restart: set from nit000 values
389            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
390            utau_b(:,:) = utau(:,:) 
391            vtau_b(:,:) = vtau(:,:)
392            qns_b (:,:) = qns (:,:)
393            emp_b (:,:) = emp(:,:)
394            sfx_b (:,:) = sfx(:,:)
395         ENDIF
396      ENDIF
397      !                                                ! ---------------------------------------- !
398      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
399         !                                             ! ---------------------------------------- !
400         IF(lwp) WRITE(numout,*)
401         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
402            &                    'at it= ', kt,' date= ', ndastp
403         IF(lwp) WRITE(numout,*) '~~~~'
404         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
405         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
406         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
407         ! The 3D heat content due to qsr forcing is treated in traqsr
408         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
409         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
410         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx )
411      ENDIF
412
413      !                                                ! ---------------------------------------- !
414      !                                                !        Outputs and control print         !
415      !                                                ! ---------------------------------------- !
416      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
417         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
418         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux 
419                                                                ! (includes virtual salt flux beneath ice
420                                                                ! in linear free surface case)
421         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
422         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
423         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
424         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
425         IF( nn_ice > 0 )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
426         CALL iom_put( "taum"  , taum       )                   ! wind stress module
427         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
428      ENDIF
429      !
430      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
431      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
432      !
433      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
434         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
435         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
436         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
437         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
438         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
439         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
440         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
441         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
442         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
443            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
444      ENDIF
445
446      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
447      !
448      IF( nn_timing == 1 )  CALL timing_stop('sbc')
449      !
450   END SUBROUTINE sbc
451
452
453   SUBROUTINE sbc_final
454      !!---------------------------------------------------------------------
455      !!                    ***  ROUTINE sbc_final  ***
456      !!
457      !! ** Purpose :   Finalize CICE (if used)
458      !!---------------------------------------------------------------------
459      !
460      IF( nn_ice == 4 )   CALL cice_sbc_final
461      !
462   END SUBROUTINE sbc_final
463
464   !!======================================================================
465END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.