New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/UKMO/2017_dev_r7573_oasis/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/UKMO/2017_dev_r7573_oasis/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 8975

Last change on this file since 8975 was 8975, checked in by andmirek, 6 years ago

#1868 first working branch
File size: 16.6 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   rst_opn    : open the ocean restart file
15   !!   rst_write  : write the ocean restart file
16   !!   rst_read   : read the ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE phycst          ! physical constants
21   USE in_out_manager  ! I/O manager
22   USE iom             ! I/O module
23   USE ioipsl, ONLY : ju2ymds    ! for calendar
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   USE divcur          ! hor. divergence and curl      (div & cur routines)
27   USE sbc_oce         ! for icesheet freshwater input variables
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   rst_opn         ! routine called by step module
33   PUBLIC   rst_write       ! routine called by step module
34   PUBLIC   rst_read        ! routine called by istate module
35   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE rst_opn( kt )
48      !!---------------------------------------------------------------------
49      !!                   ***  ROUTINE rst_opn  ***
50      !!                     
51      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
52      !!              + open the restart when we are one time step before nitrst
53      !!                   - restart header is defined when kt = nitrst-1
54      !!                   - restart data  are written when kt = nitrst
55      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt     ! ocean time-step
58      INTEGER             ::   iyear, imonth, iday
59      REAL (wp)           ::   zsec
60      REAL (wp)           ::   zfjulday
61      !!
62      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
63      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
64      CHARACTER(LEN=150)  ::   clpath   ! full path to ocean output restart file
65      !!----------------------------------------------------------------------
66      !
67      IF( kt == nit000 ) THEN   ! default definitions
68         lrst_oce = .FALSE.   
69         IF( ln_rst_list ) THEN
70            nrst_lst = 1
71            nitrst = nstocklist( nrst_lst )
72         ELSE
73            nitrst = nitend
74         ENDIF
75      ENDIF
76
77      ! frequency-based restart dumping (nn_stock)
78      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
79         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
80         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
81         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
82      ENDIF
83      ! to get better performances with NetCDF format:
84      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
85      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
86      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
87         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
88            IF ( ln_rstdate ) THEN
89               zfjulday = fjulday + rdttra(1) / rday
90               IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday )   zfjulday = REAL(NINT(zfjulday),wp)   ! avoid truncation error
91               CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )           
92               WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
93            ELSE
94               ! beware of the format used to write kt (default is i8.8, that should be large enough...)
95               IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
96               ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
97               ENDIF
98            ENDIF
99            ! create the file
100            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
101            clpath = TRIM(cn_ocerst_outdir)
102            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
103            IF(lwp) THEN
104               WRITE(numout,*)
105               SELECT CASE ( jprstlib )
106               CASE ( jprstdimg )   ;   WRITE(numout,*)                            &
107                   '             open ocean restart binary file: ',TRIM(clpath)//clname
108               CASE DEFAULT         ;   WRITE(numout,*)                            &
109                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
110               END SELECT
111               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
112               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
113               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
114               ENDIF
115            ENDIF
116            !
117            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
118            lrst_oce = .TRUE.
119         ENDIF
120      ENDIF
121      !
122   END SUBROUTINE rst_opn
123
124
125   SUBROUTINE rst_write( kt )
126      !!---------------------------------------------------------------------
127      !!                   ***  ROUTINE rstwrite  ***
128      !!                     
129      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
130      !!
131      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
132      !!              file, save fields which are necessary for restart
133      !!----------------------------------------------------------------------
134      INTEGER, INTENT(in) ::   kt   ! ocean time-step
135      !!----------------------------------------------------------------------
136
137                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
138                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
139
140                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
141                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
142                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
143                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
144                     CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb      )
145                     CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb     )
146                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
147                     !
148                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
149                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
150                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
151                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
152                     CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn      )
153                     CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn     )
154                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
155                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
156                     CALL iom_rstput( kt, nitrst, numrow, 'fromCICE'   , vcice      )
157#if defined key_zdfkpp
158                     CALL iom_rstput( kt, nitrst, numrow, 'rhd'    , rhd       )
159#endif
160                     IF( lk_oasis) THEN
161                     ! ln_coupled_iceshelf_fluxes uninitialised unless lk_oasis=true
162                     IF( ln_coupled_iceshelf_fluxes ) THEN
163                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass', greenland_icesheet_mass )
164                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
165                        CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
166                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
167                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
168                        CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
169                     ENDIF
170                     ENDIF
171
172      IF( kt == nitrst ) THEN
173         CALL iom_close( numrow )     ! close the restart file (only at last time step)
174!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
175!!gm  not sure what to do here   ===>>>  ask to Sebastian
176         lrst_oce = .FALSE.
177            IF( ln_rst_list ) THEN
178               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
179               nitrst = nstocklist( nrst_lst )
180            ENDIF
181            lrst_oce = .FALSE.
182      ENDIF
183      !
184   END SUBROUTINE rst_write
185
186
187   SUBROUTINE rst_read_open
188      !!----------------------------------------------------------------------
189      !!                   ***  ROUTINE rst_read_open  ***
190      !!
191      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
192      !!
193      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
194      !!                the file has already been opened
195      !!----------------------------------------------------------------------
196      INTEGER        ::   jlibalt = jprstlib
197      LOGICAL        ::   llok
198      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
199      !!----------------------------------------------------------------------
200      !
201      IF( numror <= 0 ) THEN
202         IF(lwp) THEN                                             ! Contol prints
203            WRITE(numout,*)
204            SELECT CASE ( jprstlib )
205            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
206            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
207            END SELECT
208            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
209            WRITE(numout,*) '~~~~~~~~'
210         ENDIF
211
212         clpath = TRIM(cn_ocerst_indir)
213         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
214         IF ( jprstlib == jprstdimg ) THEN
215           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
216           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
217           INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
218           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
219         ENDIF
220         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
221      ENDIF
222   END SUBROUTINE rst_read_open
223
224   SUBROUTINE rst_read
225      !!----------------------------------------------------------------------
226      !!                   ***  ROUTINE rst_read  ***
227      !!
228      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
229      !!
230      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
231      !!----------------------------------------------------------------------
232      REAL(wp) ::   zrdt, zrdttra1
233      INTEGER  ::   jk
234      LOGICAL  ::   llok
235      !!----------------------------------------------------------------------
236
237      CALL rst_read_open           ! open restart for reading (if not already opened)
238
239      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
240      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
241         CALL iom_get( numror, 'rdt', zrdt )
242         IF( zrdt /= rdt )   neuler = 0
243      ENDIF
244      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
245         CALL iom_get( numror, 'rdttra1', zrdttra1 )
246         IF( zrdttra1 /= rdttra(1) )   neuler = 0
247      ENDIF
248      !
249      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
250         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
251         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
252         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
253         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
254         CALL iom_get( numror, jpdom_autoglo, 'rotb'   , rotb    )
255         CALL iom_get( numror, jpdom_autoglo, 'hdivb'  , hdivb   )
256         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
257      ELSE
258         neuler = 0
259      ENDIF
260      !
261      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
262      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
263      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
264      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
265      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
266      IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
267         CALL iom_get( numror, jpdom_autoglo, 'rotn'   , rotn    )
268         CALL iom_get( numror, jpdom_autoglo, 'hdivn'  , hdivn   )
269      ELSE
270         CALL div_cur( 0 )                              ! Horizontal divergence & Relative vorticity
271      ENDIF
272      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
273         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
274      ELSE
275         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )   
276      ENDIF
277#if defined key_zdfkpp
278      IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
279         CALL iom_get( numror, jpdom_autoglo, 'rhd'    , rhd     )   ! now    in situ density anomaly
280      ELSE
281         CALL eos( tsn, rhd, fsdept_n(:,:,:) )   ! compute rhd
282      ENDIF
283#endif
284      !
285      IF( iom_varid( numror, 'greenland_icesheet_mass', ldstop = .FALSE. ) > 0 )   THEN
286         CALL iom_get( numror, 'greenland_icesheet_mass', greenland_icesheet_mass )
287         CALL iom_get( numror, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
288         CALL iom_get( numror, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
289      ELSE
290         greenland_icesheet_mass = 0.0 
291         greenland_icesheet_mass_rate_of_change = 0.0 
292         greenland_icesheet_timelapsed = 0.0
293      ENDIF
294      IF( iom_varid( numror, 'antarctica_icesheet_mass', ldstop = .FALSE. ) > 0 )   THEN
295         CALL iom_get( numror, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
296         CALL iom_get( numror, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
297         CALL iom_get( numror, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
298      ELSE
299         antarctica_icesheet_mass = 0.0 
300         antarctica_icesheet_mass_rate_of_change = 0.0 
301         antarctica_icesheet_timelapsed = 0.0
302      ENDIF
303
304      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
305         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
306         ub   (:,:,:)   = un   (:,:,:)
307         vb   (:,:,:)   = vn   (:,:,:)
308         rotb (:,:,:)   = rotn (:,:,:)
309         hdivb(:,:,:)   = hdivn(:,:,:)
310         sshb (:,:)     = sshn (:,:)
311
312         IF( lk_vvl ) THEN
313            DO jk = 1, jpk
314               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
315            END DO
316         ENDIF
317
318      ENDIF
319      !
320   END SUBROUTINE rst_read
321
322   !!=====================================================================
323END MODULE restart
Note: See TracBrowser for help on using the repository browser.