New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/UKMO/AMM15_v3_6_STABLE_package/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/UKMO/AMM15_v3_6_STABLE_package/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 8058

Last change on this file since 8058 was 8058, checked in by jgraham, 7 years ago

Clear keywords

File size: 10.1 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcrst          ! passive tracers restart
21   USE trcnam          ! Namelist read
22   USE trcini_cfc      ! CFC      initialisation
23   USE trcini_pisces   ! PISCES   initialisation
24   USE trcini_c14b     ! C14 bomb initialisation
25   USE trcini_my_trc   ! MY_TRC   initialisation
26   USE trcdta          ! initialisation from files
27   USE daymod          ! calendar manager
28   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
29   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
30   USE trcsub          ! variables to substep passive tracers
31   USE lib_mpp         ! distribued memory computing library
32   USE sbc_oce
33   USE trcice          ! tracers in sea ice
34 
35   IMPLICIT NONE
36   PRIVATE
37   
38   PUBLIC   trc_init   ! called by opa
39
40    !! * Substitutions
41#  include "domzgr_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48   
49   SUBROUTINE trc_init
50      !!---------------------------------------------------------------------
51      !!                     ***  ROUTINE trc_init  ***
52      !!
53      !! ** Purpose :   Initialization of the passive tracer fields
54      !!
55      !! ** Method  : - read namelist
56      !!              - control the consistancy
57      !!              - compute specific initialisations
58      !!              - set initial tracer fields (either read restart
59      !!                or read data or analytical formulation
60      !!---------------------------------------------------------------------
61      INTEGER ::   jk, jn, jl    ! dummy loop indices
62      CHARACTER (len=25) :: charout
63      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrcdta   ! 4D  workspace
64      !!---------------------------------------------------------------------
65      !
66      IF( nn_timing == 1 )   CALL timing_start('trc_init')
67      !
68      IF(lwp) WRITE(numout,*)
69      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
70      IF(lwp) WRITE(numout,*) '~~~~~~~'
71
72      CALL top_alloc()              ! allocate TOP arrays
73
74      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
75      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
76      IF( l_trcdm2dc .AND. lwp ) &
77         &   CALL ctl_warn(' Coupling with passive tracers and used of diurnal cycle. &
78         & Computation of a daily mean shortwave for some biogeochemical models) ')
79
80      IF( nn_cla == 1 )   &
81         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
82
83      CALL trc_nam      ! read passive tracers namelists
84      !
85      IF(lwp) WRITE(numout,*)
86      !
87      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
88      !
89      IF(lwp) WRITE(numout,*)
90                                                              ! masked grid volume
91      !                                                              ! masked grid volume
92      DO jk = 1, jpk
93         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
94      END DO
95      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
96      !                                                              ! total volume of the ocean
97      areatot = glob_sum( cvol(:,:,:) )
98
99      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
100      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
101      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
102      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
103
104      CALL trc_ice_ini                                 ! Tracers in sea ice
105
106      IF( lwp ) THEN
107         !
108         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
109         !
110      ENDIF
111
112      IF( ln_trcdta )      CALL trc_dta_init(jptra)
113
114
115      IF( ln_rsttr ) THEN
116        !
117        CALL trc_rst_read              ! restart from a file
118        !
119      ELSE
120        !
121        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
122            !
123            CALL wrk_alloc( jpi, jpj, jpk, ztrcdta )    ! Memory allocation
124            !
125            DO jn = 1, jptra
126               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
127                  jl = n_trc_index(jn) 
128                  CALL trc_dta( nit000, sf_trcdta(jl),rf_trfac(jl) )   ! read tracer data at nit000
129                  ztrcdta(:,:,:) = sf_trcdta(jl)%fnow(:,:,:)
130                  trn(:,:,:,jn) = ztrcdta(:,:,:) * tmask(:,:,:) 
131                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
132                     !                                                    (data used only for initialisation)
133                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
134                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
135                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
136                     !
137                  ENDIF
138               ENDIF
139            ENDDO
140            CALL wrk_dealloc( jpi, jpj, jpk, ztrcdta )
141        ENDIF
142        !
143        trb(:,:,:,:) = trn(:,:,:,:)
144        !
145      ENDIF
146 
147      tra(:,:,:,:) = 0._wp
148      IF( ln_zps .AND. .NOT. lk_c1d .AND. .NOT. ln_isfcav )   &              ! Partial steps: before horizontal gradient of passive
149        &    CALL zps_hde    ( nit000, jptra, trn, gtru, gtrv  )  ! Partial steps: before horizontal gradient
150      IF( ln_zps .AND. .NOT. lk_c1d .AND.       ln_isfcav )   &
151        &    CALL zps_hde_isf( nit000, jptra, trn, pgtu=gtru, pgtv=gtrv, pgtui=gtrui, pgtvi=gtrvi )       ! tracers at the bottom ocean level
152
153
154      !
155      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
156      !
157
158      trai(:) = 0._wp                                                   ! initial content of all tracers
159      DO jn = 1, jptra
160         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
161      END DO
162
163      IF(lwp) THEN               ! control print
164         WRITE(numout,*)
165         WRITE(numout,*)
166         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
167         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
168         WRITE(numout,*) '          *** Total inital content of all tracers '
169         WRITE(numout,*)
170         DO jn = 1, jptra
171            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
172         ENDDO
173         WRITE(numout,*)
174      ENDIF
175      IF(lwp) WRITE(numout,*)
176      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
177         CALL prt_ctl_trc_init
178         WRITE(charout, FMT="('ini ')")
179         CALL prt_ctl_trc_info( charout )
180         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
181      ENDIF
1829000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
183      !
184      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
185      !
186   END SUBROUTINE trc_init
187
188
189   SUBROUTINE top_alloc
190      !!----------------------------------------------------------------------
191      !!                     ***  ROUTINE top_alloc  ***
192      !!
193      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
194      !!----------------------------------------------------------------------
195      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
196      USE trc           , ONLY:   trc_alloc
197      USE trcnxt        , ONLY:   trc_nxt_alloc
198      USE trczdf        , ONLY:   trc_zdf_alloc
199      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
200#if defined key_trdmxl_trc 
201      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
202#endif
203      !
204      INTEGER :: ierr
205      !!----------------------------------------------------------------------
206      !
207      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
208      ierr = ierr + trc_alloc    ()
209      ierr = ierr + trc_nxt_alloc()
210      ierr = ierr + trc_zdf_alloc()
211      ierr = ierr + trd_trc_oce_alloc()
212#if defined key_trdmxl_trc 
213      ierr = ierr + trd_mxl_trc_alloc()
214#endif
215      !
216      IF( lk_mpp    )   CALL mpp_sum( ierr )
217      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
218      !
219   END SUBROUTINE top_alloc
220
221#else
222   !!----------------------------------------------------------------------
223   !!  Empty module :                                     No passive tracer
224   !!----------------------------------------------------------------------
225CONTAINS
226   SUBROUTINE trc_init                      ! Dummy routine   
227   END SUBROUTINE trc_init
228#endif
229
230   !!======================================================================
231END MODULE trcini
Note: See TracBrowser for help on using the repository browser.