New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim_2.F90 in branches/UKMO/AMM15_v3_6_STABLE_package_collate/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/AMM15_v3_6_STABLE_package_collate/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim_2.F90 @ 10236

Last change on this file since 10236 was 8058, checked in by jgraham, 7 years ago

Clear keywords

File size: 14.3 KB
Line 
1MODULE sbcice_lim_2
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim_2  ***
4   !! Surface module :  update surface ocean boundary condition over ice covered area using LIM sea-ice model
5   !! Sea-Ice model  :  LIM-2 Sea ice model time-stepping
6   !!======================================================================
7   !! History :  1.0   !  06-2006  (G. Madec)  from icestp_2.F90
8   !!            3.0   !  08-2008  (S. Masson, E. .... ) coupled interface
9   !!            3.3   !  05-2009  (G.Garric) addition of the lim2_evp case
10   !!----------------------------------------------------------------------
11#if defined key_lim2
12   !!----------------------------------------------------------------------
13   !!   'key_lim2' :                                    LIM-2 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   sbc_ice_lim_2   : sea-ice model time-stepping and update ocean sbc over ice-covered area
16   !!----------------------------------------------------------------------
17   USE oce              ! ocean dynamics and tracers
18   USE dom_oce          ! ocean space and time domain
19   USE ice_2
20   USE par_ice_2
21   USE iceini_2
22   USE dom_ice_2
23
24   USE sbc_oce          ! Surface boundary condition: ocean fields
25   USE sbc_ice          ! Surface boundary condition: ice   fields
26   USE sbcblk_core      ! Surface boundary condition: CORE bulk
27   USE sbcblk_clio      ! Surface boundary condition: CLIO bulk
28   USE sbccpl           ! Surface boundary condition: coupled interface
29   USE albedo
30
31   USE phycst           ! Define parameters for the routines
32   USE eosbn2           ! equation of state
33   USE limdyn_2
34   USE limtrp_2
35   USE limdmp_2
36   USE limthd_2
37   USE limsbc_2         ! sea surface boundary condition
38   USE limdia_2
39   USE limwri_2
40   USE limrst_2
41
42   USE c1d              ! 1D vertical configuration
43
44   USE lbclnk           ! lateral boundary condition - MPP link
45   USE lib_mpp          ! MPP library
46   USE wrk_nemo         ! work arrays
47   USE iom              ! I/O manager library
48   USE in_out_manager   ! I/O manager
49   USE prtctl           ! Print control
50
51# if defined key_agrif
52   USE agrif_ice
53   USE agrif_lim2_update
54# endif
55
56#if defined key_bdy 
57   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
58#endif
59
60   IMPLICIT NONE
61   PRIVATE
62
63   PUBLIC sbc_ice_lim_2 ! routine called by sbcmod.F90
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE sbc_ice_lim_2( kt, ksbc )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE sbc_ice_lim_2  ***
78      !!                   
79      !! ** Purpose :   update the ocean surface boundary condition via the
80      !!                Louvain la Neuve Sea Ice Model time stepping
81      !!
82      !! ** Method  :   ice model time stepping
83      !!              - call the ice dynamics routine
84      !!              - call the ice advection/diffusion routine
85      !!              - call the ice thermodynamics routine
86      !!              - call the routine that computes mass and
87      !!                heat fluxes at the ice/ocean interface
88      !!              - save the outputs
89      !!              - save the outputs for restart when necessary
90      !!
91      !! ** Action  : - time evolution of the LIM sea-ice model
92      !!              - update all sbc variables below sea-ice:
93      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
94      !!---------------------------------------------------------------------
95      INTEGER, INTENT(in) ::   kt      ! ocean time step
96      INTEGER, INTENT(in) ::   ksbc    ! type of sbc ( =3 CLIO bulk ; =4 CORE bulk ; =5 coupled )
97      !!
98      INTEGER  ::   ji, jj   ! dummy loop indices
99      REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_os   ! ice albedo under overcast sky
100      REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_cs   ! ice albedo under clear sky
101      REAL(wp), DIMENSION(:,:,:), POINTER :: zalb_ice  ! mean ice albedo
102      REAL(wp), DIMENSION(:,:,:), POINTER :: zsist     ! ice surface temperature (K)
103      REAL(wp), DIMENSION(:,:  ), POINTER :: zutau_ice, zvtau_ice 
104      !!----------------------------------------------------------------------
105
106      IF( kt == nit000 ) THEN
107         IF(lwp) WRITE(numout,*)
108         IF(lwp) WRITE(numout,*) 'sbc_ice_lim_2 : update ocean surface boudary condition' 
109         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM) time stepping'
110         !
111         CALL ice_init_2
112         !
113# if defined key_agrif
114         IF( .NOT. Agrif_Root() ) CALL Agrif_InitValues_cont_lim2   ! AGRIF: set the meshes
115# endif
116      ENDIF
117
118      !                                        !----------------------!
119      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only  !
120         !                                     !----------------------!
121# if defined key_agrif
122         IF( .NOT. Agrif_Root() ) lim_nbstep = MOD(lim_nbstep,Agrif_rhot()&
123         &*Agrif_PArent(nn_fsbc)/REAL(nn_fsbc)) + 1
124# endif
125
126         CALL wrk_alloc( jpi,jpj  , zutau_ice, zvtau_ice)
127         CALL wrk_alloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist )
128
129         !  Bulk Formulea !
130         !----------------!
131         ! ... mean surface ocean current at ice dynamics point
132         SELECT CASE( cp_ice_msh )
133         CASE( 'I' )                  !== B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
134            DO jj = 2, jpj
135               DO ji = 2, jpi   ! NO vector opt. possible
136                  u_oce(ji,jj) = 0.5_wp * ( ssu_m(ji-1,jj  ) * umask(ji-1,jj  ,1) &
137                     &                    + ssu_m(ji-1,jj-1) * umask(ji-1,jj-1,1) ) * tmu(ji,jj)
138                  v_oce(ji,jj) = 0.5_wp * ( ssv_m(ji  ,jj-1) * vmask(ji  ,jj-1,1) &
139                     &                    + ssv_m(ji-1,jj-1) * vmask(ji-1,jj-1,1) ) * tmu(ji,jj)
140               END DO
141            END DO
142            CALL lbc_lnk( u_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
143            CALL lbc_lnk( v_oce, 'I', -1. )   ! I-point (i.e. F-point with ice indices)
144            !
145         CASE( 'C' )                  !== C-grid ice dynamics :   U & V-points (same as ocean)
146            u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)                     ! mean surface ocean current at ice velocity point
147            v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
148            !
149         END SELECT
150
151         ! ... masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
152         CALL eos_fzp( sss_m(:,:), tfu(:,:) )
153         tfu(:,:) = tfu(:,:) + rt0
154
155         zsist (:,:,1) = sist (:,:) + rt0 * ( 1. - tmask(:,:,1) )
156
157         ! Ice albedo
158
159         CALL albedo_ice( zsist, reshape( hicif, (/jpi,jpj,1/) ), &
160                                 reshape( hsnif, (/jpi,jpj,1/) ), &
161                          zalb_cs, zalb_os )
162
163         SELECT CASE( ksbc )
164         CASE( jp_core , jp_purecpl )   ! CORE and COUPLED bulk formulations
165
166            ! albedo depends on cloud fraction because of non-linear spectral effects
167            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
168            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
169            ! (zalb_ice) is computed within the bulk routine
170
171         END SELECT
172
173         ! ... Sea-ice surface boundary conditions output from bulk formulae :
174         !     - utau_ice   ! surface ice stress i-component (I-point)   [N/m2]
175         !     - vtau_ice   ! surface ice stress j-component (I-point)   [N/m2]
176         !     - qns_ice    ! non solar heat flux over ice   (T-point)   [W/m2]
177         !     - qsr_ice    !     solar heat flux over ice   (T-point)   [W/m2]
178         !     - qla_ice    ! latent    heat flux over ice   (T-point)   [W/m2]
179         !     - dqns_ice   ! non solar heat sensistivity    (T-point)   [W/m2]
180         !     - dqla_ice   ! latent    heat sensistivity    (T-point)   [W/m2]
181         !     - tprecip    ! total precipitation            (T-point)   [Kg/m2/s]
182         !     - sprecip    ! solid precipitation            (T-point)   [Kg/m2/s]
183         !     - fr1_i0     ! 1sr fraction of qsr penetration in ice     [%]
184         !     - fr2_i0     ! 2nd fraction of qsr penetration in ice     [%]
185         !
186         SELECT CASE( ksbc )
187         CASE( jp_clio )           ! CLIO bulk formulation
188!           CALL blk_ice_clio( zsist, zalb_cs    , zalb_os    , zalb_ice   ,            &
189!              &                      utau_ice   , vtau_ice   , qns_ice    , qsr_ice,   &
190!              &                      qla_ice    , dqns_ice   , dqla_ice   ,            &
191!              &                      tprecip    , sprecip    ,                         &
192!              &                      fr1_i0     , fr2_i0     , cp_ice_msh , jpl  )
193            CALL blk_ice_clio_tau
194            CALL blk_ice_clio_flx( zsist, zalb_cs, zalb_os, zalb_ice )
195
196         CASE( jp_core )           ! CORE bulk formulation
197            CALL blk_ice_core_tau
198            CALL blk_ice_core_flx( zsist, zalb_ice )
199
200         CASE( jp_purecpl )            ! Coupled formulation : atmosphere-ice stress only (fluxes provided after ice dynamics)
201            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
202         END SELECT
203         
204         IF( ln_mixcpl) THEN
205            CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
206            utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
207            vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
208         ENDIF
209
210         CALL iom_put( 'utau_ice', utau_ice )     ! Wind stress over ice along i-axis at I-point
211         CALL iom_put( 'vtau_ice', vtau_ice )     ! Wind stress over ice along j-axis at I-point
212
213         IF(ln_ctl) THEN         ! print mean trends (used for debugging)
214            CALL prt_ctl_info( 'Ice Forcings ' )
215            CALL prt_ctl( tab2d_1=tprecip ,clinfo1=' sbc_ice_lim: precip  : ', tab2d_2=sprecip , clinfo2=' Snow    : ' )
216            CALL prt_ctl( tab2d_1=utau_ice,clinfo1=' sbc_ice_lim: utau_ice: ', tab2d_2=vtau_ice, clinfo2=' vtau_ice: ' )
217            CALL prt_ctl( tab2d_1=sst_m   ,clinfo1=' sbc_ice_lim: sst     : ', tab2d_2=sss_m   , clinfo2=' sss     : ' )
218            CALL prt_ctl( tab2d_1=u_oce   ,clinfo1=' sbc_ice_lim: u_io    : ', tab2d_2=v_oce   , clinfo2=' v_io    : ' )
219            CALL prt_ctl( tab2d_1=hsnif   ,clinfo1=' sbc_ice_lim: hsnif  1: ', tab2d_2=hicif   , clinfo2=' hicif   : ' )
220            CALL prt_ctl( tab2d_1=frld    ,clinfo1=' sbc_ice_lim: frld   1: ', tab2d_2=sist    , clinfo2=' sist    : ' )
221         ENDIF
222
223         ! ---------------- !
224         !  Ice model step  !
225         ! ---------------- !
226         numit = numit + nn_fsbc                           ! Ice model time step
227
228                           CALL lim_rst_opn_2  ( kt )  ! Open Ice restart file
229         IF( .NOT. lk_c1d ) THEN                       ! Ice dynamics & transport (except in 1D case)
230                           CALL lim_dyn_2      ( kt )      ! Ice dynamics    ( rheology/dynamics )
231                           CALL lim_trp_2      ( kt )      ! Ice transport   ( Advection/diffusion )
232           IF( ln_limdmp ) CALL lim_dmp_2      ( kt )      ! Ice damping
233#if defined key_bdy
234                           CALL bdy_ice_lim( kt ) ! bdy ice thermo
235#endif
236         END IF
237         !                                             ! Ice surface fluxes in coupled mode
238         IF( ln_cpl ) THEN   ! pure coupled and mixed forced-coupled configurations
239            a_i(:,:,1)=fr_i
240            CALL sbc_cpl_ice_flx( frld,                                              &
241            !                                optional arguments, used only in 'mixed oce-ice' case
242            &                                             palbi=zalb_ice, psst=sst_m, pist=zsist )
243            sprecip(:,:) = - emp_ice(:,:)   ! Ugly patch, WARNING, in coupled mode, sublimation included in snow (parsub = 0.)
244         ENDIF
245                           CALL lim_thd_2      ( kt )      ! Ice thermodynamics
246                           CALL lim_sbc_flx_2  ( kt )      ! update surface ocean mass, heat & salt fluxes
247
248         IF(  .NOT. lk_mpp )THEN
249            IF( MOD( kt+nn_fsbc-1, ninfo ) == 0 .OR. ntmoy == 1 )   &
250            &              CALL lim_dia_2      ( kt )      ! Ice Diagnostics
251         ENDIF
252# if ! defined key_iomput
253                           CALL lim_wri_2      ( kt )      ! Ice outputs
254# endif
255         IF( lrst_ice  )   CALL lim_rst_write_2( kt )      ! Ice restart file
256         !
257# if defined key_agrif && defined key_lim2
258         IF( .NOT. Agrif_Root() )   CALL agrif_update_lim2( kt )
259# endif
260         !
261         CALL wrk_dealloc( jpi,jpj  , zutau_ice, zvtau_ice)
262         CALL wrk_dealloc( jpi,jpj,1, zalb_os, zalb_cs, zalb_ice, zsist )
263         !
264      ENDIF                                    ! End sea-ice time step only
265      !
266      !                                        !--------------------------!
267      !                                        !  at all ocean time step  !
268      !                                        !--------------------------!
269      !                                               
270      !                                              ! Update surface ocean stresses (only in ice-dynamic case)
271      !                                                   ! otherwise the atm.-ocean stresses are used everywhere
272      IF( ln_limdyn    )   CALL lim_sbc_tau_2( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
273      !
274   END SUBROUTINE sbc_ice_lim_2
275
276#else
277   !!----------------------------------------------------------------------
278   !!   Default option           Dummy module      NO LIM 2.0 sea-ice model
279   !!----------------------------------------------------------------------
280CONTAINS
281   SUBROUTINE sbc_ice_lim_2 ( kt, ksbc )     ! Dummy routine
282      INTEGER, INTENT(in) ::   kt, ksbc   
283      WRITE(*,*) 'sbc_ice_lim_2: You should not have seen this print! error?', kt, ksbc
284   END SUBROUTINE sbc_ice_lim_2
285#endif
286
287   !!======================================================================
288END MODULE sbcice_lim_2
Note: See TracBrowser for help on using the repository browser.