source: branches/UKMO/AMM15_v3_6_STABLE_package_reanalysis4/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 11639

Last change on this file since 11639 was 11639, checked in by rrenshaw, 14 months ago

regional mean and transport diagnostics added for reanalysis

File size: 41.7 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48#if defined key_nemocice_decomp
49   USE ice_domain_size, only: nx_global, ny_global
50#endif
51   USE tideini         ! tidal components initialization   (tide_ini routine)
52   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
53   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
54   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
55   USE istate          ! initial state setting          (istate_init routine)
56   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
57   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
58   USE zdfini          ! vertical physics setting          (zdf_init routine)
59   USE phycst          ! physical constant                  (par_cst routine)
60   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
61   USE asminc          ! assimilation increments     
62   USE asmbkg          ! writing out state trajectory
63   USE asmbgc          ! biogeochemical assimilation increments
64   USE diaptr          ! poleward transports           (dia_ptr_init routine)
65   USE diadct          ! sections transports           (dia_dct_init routine)
66   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
67   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68   USE step            ! NEMO time-stepping                 (stp     routine)
69   USE icbini          ! handle bergs, initialisation
70   USE icbstp          ! handle bergs, calving, themodynamics and transport
71   USE sbccpl
72   USE cpl_oasis3      ! OASIS3 coupling
73   USE c1d             ! 1D configuration
74   USE step_c1d        ! Time stepping loop for the 1D configuration
75   USE dyndmp          ! Momentum damping
76#if defined key_top
77   USE trcini          ! passive tracer initialisation
78#endif
79   USE lib_mpp         ! distributed memory computing
80#if defined key_iomput
81   USE xios
82#endif
83   USE sbctide, ONLY: lk_tide
84   USE crsini          ! initialise grid coarsening utility
85   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
86   USE sbc_oce, ONLY: lk_oasis
87   USE stopar
88   USE stopts
89   USE diatmb          ! Top,middle,bottom output
90   USE diaregmean      ! regional means output
91   USE diapea          ! potential energy anomaly output
92   USE dia25h          ! 25h mean output
93   USE diaopfoam       ! FOAM operational output
94   USE diurnal_bulk    ! diurnal bulk SST
95
96   IMPLICIT NONE
97   PRIVATE
98
99   PUBLIC   nemo_gcm    ! called by model.F90
100   PUBLIC   nemo_init   ! needed by AGRIF
101   PUBLIC   nemo_alloc  ! needed by TAM
102
103   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
104
105   !!----------------------------------------------------------------------
106   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
107   !! $Id$
108   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
109   !!----------------------------------------------------------------------
110CONTAINS
111
112   SUBROUTINE nemo_gcm
113      !!----------------------------------------------------------------------
114      !!                     ***  ROUTINE nemo_gcm  ***
115      !!
116      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
117      !!              curvilinear mesh on the sphere.
118      !!
119      !! ** Method  : - model general initialization
120      !!              - launch the time-stepping (stp routine)
121      !!              - finalize the run by closing files and communications
122      !!
123      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
124      !!              Madec, 2008, internal report, IPSL.
125      !!----------------------------------------------------------------------
126      INTEGER ::   istp       ! time step index
127      !!----------------------------------------------------------------------
128      !
129#if defined key_agrif
130      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
131#endif
132
133      !                            !-----------------------!
134      CALL nemo_init               !==  Initialisations  ==!
135      !                            !-----------------------!
136#if defined key_agrif
137      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
138      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
139# if defined key_top
140      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
141# endif
142# if defined key_lim2
143      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
144# endif
145#endif
146      ! check that all process are still there... If some process have an error,
147      ! they will never enter in step and other processes will wait until the end of the cpu time!
148      IF( lk_mpp )   CALL mpp_max( nstop )
149
150      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
151
152      !                            !-----------------------!
153      !                            !==   time stepping   ==!
154      !                            !-----------------------!
155      istp = nit000
156#if defined key_c1d
157         DO WHILE ( istp <= nitend .AND. nstop == 0 )
158            CALL stp_c1d( istp )
159            istp = istp + 1
160         END DO
161#else
162          IF( lk_asminc ) THEN
163             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
164             IF( ln_asmdin ) THEN                        ! Direct initialization
165                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
166                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
167                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
168                IF( lk_bgcinc ) CALL bgc_asm_inc( nit000 - 1 )    ! BGC
169             ENDIF
170          ENDIF
171
172#if defined key_agrif
173          CALL Agrif_Regrid()
174#endif
175
176         DO WHILE ( istp <= nitend .AND. nstop == 0 )
177#if defined key_agrif
178            CALL stp                         ! AGRIF: time stepping
179#else
180            IF (lk_oasis) CALL sbc_cpl_snd( istp )  ! Coupling to atmos   
181            CALL stp( istp )   
182            ! We don't couple on the final timestep because   
183            ! our restart file has already been written   
184            ! and contains all the necessary data for a   
185            ! restart. sbc_cpl_snd could be called here   
186            ! but it would require   
187            ! a) A test to ensure it was not performed   
188            !    on the very last time-step   
189            ! b) the presence of another call to   
190            !    sbc_cpl_snd call prior to the main DO loop   
191            ! This solution produces identical results   
192            ! with fewer lines of code. 
193#endif
194            istp = istp + 1
195            IF( lk_mpp )   CALL mpp_max( nstop )
196         END DO
197#endif
198
199      IF( lk_diaobs   )   CALL dia_obs_wri
200      !
201      IF( ( lk_asminc ).AND.( ln_balwri ) ) CALL asm_bgc_bal_wri( nitend )  ! Output balancing increments
202      !
203      IF( ln_icebergs )   CALL icb_end( nitend )
204
205      !                            !------------------------!
206      !                            !==  finalize the run  ==!
207      !                            !------------------------!
208      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
209      !
210      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
211         WRITE(numout,cform_err)
212         WRITE(numout,*) nstop, ' error have been found'
213      ENDIF
214      !
215#if defined key_agrif
216      IF( .NOT. Agrif_Root() ) THEN
217         CALL Agrif_ParentGrid_To_ChildGrid()
218         IF( lk_diaobs ) CALL dia_obs_wri
219         IF( nn_timing == 1 )   CALL timing_finalize
220         CALL Agrif_ChildGrid_To_ParentGrid()
221      ENDIF
222#endif
223      IF( nn_timing == 1 )   CALL timing_finalize
224      !
225      CALL nemo_closefile
226      !
227#if defined key_iomput
228      CALL xios_finalize                ! end mpp communications with xios
229      IF( lk_oasis ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
230#else
231      IF( lk_oasis ) THEN
232         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
233      ELSE
234         IF( lk_mpp )   CALL mppstop    ! end mpp communications
235      ENDIF
236#endif
237      !
238   END SUBROUTINE nemo_gcm
239
240
241   SUBROUTINE nemo_init
242      !!----------------------------------------------------------------------
243      !!                     ***  ROUTINE nemo_init  ***
244      !!
245      !! ** Purpose :   initialization of the NEMO GCM
246      !!----------------------------------------------------------------------
247      INTEGER ::   ji            ! dummy loop indices
248      INTEGER ::   ilocal_comm   ! local integer
249      INTEGER ::   ios
250      CHARACTER(len=80), DIMENSION(16) ::   cltxt
251      !
252      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
253         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
254         &             nn_bench, nn_timing
255      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
256         &             jpizoom, jpjzoom, jperio, ln_use_jattr
257      !!----------------------------------------------------------------------
258      !
259      cltxt = ''
260      cxios_context = 'nemo'
261      !
262      !                             ! Open reference namelist and configuration namelist files
263      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
264      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
265      !
266      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
267      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
268901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
269
270      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
271      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
272902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
273
274      !
275      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
276      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
277903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
278
279      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
280      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
281904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
282
283! Force values for AGRIF zoom (cf. agrif_user.F90)
284#if defined key_agrif
285   IF( .NOT. Agrif_Root() ) THEN
286      jpiglo  = nbcellsx + 2 + 2*nbghostcells
287      jpjglo  = nbcellsy + 2 + 2*nbghostcells
288      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
289      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
290      jpidta  = jpiglo
291      jpjdta  = jpjglo
292      jpizoom = 1
293      jpjzoom = 1
294      nperio  = 0
295      jperio  = 0
296      ln_use_jattr = .false.
297   ENDIF
298#endif
299      !
300      !                             !--------------------------------------------!
301      !                             !  set communicator & select the local node  !
302      !                             !  NB: mynode also opens output.namelist.dyn !
303      !                             !      on unit number numond on first proc   !
304      !                             !--------------------------------------------!
305#if defined key_iomput
306      IF( Agrif_Root() ) THEN
307         IF( lk_oasis ) THEN
308            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
309            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
310         ELSE
311            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
312         ENDIF
313      ENDIF
314      ! Nodes selection (control print return in cltxt)
315      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
316#else
317      IF( lk_oasis ) THEN
318         IF( Agrif_Root() ) THEN
319            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
320         ENDIF
321         ! Nodes selection (control print return in cltxt)
322         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
323      ELSE
324         ilocal_comm = 0
325         ! Nodes selection (control print return in cltxt)
326         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
327      ENDIF
328#endif
329      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
330
331      lwm = (narea == 1)                                    ! control of output namelists
332      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
333
334      IF(lwm) THEN
335         ! write merged namelists from earlier to output namelist now that the
336         ! file has been opened in call to mynode. nammpp has already been
337         ! written in mynode (if lk_mpp_mpi)
338         WRITE( numond, namctl )
339         WRITE( numond, namcfg )
340      ENDIF
341
342      ! If dimensions of processor grid weren't specified in the namelist file
343      ! then we calculate them here now that we have our communicator size
344      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
345#if   defined key_mpp_mpi
346         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
347#else
348         jpni  = 1
349         jpnj  = 1
350         jpnij = jpni*jpnj
351#endif
352      END IF
353
354      ! Calculate domain dimensions given calculated jpni and jpnj
355      ! This used to be done in par_oce.F90 when they were parameters rather
356      ! than variables
357      IF( Agrif_Root() ) THEN
358#if defined key_nemocice_decomp
359         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
360         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
361#else
362         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
363         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
364#endif
365      ENDIF         
366         jpk = jpkdta                                             ! third dim
367#if defined key_agrif
368         ! simple trick to use same vertical grid as parent
369         ! but different number of levels:
370         ! Save maximum number of levels in jpkdta, then define all vertical grids
371         ! with this number.
372         ! Suppress once vertical online interpolation is ok
373         IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
374#endif
375         jpim1 = jpi-1                                            ! inner domain indices
376         jpjm1 = jpj-1                                            !   "           "
377         jpkm1 = jpk-1                                            !   "           "
378         jpij  = jpi*jpj                                          !  jpi x j
379
380      IF(lwp) THEN                            ! open listing units
381         !
382         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
383         !
384         WRITE(numout,*)
385         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
386         WRITE(numout,*) '                       NEMO team'
387         WRITE(numout,*) '            Ocean General Circulation Model'
388         WRITE(numout,*) '                  version 3.6  (2015) '
389         WRITE(numout,*)
390         WRITE(numout,*)
391         DO ji = 1, SIZE(cltxt)
392            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
393         END DO
394         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
395         !
396      ENDIF
397
398      ! Now we know the dimensions of the grid and numout has been set we can
399      ! allocate arrays
400      CALL nemo_alloc()
401
402      !                             !-------------------------------!
403      !                             !  NEMO general initialization  !
404      !                             !-------------------------------!
405
406      CALL nemo_ctl                          ! Control prints & Benchmark
407
408      !                                      ! Domain decomposition
409      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
410      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
411      ENDIF
412      !
413      IF( nn_timing == 1 )  CALL timing_init
414      !
415      !                                      ! General initialization
416                            CALL     phy_cst    ! Physical constants
417                            CALL     eos_init   ! Equation of state
418      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
419                            CALL     dom_cfg    ! Domain configuration
420                            CALL     dom_init   ! Domain
421
422      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
423
424      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
425
426                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
427
428      CALL diurnal_sst_bulk_init                ! diurnal sst
429      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin 
430
431      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
432
433                            CALL     sbc_init   ! Forcings : surface module (clem: moved here for bdy purpose)
434
435      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
436      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
437      IF( lk_bdy .AND. lk_tide )   &
438         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
439
440                            CALL dyn_nept_init  ! simplified form of Neptune effect
441      !     
442      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
443      !
444                                ! Ocean physics
445      !                                         ! Vertical physics
446                            CALL     zdf_init      ! namelist read
447                            CALL zdf_bfr_init      ! bottom friction
448      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
449      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
450      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
451      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
452      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
453      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
454         &                  CALL zdf_ddm_init      ! double diffusive mixing
455      !                                         ! Lateral physics
456                            CALL ldf_tra_init      ! Lateral ocean tracer physics
457                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
458      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
459
460      !                                     ! Active tracers
461                            CALL tra_qsr_init   ! penetrative solar radiation qsr
462                            CALL tra_bbc_init   ! bottom heat flux
463      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
464                            CALL tra_dmp_init   ! internal damping trends- tracers
465                            CALL tra_adv_init   ! horizontal & vertical advection
466                            CALL tra_ldf_init   ! lateral mixing
467                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
468
469      !                                     ! Dynamics
470      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
471                            CALL dyn_adv_init   ! advection (vector or flux form)
472                            CALL dyn_vor_init   ! vorticity term including Coriolis
473                            CALL dyn_ldf_init   ! lateral mixing
474                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
475                            CALL dyn_zdf_init   ! vertical diffusion
476                            CALL dyn_spg_init   ! surface pressure gradient
477
478      !                                     ! Misc. options
479      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
480                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
481                            CALL sto_par_init   ! Stochastic parametrization
482      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
483     
484#if defined key_top
485      !                                     ! Passive tracers
486                            CALL     trc_init
487#endif
488      !                                     ! Diagnostics
489      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
490      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
491                            CALL dia_ptr_init   ! Poleward TRansports initialization
492      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
493                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
494                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
495      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
496                            CALL dia_obs_init            ! Initialize observational data
497                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
498      ENDIF
499
500      !                                     ! Assimilation increments
501      IF( lk_asminc ) THEN 
502#if defined key_shelf 
503         CALL  zdf_mxl_tref()     ! Initialization of hmld_tref
504#endif
505         CALL asm_inc_init     ! Initialize assimilation increments
506      ENDIF
507
508      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
509                            CALL dia_tmb_init  ! TMB outputs
510                            CALL dia_regmean_init  ! TMB outputs
511                            CALL dia_pea_init  ! TMB outputs
512                            CALL dia_25h_init  ! 25h mean  outputs
513                            CALL dia_diaopfoam_init  ! FOAM operational output
514      !
515   END SUBROUTINE nemo_init
516
517
518   SUBROUTINE nemo_ctl
519      !!----------------------------------------------------------------------
520      !!                     ***  ROUTINE nemo_ctl  ***
521      !!
522      !! ** Purpose :   control print setting
523      !!
524      !! ** Method  : - print namctl information and check some consistencies
525      !!----------------------------------------------------------------------
526      !
527      IF(lwp) THEN                  ! control print
528         WRITE(numout,*)
529         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
530         WRITE(numout,*) '~~~~~~~ '
531         WRITE(numout,*) '   Namelist namctl'
532         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
533         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
534         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
535         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
536         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
537         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
538         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
539         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
540         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
541         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
542      ENDIF
543      !
544      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
545      nictls    = nn_ictls
546      nictle    = nn_ictle
547      njctls    = nn_jctls
548      njctle    = nn_jctle
549      isplt     = nn_isplt
550      jsplt     = nn_jsplt
551      nbench    = nn_bench
552
553      IF(lwp) THEN                  ! control print
554         WRITE(numout,*)
555         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
556         WRITE(numout,*) '~~~~~~~ '
557         WRITE(numout,*) '   Namelist namcfg'
558         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
559         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
560         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
561         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
562         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
563         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
564         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
565         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
566         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
567         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
568         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
569         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
570      ENDIF
571      !                             ! Parameter control
572      !
573      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
574         IF( lk_mpp .AND. jpnij > 1 ) THEN
575            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
576         ELSE
577            IF( isplt == 1 .AND. jsplt == 1  ) THEN
578               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
579                  &           ' - the print control will be done over the whole domain' )
580            ENDIF
581            ijsplt = isplt * jsplt            ! total number of processors ijsplt
582         ENDIF
583         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
584         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
585         !
586         !                              ! indices used for the SUM control
587         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
588            lsp_area = .FALSE.
589         ELSE                                             ! print control done over a specific  area
590            lsp_area = .TRUE.
591            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
592               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
593               nictls = 1
594            ENDIF
595            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
596               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
597               nictle = jpiglo
598            ENDIF
599            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
600               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
601               njctls = 1
602            ENDIF
603            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
604               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
605               njctle = jpjglo
606            ENDIF
607         ENDIF
608      ENDIF
609      !
610      IF( nbench == 1 ) THEN              ! Benchmark
611         SELECT CASE ( cp_cfg )
612         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
613         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
614            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
615         END SELECT
616      ENDIF
617      !
618      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
619         &                                               'f2003 standard. '                              ,  &
620         &                                               'Compile with key_nosignedzero enabled' )
621      !
622   END SUBROUTINE nemo_ctl
623
624
625   SUBROUTINE nemo_closefile
626      !!----------------------------------------------------------------------
627      !!                     ***  ROUTINE nemo_closefile  ***
628      !!
629      !! ** Purpose :   Close the files
630      !!----------------------------------------------------------------------
631      !
632      IF( lk_mpp )   CALL mppsync
633      !
634      CALL iom_close                                 ! close all input/output files managed by iom_*
635      !
636      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
637      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
638      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
639      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
640      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
641      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
642      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
643      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
644      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
645      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
646      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
647      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
648      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
649      IF( numdct_NOOS     /= -1 )   CLOSE( numdct_NOOS     )   ! NOOS transports
650
651      !
652      numout = 6                                     ! redefine numout in case it is used after this point...
653      !
654   END SUBROUTINE nemo_closefile
655
656
657   SUBROUTINE nemo_alloc
658      !!----------------------------------------------------------------------
659      !!                     ***  ROUTINE nemo_alloc  ***
660      !!
661      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
662      !!
663      !! ** Method  :
664      !!----------------------------------------------------------------------
665      USE diawri    , ONLY: dia_wri_alloc
666      USE dom_oce   , ONLY: dom_oce_alloc
667      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
668      USE ldftra_oce, ONLY: ldftra_oce_alloc
669      USE trc_oce   , ONLY: trc_oce_alloc
670      USE diainsitutem, ONLY: insitu_tem_alloc
671#if defined key_diadct 
672      USE diadct    , ONLY: diadct_alloc 
673#endif 
674#if defined key_bdy
675      USE bdy_oce   , ONLY: bdy_oce_alloc
676#endif
677      !
678      INTEGER :: ierr
679      !!----------------------------------------------------------------------
680      !
681      ierr =        oce_alloc       ()          ! ocean
682      ierr = ierr + dia_wri_alloc   ()
683      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
684      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
685      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
686      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
687      ierr = ierr + insitu_tem_alloc()
688      !
689      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
690      !
691#if defined key_diadct 
692      ierr = ierr + diadct_alloc    ()          !
693#endif 
694#if defined key_bdy
695      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
696#endif
697      !
698      IF( lk_mpp    )   CALL mpp_sum( ierr )
699      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
700      !
701   END SUBROUTINE nemo_alloc
702
703
704   SUBROUTINE nemo_partition( num_pes )
705      !!----------------------------------------------------------------------
706      !!                 ***  ROUTINE nemo_partition  ***
707      !!
708      !! ** Purpose :
709      !!
710      !! ** Method  :
711      !!----------------------------------------------------------------------
712      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
713      !
714      INTEGER, PARAMETER :: nfactmax = 20
715      INTEGER :: nfact ! The no. of factors returned
716      INTEGER :: ierr  ! Error flag
717      INTEGER :: ji
718      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
719      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
720      !!----------------------------------------------------------------------
721      !
722      ierr = 0
723      !
724      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
725      !
726      IF( nfact <= 1 ) THEN
727         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
728         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
729         jpnj = 1
730         jpni = num_pes
731      ELSE
732         ! Search through factors for the pair that are closest in value
733         mindiff = 1000000
734         imin    = 1
735         DO ji = 1, nfact-1, 2
736            idiff = ABS( ifact(ji) - ifact(ji+1) )
737            IF( idiff < mindiff ) THEN
738               mindiff = idiff
739               imin = ji
740            ENDIF
741         END DO
742         jpnj = ifact(imin)
743         jpni = ifact(imin + 1)
744      ENDIF
745      !
746      jpnij = jpni*jpnj
747      !
748   END SUBROUTINE nemo_partition
749
750
751   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
752      !!----------------------------------------------------------------------
753      !!                     ***  ROUTINE factorise  ***
754      !!
755      !! ** Purpose :   return the prime factors of n.
756      !!                knfax factors are returned in array kfax which is of
757      !!                maximum dimension kmaxfax.
758      !! ** Method  :
759      !!----------------------------------------------------------------------
760      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
761      INTEGER                    , INTENT(  out) ::   kerr, knfax
762      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
763      !
764      INTEGER :: ifac, jl, inu
765      INTEGER, PARAMETER :: ntest = 14
766      INTEGER, DIMENSION(ntest) :: ilfax
767      !
768      ! ilfax contains the set of allowed factors.
769      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
770      !!----------------------------------------------------------------------
771      ! ilfax contains the set of allowed factors.
772      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
773
774      ! Clear the error flag and initialise output vars
775      kerr = 0
776      kfax = 1
777      knfax = 0
778
779      ! Find the factors of n.
780      IF( kn == 1 )   GOTO 20
781
782      ! nu holds the unfactorised part of the number.
783      ! knfax holds the number of factors found.
784      ! l points to the allowed factor list.
785      ! ifac holds the current factor.
786
787      inu   = kn
788      knfax = 0
789
790      DO jl = ntest, 1, -1
791         !
792         ifac = ilfax(jl)
793         IF( ifac > inu )   CYCLE
794
795         ! Test whether the factor will divide.
796
797         IF( MOD(inu,ifac) == 0 ) THEN
798            !
799            knfax = knfax + 1            ! Add the factor to the list
800            IF( knfax > kmaxfax ) THEN
801               kerr = 6
802               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
803               return
804            ENDIF
805            kfax(knfax) = ifac
806            ! Store the other factor that goes with this one
807            knfax = knfax + 1
808            kfax(knfax) = inu / ifac
809            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
810         ENDIF
811         !
812      END DO
813
814   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
815      !
816   END SUBROUTINE factorise
817
818#if defined key_mpp_mpi
819
820   SUBROUTINE nemo_northcomms
821      !!======================================================================
822      !!                     ***  ROUTINE  nemo_northcomms  ***
823      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
824      !!                       point-to-point messaging
825      !!=====================================================================
826      !!----------------------------------------------------------------------
827      !!
828      !! ** Purpose :   Initialization of the northern neighbours lists.
829      !!----------------------------------------------------------------------
830      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
831      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
832      !!----------------------------------------------------------------------
833
834      INTEGER  ::   sxM, dxM, sxT, dxT, jn
835      INTEGER  ::   njmppmax
836
837      njmppmax = MAXVAL( njmppt )
838   
839      !initializes the north-fold communication variables
840      isendto(:) = 0
841      nsndto = 0
842
843      !if I am a process in the north
844      IF ( njmpp == njmppmax ) THEN
845          !sxM is the first point (in the global domain) needed to compute the
846          !north-fold for the current process
847          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
848          !dxM is the last point (in the global domain) needed to compute the
849          !north-fold for the current process
850          dxM = jpiglo - nimppt(narea) + 2
851
852          !loop over the other north-fold processes to find the processes
853          !managing the points belonging to the sxT-dxT range
854 
855          DO jn = 1, jpni
856                !sxT is the first point (in the global domain) of the jn
857                !process
858                sxT = nfiimpp(jn, jpnj)
859                !dxT is the last point (in the global domain) of the jn
860                !process
861                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
862                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
863                   nsndto = nsndto + 1
864                     isendto(nsndto) = jn
865                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
866                   nsndto = nsndto + 1
867                     isendto(nsndto) = jn
868                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
869                   nsndto = nsndto + 1
870                     isendto(nsndto) = jn
871                END IF
872          END DO
873          nfsloop = 1
874          nfeloop = nlci
875          DO jn = 2,jpni-1
876           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
877              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
878                 nfsloop = nldi
879              ENDIF
880              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
881                 nfeloop = nlei
882              ENDIF
883           ENDIF
884        END DO
885
886      ENDIF
887      l_north_nogather = .TRUE.
888   END SUBROUTINE nemo_northcomms
889#else
890   SUBROUTINE nemo_northcomms      ! Dummy routine
891      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
892   END SUBROUTINE nemo_northcomms
893#endif
894
895   !!======================================================================
896END MODULE nemogcm
897
898
Note: See TracBrowser for help on using the repository browser.