1 | MODULE trcsms_fabm |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE trcsms_fabm *** |
---|
4 | !! TOP : Main module of the FABM tracers |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2015-04 (PML) Original code |
---|
7 | !! History : 1.1 ! 2020-06 (PML) Update to FABM 1.0, improved performance |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | #if defined key_fabm |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_fabm' FABM tracers |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! trc_sms_fabm : FABM model main routine |
---|
14 | !! trc_sms_fabm_alloc : allocate arrays specific to FABM sms |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE par_trc ! TOP parameters |
---|
17 | USE oce_trc ! Ocean variables |
---|
18 | USE trc ! TOP variables |
---|
19 | USE trcbc |
---|
20 | USE trd_oce |
---|
21 | USE trdtrc |
---|
22 | USE traqsr,only: ln_qsr_spec |
---|
23 | #if defined key_trdtrc && defined key_iomput |
---|
24 | USE trdtrc_oce |
---|
25 | #endif |
---|
26 | |
---|
27 | USE oce, only: tsn ! Needed? |
---|
28 | USE sbc_oce, only: lk_oasis,fr_i |
---|
29 | USE dom_oce |
---|
30 | USE zdf_oce |
---|
31 | USE iom |
---|
32 | USE xios |
---|
33 | USE cpl_oasis3 |
---|
34 | USE st2D_fabm |
---|
35 | USE inputs_fabm |
---|
36 | USE vertical_movement_fabm |
---|
37 | USE zdfmxl |
---|
38 | USE asmbgc, ONLY: mld_choice_bgc |
---|
39 | USE lbclnk |
---|
40 | USE fabm_types, ONLY: standard_variables |
---|
41 | USE par_fabm, ONLY: jp_fabm_swr |
---|
42 | |
---|
43 | !USE fldread ! time interpolation |
---|
44 | |
---|
45 | IMPLICIT NONE |
---|
46 | |
---|
47 | # include "domzgr_substitute.h90" |
---|
48 | # include "vectopt_loop_substitute.h90" |
---|
49 | |
---|
50 | PRIVATE |
---|
51 | |
---|
52 | PUBLIC trc_sms_fabm ! called by trcsms.F90 module |
---|
53 | PUBLIC trc_sms_fabm_alloc ! called by trcini_fabm.F90 module |
---|
54 | PUBLIC trc_sms_fabm_check_mass ! called by trcwri_fabm.F90 |
---|
55 | PUBLIC nemo_fabm_start |
---|
56 | |
---|
57 | ! Work arrays |
---|
58 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: flux ! Cross-interface flux of pelagic variables (# m-2 s-1) |
---|
59 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: current_total ! Totals of conserved quantities |
---|
60 | |
---|
61 | ! Arrays for environmental variables that are computed by the coupler |
---|
62 | REAL(wp), PUBLIC, TARGET, ALLOCATABLE, DIMENSION(:,:,:) :: prn,rho |
---|
63 | REAL(wp), PUBLIC, TARGET, ALLOCATABLE, DIMENSION(:,:) :: taubot |
---|
64 | REAL(wp), PUBLIC, TARGET :: daynumber_in_year |
---|
65 | |
---|
66 | ! State repair counters |
---|
67 | INTEGER, SAVE :: repair_interior_count = 0 |
---|
68 | INTEGER, SAVE :: repair_surface_count = 0 |
---|
69 | INTEGER, SAVE :: repair_bottom_count = 0 |
---|
70 | |
---|
71 | ! Coupler parameters |
---|
72 | INTEGER, PUBLIC :: nn_adv ! Vertical advection scheme for sinking/floating/movement |
---|
73 | ! (1: 1st order upwind, 3: 3rd order TVD) |
---|
74 | |
---|
75 | ! Flag indicating whether model%start has been called (will be done on-demand) |
---|
76 | LOGICAL, SAVE :: started = .false. |
---|
77 | |
---|
78 | !!---------------------------------------------------------------------- |
---|
79 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
80 | !! $Id$ |
---|
81 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
82 | !!---------------------------------------------------------------------- |
---|
83 | CONTAINS |
---|
84 | |
---|
85 | SUBROUTINE trc_sms_fabm( kt ) |
---|
86 | !!---------------------------------------------------------------------- |
---|
87 | !! *** trc_sms_fabm *** |
---|
88 | !! |
---|
89 | !! ** Purpose : main routine of FABM model |
---|
90 | !! |
---|
91 | !! ** Method : - |
---|
92 | !!---------------------------------------------------------------------- |
---|
93 | ! |
---|
94 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
---|
95 | INTEGER :: jn, jk |
---|
96 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrfabm, pdat |
---|
97 | REAL(wp), DIMENSION(jpi,jpj) :: vint |
---|
98 | |
---|
99 | !!---------------------------------------------------------------------- |
---|
100 | ! |
---|
101 | IF( nn_timing == 1 ) CALL timing_start('trc_sms_fabm') |
---|
102 | ! |
---|
103 | IF(lwp) WRITE(numout,*) |
---|
104 | IF(lwp) WRITE(numout,'(a,i0,a,i4.4,a,i2.2,a,i2.2,a,i5,a)') & |
---|
105 | ' trc_sms_fabm: FABM model, iteration ',kt,' ', & |
---|
106 | nyear,'-',nmonth,'-',nday,' ',nsec_day," secs" |
---|
107 | IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~' |
---|
108 | |
---|
109 | IF (.NOT. started) CALL nemo_fabm_start |
---|
110 | |
---|
111 | CALL update_inputs( kt ) |
---|
112 | |
---|
113 | CALL compute_fabm( kt ) |
---|
114 | |
---|
115 | CALL compute_vertical_movement( kt, nn_adv ) |
---|
116 | |
---|
117 | CALL st2d_fabm_nxt( kt ) |
---|
118 | |
---|
119 | CALL asmdiags_fabm( kt ) |
---|
120 | |
---|
121 | IF( l_trdtrc ) CALL wrk_alloc( jpi, jpj, jpk, ztrfabm ) |
---|
122 | |
---|
123 | CALL trc_bc_read ( kt ) ! tracers: surface and lateral Boundary Conditions |
---|
124 | CALL trc_rnf_fabm ( kt ) ! River forcings |
---|
125 | |
---|
126 | ! Send 3D diagnostics to output (these apply to time "n") |
---|
127 | DO jn = 1, size(model%interior_diagnostic_variables) |
---|
128 | IF (model%interior_diagnostic_variables(jn)%save) THEN |
---|
129 | ! Save 3D field |
---|
130 | pdat => model%get_interior_diagnostic_data(jn) |
---|
131 | CALL iom_put(model%interior_diagnostic_variables(jn)%name, pdat) |
---|
132 | |
---|
133 | ! Save depth integral if selected for output in XIOS |
---|
134 | IF (iom_use(TRIM(model%interior_diagnostic_variables(jn)%name)//'_VINT')) THEN |
---|
135 | vint = 0._wp |
---|
136 | DO jk = 1, jpkm1 |
---|
137 | vint = vint + pdat(:,:,jk) * fse3t(:,:,jk) * tmask(:,:,jk) |
---|
138 | END DO |
---|
139 | CALL iom_put(TRIM(model%interior_diagnostic_variables(jn)%name)//'_VINT', vint) |
---|
140 | END IF |
---|
141 | END IF |
---|
142 | END DO |
---|
143 | |
---|
144 | ! Send 2D diagnostics to output (these apply to time "n") |
---|
145 | DO jn = 1, size(model%horizontal_diagnostic_variables) |
---|
146 | IF (model%horizontal_diagnostic_variables(jn)%save) & |
---|
147 | CALL iom_put( model%horizontal_diagnostic_variables(jn)%name, model%get_horizontal_diagnostic_data(jn)) |
---|
148 | END DO |
---|
149 | |
---|
150 | IF( l_trdtrc ) THEN ! Save the trends in the mixed layer |
---|
151 | DO jn = jp_fabm0, jp_fabm1 |
---|
152 | ztrfabm(:,:,:) = tra(:,:,:,jn) |
---|
153 | CALL trd_trc( ztrfabm, jn, jptra_sms, kt ) ! save trends |
---|
154 | END DO |
---|
155 | CALL wrk_dealloc( jpi, jpj, jpk, ztrfabm ) |
---|
156 | END IF |
---|
157 | ! |
---|
158 | IF( nn_timing == 1 ) CALL timing_stop('trc_sms_fabm') |
---|
159 | |
---|
160 | END SUBROUTINE trc_sms_fabm |
---|
161 | |
---|
162 | SUBROUTINE asmdiags_fabm( kt ) |
---|
163 | INTEGER, INTENT(IN) :: kt |
---|
164 | INTEGER :: ji,jj,jk,jkmax |
---|
165 | REAL(wp), DIMENSION(jpi,jpj) :: zmld |
---|
166 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: pgrow_3d, ploss_3d |
---|
167 | |
---|
168 | IF (kt == nittrc000) THEN |
---|
169 | MLD_MAX(:,:) = 0.0 |
---|
170 | ENDIF |
---|
171 | PGROW_AVG(:,:) = 0.0 |
---|
172 | PLOSS_AVG(:,:) = 0.0 |
---|
173 | PHYT_AVG(:,:) = 0.0 |
---|
174 | |
---|
175 | pgrow_3d(:,:,:) = model%get_interior_diagnostic_data(jp_fabm_pgrow) |
---|
176 | ploss_3d(:,:,:) = model%get_interior_diagnostic_data(jp_fabm_ploss) |
---|
177 | |
---|
178 | SELECT CASE( mld_choice_bgc ) |
---|
179 | CASE ( 1 ) ! Turbocline/mixing depth [W points] |
---|
180 | zmld(:,:) = hmld(:,:) |
---|
181 | CASE ( 2 ) ! Density criterion (0.01 kg/m^3 change from 10m) [W points] |
---|
182 | zmld(:,:) = hmlp(:,:) |
---|
183 | CASE ( 3 ) ! Kara MLD [Interpolated] |
---|
184 | #if defined key_karaml |
---|
185 | IF ( ln_kara ) THEN |
---|
186 | zmld(:,:) = hmld_kara(:,:) |
---|
187 | ELSE |
---|
188 | CALL ctl_stop( ' Kara mixed layer requested for BGC assimilation,', & |
---|
189 | & ' but ln_kara=.false.' ) |
---|
190 | ENDIF |
---|
191 | #else |
---|
192 | CALL ctl_stop( ' Kara mixed layer requested for BGC assimilation,', & |
---|
193 | & ' but is not defined' ) |
---|
194 | #endif |
---|
195 | CASE ( 4 ) ! Temperature criterion (0.2 K change from surface) [T points] |
---|
196 | zmld(:,:) = hmld_tref(:,:) |
---|
197 | CASE ( 5 ) ! Density criterion (0.01 kg/m^3 change from 10m) [T points] |
---|
198 | zmld(:,:) = hmlpt(:,:) |
---|
199 | END SELECT |
---|
200 | |
---|
201 | DO jj = 2, jpjm1 |
---|
202 | DO ji = 2, jpim1 |
---|
203 | ! |
---|
204 | jkmax = jpk-1 |
---|
205 | DO jk = jpk-1, 1, -1 |
---|
206 | IF ( ( zmld(ji,jj) > gdepw_n(ji,jj,jk) ) .AND. & |
---|
207 | & ( zmld(ji,jj) <= gdepw_n(ji,jj,jk+1) ) ) THEN |
---|
208 | zmld(ji,jj) = gdepw_n(ji,jj,jk+1) |
---|
209 | jkmax = jk |
---|
210 | ENDIF |
---|
211 | END DO |
---|
212 | ! |
---|
213 | DO jk = 1, jkmax |
---|
214 | PHYT_AVG(ji,jj) = PHYT_AVG(ji,jj) + & |
---|
215 | & trn(ji,jj,jk,jp_fabm_m1+jp_fabm_p1n) + & |
---|
216 | & trn(ji,jj,jk,jp_fabm_m1+jp_fabm_p2n) + & |
---|
217 | & trn(ji,jj,jk,jp_fabm_m1+jp_fabm_p3n) + & |
---|
218 | & trn(ji,jj,jk,jp_fabm_m1+jp_fabm_p4n) |
---|
219 | IF ( pgrow_3d(ji,jj,jk) .GT. 0.0 ) THEN |
---|
220 | PGROW_AVG(ji,jj) = PGROW_AVG(ji,jj) + & |
---|
221 | & pgrow_3d(ji,jj,jk) |
---|
222 | ENDIF |
---|
223 | IF ( ploss_3d(ji,jj,jk) .GT. 0.0 ) THEN |
---|
224 | PLOSS_AVG(ji,jj) = PLOSS_AVG(ji,jj) + & |
---|
225 | & ploss_3d(ji,jj,jk) |
---|
226 | ENDIF |
---|
227 | END DO |
---|
228 | |
---|
229 | PHYT_AVG(ji,jj) = PHYT_AVG(ji,jj) / REAL(jkmax) |
---|
230 | PGROW_AVG(ji,jj) = PGROW_AVG(ji,jj) / REAL(jkmax) |
---|
231 | PLOSS_AVG(ji,jj) = PLOSS_AVG(ji,jj) / REAL(jkmax) |
---|
232 | |
---|
233 | IF ( zmld(ji,jj) .GT. MLD_MAX(ji,jj) ) THEN |
---|
234 | MLD_MAX(ji,jj) = zmld(ji,jj) |
---|
235 | ENDIF |
---|
236 | ! |
---|
237 | END DO |
---|
238 | END DO |
---|
239 | |
---|
240 | PHYT_AVG(:,:) = PHYT_AVG(:,:) * tmask(:,:,1) |
---|
241 | PGROW_AVG(:,:) = PGROW_AVG(:,:) * tmask(:,:,1) |
---|
242 | PLOSS_AVG(:,:) = PLOSS_AVG(:,:) * tmask(:,:,1) |
---|
243 | MLD_MAX(:,:) = MLD_MAX(:,:) * tmask(:,:,1) |
---|
244 | |
---|
245 | END SUBROUTINE asmdiags_fabm |
---|
246 | |
---|
247 | SUBROUTINE compute_fabm( kt ) |
---|
248 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
---|
249 | |
---|
250 | INTEGER :: ji,jj,jk,jn |
---|
251 | LOGICAL :: valid, repaired |
---|
252 | REAL(wp) :: zalfg,zztmpx,zztmpy |
---|
253 | |
---|
254 | ! Validate current model state (setting argument to .TRUE. enables repair=clipping) |
---|
255 | CALL check_state(.TRUE., valid, repaired) |
---|
256 | IF (.NOT. valid) THEN |
---|
257 | WRITE(numout,*) "Invalid value in FABM encountered in area ",narea,"!!!" |
---|
258 | #if defined key_iomput |
---|
259 | CALL xios_finalize ! end mpp communications with xios |
---|
260 | IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS |
---|
261 | #else |
---|
262 | IF( lk_oasis ) THEN |
---|
263 | CALL cpl_finalize ! end coupling and mpp communications with OASIS |
---|
264 | ELSE |
---|
265 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
---|
266 | ENDIF |
---|
267 | #endif |
---|
268 | END IF |
---|
269 | IF (repaired) THEN |
---|
270 | WRITE(numout,*) "Total interior repairs up to now on process",narea,":",repair_interior_count |
---|
271 | WRITE(numout,*) "Total surface repairs up to now on process",narea,":",repair_surface_count |
---|
272 | WRITE(numout,*) "Total bottom repairs up to now on process",narea,":",repair_bottom_count |
---|
273 | ENDIF |
---|
274 | |
---|
275 | daynumber_in_year = fjulday - fjulstartyear + 1 |
---|
276 | |
---|
277 | ! Compute the now hydrostatic pressure |
---|
278 | ! copied from istate.F90 |
---|
279 | ! ------------------------------------ |
---|
280 | |
---|
281 | IF (ALLOCATED(rho)) rho = rau0 * ( 1._wp + rhd ) |
---|
282 | |
---|
283 | IF (ALLOCATED(prn)) THEN |
---|
284 | zalfg = 0.5e-4_wp * grav ! FABM wants dbar, convert from Pa (and multiply with 0.5 to average 2 cell thicknesses below) |
---|
285 | prn(:,:,1) = 10.1325_wp + zalfg * fse3t(:,:,1) * rho(:,:,1) |
---|
286 | DO jk = 2, jpkm1 ! Vertical integration from the surface |
---|
287 | prn(:,:,jk) = prn(:,:,jk-1) + zalfg * ( & |
---|
288 | fse3t(:,:,jk-1) * rho(:,:,jk-1) & |
---|
289 | + fse3t(:,:,jk) * rho(:,:,jk) ) |
---|
290 | END DO |
---|
291 | END IF |
---|
292 | |
---|
293 | ! Compute the bottom stress |
---|
294 | ! copied from diawri.F90 |
---|
295 | ! ------------------------------------ |
---|
296 | |
---|
297 | IF (ALLOCATED(taubot)) THEN |
---|
298 | taubot(:,:) = 0._wp |
---|
299 | DO jj = 2, jpjm1 |
---|
300 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
301 | zztmpx = ( bfrua(ji ,jj) * un(ji ,jj,mbku(ji ,jj)) & |
---|
302 | & + bfrua(ji-1,jj) * un(ji-1,jj,mbku(ji-1,jj)) ) |
---|
303 | zztmpy = ( bfrva(ji, jj) * vn(ji,jj ,mbkv(ji,jj )) & |
---|
304 | & + bfrva(ji,jj-1) * vn(ji,jj-1,mbkv(ji,jj-1)) ) |
---|
305 | taubot(ji,jj) = 0.5_wp * rau0 * SQRT( zztmpx * zztmpx + zztmpy * zztmpy ) * tmask(ji,jj,1) |
---|
306 | ! |
---|
307 | END DO |
---|
308 | END DO |
---|
309 | END IF |
---|
310 | |
---|
311 | CALL model%prepare_inputs(real(kt, wp),nyear,nmonth,nday,REAL(nsec_day,wp)) |
---|
312 | |
---|
313 | ! Retrieve 3D shortwave and store in etot3 |
---|
314 | IF (ln_qsr_spec) THEN |
---|
315 | etot3(:,:,:) = model%get_interior_diagnostic_data(jp_fabm_swr) |
---|
316 | ENDIF |
---|
317 | |
---|
318 | ! Zero rate array of interface-attached state variables |
---|
319 | fabm_st2Da = 0._wp |
---|
320 | |
---|
321 | ! Compute interfacial source terms and fluxes |
---|
322 | DO jj=2,jpjm1 |
---|
323 | ! Process bottom (get_bottom_sources increments rather than sets, so zero flux array first) |
---|
324 | flux = 0._wp |
---|
325 | CALL model%get_bottom_sources(fs_2,fs_jpim1,jj,flux,fabm_st2Da(fs_2:fs_jpim1,jj,jp_fabm_surface+1:)) |
---|
326 | DO jn=1,jp_fabm |
---|
327 | ! Divide bottom fluxes by height of bottom layer and add to source terms. |
---|
328 | DO ji=fs_2,fs_jpim1 |
---|
329 | tra(ji,jj,mbkt(ji,jj),jp_fabm_m1+jn) = tra(ji,jj,mbkt(ji,jj),jp_fabm_m1+jn) + flux(ji,jn)/fse3t(ji,jj,mbkt(ji,jj)) |
---|
330 | END DO |
---|
331 | END DO |
---|
332 | |
---|
333 | ! Process surface (get_surface_sources increments rather than sets, so zero flux array first) |
---|
334 | flux = 0._wp |
---|
335 | CALL model%get_surface_sources(fs_2,fs_jpim1,jj,flux,fabm_st2Da(fs_2:fs_jpim1,jj,1:jp_fabm_surface)) |
---|
336 | ! Divide surface fluxes by height of surface layer and add to source terms. |
---|
337 | DO jn=1,jp_fabm |
---|
338 | DO ji=fs_2,fs_jpim1 |
---|
339 | tra(ji,jj,1,jp_fabm_m1+jn) = tra(ji,jj,1,jp_fabm_m1+jn) + flux(ji,jn)/fse3t(ji,jj,1) |
---|
340 | END DO |
---|
341 | END DO |
---|
342 | END DO |
---|
343 | |
---|
344 | ! Compute interior source terms (NB get_interior_sources increments rather than sets) |
---|
345 | DO jk=1,jpkm1 |
---|
346 | DO jj=2,jpjm1 |
---|
347 | CALL model%get_interior_sources(fs_2,fs_jpim1,jj,jk,tra(fs_2:fs_jpim1,jj,jk,jp_fabm0:jp_fabm1)) |
---|
348 | END DO |
---|
349 | END DO |
---|
350 | |
---|
351 | CALL model%finalize_outputs() |
---|
352 | END SUBROUTINE compute_fabm |
---|
353 | |
---|
354 | SUBROUTINE check_state(repair, valid, repaired) |
---|
355 | LOGICAL, INTENT(IN) :: repair |
---|
356 | LOGICAL, INTENT(OUT) :: valid, repaired |
---|
357 | |
---|
358 | INTEGER :: jj, jk |
---|
359 | LOGICAL :: valid_int, valid_sf, valid_bt |
---|
360 | |
---|
361 | valid = .TRUE. ! Whether the model state is valid after this subroutine returns |
---|
362 | repaired = .FALSE. ! Whether the model state has been repaired by this subroutine |
---|
363 | DO jk=1,jpkm1 |
---|
364 | DO jj=2,jpjm1 |
---|
365 | CALL model%check_interior_state(fs_2, fs_jpim1, jj, jk, repair, valid_int) |
---|
366 | IF (repair .AND. .NOT. valid_int) THEN |
---|
367 | repair_interior_count = repair_interior_count + 1 |
---|
368 | repaired = .TRUE. |
---|
369 | END IF |
---|
370 | IF (.NOT. (valid_int .OR. repair)) valid = .FALSE. |
---|
371 | END DO |
---|
372 | END DO |
---|
373 | DO jj=2,jpjm1 |
---|
374 | CALL model%check_surface_state(fs_2, fs_jpim1, jj, repair, valid_sf) |
---|
375 | IF (repair .AND. .NOT. valid_sf) THEN |
---|
376 | repair_surface_count = repair_surface_count + 1 |
---|
377 | repaired = .TRUE. |
---|
378 | END IF |
---|
379 | IF (.NOT. (valid_sf .AND. valid_bt) .AND. .NOT. repair) valid = .FALSE. |
---|
380 | CALL model%check_bottom_state(fs_2, fs_jpim1, jj, repair, valid_bt) |
---|
381 | IF (repair .AND. .NOT. valid_bt) THEN |
---|
382 | repair_bottom_count = repair_bottom_count + 1 |
---|
383 | repaired = .TRUE. |
---|
384 | END IF |
---|
385 | IF (.NOT. (valid_sf .AND. valid_bt) .AND. .NOT. repair) valid = .FALSE. |
---|
386 | END DO |
---|
387 | END SUBROUTINE |
---|
388 | |
---|
389 | SUBROUTINE trc_sms_fabm_check_mass() |
---|
390 | REAL(wp) :: total(SIZE(model%conserved_quantities)) |
---|
391 | INTEGER :: ji,jk,jj,jn |
---|
392 | |
---|
393 | total = 0._wp |
---|
394 | |
---|
395 | IF (.NOT. started) CALL nemo_fabm_start |
---|
396 | |
---|
397 | DO jk=1,jpkm1 |
---|
398 | DO jj=2,jpjm1 |
---|
399 | CALL model%get_interior_conserved_quantities(fs_2,fs_jpim1,jj,jk,current_total) |
---|
400 | DO jn=1,SIZE(model%conserved_quantities) |
---|
401 | DO ji=fs_2,fs_jpim1 |
---|
402 | total(jn) = total(jn) + cvol(ji,jj,jk) * current_total(ji,jn) * tmask_i(ji,jj) |
---|
403 | END DO |
---|
404 | END DO |
---|
405 | END DO |
---|
406 | END DO |
---|
407 | |
---|
408 | DO jj=2,jpjm1 |
---|
409 | CALL model%get_horizontal_conserved_quantities(fs_2,fs_jpim1,jj,current_total) |
---|
410 | DO jn=1,SIZE(model%conserved_quantities) |
---|
411 | DO ji=fs_2,fs_jpim1 |
---|
412 | total(jn) = total(jn) + e1e2t(ji,jj) * current_total(ji,jn) * tmask_i(ji,jj) |
---|
413 | END DO |
---|
414 | END DO |
---|
415 | END DO |
---|
416 | |
---|
417 | IF( lk_mpp ) CALL mpp_sum(total,SIZE(model%conserved_quantities)) |
---|
418 | |
---|
419 | DO jn=1,SIZE(model%conserved_quantities) |
---|
420 | IF(lwp) WRITE(numout,*) 'FABM '//TRIM(model%conserved_quantities(jn)%name),total(jn),TRIM(model%conserved_quantities(jn)%units)//'*m3' |
---|
421 | END DO |
---|
422 | |
---|
423 | END SUBROUTINE trc_sms_fabm_check_mass |
---|
424 | |
---|
425 | SUBROUTINE st2d_fabm_nxt( kt ) |
---|
426 | !!---------------------------------------------------------------------- |
---|
427 | !! *** st2d_fabm_nxt *** |
---|
428 | !! |
---|
429 | !! ** Purpose : routine to integrate 2d states in time |
---|
430 | !! |
---|
431 | !! ** Method : based on integration of 3D passive tracer fields |
---|
432 | !! implemented in TOP_SRC/TRP/trcnxt.F90, plus |
---|
433 | !! tra_nxt_fix in OPA_SRC/TRA/tranxt.F90. Similar to |
---|
434 | !! time integration of sea surface height in |
---|
435 | !! OPA_SRC/DYN/sshwzv.F90. |
---|
436 | !!---------------------------------------------------------------------- |
---|
437 | ! |
---|
438 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
---|
439 | REAL(wp) :: z2dt |
---|
440 | INTEGER :: jn |
---|
441 | |
---|
442 | !!---------------------------------------------------------------------- |
---|
443 | ! |
---|
444 | IF( neuler == 0 .AND. kt == nittrc000 ) THEN |
---|
445 | z2dt = rdt ! set time step size (Euler) |
---|
446 | ELSE |
---|
447 | z2dt = 2._wp * rdt ! set time step size (Leapfrog) |
---|
448 | ENDIF |
---|
449 | |
---|
450 | ! Forward Euler time step to compute "now" |
---|
451 | DO jn=1,jp_fabm_surface+jp_fabm_bottom |
---|
452 | fabm_st2Da(:,:,jn) = (fabm_st2db(:,:,jn) + z2dt * fabm_st2da(:,:,jn)) * tmask(:,:,1) |
---|
453 | ENDDO |
---|
454 | |
---|
455 | IF( neuler == 0 .AND. kt == nittrc000 ) THEN ! Euler time-stepping at first time-step |
---|
456 | ! ! (only swap) |
---|
457 | fabm_st2Dn(:,:,:) = fabm_st2Da(:,:,:) |
---|
458 | ! |
---|
459 | ELSE |
---|
460 | ! Update now state + Asselin filter time stepping |
---|
461 | fabm_st2Db(:,:,:) = (1._wp - 2._wp*atfp) * fabm_st2Dn(:,:,:) + & |
---|
462 | atfp * ( fabm_st2Db(:,:,:) + fabm_st2Da(:,:,:) ) |
---|
463 | fabm_st2Dn(:,:,:) = fabm_st2Da(:,:,:) |
---|
464 | ENDIF |
---|
465 | |
---|
466 | END SUBROUTINE st2d_fabm_nxt |
---|
467 | |
---|
468 | INTEGER FUNCTION trc_sms_fabm_alloc() |
---|
469 | INTEGER :: jn |
---|
470 | !!---------------------------------------------------------------------- |
---|
471 | !! *** ROUTINE trc_sms_fabm_alloc *** |
---|
472 | !!---------------------------------------------------------------------- |
---|
473 | ! |
---|
474 | ! ALLOCATE here the arrays specific to FABM |
---|
475 | ALLOCATE( lk_rad_fabm(jp_fabm)) |
---|
476 | IF (model%variable_needs_values(fabm_standard_variables%pressure)) ALLOCATE(prn(jpi, jpj, jpk)) |
---|
477 | IF (ALLOCATED(prn) .or. model%variable_needs_values(fabm_standard_variables%density)) ALLOCATE(rho(jpi, jpj, jpk)) |
---|
478 | IF (model%variable_needs_values(fabm_standard_variables%bottom_stress)) ALLOCATE(taubot(jpi, jpj)) |
---|
479 | ! ALLOCATE( tab(...) , STAT=trc_sms_fabm_alloc ) |
---|
480 | |
---|
481 | ! Allocate arrays to hold state for surface-attached and bottom-attached state variables |
---|
482 | ALLOCATE(fabm_st2Dn(jpi, jpj, jp_fabm_surface+jp_fabm_bottom)) |
---|
483 | ALLOCATE(fabm_st2Da(jpi, jpj, jp_fabm_surface+jp_fabm_bottom)) |
---|
484 | ALLOCATE(fabm_st2Db(jpi, jpj, jp_fabm_surface+jp_fabm_bottom)) |
---|
485 | |
---|
486 | ! Work array to hold surface and bottom fluxes |
---|
487 | ALLOCATE(flux(fs_2:fs_jpim1,jp_fabm)) |
---|
488 | |
---|
489 | ! Allocate work arrays for vertical movement |
---|
490 | ALLOCATE(w_ct(fs_2:fs_jpim1,1:jpkm1,jp_fabm)) |
---|
491 | ALLOCATE(current_total(fs_2:fs_jpim1,SIZE(model%conserved_quantities))) |
---|
492 | #if defined key_trdtrc && defined key_iomput |
---|
493 | IF( lk_trdtrc ) ALLOCATE(tr_vmv(jpi,jpj,jpk,jp_fabm)) |
---|
494 | IF( lk_trdtrc ) ALLOCATE(tr_inp(jpi,jpj,jpk)) |
---|
495 | #endif |
---|
496 | |
---|
497 | trc_sms_fabm_alloc = 0 ! set to zero if no array to be allocated |
---|
498 | ! |
---|
499 | IF( trc_sms_fabm_alloc /= 0 ) CALL ctl_warn('trc_sms_fabm_alloc : failed to allocate arrays') |
---|
500 | ! |
---|
501 | |
---|
502 | ! Provide FABM with domain extents |
---|
503 | CALL model%set_domain(jpi, jpj, jpk, rdt) |
---|
504 | CALL model%set_domain_start(fs_2, 2, 1) |
---|
505 | CALL model%set_domain_stop(fs_jpim1, jpjm1, jpkm1) |
---|
506 | |
---|
507 | ! Provide FABM with the vertical indices of the bottom, and the land-sea mask. |
---|
508 | CALL model%set_bottom_index(mbkt) ! NB mbkt extents should match dimension lengths provided to set_domain |
---|
509 | CALL model%set_mask(tmask,tmask(:,:,1)) ! NB tmask extents should match dimension lengths provided to set_domain |
---|
510 | |
---|
511 | ! Initialize state and send pointers to state data to FABM |
---|
512 | ! We mask land points in states with zeros, as per with NEMO "convention" |
---|
513 | ! NB we cannot call model%initialize_*_state at this point, because model%start has not been called yet. |
---|
514 | DO jn=1,jp_fabm |
---|
515 | trn(:,:,:,jp_fabm_m1+jn) = model%interior_state_variables(jn)%initial_value * tmask |
---|
516 | CALL model%link_interior_state_data(jn,trn(:,:,:,jp_fabm_m1+jn)) |
---|
517 | END DO |
---|
518 | DO jn=1,jp_fabm_surface |
---|
519 | fabm_st2Dn(:,:,jn) = model%surface_state_variables(jn)%initial_value * tmask(:,:,1) |
---|
520 | CALL model%link_surface_state_data(jn,fabm_st2Dn(:,:,jn)) |
---|
521 | END DO |
---|
522 | DO jn=1,jp_fabm_bottom |
---|
523 | fabm_st2Dn(:,:,jp_fabm_surface+jn) = model%bottom_state_variables(jn)%initial_value * tmask(:,:,1) |
---|
524 | CALL model%link_bottom_state_data(jn,fabm_st2Dn(:,:,jp_fabm_surface+jn)) |
---|
525 | END DO |
---|
526 | |
---|
527 | ! Send pointers to environmental data to FABM |
---|
528 | CALL model%link_interior_data(fabm_standard_variables%depth, fsdept(:,:,:)) |
---|
529 | CALL model%link_interior_data(fabm_standard_variables%temperature, tsn(:,:,:,jp_tem)) |
---|
530 | CALL model%link_interior_data(fabm_standard_variables%practical_salinity, tsn(:,:,:,jp_sal)) |
---|
531 | IF (ALLOCATED(rho)) CALL model%link_interior_data(fabm_standard_variables%density, rho(:,:,:)) |
---|
532 | IF (ALLOCATED(prn)) CALL model%link_interior_data(fabm_standard_variables%pressure, prn) |
---|
533 | IF (ALLOCATED(taubot)) CALL model%link_horizontal_data(fabm_standard_variables%bottom_stress, taubot(:,:)) |
---|
534 | CALL model%link_interior_data(fabm_standard_variables%cell_thickness, fse3t(:,:,:)) |
---|
535 | CALL model%link_horizontal_data(fabm_standard_variables%latitude, gphit) |
---|
536 | CALL model%link_horizontal_data(fabm_standard_variables%longitude, glamt) |
---|
537 | CALL model%link_scalar(fabm_standard_variables%number_of_days_since_start_of_the_year, daynumber_in_year) |
---|
538 | CALL model%link_horizontal_data(fabm_standard_variables%wind_speed, wndm(:,:)) |
---|
539 | CALL model%link_horizontal_data(fabm_standard_variables%surface_downwelling_shortwave_flux, qsr(:,:)) |
---|
540 | CALL model%link_horizontal_data(fabm_standard_variables%bottom_depth_below_geoid, bathy(:,:)) |
---|
541 | CALL model%link_horizontal_data(fabm_standard_variables%ice_area_fraction, fr_i(:,:)) |
---|
542 | |
---|
543 | ! Obtain user-specified input variables (read from NetCDF file) |
---|
544 | CALL link_inputs |
---|
545 | CALL update_inputs(nit000, .FALSE.) |
---|
546 | |
---|
547 | ! Set mask for negativity corrections to the relevant states |
---|
548 | lk_rad_fabm(:) = .FALSE. |
---|
549 | DO jn=1,jp_fabm |
---|
550 | IF (model%interior_state_variables(jn)%minimum >= 0._wp) THEN |
---|
551 | lk_rad_fabm(jn) = .TRUE. |
---|
552 | IF(lwp) WRITE(numout,*) 'FABM clipping for '//TRIM(model%interior_state_variables(jn)%name)//' activated.' |
---|
553 | END IF |
---|
554 | END DO |
---|
555 | |
---|
556 | |
---|
557 | ! Copy initial condition for interface-attached state variables to "previous" state field |
---|
558 | ! NB NEMO does this itself for pelagic state variables (trb) in TOP_SRC/trcini.F90. |
---|
559 | fabm_st2Db = fabm_st2Dn |
---|
560 | |
---|
561 | END FUNCTION trc_sms_fabm_alloc |
---|
562 | |
---|
563 | SUBROUTINE nemo_fabm_start() |
---|
564 | INTEGER :: jn |
---|
565 | |
---|
566 | ! Make FABM aware of diagnostics that are not needed [not included in output] |
---|
567 | ! This works only after iom has completely initialised, because it depends on iom_use |
---|
568 | DO jn=1,size(model%interior_diagnostic_variables) |
---|
569 | model%interior_diagnostic_variables(jn)%save = iom_use(model%interior_diagnostic_variables(jn)%name) & |
---|
570 | .or. iom_use(TRIM(model%interior_diagnostic_variables(jn)%name)//'_VINT') & |
---|
571 | .or. iom_use(TRIM(model%interior_diagnostic_variables(jn)%name)//'25h') & |
---|
572 | .or. iom_use('top_'//TRIM(model%interior_diagnostic_variables(jn)%name)) & |
---|
573 | .or. iom_use('mid_'//TRIM(model%interior_diagnostic_variables(jn)%name)) & |
---|
574 | .or. iom_use('bot_'//TRIM(model%interior_diagnostic_variables(jn)%name)) |
---|
575 | END DO |
---|
576 | model%interior_diagnostic_variables(jp_fabm_o3ta)%save = .TRUE. |
---|
577 | model%interior_diagnostic_variables(jp_fabm_o3ph)%save = .TRUE. |
---|
578 | model%interior_diagnostic_variables(jp_fabm_o3pc)%save = .TRUE. |
---|
579 | model%interior_diagnostic_variables(jp_fabm_xeps)%save = .TRUE. |
---|
580 | model%interior_diagnostic_variables(jp_fabm_pgrow)%save = .TRUE. |
---|
581 | model%interior_diagnostic_variables(jp_fabm_ploss)%save = .TRUE. |
---|
582 | IF( ln_qsr_spec ) THEN |
---|
583 | model%interior_diagnostic_variables(jp_fabm_swr)%save = .TRUE. |
---|
584 | ENDIF |
---|
585 | DO jn=1,size(model%horizontal_diagnostic_variables) |
---|
586 | model%horizontal_diagnostic_variables(jn)%save = iom_use(model%horizontal_diagnostic_variables(jn)%name) & |
---|
587 | .or. iom_use(TRIM(model%horizontal_diagnostic_variables(jn)%name)//'25h') |
---|
588 | END DO |
---|
589 | |
---|
590 | ! Check whether FABM has all required data |
---|
591 | ! [after this, the save attribute of diagnostic variables can no longer change!] |
---|
592 | CALL model%start() |
---|
593 | |
---|
594 | started = .TRUE. |
---|
595 | |
---|
596 | END SUBROUTINE |
---|
597 | |
---|
598 | #else |
---|
599 | !!---------------------------------------------------------------------- |
---|
600 | !! Dummy module No FABM model |
---|
601 | !!---------------------------------------------------------------------- |
---|
602 | CONTAINS |
---|
603 | SUBROUTINE trc_sms_fabm( kt ) ! Empty routine |
---|
604 | INTEGER, INTENT( in ) :: kt |
---|
605 | WRITE(*,*) 'trc_sms_fabm: You should not have seen this print! error?', kt |
---|
606 | END SUBROUTINE trc_sms_fabm |
---|
607 | #endif |
---|
608 | |
---|
609 | !!====================================================================== |
---|
610 | END MODULE trcsms_fabm |
---|