New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/UKMO/AMM15_v3_6_STABLE_package_collate_utils366_fabmv1_v2/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/AMM15_v3_6_STABLE_package_collate_utils366_fabmv1_v2/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 13496

Last change on this file since 13496 was 13496, checked in by dford, 4 years ago

Two-way NEMO-ERSEM coupling via chlorophyll field.
File size: 37.5 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            4.0  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_qsr      : trend due to the solar radiation penetration
17   !!   tra_qsr_init : solar radiation penetration initialization
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and active tracers
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce         ! surface boundary condition: ocean
22   USE trc_oce         ! share SMS/Ocean variables
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! trends manager: tracers
25   USE in_out_manager  ! I/O manager
26   USE phycst          ! physical constants
27   USE prtctl          ! Print control
28   USE iom             ! I/O manager
29   USE fldread         ! read input fields
30   USE restart         ! ocean restart
31   USE lib_mpp         ! MPP library
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34#if defined key_fabm
35   USE trc, ONLY: trn  ! FABM variables
36   USE par_fabm        ! FABM parameters
37#endif
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
43   PUBLIC   tra_qsr_init  ! routine called by nemogcm.F90
44
45   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
46   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
47   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag 
48   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
49   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
50   LOGICAL , PUBLIC ::   ln_qsr_ice   !: light penetration for ice-model LIM3 (clem)
51   LOGICAL , PUBLIC ::   ln_qsr_spec  !: spectral model heating from ERSEM
52   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
53   INTEGER , PUBLIC ::   nn_kd490dta  !: use kd490dta data (=1) or not (=0)
54   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
55   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
56   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
57 
58   ! Module variables
59   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
60   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_kd490 ! structure of input kd490 (file informations, fields read)
63   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
64   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
65
66   !! * Substitutions
67#  include "domzgr_substitute.h90"
68#  include "vectopt_loop_substitute.h90"
69   !!----------------------------------------------------------------------
70   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
71   !! $Id$
72   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE tra_qsr( kt )
77      !!----------------------------------------------------------------------
78      !!                  ***  ROUTINE tra_qsr  ***
79      !!
80      !! ** Purpose :   Compute the temperature trend due to the solar radiation
81      !!      penetration and add it to the general temperature trend.
82      !!
83      !! ** Method  : The profile of the solar radiation within the ocean is defined
84      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
85      !!      Considering the 2 wavebands case:
86      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
87      !!         The temperature trend associated with the solar radiation penetration
88      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
89      !!         At the bottom, boudary condition for the radiation is no flux :
90      !!      all heat which has not been absorbed in the above levels is put
91      !!      in the last ocean level.
92      !!         In z-coordinate case, the computation is only done down to the
93      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
94      !!      used for the computation are calculated one for once as they
95      !!      depends on k only.
96      !!
97      !! ** Action  : - update ta with the penetrative solar radiation trend
98      !!              - save the trend in ttrd ('key_trdtra')
99      !!
100      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
101      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
102      !!----------------------------------------------------------------------
103      !
104      INTEGER, INTENT(in) ::   kt     ! ocean time-step
105      !
106      INTEGER  ::   ji, jj, jk           ! dummy loop indices
107      INTEGER  ::   irgb                 ! local integers
108      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
109      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
110      REAL(wp) ::   zzc0, zzc1, zzc2, zzc3   !    -         -
111      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
112      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
113      REAL(wp), POINTER, DIMENSION(:,:,:) :: zekb_3d, zekg_3d, zekr_3d
114      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
115      !!----------------------------------------------------------------------
116      !
117      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
118      !
119      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
120      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
121      CALL wrk_alloc( jpi, jpj, jpk, zekb_3d, zekg_3d, zekr_3d ) 
122      !
123      IF( kt == nit000 ) THEN
124         IF(lwp) WRITE(numout,*)
125         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
126         IF(lwp) WRITE(numout,*) '~~~~~~~'
127         IF( .NOT.ln_traqsr )   RETURN
128      ENDIF
129
130      IF( l_trdtra ) THEN      ! Save ta and sa trends
131         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
132         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
133      ENDIF
134
135      !                                        Set before qsr tracer content field
136      !                                        ***********************************
137      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
138         !                                        ! -----------------------------------
139         qsr_hc(:,:,:) = 0.e0
140         !
141         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
142              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
143            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
144            zfact = 0.5e0
145            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
146         ELSE                                           ! No restart or restart not found: Euler forward time stepping
147            zfact = 1.e0
148            qsr_hc_b(:,:,:) = 0.e0
149         ENDIF
150      ELSE                                        ! Swap of forcing field
151         !                                        ! ---------------------
152         zfact = 0.5e0
153         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
154      ENDIF
155      !                                        Compute now qsr tracer content field
156      !                                        ************************************
157     
158      !                                           ! ============================================== !
159      IF( ln_qsr_spec ) THEN                      !  ERSEM spectral heating                        !
160         !                                        ! ============================================== !
161         DO jk = 1, jpkm1
162           qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) )
163         END DO
164         !                                        Add to the general trend
165         DO jk = 1, jpkm1
166            DO jj = 2, jpjm1
167               DO ji = fs_2, fs_jpim1   ! vector opt.
168                  z1_e3t = zfact / fse3t(ji,jj,jk)
169                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
170               END DO
171            END DO
172         END DO
173         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
174         IF ( ln_qsr_ice ) THEN
175            DO jj = 1, jpj
176               DO ji = 1, jpi
177                  IF ( qsr(ji,jj) /= 0._wp ) THEN
178                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
179                  ELSE
180                     fraqsr_1lev(ji,jj) = 1.
181                  ENDIF
182               END DO
183            END DO
184         ENDIF
185         !
186
187         !                                        ! ============================================== !
188      ELSEIF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
189         !                                        ! ============================================== !
190         DO jk = 1, jpkm1
191            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
192         END DO
193         !                                        Add to the general trend
194         DO jk = 1, jpkm1
195            DO jj = 2, jpjm1 
196               DO ji = fs_2, fs_jpim1   ! vector opt.
197                  z1_e3t = zfact / fse3t(ji,jj,jk)
198                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
199               END DO
200            END DO
201         END DO
202         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
203         ! clem: store attenuation coefficient of the first ocean level
204         IF ( ln_qsr_ice ) THEN
205            DO jj = 1, jpj
206               DO ji = 1, jpi
207                  IF ( qsr(ji,jj) /= 0._wp ) THEN
208                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
209                  ELSE
210                     fraqsr_1lev(ji,jj) = 1.
211                  ENDIF
212               END DO
213            END DO
214         ENDIF
215         !                                        ! ============================================== !
216      ELSE                                        !  Ocean alone :
217         !                                        ! ============================================== !
218         !
219         !                                                ! ------------------------- !
220         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
221            !                                             ! ------------------------- !
222            ! Set chlorophyl concentration
223            IF( nn_chldta == 2 .OR. nn_chldta == 1 .OR. lk_vvl ) THEN   !*  Variable Chlorophyll or ocean volume
224               !
225               IF( nn_chldta == 2 ) THEN
226                  DO jk = 1, nksr+1
227                     DO jj = 1, jpj
228                        DO ji = 1, jpi
229#if defined key_fabm
230                           zchl = trn(ji,jj,jk,jp_fabm_m1+jp_fabm_chl1) + trn(ji,jj,jk,jp_fabm_m1+jp_fabm_chl2) + &
231                              &   trn(ji,jj,jk,jp_fabm_m1+jp_fabm_chl3) + trn(ji,jj,jk,jp_fabm_m1+jp_fabm_chl4)
232#endif
233                           zchl = MIN(  10. , MAX( 0.03, zchl )  )
234                           irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
235                           !                                                         
236                           zekb_3d(ji,jj,jk) = rkrgb(1,irgb)
237                           zekg_3d(ji,jj,jk) = rkrgb(2,irgb)
238                           zekr_3d(ji,jj,jk) = rkrgb(3,irgb)
239                        END DO
240                     END DO
241                  END DO
242                  !
243               ELSEIF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
244                  !
245                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
246                  !         
247!CDIR COLLAPSE
248!CDIR NOVERRCHK
249                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
250!CDIR NOVERRCHK
251                     DO ji = 1, jpi
252                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
253                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
254                        zekb(ji,jj) = rkrgb(1,irgb)
255                        zekg(ji,jj) = rkrgb(2,irgb)
256                        zekr(ji,jj) = rkrgb(3,irgb)
257                     END DO
258                  END DO
259               ELSE                                            ! Variable ocean volume but constant chrlorophyll
260                  zchl = 0.05                                     ! constant chlorophyll
261                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
262                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
263                  zekg(:,:) = rkrgb(2,irgb)
264                  zekr(:,:) = rkrgb(3,irgb)
265               ENDIF
266               !
267               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
268               ze0(:,:,1) = rn_abs  * qsr(:,:)
269               ze1(:,:,1) = zcoef * qsr(:,:)
270               ze2(:,:,1) = zcoef * qsr(:,:)
271               ze3(:,:,1) = zcoef * qsr(:,:)
272               zea(:,:,1) =         qsr(:,:)
273               !
274               DO jk = 2, nksr+1
275                  IF( nn_chldta == 2 ) THEN
276                     zekb(:,:) = zekb_3d(:,:,jk)
277                     zekg(:,:) = zekg_3d(:,:,jk)
278                     zekr(:,:) = zekr_3d(:,:,jk)
279                  ENDIF
280!CDIR NOVERRCHK
281                  DO jj = 1, jpj
282!CDIR NOVERRCHK   
283                     DO ji = 1, jpi
284                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
285                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
286                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
287                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
288                        ze0(ji,jj,jk) = zc0
289                        ze1(ji,jj,jk) = zc1
290                        ze2(ji,jj,jk) = zc2
291                        ze3(ji,jj,jk) = zc3
292                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
293                     END DO
294                  END DO
295               END DO
296               ! clem: store attenuation coefficient of the first ocean level
297               IF ( ln_qsr_ice ) THEN
298                  IF( nn_chldta == 2 ) THEN
299                     zekb(:,:) = zekb_3d(:,:,1)
300                     zekg(:,:) = zekg_3d(:,:,1)
301                     zekr(:,:) = zekr_3d(:,:,1)
302                  ENDIF
303                  DO jj = 1, jpj
304                     DO ji = 1, jpi
305                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
306                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
307                        zzc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
308                        zzc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
309                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 + zzc2  + zzc3  ) * tmask(ji,jj,2) 
310                     END DO
311                  END DO
312               ENDIF
313               !
314               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
315                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
316               END DO
317               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
318               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
319               !
320            ELSE                                                 !*  Constant Chlorophyll
321               DO jk = 1, nksr
322                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
323               END DO
324               ! clem: store attenuation coefficient of the first ocean level
325               IF ( ln_qsr_ice ) THEN
326                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
327               ENDIF
328           ENDIF
329
330         ENDIF
331         !                                                ! ------------------------- !
332         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
333            !                                             ! ------------------------- !
334            !
335            IF( lk_vvl ) THEN                                  !* variable volume
336               zz0   =        rn_abs   * r1_rau0_rcp
337               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
338               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
339                  DO jj = 1, jpj
340                     DO ji = 1, jpi
341                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
342                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
343                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
344                     END DO
345                  END DO
346               END DO
347               ! clem: store attenuation coefficient of the first ocean level
348               IF ( ln_qsr_ice ) THEN
349                  DO jj = 1, jpj
350                     DO ji = 1, jpi
351                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
352                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
353                        fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp
354                     END DO
355                  END DO
356               ENDIF
357            ELSE                                               !* constant volume: coef. computed one for all
358               DO jk = 1, nksr
359                  DO jj = 2, jpjm1
360                     DO ji = fs_2, fs_jpim1   ! vector opt.
361                        ! (ISF) no light penetration below the ice shelves         
362                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1)
363                     END DO
364                  END DO
365               END DO
366               ! clem: store attenuation coefficient of the first ocean level
367               IF ( ln_qsr_ice ) THEN
368                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
369               ENDIF
370               !
371            ENDIF
372            !
373         ENDIF
374! slwa
375         IF( nn_kd490dta == 1 ) THEN                      !  use KD490 data read in   !
376            !                                             ! ------------------------- !
377               nksr = jpk - 1
378               !
379               CALL fld_read( kt, 1, sf_kd490 )     ! Read kd490 data and provide it at the current time step
380               !
381               zcoef  = ( 1. - rn_abs )
382               ze0(:,:,1) = rn_abs  * qsr(:,:)
383               ze1(:,:,1) = zcoef * qsr(:,:)
384               zea(:,:,1) =         qsr(:,:)
385               !
386               DO jk = 2, nksr+1
387!CDIR NOVERRCHK
388                  DO jj = 1, jpj
389!CDIR NOVERRCHK   
390                     DO ji = 1, jpi
391                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
392                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * sf_kd490(1)%fnow(ji,jj,1) )
393                        ze0(ji,jj,jk) = zc0
394                        ze1(ji,jj,jk) = zc1
395                        zea(ji,jj,jk) = ( zc0 + zc1 ) * tmask(ji,jj,jk)
396                     END DO
397                  END DO
398               END DO
399               ! clem: store attenuation coefficient of the first ocean level
400               IF ( ln_qsr_ice ) THEN
401                  DO jj = 1, jpj
402                     DO ji = 1, jpi
403                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
404                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * sf_kd490(1)%fnow(ji,jj,1) )
405                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 ) * tmask(ji,jj,2) 
406                     END DO
407                  END DO
408               ENDIF
409               !
410               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
411                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
412               END DO
413               zea(:,:,nksr+1:jpk) = 0.e0     !
414               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
415               !
416        ENDIF   ! use KD490 data
417!slwa
418         !
419         !                                        Add to the general trend
420         DO jk = 1, nksr
421            DO jj = 2, jpjm1 
422               DO ji = fs_2, fs_jpim1   ! vector opt.
423                  z1_e3t = zfact / fse3t(ji,jj,jk)
424                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
425               END DO
426            END DO
427         END DO
428         !
429      ENDIF
430      !
431      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
432         !                                     *******************************
433         IF(lwp) WRITE(numout,*)
434         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
435            &                    'at it= ', kt,' date= ', ndastp
436         IF(lwp) WRITE(numout,*) '~~~~'
437         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b'   , qsr_hc      )
438         CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev )   ! default definition in sbcssm
439         !
440      ENDIF
441
442      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
443         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
444         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
445         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
446      ENDIF
447      !                       ! print mean trends (used for debugging)
448      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
449      !
450      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
451      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
452      CALL wrk_dealloc( jpi, jpj, jpk, zekb_3d, zekg_3d, zekr_3d ) 
453      !
454      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
455      !
456   END SUBROUTINE tra_qsr
457
458
459   SUBROUTINE tra_qsr_init
460      !!----------------------------------------------------------------------
461      !!                  ***  ROUTINE tra_qsr_init  ***
462      !!
463      !! ** Purpose :   Initialization for the penetrative solar radiation
464      !!
465      !! ** Method  :   The profile of solar radiation within the ocean is set
466      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
467      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
468      !!      default values correspond to clear water (type I in Jerlov'
469      !!      (1968) classification.
470      !!         called by tra_qsr at the first timestep (nit000)
471      !!
472      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
473      !!
474      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
475      !!----------------------------------------------------------------------
476      !
477      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
478      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
479      INTEGER  ::   ios                          ! Local integer output status for namelist read
480      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
481      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
482      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
483      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
484      !
485      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
486      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
487      TYPE(FLD_N)        ::   sn_kd490 ! informations about the kd490 field to be read
488      !!
489      NAMELIST/namtra_qsr/  sn_chl, sn_kd490, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
490         &                  ln_qsr_spec, nn_chldta, rn_abs, rn_si0, rn_si1, nn_kd490dta
491      !!----------------------------------------------------------------------
492
493      !
494      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
495      !
496      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
497      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
498      !
499
500      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
501      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
502901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
503
504      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
505      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
506902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
507      IF(lwm) WRITE ( numond, namtra_qsr )
508      !
509      IF(lwp) THEN                ! control print
510         WRITE(numout,*)
511         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
512         WRITE(numout,*) '~~~~~~~~~~~~'
513         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
514         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
515         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
516         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
517         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
518         WRITE(numout,*) '      ERSEM spectral heating model             ln_qsr_spec= ', ln_qsr_spec
519         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
520         WRITE(numout,*) '      RGB: model (2), file (1) or cst (0) chl   nn_chldta = ', nn_chldta
521         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
522         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
523         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
524         WRITE(numout,*) '      read in KD490 data                       nn_kd490dta  = ', nn_kd490dta
525      ENDIF
526
527      IF( ln_traqsr ) THEN     ! control consistency
528         !                     
529         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
530            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
531            ln_qsr_bio = .FALSE.
532         ENDIF
533         !
534         ioptio = 0                      ! Parameter control
535         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
536         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
537         IF( ln_qsr_bio  )   ioptio = ioptio + 1
538         IF( ln_qsr_spec )   ioptio = ioptio + 1
539         IF( nn_kd490dta == 1 )   ioptio = ioptio + 1
540         !
541         IF( ioptio /= 1 ) &
542            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
543            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
544         !
545         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
546         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
547         IF( ln_qsr_rgb .AND. nn_chldta == 2 )   nqsr =  3
548         IF( ln_qsr_2bd                      )   nqsr =  4
549         IF( ln_qsr_bio                      )   nqsr =  5
550         IF( nn_kd490dta == 1                )   nqsr =  6
551         IF( ln_qsr_spec                     )   nqsr =  7
552         !
553         IF(lwp) THEN                   ! Print the choice
554            WRITE(numout,*)
555            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
556            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data from file'
557            IF( nqsr ==  3 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data from model'
558            IF( nqsr ==  4 )   WRITE(numout,*) '         2 bands light penetration'
559            IF( nqsr ==  5 )   WRITE(numout,*) '         bio-model light penetration'
560            IF( nqsr ==  6 )   WRITE(numout,*) '         KD490 light penetration'
561            IF( nqsr ==  7 )   WRITE(numout,*) '         ERSEM spectral light penetration'
562         ENDIF
563#if ! defined key_fabm
564         !
565         IF( nqsr ==  2 ) THEN
566            CALL ctl_stop( 'nn_chldta=2 so trying to use ERSEM chlorophyll for light penetration', &
567               &           'but not running with ERSEM' )
568         ELSEIF( nqsr ==  7 ) THEN
569            CALL ctl_stop( 'ln_qsr_spec=.true. so trying to use ERSEM spectral light penetration', &
570               &           'but not running with ERSEM' )
571         ENDIF
572#endif
573         !
574      ENDIF
575      !                          ! ===================================== !
576      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
577         !                       ! ===================================== !
578         !
579         xsi0r = 1.e0 / rn_si0
580         xsi1r = 1.e0 / rn_si1
581         IF( nn_kd490dta == 1 ) THEN           !* KD490 data : set sf_kd490 structure
582            IF(lwp) WRITE(numout,*)
583            IF(lwp) WRITE(numout,*) '        KD490 read in a file'
584            ALLOCATE( sf_kd490(1), STAT=ierror )
585            IF( ierror > 0 ) THEN
586               CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_kd490 structure' )   ;   RETURN
587            ENDIF
588            ALLOCATE( sf_kd490(1)%fnow(jpi,jpj,1)   )
589            IF( sn_kd490%ln_tint )ALLOCATE( sf_kd490(1)%fdta(jpi,jpj,1,2) )
590            !                                        ! fill sf_kd490 with sn_kd490 and control print
591            CALL fld_fill( sf_kd490, (/ sn_kd490 /), cn_dir, 'tra_qsr_init',   &
592               &                                         'Solar penetration function of read KD490', 'namtra_qsr' )
593         !                                ! ---------------------------------- !
594         ELSEIF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
595            !                             ! ---------------------------------- !
596            !
597            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
598            !
599            !                                   !* level of light extinction
600            IF(  ln_sco ) THEN   ;   nksr = jpkm1
601            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
602            ENDIF
603
604            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
605            !
606            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
607               IF(lwp) WRITE(numout,*)
608               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
609               ALLOCATE( sf_chl(1), STAT=ierror )
610               IF( ierror > 0 ) THEN
611                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
612               ENDIF
613               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
614               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
615               !                                        ! fill sf_chl with sn_chl and control print
616               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
617                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
618               !
619            ELSEIF( nn_chldta == 2 ) THEN       !* Chl data will be got from model at each time step
620               IF(lwp) WRITE(numout,*)
621               IF(lwp) WRITE(numout,*) '        Chlorophyll will be taken from model at each time step'
622            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
623               IF(lwp) WRITE(numout,*)
624               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
625               IF( lk_vvl ) THEN                   ! variable volume
626                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
627               ELSE                                ! constant volume: computes one for all
628                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
629                  !
630                  zchl = 0.05                                 ! constant chlorophyll
631                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
632                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
633                  zekg(:,:) = rkrgb(2,irgb)
634                  zekr(:,:) = rkrgb(3,irgb)
635                  !
636                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
637                  ze0(:,:,1) = rn_abs
638                  ze1(:,:,1) = zcoef
639                  ze2(:,:,1) = zcoef 
640                  ze3(:,:,1) = zcoef
641                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
642               
643                  DO jk = 2, nksr+1
644!CDIR NOVERRCHK
645                     DO jj = 1, jpj
646!CDIR NOVERRCHK   
647                        DO ji = 1, jpi
648                           zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r     )
649                           zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) )
650                           zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) )
651                           zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) )
652                           ze0(ji,jj,jk) = zc0
653                           ze1(ji,jj,jk) = zc1
654                           ze2(ji,jj,jk) = zc2
655                           ze3(ji,jj,jk) = zc3
656                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
657                        END DO
658                     END DO
659                  END DO 
660                  !
661                  DO jk = 1, nksr
662                     ! (ISF) no light penetration below the ice shelves
663                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1)
664                  END DO
665                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
666               ENDIF
667            ENDIF
668            !
669         ENDIF
670            !                             ! ---------------------------------- !
671         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
672            !                             ! ---------------------------------- !
673            !
674            !                                ! level of light extinction
675            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
676            IF(lwp) THEN
677               WRITE(numout,*)
678            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
679            ENDIF
680            !
681            IF( lk_vvl ) THEN                   ! variable volume
682               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
683            ELSE                                ! constant volume: computes one for all
684               zz0 =        rn_abs   * r1_rau0_rcp
685               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
686               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
687                  DO jj = 1, jpj                              ! top 400 meters
688                     DO ji = 1, jpi
689                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
690                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
691                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) * tmask(ji,jj,1) 
692                     END DO
693                  END DO
694               END DO
695               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
696               !
697            ENDIF
698         ENDIF
699         !                       ! ===================================== !
700      ELSE                       !        No light penetration           !                   
701         !                       ! ===================================== !
702         IF(lwp) THEN
703            WRITE(numout,*)
704            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
705            WRITE(numout,*) '~~~~~~~~~~~~'
706         ENDIF
707      ENDIF
708      !
709      ! initialisation of fraqsr_1lev used in sbcssm
710      IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN
711         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev'  , fraqsr_1lev  )
712      ELSE
713         fraqsr_1lev(:,:) = 1._wp   ! default definition
714      ENDIF
715      !
716      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
717      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
718      !
719      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
720      !
721   END SUBROUTINE tra_qsr_init
722
723   !!======================================================================
724END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.