Context Navigation

← Previous Revision
Latest Revision
Next Revision →
Blame
Revision Log

sbcrnf.F90 @ 11286

Last change on this file since 11286 was 11286, checked in by dford, 5 years ago
Merge in latest version of AMM15_v3_6_STABLE_package_collate.
File size: 29.9 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE sbcisf ! PM we could remove it I think
22	USE closea ! closed seas
23	USE fldread ! read input field at current time step
24	USE in_out_manager ! I/O manager
25	USE iom ! I/O module
26	USE lib_mpp ! MPP library
27	USE eosbn2
28	USE wrk_nemo ! Memory allocation
29
30	IMPLICIT NONE
31	PRIVATE
32
33	PUBLIC sbc_rnf ! routine call in sbcmod module
34	PUBLIC sbc_rnf_div ! routine called in divcurl module
35	PUBLIC sbc_rnf_alloc ! routine call in sbcmod module
36	PUBLIC sbc_rnf_init ! (PUBLIC for TAM)
37	! !!* namsbc_rnf namelist *
38	CHARACTER(len=100) :: cn_dir !: Root directory for location of rnf files
39	LOGICAL :: ln_rnf_depth !: depth river runoffs attribute specified in a file
40	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
41	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
42	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
43	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44	LOGICAL :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
45	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
46	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
47	TYPE(FLD_N) :: sn_cnf !: information about the runoff mouth file to be read
48	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
49	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
50	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
51	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
52	REAL(wp) :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
53	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
54	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
55
56	LOGICAL , PUBLIC :: l_rnfcpl = .false. ! runoffs recieved from oasis
57
58	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
59	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
60	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
61	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
62	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
63	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
64
65	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
66	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
67	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
68
69	!! * Substitutions
70	# include "domzgr_substitute.h90"
71	!!----------------------------------------------------------------------
72	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
73	!! $Id$
74	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
75	!!----------------------------------------------------------------------
76	CONTAINS
77
78	INTEGER FUNCTION sbc_rnf_alloc()
79	!!----------------------------------------------------------------------
80	!! * ROUTINE sbc_rnf_alloc *
81	!!----------------------------------------------------------------------
82	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
83	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
84	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , &
85	& xrnfmask(jpi,jpj,1) , STAT=sbc_rnf_alloc )
86	!
87	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
88	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
89	END FUNCTION sbc_rnf_alloc
90
91
92	SUBROUTINE sbc_rnf( kt )
93	!!----------------------------------------------------------------------
94	!! * ROUTINE sbc_rnf *
95	!!
96	!! ** Purpose : Introduce a climatological run off forcing
97	!!
98	!! ** Method : Set each river mouth with a monthly climatology
99	!! provided from different data.
100	!! CAUTION : upward water flux, runoff forced to be < 0
101	!!
102	!! ** Action : runoff updated runoff field at time-step kt
103	!!----------------------------------------------------------------------
104	INTEGER, INTENT(in) :: kt ! ocean time step
105	!
106	INTEGER :: ji, jj ! dummy loop indices
107	INTEGER :: z_err = 0 ! dummy integer for error handling
108	!!----------------------------------------------------------------------
109	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
110	!
111	CALL wrk_alloc( jpi,jpj, ztfrz)
112
113	! ! ---------------------------------------- !
114	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
115	! ! ---------------------------------------- !
116	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
117	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
118	!
119	ENDIF
120
121	! !-------------------!
122	! ! Update runoff !
123	! !-------------------!
124	!
125	IF( .NOT. l_rnfcpl ) CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
126	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
127	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
128	!
129	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
130	!
131	IF( .NOT. l_rnfcpl ) &
132	rnf(:,:) = rnf(:,:) * (1. - xrnfmask(:,:,1)) + rn_rfact * sf_rnf(1)%fnow(:,:,1) * xrnfmask(:,:,1) ! updated runoff value at time step kt
133	!
134	! ! set temperature & salinity content of runoffs
135	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
136	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
137	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
138	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
139	END WHERE
140	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
141	ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
142	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
143	END WHERE
144	ELSE ! use SST as runoffs temperature
145	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
146	ENDIF
147	! ! use runoffs salinity data
148	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
149	! ! else use S=0 for runoffs (done one for all in the init)
150	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
151	ENDIF
152	!
153	! ! ---------------------------------------- !
154	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
155	! ! ---------------------------------------- !
156	IF( ln_rstart .AND. & !* Restart: read in restart file
157	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
158	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
159	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
160	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
161	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
162	ELSE !* no restart: set from nit000 values
163	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
164	rnf_b (:,: ) = rnf (:,: )
165	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
166	ENDIF
167	ENDIF
168	! ! ---------------------------------------- !
169	IF( lrst_oce ) THEN ! Write in the ocean restart file !
170	! ! ---------------------------------------- !
171	IF(lwp) WRITE(numout,*)
172	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
173	& 'at it= ', kt,' date= ', ndastp
174	IF(lwp) WRITE(numout,*) '~~~~'
175	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
176	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
177	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
178	ENDIF
179	!
180	CALL wrk_dealloc( jpi,jpj, ztfrz)
181	!
182	END SUBROUTINE sbc_rnf
183
184
185	SUBROUTINE sbc_rnf_div( phdivn )
186	!!----------------------------------------------------------------------
187	!! * ROUTINE sbc_rnf *
188	!!
189	!! ** Purpose : update the horizontal divergence with the runoff inflow
190	!!
191	!! ** Method :
192	!! CAUTION : rnf is positive (inflow) decreasing the
193	!! divergence and expressed in m/s
194	!!
195	!! ** Action : phdivn decreased by the runoff inflow
196	!!----------------------------------------------------------------------
197	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
198	!!
199	INTEGER :: ji, jj, jk ! dummy loop indices
200	REAL(wp) :: zfact ! local scalar
201	!!----------------------------------------------------------------------
202	!
203	zfact = 0.5_wp
204	!
205	IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN !== runoff distributed over several levels ==!
206	IF( lk_vvl ) THEN ! variable volume case
207	DO jj = 1, jpj ! update the depth over which runoffs are distributed
208	DO ji = 1, jpi
209	h_rnf(ji,jj) = 0._wp
210	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
211	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
212	END DO
213	! ! apply the runoff input flow
214	DO jk = 1, nk_rnf(ji,jj)
215	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
216	END DO
217	END DO
218	END DO
219	ELSE ! constant volume case : just apply the runoff input flow
220	DO jj = 1, jpj
221	DO ji = 1, jpi
222	DO jk = 1, nk_rnf(ji,jj)
223	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
224	END DO
225	END DO
226	END DO
227	ENDIF
228	ELSE !== runoff put only at the surface ==!
229	IF( lk_vvl ) THEN ! variable volume case
230	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
231	ENDIF
232	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
233	ENDIF
234	!
235	END SUBROUTINE sbc_rnf_div
236
237
238	SUBROUTINE sbc_rnf_init
239	!!----------------------------------------------------------------------
240	!! * ROUTINE sbc_rnf_init *
241	!!
242	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
243	!!
244	!! ** Method : - read the runoff namsbc_rnf namelist
245	!!
246	!! ** Action : - read parameters
247	!!----------------------------------------------------------------------
248	CHARACTER(len=32) :: rn_dep_file ! runoff file name
249	INTEGER :: ji, jj, jk, jm ! dummy loop indices
250	INTEGER :: ierror, inum ! temporary integer
251	INTEGER :: ios ! Local integer output status for namelist read
252	INTEGER :: nbrec ! temporary integer
253	REAL(wp) :: zacoef
254	REAL(wp), DIMENSION(12) :: zrec ! times records
255	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl
256	REAL(wp), DIMENSION(:,: ), ALLOCATABLE :: zrnf
257	!
258	NAMELIST/namsbc_rnf/ cn_dir , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
259	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
260	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
261	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file
262	!!----------------------------------------------------------------------
263	!
264	! !== allocate runoff arrays
265	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
266	!
267	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
268	ln_rnf_mouth = .FALSE. ! default definition needed for example by sbc_ssr or by tra_adv_muscl
269	nkrnf = 0
270	rnf (:,:) = 0.0_wp
271	rnf_b (:,:) = 0.0_wp
272	rnfmsk (:,:) = 0.0_wp
273	rnfmsk_z(:) = 0.0_wp
274	RETURN
275	ENDIF
276	!
277	! ! ============
278	! ! Namelist
279	! ! ============
280	!
281	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
282	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
283	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
284
285	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
286	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
287	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
288	IF(lwm) WRITE ( numond, namsbc_rnf )
289	!
290	! ! Control print
291	IF(lwp) THEN
292	WRITE(numout,*)
293	WRITE(numout,*) 'sbc_rnf : runoff '
294	WRITE(numout,*) '~~~~~~~ '
295	WRITE(numout,*) ' Namelist namsbc_rnf'
296	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
297	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
298	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
299	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
300	ENDIF
301	! ! ==================
302	! ! Type of runoff
303	! ! ==================
304	!
305	IF( .NOT. l_rnfcpl ) THEN
306	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
307	IF(lwp) WRITE(numout,*)
308	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
309	IF( ierror > 0 ) THEN
310	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
311	ENDIF
312	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
313	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
314	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
315	ENDIF
316	!
317	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
318	IF(lwp) WRITE(numout,*)
319	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
320	ALLOCATE( sf_t_rnf(1), STAT=ierror )
321	IF( ierror > 0 ) THEN
322	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
323	ENDIF
324	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
325	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
326	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
327	ENDIF
328	!
329	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
330	IF(lwp) WRITE(numout,*)
331	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
332	ALLOCATE( sf_s_rnf(1), STAT=ierror )
333	IF( ierror > 0 ) THEN
334	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
335	ENDIF
336	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
337	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
338	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
339	ENDIF
340	!
341	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
342	IF(lwp) WRITE(numout,*)
343	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
344	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
345	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
346	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
347	ENDIF
348	CALL iom_open ( rn_dep_file, inum ) ! open file
349	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
350	CALL iom_close( inum ) ! close file
351	!
352	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
353	DO jj = 1, jpj
354	DO ji = 1, jpi
355	IF( h_rnf(ji,jj) > 0._wp ) THEN
356	jk = 2
357	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
358	END DO
359	nk_rnf(ji,jj) = jk
360	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
361	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
362	ELSE
363	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
364	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
365	ENDIF
366	END DO
367	END DO
368	DO jj = 1, jpj ! set the associated depth
369	DO ji = 1, jpi
370	h_rnf(ji,jj) = 0._wp
371	DO jk = 1, nk_rnf(ji,jj)
372	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
373	END DO
374	END DO
375	END DO
376	!
377	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
378	!
379	IF(lwp) WRITE(numout,*)
380	IF(lwp) WRITE(numout,*) ' depth of runoff computed once from max value of runoff'
381	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
382	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
383	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
384
385	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
386	CALL iom_gettime( inum, zrec, kntime=nbrec)
387	ALLOCATE( zrnfcl(jpi,jpj,nbrec) ) ; ALLOCATE( zrnf(jpi,jpj) )
388	DO jm = 1, nbrec
389	CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
390	END DO
391	CALL iom_close( inum )
392	zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! maximum value in time
393	DEALLOCATE( zrnfcl )
394	!
395	h_rnf(:,:) = 1.
396	!
397	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
398	!
399	WHERE( zrnf(:,:) > 0._wp ) h_rnf(:,:) = zacoef * zrnf(:,:) ! compute depth for all runoffs
400	!
401	DO jj = 1, jpj ! take in account min depth of ocean rn_hmin
402	DO ji = 1, jpi
403	IF( zrnf(ji,jj) > 0._wp ) THEN
404	jk = mbkt(ji,jj)
405	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
406	ENDIF
407	END DO
408	END DO
409	!
410	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
411	DO jj = 1, jpj
412	DO ji = 1, jpi
413	IF( zrnf(ji,jj) > 0._wp ) THEN
414	jk = 2
415	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
416	END DO
417	nk_rnf(ji,jj) = jk
418	ELSE
419	nk_rnf(ji,jj) = 1
420	ENDIF
421	END DO
422	END DO
423	!
424	DEALLOCATE( zrnf )
425	!
426	DO jj = 1, jpj ! set the associated depth
427	DO ji = 1, jpi
428	h_rnf(ji,jj) = 0._wp
429	DO jk = 1, nk_rnf(ji,jj)
430	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
431	END DO
432	END DO
433	END DO
434	!
435	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
436	IF(lwp) WRITE(numout,*) ' create runoff depht file'
437	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
438	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
439	CALL iom_close ( inum )
440	ENDIF
441	ELSE ! runoffs applied at the surface
442	nk_rnf(:,:) = 1
443	h_rnf (:,:) = fse3t(:,:,1)
444	ENDIF
445	!
446	xrnfmask(:,:,:) = 1. ! default value for points using river forcing
447	IF (ln_usernfmask) THEN
448	IF(lwp) WRITE(numout,*)
449	IF(lwp) WRITE(numout,*) ' runoff mask read in a file'
450	CALL iom_open( 'rnfmask', inum )
451	CALL iom_get( inum, jpdom_data, 'rnfmask', xrnfmask(:,:,1), 1)
452	CALL iom_close( inum )
453	ENDIF
454	!
455	rnf(:,:) = 0._wp ! runoff initialisation
456	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
457	!
458	! ! ========================
459	! ! River mouth vicinity
460	! ! ========================
461	!
462	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
463	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
464	! ! - set to zero SSS damping (ln_ssr=T)
465	! ! - mixed upstream-centered (ln_traadv_cen2=T)
466	!
467	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
468	& 'be spread through depth by ln_rnf_depth' )
469	!
470	nkrnf = 0 ! Number of level over which Kz increase
471	IF( rn_hrnf > 0._wp ) THEN
472	nkrnf = 2
473	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1
474	END DO
475	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
476	ENDIF
477	IF(lwp) WRITE(numout,*)
478	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
479	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
480	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
481	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
482	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
483	!
484	CALL rnf_mouth ! set river mouth mask
485	!
486	ELSE ! No treatment at river mouths
487	IF(lwp) WRITE(numout,*)
488	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
489	rnfmsk (:,:) = 0._wp
490	rnfmsk_z(:) = 0._wp
491	nkrnf = 0
492	ENDIF
493	!
494	END SUBROUTINE sbc_rnf_init
495
496
497	SUBROUTINE rnf_mouth
498	!!----------------------------------------------------------------------
499	!! * ROUTINE rnf_mouth *
500	!!
501	!! ** Purpose : define the river mouths mask
502	!!
503	!! ** Method : read the river mouth mask (=0/1) in the river runoff
504	!! climatological file. Defined a given vertical structure.
505	!! CAUTION, the vertical structure is hard coded on the
506	!! first 5 levels.
507	!! This fields can be used to:
508	!! - set an upstream advection scheme
509	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
510	!! - increase vertical on the top nn_krnf vertical levels
511	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
512	!! - set to zero SSS restoring flux at river mouth grid points
513	!!
514	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
515	!! rnfmsk_z vertical structure
516	!!----------------------------------------------------------------------
517	INTEGER :: inum ! temporary integers
518	CHARACTER(len=140) :: cl_rnfile ! runoff file name
519	!!----------------------------------------------------------------------
520	!
521	IF(lwp) WRITE(numout,*)
522	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
523	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
524	!
525	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
526	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
527	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
528	ENDIF
529	!
530	! horizontal mask (read in NetCDF file)
531	CALL iom_open ( cl_rnfile, inum ) ! open file
532	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
533	CALL iom_close( inum ) ! close file
534	!
535	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
536	!
537	rnfmsk_z(:) = 0._wp ! vertical structure
538	rnfmsk_z(1) = 1.0
539	rnfmsk_z(2) = 1.0 ! **********
540	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
541	rnfmsk_z(4) = 0.25 ! **********
542	rnfmsk_z(5) = 0.125
543	!
544	END SUBROUTINE rnf_mouth
545
546	!!======================================================================
547	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/AMM15_v3_6_STABLE_package_collate_xeps/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 11286

Download in other formats: