New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/UKMO/AMM15_v3_6_STABLE_package_collate_BGC_DA/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/UKMO/AMM15_v3_6_STABLE_package_collate_BGC_DA/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 10574

Last change on this file since 10574 was 10574, checked in by dford, 5 years ago
Merge in functionality added to GO6 at r10149.
File size: 40.8 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!!----------------------------------------------------------------------
33
34	!!----------------------------------------------------------------------
35	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36	!! nemo_init : initialization of the NEMO system
37	!! nemo_ctl : initialisation of the contol print
38	!! nemo_closefile : close remaining open files
39	!! nemo_alloc : dynamical allocation
40	!! nemo_partition : calculate MPP domain decomposition
41	!! factorise : calculate the factors of the no. of MPI processes
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE bdyini ! open boundary cond. setting (bdy_init routine)
53	USE bdydta ! open boundary cond. setting (bdy_dta_init routine)
54	USE bdytides ! open boundary cond. setting (bdytide_init routine)
55	USE istate ! initial state setting (istate_init routine)
56	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
57	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
58	USE zdfini ! vertical physics setting (zdf_init routine)
59	USE phycst ! physical constant (par_cst routine)
60	USE trdini ! dyn/tra trends initialization (trd_init routine)
61	USE asminc ! assimilation increments
62	USE asmbkg ! writing out state trajectory
63	USE asmbgc ! biogeochemical assimilation increments
64	USE diaptr ! poleward transports (dia_ptr_init routine)
65	USE diadct ! sections transports (dia_dct_init routine)
66	USE diaobs ! Observation diagnostics (dia_obs_init routine)
67	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68	USE step ! NEMO time-stepping (stp routine)
69	USE icbini ! handle bergs, initialisation
70	USE icbstp ! handle bergs, calving, themodynamics and transport
71	USE cpl_oasis3 ! OASIS3 coupling
72	USE c1d ! 1D configuration
73	USE step_c1d ! Time stepping loop for the 1D configuration
74	USE dyndmp ! Momentum damping
75	#if defined key_top
76	USE trcini ! passive tracer initialisation
77	#endif
78	USE lib_mpp ! distributed memory computing
79	#if defined key_iomput
80	USE xios
81	#endif
82	USE sbctide, ONLY: lk_tide
83	USE crsini ! initialise grid coarsening utility
84	USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
85	USE sbc_oce, ONLY: lk_oasis
86	USE stopar
87	USE stopts
88	USE diatmb ! Top,middle,bottom output
89	USE dia25h ! 25h mean output
90	USE diaopfoam ! FOAM operational output
91	USE diurnal_bulk ! diurnal bulk SST
92
93	IMPLICIT NONE
94	PRIVATE
95
96	PUBLIC nemo_gcm ! called by model.F90
97	PUBLIC nemo_init ! needed by AGRIF
98	PUBLIC nemo_alloc ! needed by TAM
99
100	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
101
102	!!----------------------------------------------------------------------
103	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
104	!! $Id$
105	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
106	!!----------------------------------------------------------------------
107	CONTAINS
108
109	SUBROUTINE nemo_gcm
110	!!----------------------------------------------------------------------
111	!! * ROUTINE nemo_gcm *
112	!!
113	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
114	!! curvilinear mesh on the sphere.
115	!!
116	!! ** Method : - model general initialization
117	!! - launch the time-stepping (stp routine)
118	!! - finalize the run by closing files and communications
119	!!
120	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
121	!! Madec, 2008, internal report, IPSL.
122	!!----------------------------------------------------------------------
123	INTEGER :: istp ! time step index
124	!!----------------------------------------------------------------------
125	!
126	#if defined key_agrif
127	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
128	#endif
129
130	! !-----------------------!
131	CALL nemo_init !== Initialisations ==!
132	! !-----------------------!
133	#if defined key_agrif
134	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
135	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
136	# if defined key_top
137	CALL Agrif_Declare_Var_top ! " " " " " TOP
138	# endif
139	# if defined key_lim2
140	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
141	# endif
142	#endif
143	! check that all process are still there... If some process have an error,
144	! they will never enter in step and other processes will wait until the end of the cpu time!
145	IF( lk_mpp ) CALL mpp_max( nstop )
146
147	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
148
149	! !-----------------------!
150	! !== time stepping ==!
151	! !-----------------------!
152	istp = nit000
153	#if defined key_c1d
154	DO WHILE ( istp <= nitend .AND. nstop == 0 )
155	CALL stp_c1d( istp )
156	istp = istp + 1
157	END DO
158	#else
159	IF( lk_asminc ) THEN
160	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
161	IF( ln_asmdin ) THEN ! Direct initialization
162	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
163	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
164	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
165	IF( lk_bgcinc ) CALL bgc_asm_inc( nit000 - 1 ) ! BGC
166	ENDIF
167	ENDIF
168
169	#if defined key_agrif
170	CALL Agrif_Regrid()
171	#endif
172
173	DO WHILE ( istp <= nitend .AND. nstop == 0 )
174	#if defined key_agrif
175	CALL stp ! AGRIF: time stepping
176	#else
177	CALL stp( istp ) ! standard time stepping
178	#endif
179	istp = istp + 1
180	IF( lk_mpp ) CALL mpp_max( nstop )
181	END DO
182	#endif
183
184	IF( lk_diaobs ) CALL dia_obs_wri
185	!
186	IF( ( lk_asminc ).AND.( ln_balwri ) ) CALL asm_bgc_bal_wri( nitend ) ! Output balancing increments
187	!
188	IF( ln_icebergs ) CALL icb_end( nitend )
189
190	! !------------------------!
191	! !== finalize the run ==!
192	! !------------------------!
193	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
194	!
195	IF( nstop /= 0 .AND. lwp ) THEN ! error print
196	WRITE(numout,cform_err)
197	WRITE(numout,*) nstop, ' error have been found'
198	ENDIF
199	!
200	#if defined key_agrif
201	IF( .NOT. Agrif_Root() ) THEN
202	CALL Agrif_ParentGrid_To_ChildGrid()
203	IF( lk_diaobs ) CALL dia_obs_wri
204	IF( nn_timing == 1 ) CALL timing_finalize
205	CALL Agrif_ChildGrid_To_ParentGrid()
206	ENDIF
207	#endif
208	IF( nn_timing == 1 ) CALL timing_finalize
209	!
210	CALL nemo_closefile
211	!
212	#if defined key_iomput
213	CALL xios_finalize ! end mpp communications with xios
214	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
215	#else
216	IF( lk_oasis ) THEN
217	CALL cpl_finalize ! end coupling and mpp communications with OASIS
218	ELSE
219	IF( lk_mpp ) CALL mppstop ! end mpp communications
220	ENDIF
221	#endif
222	!
223	END SUBROUTINE nemo_gcm
224
225
226	SUBROUTINE nemo_init
227	!!----------------------------------------------------------------------
228	!! * ROUTINE nemo_init *
229	!!
230	!! ** Purpose : initialization of the NEMO GCM
231	!!----------------------------------------------------------------------
232	INTEGER :: ji ! dummy loop indices
233	INTEGER :: ilocal_comm ! local integer
234	INTEGER :: ios
235	CHARACTER(len=80), DIMENSION(16) :: cltxt
236	!
237	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
238	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
239	& nn_bench, nn_timing
240	NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
241	& jpizoom, jpjzoom, jperio, ln_use_jattr
242	!!----------------------------------------------------------------------
243	!
244	cltxt = ''
245	cxios_context = 'nemo'
246	!
247	! ! Open reference namelist and configuration namelist files
248	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
249	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
250	!
251	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
252	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
253	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
254
255	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
256	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
257	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
258
259	!
260	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark
261	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
262	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
263
264	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
265	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
266	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
267
268	! Force values for AGRIF zoom (cf. agrif_user.F90)
269	#if defined key_agrif
270	IF( .NOT. Agrif_Root() ) THEN
271	jpiglo = nbcellsx + 2 + 2*nbghostcells
272	jpjglo = nbcellsy + 2 + 2*nbghostcells
273	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
274	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
275	jpidta = jpiglo
276	jpjdta = jpjglo
277	jpizoom = 1
278	jpjzoom = 1
279	nperio = 0
280	jperio = 0
281	ln_use_jattr = .false.
282	ENDIF
283	#endif
284	!
285	! !--------------------------------------------!
286	! ! set communicator & select the local node !
287	! ! NB: mynode also opens output.namelist.dyn !
288	! ! on unit number numond on first proc !
289	! !--------------------------------------------!
290	#if defined key_iomput
291	IF( Agrif_Root() ) THEN
292	IF( lk_oasis ) THEN
293	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
294	CALL xios_initialize( "not used",local_comm=ilocal_comm ) ! send nemo communicator to xios
295	ELSE
296	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
297	ENDIF
298	ENDIF
299	! Nodes selection (control print return in cltxt)
300	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
301	#else
302	IF( lk_oasis ) THEN
303	IF( Agrif_Root() ) THEN
304	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
305	ENDIF
306	! Nodes selection (control print return in cltxt)
307	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
308	ELSE
309	ilocal_comm = 0
310	! Nodes selection (control print return in cltxt)
311	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
312	ENDIF
313	#endif
314	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
315
316	lwm = (narea == 1) ! control of output namelists
317	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
318
319	IF(lwm) THEN
320	! write merged namelists from earlier to output namelist now that the
321	! file has been opened in call to mynode. nammpp has already been
322	! written in mynode (if lk_mpp_mpi)
323	WRITE( numond, namctl )
324	WRITE( numond, namcfg )
325	ENDIF
326
327	! If dimensions of processor grid weren't specified in the namelist file
328	! then we calculate them here now that we have our communicator size
329	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
330	#if defined key_mpp_mpi
331	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
332	#else
333	jpni = 1
334	jpnj = 1
335	jpnij = jpni*jpnj
336	#endif
337	END IF
338
339	! Calculate domain dimensions given calculated jpni and jpnj
340	! This used to be done in par_oce.F90 when they were parameters rather
341	! than variables
342	IF( Agrif_Root() ) THEN
343	#if defined key_nemocice_decomp
344	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
345	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
346	#else
347	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
348	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
349	#endif
350	ENDIF
351	jpk = jpkdta ! third dim
352	#if defined key_agrif
353	! simple trick to use same vertical grid as parent
354	! but different number of levels:
355	! Save maximum number of levels in jpkdta, then define all vertical grids
356	! with this number.
357	! Suppress once vertical online interpolation is ok
358	IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
359	#endif
360	jpim1 = jpi-1 ! inner domain indices
361	jpjm1 = jpj-1 ! " "
362	jpkm1 = jpk-1 ! " "
363	jpij = jpi*jpj ! jpi x j
364
365	IF(lwp) THEN ! open listing units
366	!
367	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
368	!
369	WRITE(numout,*)
370	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
371	WRITE(numout,*) ' NEMO team'
372	WRITE(numout,*) ' Ocean General Circulation Model'
373	WRITE(numout,*) ' version 3.6 (2015) '
374	WRITE(numout,*)
375	WRITE(numout,*)
376	DO ji = 1, SIZE(cltxt)
377	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
378	END DO
379	WRITE(numout,cform_aaa) ! Flag AAAAAAA
380	!
381	ENDIF
382
383	! Now we know the dimensions of the grid and numout has been set we can
384	! allocate arrays
385	CALL nemo_alloc()
386
387	! !-------------------------------!
388	! ! NEMO general initialization !
389	! !-------------------------------!
390
391	CALL nemo_ctl ! Control prints & Benchmark
392
393	! ! Domain decomposition
394	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
395	ELSE ; CALL mpp_init2 ! eliminate land processors
396	ENDIF
397	!
398	IF( nn_timing == 1 ) CALL timing_init
399	!
400	! ! General initialization
401	CALL phy_cst ! Physical constants
402	CALL eos_init ! Equation of state
403	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
404	CALL dom_cfg ! Domain configuration
405	CALL dom_init ! Domain
406
407	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
408
409	IF( ln_ctl ) CALL prt_ctl_init ! Print control
410
411	CALL istate_init ! ocean initial state (Dynamics and tracers)
412
413	CALL diurnal_sst_bulk_init ! diurnal sst
414	IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin
415
416	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
417
418	CALL sbc_init ! Forcings : surface module (clem: moved here for bdy purpose)
419
420	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
421	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
422	IF( lk_bdy .AND. lk_tide ) &
423	& CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
424
425	CALL dyn_nept_init ! simplified form of Neptune effect
426	!
427	IF( ln_crs ) CALL crs_init ! Domain initialization of coarsened grid
428	!
429	! Ocean physics
430	! ! Vertical physics
431	CALL zdf_init ! namelist read
432	CALL zdf_bfr_init ! bottom friction
433	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
434	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
435	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
436	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
437	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
438	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
439	& CALL zdf_ddm_init ! double diffusive mixing
440	! ! Lateral physics
441	CALL ldf_tra_init ! Lateral ocean tracer physics
442	CALL ldf_dyn_init ! Lateral ocean momentum physics
443	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
444
445	! ! Active tracers
446	CALL tra_qsr_init ! penetrative solar radiation qsr
447	CALL tra_bbc_init ! bottom heat flux
448	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
449	CALL tra_dmp_init ! internal damping trends- tracers
450	CALL tra_adv_init ! horizontal & vertical advection
451	CALL tra_ldf_init ! lateral mixing
452	CALL tra_zdf_init ! vertical mixing and after tracer fields
453
454	! ! Dynamics
455	IF( lk_c1d ) CALL dyn_dmp_init ! internal damping trends- momentum
456	CALL dyn_adv_init ! advection (vector or flux form)
457	CALL dyn_vor_init ! vorticity term including Coriolis
458	CALL dyn_ldf_init ! lateral mixing
459	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
460	CALL dyn_zdf_init ! vertical diffusion
461	CALL dyn_spg_init ! surface pressure gradient
462
463	! ! Misc. options
464	IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 ) CALL cla_init ! Cross Land Advection
465	CALL icb_init( rdt, nit000) ! initialise icebergs instance
466	CALL sto_par_init ! Stochastic parametrization
467	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
468
469	#if defined key_top
470	! ! Passive tracers
471	CALL trc_init
472	#endif
473	! ! Diagnostics
474	IF( lk_floats ) CALL flo_init ! drifting Floats
475	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
476	CALL dia_ptr_init ! Poleward TRansports initialization
477	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
478	CALL dia_hsb_init ! heat content, salt content and volume budgets
479	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
480	IF( lk_diaobs ) THEN ! Observation & model comparison
481	CALL dia_obs_init ! Initialize observational data
482	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
483	ENDIF
484
485	! ! Assimilation increments
486	IF( lk_asminc ) THEN
487	#if defined key_shelf
488	CALL zdf_mxl_tref() ! Initialization of hmld_tref
489	#endif
490	CALL asm_inc_init ! Initialize assimilation increments
491	ENDIF
492
493	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
494	CALL dia_tmb_init ! TMB outputs
495	CALL dia_25h_init ! 25h mean outputs
496	CALL dia_diaopfoam_init ! FOAM operational output
497	!
498	END SUBROUTINE nemo_init
499
500
501	SUBROUTINE nemo_ctl
502	!!----------------------------------------------------------------------
503	!! * ROUTINE nemo_ctl *
504	!!
505	!! ** Purpose : control print setting
506	!!
507	!! ** Method : - print namctl information and check some consistencies
508	!!----------------------------------------------------------------------
509	!
510	IF(lwp) THEN ! control print
511	WRITE(numout,*)
512	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
513	WRITE(numout,*) '~~~~~~~ '
514	WRITE(numout,*) ' Namelist namctl'
515	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
516	WRITE(numout,*) ' level of print nn_print = ', nn_print
517	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
518	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
519	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
520	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
521	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
522	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
523	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
524	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
525	ENDIF
526	!
527	nprint = nn_print ! convert DOCTOR namelist names into OLD names
528	nictls = nn_ictls
529	nictle = nn_ictle
530	njctls = nn_jctls
531	njctle = nn_jctle
532	isplt = nn_isplt
533	jsplt = nn_jsplt
534	nbench = nn_bench
535
536	IF(lwp) THEN ! control print
537	WRITE(numout,*)
538	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
539	WRITE(numout,*) '~~~~~~~ '
540	WRITE(numout,*) ' Namelist namcfg'
541	WRITE(numout,*) ' configuration name cp_cfg = ', TRIM(cp_cfg)
542	WRITE(numout,*) ' configuration zoom name cp_cfz = ', TRIM(cp_cfz)
543	WRITE(numout,*) ' configuration resolution jp_cfg = ', jp_cfg
544	WRITE(numout,*) ' 1st lateral dimension ( >= jpi ) jpidta = ', jpidta
545	WRITE(numout,*) ' 2nd " " ( >= jpj ) jpjdta = ', jpjdta
546	WRITE(numout,*) ' 3nd " " jpkdta = ', jpkdta
547	WRITE(numout,*) ' 1st dimension of global domain in i jpiglo = ', jpiglo
548	WRITE(numout,*) ' 2nd - - in j jpjglo = ', jpjglo
549	WRITE(numout,*) ' left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
550	WRITE(numout,*) ' left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
551	WRITE(numout,*) ' lateral cond. type (between 0 and 6) jperio = ', jperio
552	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
553	ENDIF
554	! ! Parameter control
555	!
556	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
557	IF( lk_mpp .AND. jpnij > 1 ) THEN
558	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
559	ELSE
560	IF( isplt == 1 .AND. jsplt == 1 ) THEN
561	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
562	& ' - the print control will be done over the whole domain' )
563	ENDIF
564	ijsplt = isplt * jsplt ! total number of processors ijsplt
565	ENDIF
566	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
567	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
568	!
569	! ! indices used for the SUM control
570	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
571	lsp_area = .FALSE.
572	ELSE ! print control done over a specific area
573	lsp_area = .TRUE.
574	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
575	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
576	nictls = 1
577	ENDIF
578	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
579	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
580	nictle = jpiglo
581	ENDIF
582	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
583	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
584	njctls = 1
585	ENDIF
586	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
587	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
588	njctle = jpjglo
589	ENDIF
590	ENDIF
591	ENDIF
592	!
593	IF( nbench == 1 ) THEN ! Benchmark
594	SELECT CASE ( cp_cfg )
595	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
596	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
597	& ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
598	END SELECT
599	ENDIF
600	!
601	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
602	& 'f2003 standard. ' , &
603	& 'Compile with key_nosignedzero enabled' )
604	!
605	END SUBROUTINE nemo_ctl
606
607
608	SUBROUTINE nemo_closefile
609	!!----------------------------------------------------------------------
610	!! * ROUTINE nemo_closefile *
611	!!
612	!! ** Purpose : Close the files
613	!!----------------------------------------------------------------------
614	!
615	IF( lk_mpp ) CALL mppsync
616	!
617	CALL iom_close ! close all input/output files managed by iom_*
618	!
619	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
620	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
621	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
622	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
623	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
624	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
625	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
626	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
627	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
628	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
629	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
630	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
631	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
632
633	!
634	numout = 6 ! redefine numout in case it is used after this point...
635	!
636	END SUBROUTINE nemo_closefile
637
638
639	SUBROUTINE nemo_alloc
640	!!----------------------------------------------------------------------
641	!! * ROUTINE nemo_alloc *
642	!!
643	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
644	!!
645	!! ** Method :
646	!!----------------------------------------------------------------------
647	USE diawri , ONLY: dia_wri_alloc
648	USE dom_oce , ONLY: dom_oce_alloc
649	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
650	USE ldftra_oce, ONLY: ldftra_oce_alloc
651	USE trc_oce , ONLY: trc_oce_alloc
652	USE diainsitutem, ONLY: insitu_tem_alloc
653	#if defined key_diadct
654	USE diadct , ONLY: diadct_alloc
655	#endif
656	#if defined key_bdy
657	USE bdy_oce , ONLY: bdy_oce_alloc
658	#endif
659	!
660	INTEGER :: ierr
661	!!----------------------------------------------------------------------
662	!
663	ierr = oce_alloc () ! ocean
664	ierr = ierr + dia_wri_alloc ()
665	ierr = ierr + dom_oce_alloc () ! ocean domain
666	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
667	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
668	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
669	ierr = ierr + insitu_tem_alloc()
670	!
671	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
672	!
673	#if defined key_diadct
674	ierr = ierr + diadct_alloc () !
675	#endif
676	#if defined key_bdy
677	ierr = ierr + bdy_oce_alloc () ! bdy masks (incl. initialization)
678	#endif
679	!
680	IF( lk_mpp ) CALL mpp_sum( ierr )
681	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
682	!
683	END SUBROUTINE nemo_alloc
684
685
686	SUBROUTINE nemo_partition( num_pes )
687	!!----------------------------------------------------------------------
688	!! * ROUTINE nemo_partition *
689	!!
690	!! ** Purpose :
691	!!
692	!! ** Method :
693	!!----------------------------------------------------------------------
694	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
695	!
696	INTEGER, PARAMETER :: nfactmax = 20
697	INTEGER :: nfact ! The no. of factors returned
698	INTEGER :: ierr ! Error flag
699	INTEGER :: ji
700	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
701	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
702	!!----------------------------------------------------------------------
703	!
704	ierr = 0
705	!
706	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
707	!
708	IF( nfact <= 1 ) THEN
709	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
710	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
711	jpnj = 1
712	jpni = num_pes
713	ELSE
714	! Search through factors for the pair that are closest in value
715	mindiff = 1000000
716	imin = 1
717	DO ji = 1, nfact-1, 2
718	idiff = ABS( ifact(ji) - ifact(ji+1) )
719	IF( idiff < mindiff ) THEN
720	mindiff = idiff
721	imin = ji
722	ENDIF
723	END DO
724	jpnj = ifact(imin)
725	jpni = ifact(imin + 1)
726	ENDIF
727	!
728	jpnij = jpni*jpnj
729	!
730	END SUBROUTINE nemo_partition
731
732
733	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
734	!!----------------------------------------------------------------------
735	!! * ROUTINE factorise *
736	!!
737	!! ** Purpose : return the prime factors of n.
738	!! knfax factors are returned in array kfax which is of
739	!! maximum dimension kmaxfax.
740	!! ** Method :
741	!!----------------------------------------------------------------------
742	INTEGER , INTENT(in ) :: kn, kmaxfax
743	INTEGER , INTENT( out) :: kerr, knfax
744	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
745	!
746	INTEGER :: ifac, jl, inu
747	INTEGER, PARAMETER :: ntest = 14
748	INTEGER, DIMENSION(ntest) :: ilfax
749	!
750	! ilfax contains the set of allowed factors.
751	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
752	!!----------------------------------------------------------------------
753	! ilfax contains the set of allowed factors.
754	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
755
756	! Clear the error flag and initialise output vars
757	kerr = 0
758	kfax = 1
759	knfax = 0
760
761	! Find the factors of n.
762	IF( kn == 1 ) GOTO 20
763
764	! nu holds the unfactorised part of the number.
765	! knfax holds the number of factors found.
766	! l points to the allowed factor list.
767	! ifac holds the current factor.
768
769	inu = kn
770	knfax = 0
771
772	DO jl = ntest, 1, -1
773	!
774	ifac = ilfax(jl)
775	IF( ifac > inu ) CYCLE
776
777	! Test whether the factor will divide.
778
779	IF( MOD(inu,ifac) == 0 ) THEN
780	!
781	knfax = knfax + 1 ! Add the factor to the list
782	IF( knfax > kmaxfax ) THEN
783	kerr = 6
784	write (,) 'FACTOR: insufficient space in factor array ', knfax
785	return
786	ENDIF
787	kfax(knfax) = ifac
788	! Store the other factor that goes with this one
789	knfax = knfax + 1
790	kfax(knfax) = inu / ifac
791	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
792	ENDIF
793	!
794	END DO
795
796	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
797	!
798	END SUBROUTINE factorise
799
800	#if defined key_mpp_mpi
801
802	SUBROUTINE nemo_northcomms
803	!!======================================================================
804	!! * ROUTINE nemo_northcomms *
805	!! nemo_northcomms : Setup for north fold exchanges with explicit
806	!! point-to-point messaging
807	!!=====================================================================
808	!!----------------------------------------------------------------------
809	!!
810	!! ** Purpose : Initialization of the northern neighbours lists.
811	!!----------------------------------------------------------------------
812	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
813	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
814	!!----------------------------------------------------------------------
815
816	INTEGER :: sxM, dxM, sxT, dxT, jn
817	INTEGER :: njmppmax
818
819	njmppmax = MAXVAL( njmppt )
820
821	!initializes the north-fold communication variables
822	isendto(:) = 0
823	nsndto = 0
824
825	!if I am a process in the north
826	IF ( njmpp == njmppmax ) THEN
827	!sxM is the first point (in the global domain) needed to compute the
828	!north-fold for the current process
829	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
830	!dxM is the last point (in the global domain) needed to compute the
831	!north-fold for the current process
832	dxM = jpiglo - nimppt(narea) + 2
833
834	!loop over the other north-fold processes to find the processes
835	!managing the points belonging to the sxT-dxT range
836
837	DO jn = 1, jpni
838	!sxT is the first point (in the global domain) of the jn
839	!process
840	sxT = nfiimpp(jn, jpnj)
841	!dxT is the last point (in the global domain) of the jn
842	!process
843	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
844	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
845	nsndto = nsndto + 1
846	isendto(nsndto) = jn
847	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
848	nsndto = nsndto + 1
849	isendto(nsndto) = jn
850	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
851	nsndto = nsndto + 1
852	isendto(nsndto) = jn
853	END IF
854	END DO
855	nfsloop = 1
856	nfeloop = nlci
857	DO jn = 2,jpni-1
858	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
859	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
860	nfsloop = nldi
861	ENDIF
862	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
863	nfeloop = nlei
864	ENDIF
865	ENDIF
866	END DO
867
868	ENDIF
869	l_north_nogather = .TRUE.
870	END SUBROUTINE nemo_northcomms
871	#else
872	SUBROUTINE nemo_northcomms ! Dummy routine
873	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
874	END SUBROUTINE nemo_northcomms
875	#endif
876
877	!!======================================================================
878	END MODULE nemogcm
879
880

Note: See TracBrowser for help on using the repository browser.

Download in other formats: