New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
obsinter_z1d.h90 in branches/UKMO/AMM15_v3_6_STABLE_package_reanalysis3/NEMOGCM/NEMO/OPA_SRC/OBS – NEMO

source: branches/UKMO/AMM15_v3_6_STABLE_package_reanalysis3/NEMOGCM/NEMO/OPA_SRC/OBS/obsinter_z1d.h90

Last change on this file was 11260, checked in by rrenshaw, 5 years ago

further fix for ob below model bathymetry
File size: 7.8 KB
Line 
1   !!----------------------------------------------------------------------
2   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
3   !! $Id$
4   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
5   !!----------------------------------------------------------------------
6
7   SUBROUTINE obs_int_z1d( kpk, kkco, k1dint, kdep, &
8      &                    pobsdep, pobsk, pobs2k,  &
9      &                    pobs, pdep, pobsmask )
10      !!---------------------------------------------------------------------
11      !!
12      !!                   ***  ROUTINE obs_int_z1d ***
13      !!
14      !! ** Purpose : Vertical interpolation to the observation point.
15      !! 
16      !! ** Method  : If k1dint = 0 then use linear interpolation.
17      !!              If k1dint = 1 then use cubic spline interpolation.
18      !!
19      !! ** Action  :
20      !!
21      !! References :
22      !!
23      !! History
24      !!      ! 97-11 (A. Weaver, S. Ricci, N. Daget)
25      !!      ! 06-03 (G. Smith) Conversion to F90 for use with NEMOVAR
26      !!      ! 06-10 (A. Weaver) Cleanup
27      !!      ! 07-01 (K. Mogensen) Use profile rather than single level
28      !!      ! 19-07 (R. Renshaw) Avoid division by zero
29      !!---------------------------------------------------------------------
30
31      !! * Arguments
32      INTEGER, INTENT(IN) :: kpk        ! Number of vertical levels
33      INTEGER, INTENT(IN) :: k1dint     ! 0 = linear; 1 = cubic spline interpolation
34      INTEGER, INTENT(IN) :: kdep       ! Number of levels in profile
35      INTEGER, INTENT(IN), DIMENSION(kdep) :: &
36         & kkco                 ! Array indicies for interpolation
37      REAL(KIND=wp), INTENT(IN), DIMENSION(kdep) :: &
38         & pobsdep              ! Depth of the observation
39      REAL(KIND=wp), INTENT(IN), DIMENSION(kpk) :: &
40         & pobsk,  &            ! Model profile at a given (lon,lat)
41         & pobs2k, &            ! 2nd derivative of the interpolating function
42         & pdep,   &            ! Model depth array
43         & pobsmask             ! Vertical mask
44      REAL(KIND=wp), INTENT(OUT), DIMENSION(kdep) :: &
45         & pobs                 ! Model equivalent at observation point
46 
47      !! * Local declarations
48      REAL(KIND=wp) :: z1dm       ! Distance above and below obs to model grid points
49      REAL(KIND=wp) :: z1dp         
50      REAL(KIND=wp) :: zsum       ! Dummy variables for computation
51      REAL(KIND=wp) :: zsum2
52      INTEGER :: jdep             ! Observation depths loop variable
53   
54      !------------------------------------------------------------------------
55      ! Loop over all observation depths
56      !------------------------------------------------------------------------
57
58      DO jdep = 1, kdep
59
60         !---------------------------------------------------------------------
61         ! Initialization
62         !---------------------------------------------------------------------
63         z1dm = ( pdep(kkco(jdep)) - pobsdep(jdep)      )
64         z1dp = ( pobsdep(jdep)    - pdep(kkco(jdep)-1) )
65!        Where ob is below model bottom, use model bottom rather than extrapolate
66         IF ( pdep(kkco(jdep)) <= pobsdep(jdep) ) z1dm = 0.0_wp
67!        Where lower level is missing, use higher level
68         IF ( pobsmask(kkco(jdep)) == 0.0_wp ) z1dp = 0.0_wp
69
70         zsum = z1dm + z1dp
71         ! if pobsmask==0 and model level depth==observed depth, we get zsum=0
72         IF ( zsum > 0.0_wp ) THEN
73         
74         IF ( k1dint == 0 ) THEN
75
76            !-----------------------------------------------------------------
77            !  Linear interpolation
78            !-----------------------------------------------------------------
79            pobs(jdep) = (   z1dm * pobsk(kkco(jdep)-1) &
80               &           + z1dp * pobsk(kkco(jdep)  ) ) / zsum
81
82         ELSEIF ( k1dint == 1 ) THEN
83
84            !-----------------------------------------------------------------
85            ! Cubic spline interpolation
86            !-----------------------------------------------------------------
87            zsum2 = zsum * zsum
88            pobs(jdep)  = (  z1dm                             * pobsk (kkco(jdep)-1) &
89               &           + z1dp                             * pobsk (kkco(jdep)  ) &
90               &           + ( z1dm * ( z1dm * z1dm - zsum2 ) * pobs2k(kkco(jdep)-1) &
91               &           +   z1dp * ( z1dp * z1dp - zsum2 ) * pobs2k(kkco(jdep)  ) &
92               &             ) / 6.0_wp                                              &
93               &          ) / zsum
94
95         ENDIF
96
97         ELSE  ! take value directly from the higher model level
98            pobs(jdep)  = pobsk(kkco(jdep)-1)
99         ENDIF
100
101      END DO
102
103   END SUBROUTINE obs_int_z1d
104
105   SUBROUTINE obs_int_z1d_spl( kpk, pobsk, pobs2k, &
106      &                        pdep, pobsmask )
107      !!--------------------------------------------------------------------
108      !!
109      !!                  *** ROUTINE obs_int_z1d_spl ***
110      !!
111      !! ** Purpose : Compute the local vector of vertical second-derivatives
112      !!              of the interpolating function used with a cubic spline.
113      !! 
114      !! ** Method  :
115      !!
116      !!    Top and bottom boundary conditions on the 2nd derivative are
117      !!    set to zero.
118      !!
119      !! ** Action  :
120      !!
121      !! References :
122      !!
123      !! History
124      !!      ! 01-11 (A. Weaver, S. Ricci, N. Daget)
125      !!      ! 06-03 (G. Smith) Conversion to F90 for use with NEMOVAR
126      !!      ! 06-10 (A. Weaver) Cleanup
127      !!----------------------------------------------------------------------
128     
129      !! * Arguments
130      INTEGER, INTENT(IN) :: kpk               ! Number of vertical levels
131      REAL(KIND=wp), INTENT(IN), DIMENSION(kpk) :: &
132         & pobsk, &          ! Model profile at a given (lon,lat)
133         & pdep,  &          ! Model depth array
134         & pobsmask          ! Vertical mask
135      REAL(KIND=wp), INTENT(OUT), DIMENSION(kpk) :: &
136         & pobs2k            ! 2nd derivative of the interpolating function
137 
138      !! * Local declarations
139      INTEGER :: jk
140      REAL(KIND=wp) :: za
141      REAL(KIND=wp) :: zb
142      REAL(KIND=wp) :: zc
143      REAL(KIND=wp) :: zpa
144      REAL(KIND=wp) :: zkm
145      REAL(KIND=wp) :: zkp
146      REAL(KIND=wp) :: zk
147      REAL(KIND=wp), DIMENSION(kpk-1) :: &
148         & zs, &
149         & zp, &
150         & zu, &
151         & zv
152
153      !-----------------------------------------------------------------------
154      ! Matrix initialisation
155      !-----------------------------------------------------------------------
156      zs(1) =  0.0_wp
157      zp(1) =  0.0_wp
158      zv(1) = -0.5_wp
159      DO jk = 2, kpk-1
160         zs(jk) =  ( pdep(jk  ) - pdep(jk-1) ) &
161            &    / ( pdep(jk+1) - pdep(jk-1) )
162         zp(jk) = zs(jk) * zv(jk-1) + 2.0_wp
163         zv(jk) = ( zs(jk) - 1.0_wp ) / zp(jk)
164      END DO
165 
166      !-----------------------------------------------------------------------
167      ! Solution of the tridiagonal system
168      !-----------------------------------------------------------------------
169 
170      ! Top boundary condition
171      zu(1) = 0.0_wp
172 
173      DO jk = 2, kpk-1
174         za = pdep(jk+1) - pdep(jk-1)
175         zb = pdep(jk+1) - pdep(jk  )
176         zc = pdep(jk  ) - pdep(jk-1)
177 
178         zpa = 6.0_wp / ( zp(jk) * za )
179         zkm = zpa / zc
180         zkp = zpa / zb
181         zk  = - ( zkm + zkp )
182 
183         zu(jk) =  pobsk(jk+1) * zkp  &
184            &    + pobsk(jk  ) * zk   &
185            &    + pobsk(jk-1) * zkm  &
186            &    + zu(jk-1) * ( -zs(jk) / zp(jk) )
187      END DO
188 
189      !-----------------------------------------------------------------------
190      ! Second derivative
191      !-----------------------------------------------------------------------
192      pobs2k(kpk) = 0.0_wp
193 
194      ! Bottom boundary condition
195      DO jk = kpk-1, 1, -1
196         pobs2k(jk) = zv(jk) * pobs2k(jk+1) + zu(jk)
197         IF ( pobsmask(jk+1) == 0.0_wp ) pobs2k(jk) = 0.0_wp
198      END DO
199 
200  END SUBROUTINE obs_int_z1d_spl
201
202
Note: See TracBrowser for help on using the repository browser.