New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/UKMO/AMM15_v3_6_STABLE_package/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/AMM15_v3_6_STABLE_package/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 8059

Last change on this file since 8059 was 8059, checked in by jgraham, 7 years ago

Merged branches required for AMM15 simulations, see ticket #1904.
Merged branches include:
branches/UKMO/CO6_KD490
branches/UKMO/CO6_Restartable_Tidal_Analysis
branches/UKMO/AMM15_v3_6_STABLE

File size: 33.0 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE diaptr         ! poleward transport diagnostics
29   !
30   USE lib_mpp        ! MPP library
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE in_out_manager ! I/O manager
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
41   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
42
43   LOGICAL ::   l_trd   ! flag to compute trends
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
56      &                                       ptb, ptn, pta, kjpt )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_tvd  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of
61      !!       tracers and add it to the general trend of tracer equations
62      !!
63      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
64      !!       corrected flux (monotonic correction)
65      !!       note: - this advection scheme needs a leap-frog time scheme
66      !!
67      !! ** Action : - update (pta) with the now advective tracer trends
68      !!             - save the trends
69      !!----------------------------------------------------------------------
70      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
71      !
72      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
76      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !
81      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
82      INTEGER  ::   ik 
83      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
84      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
85      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
88      !!----------------------------------------------------------------------
89      !
90      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
91      !
92      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
98         !
99         l_trd = .FALSE.
100         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
101      ENDIF
102! slwa unless you use l_trdtra too, the above switches off trend calculations for l_trdtrc
103         l_trd = .FALSE.
104         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
105!slwa
106      !
107      IF( l_trd )  THEN
108         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
109         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
110      ENDIF
111      !
112      zwi(:,:,:) = 0.e0 ; 
113      !
114      !                                                          ! ===========
115      DO jn = 1, kjpt                                            ! tracer loop
116         !                                                       ! ===========
117         ! 1. Bottom and k=1 value : flux set to zero
118         ! ----------------------------------
119         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
120         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
121         
122         zwz(:,:,1  ) = 0._wp
123         ! 2. upstream advection with initial mass fluxes & intermediate update
124         ! --------------------------------------------------------------------
125         ! upstream tracer flux in the i and j direction
126         DO jk = 1, jpkm1
127            DO jj = 1, jpjm1
128               DO ji = 1, fs_jpim1   ! vector opt.
129                  ! upstream scheme
130                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
131                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
132                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
133                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
134                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
135                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
136               END DO
137            END DO
138         END DO
139
140         ! upstream tracer flux in the k direction
141         ! Interior value
142         DO jk = 2, jpkm1
143            DO jj = 1, jpj
144               DO ji = 1, jpi
145                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
146                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
147                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
148               END DO
149            END DO
150         END DO
151         ! Surface value
152         IF( lk_vvl ) THEN   
153            IF ( ln_isfcav ) THEN
154               DO jj = 1, jpj
155                  DO ji = 1, jpi
156                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable
157                  END DO
158               END DO
159            ELSE
160               zwz(:,:,1) = 0.e0          ! volume variable
161            END IF
162         ELSE               
163            IF ( ln_isfcav ) THEN
164               DO jj = 1, jpj
165                  DO ji = 1, jpi
166                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
167                  END DO
168               END DO   
169            ELSE
170               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
171            END IF
172         ENDIF
173
174         ! total advective trend
175         DO jk = 1, jpkm1
176            z2dtt = p2dt(jk)
177            DO jj = 2, jpjm1
178               DO ji = fs_2, fs_jpim1   ! vector opt.
179                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
180                  ! total intermediate advective trends
181                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
182                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
183                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
184                  ! update and guess with monotonic sheme
185                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
186                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
187               END DO
188            END DO
189         END DO
190         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
191         CALL lbc_lnk( zwi, 'T', 1. ) 
192
193         !                                 ! trend diagnostics (contribution of upstream fluxes)
194         IF( l_trd )  THEN 
195            ! store intermediate advective trends
196            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
197         END IF
198         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
199         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
200           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
201           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
202         ENDIF
203
204         ! 3. antidiffusive flux : high order minus low order
205         ! --------------------------------------------------
206         ! antidiffusive flux on i and j
207         DO jk = 1, jpkm1
208            DO jj = 1, jpjm1
209               DO ji = 1, fs_jpim1   ! vector opt.
210                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
211                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
212               END DO
213            END DO
214         END DO
215     
216         ! antidiffusive flux on k
217         ! Interior value
218         DO jk = 2, jpkm1                   
219            DO jj = 1, jpj
220               DO ji = 1, jpi
221                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
222               END DO
223            END DO
224         END DO
225         ! surface value
226         IF ( ln_isfcav ) THEN
227            DO jj = 1, jpj
228               DO ji = 1, jpi
229                  zwz(ji,jj,mikt(ji,jj)) = 0.e0
230               END DO
231            END DO
232         ELSE
233            zwz(:,:,1) = 0.e0
234         END IF
235         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
236         CALL lbc_lnk( zwz, 'W',  1. )
237
238         ! 4. monotonicity algorithm
239         ! -------------------------
240         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
241
242
243         ! 5. final trend with corrected fluxes
244         ! ------------------------------------
245         DO jk = 1, jpkm1
246            DO jj = 2, jpjm1
247               DO ji = fs_2, fs_jpim1   ! vector opt. 
248                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
249                  ! total advective trends
250                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
251                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
252                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
253                  ! add them to the general tracer trends
254                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
255               END DO
256            END DO
257         END DO
258
259         !                                 ! trend diagnostics (contribution of upstream fluxes)
260         IF( l_trd )  THEN
261            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
262            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
263            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
264           
265            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
266            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
267            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
268         END IF
269         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
270         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
271           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
272           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
273         ENDIF
274         !
275      END DO
276      !
277                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
278      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
279      !
280      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
281      !
282   END SUBROUTINE tra_adv_tvd
283
284   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
285      &                                       ptb, ptn, pta, kjpt )
286      !!----------------------------------------------------------------------
287      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
288      !!
289      !! **  Purpose :   Compute the now trend due to total advection of
290      !!       tracers and add it to the general trend of tracer equations
291      !!
292      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
293      !!       corrected flux (monotonic correction). This version use sub-
294      !!       timestepping for the vertical advection which increases stability
295      !!       when vertical metrics are small.
296      !!       note: - this advection scheme needs a leap-frog time scheme
297      !!
298      !! ** Action : - update (pta) with the now advective tracer trends
299      !!             - save the trends
300      !!----------------------------------------------------------------------
301      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
302      !
303      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
304      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
305      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
306      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
307      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
308      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
309      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
310      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
311      !
312      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
313      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
314      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
315      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
316      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
317      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
318      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
319      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
320      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
321      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
322      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
323      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
324      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
325      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
326      !!----------------------------------------------------------------------
327      !
328      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
329      !
330      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
331      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
332      CALL wrk_alloc( jpi, jpj, jpk, kjpt+1, ztrs )
333      !
334      IF( kt == kit000 )  THEN
335         IF(lwp) WRITE(numout,*)
336         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
337         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
338      ENDIF
339      !
340      l_trd = .FALSE.
341      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
342      !
343      IF( l_trd )  THEN
344         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
345         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
346      ENDIF
347      !
348      zwi(:,:,:) = 0._wp
349      z_rzts = 1._wp / REAL( jnzts, wp )
350      zr_p2dt(:) = 1._wp / p2dt(:)
351      !
352      !                                                          ! ===========
353      DO jn = 1, kjpt                                            ! tracer loop
354         !                                                       ! ===========
355         ! 1. Bottom value : flux set to zero
356         ! ----------------------------------
357         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
358         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
359
360         ! 2. upstream advection with initial mass fluxes & intermediate update
361         ! --------------------------------------------------------------------
362         ! upstream tracer flux in the i and j direction
363         DO jk = 1, jpkm1
364            DO jj = 1, jpjm1
365               DO ji = 1, fs_jpim1   ! vector opt.
366                  ! upstream scheme
367                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
368                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
369                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
370                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
371                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
372                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
373               END DO
374            END DO
375         END DO
376
377         ! upstream tracer flux in the k direction
378         ! Interior value
379         DO jk = 2, jpkm1
380            DO jj = 1, jpj
381               DO ji = 1, jpi
382                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
383                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
384                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
385               END DO
386            END DO
387         END DO
388         ! Surface value
389         IF( lk_vvl ) THEN
390            IF ( ln_isfcav ) THEN
391               DO jj = 1, jpj
392                  DO ji = 1, jpi
393                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable +    isf
394                  END DO
395               END DO
396            ELSE
397               zwz(:,:,1) = 0.e0                              ! volume variable + no isf
398            END IF
399         ELSE
400            IF ( ln_isfcav ) THEN
401               DO jj = 1, jpj
402                  DO ji = 1, jpi
403                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface +    isf
404                  END DO
405               END DO
406            ELSE
407               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)                                               ! linear free surface + no isf
408            END IF
409         ENDIF
410
411         ! total advective trend
412         DO jk = 1, jpkm1
413            z2dtt = p2dt(jk)
414            DO jj = 2, jpjm1
415               DO ji = fs_2, fs_jpim1   ! vector opt.
416                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
417                  ! total intermediate advective trends
418                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
419                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
420                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
421                  ! update and guess with monotonic sheme
422                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
423                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
424               END DO
425            END DO
426         END DO
427         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
428         CALL lbc_lnk( zwi, 'T', 1. ) 
429
430         !                                 ! trend diagnostics (contribution of upstream fluxes)
431         IF( l_trd )  THEN 
432            ! store intermediate advective trends
433            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
434         END IF
435         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
436         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
437           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
438           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
439         ENDIF
440
441         ! 3. antidiffusive flux : high order minus low order
442         ! --------------------------------------------------
443         ! antidiffusive flux on i and j
444
445
446         DO jk = 1, jpkm1
447
448            DO jj = 1, jpjm1
449               DO ji = 1, fs_jpim1   ! vector opt.
450                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
451                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
452
453                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
454                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
455               END DO
456            END DO
457
458            DO jj = 2, jpjm1         ! partial horizontal divergence
459               DO ji = fs_2, fs_jpim1
460                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
461                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
462               END DO
463            END DO
464
465            DO jj = 1, jpjm1
466               DO ji = 1, fs_jpim1   ! vector opt.
467                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
468                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
469               END DO
470            END DO
471         END DO
472     
473         ! antidiffusive flux on k
474         zwz(:,:,1) = 0._wp        ! Surface value
475         zwz_sav(:,:,:) = zwz(:,:,:)
476         !
477         ztrs(:,:,:,1) = ptb(:,:,:,jn)
478         zwzts(:,:,:) = 0._wp
479
480         DO jl = 1, jnzts                   ! Start of sub timestepping loop
481
482            IF( jl == 1 ) THEN              ! Euler forward to kick things off
483              jtb = 1   ;   jtn = 1   ;   jta = 2
484              zts(:) = p2dt(:) * z_rzts
485              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
486                                            ! starting at jl =1 if jnzts is odd;
487                                            ! starting at jl =2 otherwise
488            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
489              jtb = 1   ;   jtn = 2   ;   jta = 3
490              zts(:) = 2._wp * p2dt(:) * z_rzts
491            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
492              jtb = MOD(jtb,3) + 1
493              jtn = MOD(jtn,3) + 1
494              jta = MOD(jta,3) + 1
495            ENDIF
496            DO jk = 2, jpkm1          ! Interior value
497               DO jj = 2, jpjm1
498                  DO ji = fs_2, fs_jpim1
499                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
500                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
501                  END DO
502               END DO
503            END DO
504
505            jtaken = MOD( jtaken + 1 , 2 )
506
507            DO jk = 2, jpkm1          ! Interior value
508               DO jj = 2, jpjm1
509                  DO ji = fs_2, fs_jpim1
510                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
511                     ! total advective trends
512                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
513                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
514                  END DO
515               END DO
516            END DO
517
518         END DO
519
520         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
521            DO jj = 2, jpjm1
522               DO ji = fs_2, fs_jpim1
523                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
524               END DO
525            END DO
526         END DO
527         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
528         CALL lbc_lnk( zwz, 'W',  1. )
529
530         ! 4. monotonicity algorithm
531         ! -------------------------
532         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
533
534
535         ! 5. final trend with corrected fluxes
536         ! ------------------------------------
537         DO jk = 1, jpkm1
538            DO jj = 2, jpjm1
539               DO ji = fs_2, fs_jpim1   ! vector opt. 
540                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
541                  ! total advective trends
542                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
543                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
544                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
545                  ! add them to the general tracer trends
546                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
547               END DO
548            END DO
549         END DO
550
551         !                                 ! trend diagnostics (contribution of upstream fluxes)
552         IF( l_trd )  THEN
553            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
554            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
555            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
556           
557            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
558            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
559            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
560         END IF
561         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
562         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
563           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
564           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
565         ENDIF
566         !
567      END DO
568      !
569                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
570                   CALL wrk_dealloc( jpi, jpj, jpk, kjpt+1, ztrs )
571                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
572      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
573      !
574      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
575      !
576   END SUBROUTINE tra_adv_tvd_zts
577
578   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
579      !!---------------------------------------------------------------------
580      !!                    ***  ROUTINE nonosc  ***
581      !!     
582      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
583      !!       scheme and the before field by a nonoscillatory algorithm
584      !!
585      !! **  Method  :   ... ???
586      !!       warning : pbef and paft must be masked, but the boundaries
587      !!       conditions on the fluxes are not necessary zalezak (1979)
588      !!       drange (1995) multi-dimensional forward-in-time and upstream-
589      !!       in-space based differencing for fluid
590      !!----------------------------------------------------------------------
591      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
592      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
593      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
594      !
595      INTEGER  ::   ji, jj, jk   ! dummy loop indices
596      INTEGER  ::   ikm1         ! local integer
597      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
598      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
599      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
600      !!----------------------------------------------------------------------
601      !
602      IF( nn_timing == 1 )  CALL timing_start('nonosc')
603      !
604      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
605      !
606      zbig  = 1.e+40_wp
607      zrtrn = 1.e-15_wp
608      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
609
610      ! Search local extrema
611      ! --------------------
612      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
613      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
614         &        paft * tmask - zbig * ( 1._wp - tmask )  )
615      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
616         &        paft * tmask + zbig * ( 1._wp - tmask )  )
617
618      DO jk = 1, jpkm1
619         ikm1 = MAX(jk-1,1)
620         z2dtt = p2dt(jk)
621         DO jj = 2, jpjm1
622            DO ji = fs_2, fs_jpim1   ! vector opt.
623
624               ! search maximum in neighbourhood
625               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
626                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
627                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
628                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
629
630               ! search minimum in neighbourhood
631               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
632                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
633                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
634                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
635
636               ! positive part of the flux
637               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
638                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
639                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
640
641               ! negative part of the flux
642               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
643                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
644                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
645
646               ! up & down beta terms
647               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
648               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
649               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
650            END DO
651         END DO
652      END DO
653      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
654
655      ! 3. monotonic flux in the i & j direction (paa & pbb)
656      ! ----------------------------------------
657      DO jk = 1, jpkm1
658         DO jj = 2, jpjm1
659            DO ji = fs_2, fs_jpim1   ! vector opt.
660               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
661               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
662               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
663               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
664
665               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
666               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
667               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
668               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
669
670      ! monotonic flux in the k direction, i.e. pcc
671      ! -------------------------------------------
672               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
673               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
674               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
675               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
676            END DO
677         END DO
678      END DO
679      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
680      !
681      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
682      !
683      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
684      !
685   END SUBROUTINE nonosc
686
687   !!======================================================================
688END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.