New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdytides.F90 in branches/UKMO/CO6_KD490/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: branches/UKMO/CO6_KD490/NEMOGCM/NEMO/OPA_SRC/BDY/bdytides.F90 @ 6332

Last change on this file since 6332 was 6332, checked in by deazer, 8 years ago

Tested Initial run one day physics only in rose suite.
File size: 29.8 KB
Line 
1MODULE bdytides
2   !!======================================================================
3   !!                       ***  MODULE  bdytides  ***
4   !! Ocean dynamics:   Tidal forcing at open boundaries
5   !!======================================================================
6   !! History :  2.0  !  2007-01  (D.Storkey)  Original code
7   !!            2.3  !  2008-01  (J.Holt)  Add date correction. Origins POLCOMS v6.3 2007
8   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
9   !!            3.3  !  2010-09  (D.Storkey and E.O'Dea)  bug fixes
10   !!            3.4  !  2012-09  (G. Reffray and J. Chanut) New inputs + mods
11   !!            3.5  !  2013-07  (J. Chanut) Compliant with time splitting changes
12   !!----------------------------------------------------------------------
13#if defined key_bdy
14   !!----------------------------------------------------------------------
15   !!   'key_bdy'     Open Boundary Condition
16   !!----------------------------------------------------------------------
17   !!   PUBLIC
18   !!      bdytide_init     : read of namelist and initialisation of tidal harmonics data
19   !!      tide_update   : calculation of tidal forcing at each timestep
20   !!----------------------------------------------------------------------
21   USE timing          ! Timing
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE iom
25   USE in_out_manager  ! I/O units
26   USE phycst          ! physical constants
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28   USE bdy_par         ! Unstructured boundary parameters
29   USE bdy_oce         ! ocean open boundary conditions
30   USE daymod          ! calendar
31   USE wrk_nemo        ! Memory allocation
32   USE tideini
33!   USE tide_mod       ! Useless ??
34   USE fldread
35   USE dynspg_oce, ONLY: lk_dynspg_ts
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   bdytide_init     ! routine called in bdy_init
41   PUBLIC   bdytide_update   ! routine called in bdy_dta
42   PUBLIC   bdy_dta_tides    ! routine called in dyn_spg_ts
43
44   TYPE, PUBLIC ::   TIDES_DATA     !: Storage for external tidal harmonics data
45      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh0       !: Tidal constituents : SSH0 (read in file)
46      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u0         !: Tidal constituents : U0   (read in file)
47      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   v0         !: Tidal constituents : V0   (read in file)
48      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   ssh        !: Tidal constituents : SSH  (after nodal cor.)
49      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   u          !: Tidal constituents : U    (after nodal cor.)
50      REAL(wp), POINTER, DIMENSION(:,:,:)    ::   v          !: Tidal constituents : V    (after nodal cor.)
51   END TYPE TIDES_DATA
52
53!$AGRIF_DO_NOT_TREAT
54   TYPE(TIDES_DATA), PUBLIC, DIMENSION(jp_bdy), TARGET :: tides  !: External tidal harmonics data
55!$AGRIF_END_DO_NOT_TREAT
56   TYPE(OBC_DATA)  , PRIVATE, DIMENSION(jp_bdy) :: dta_bdy_s  !: bdy external data (slow component)
57
58   !!----------------------------------------------------------------------
59   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
60   !! $Id$
61   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE bdytide_init
66      !!----------------------------------------------------------------------
67      !!                    ***  SUBROUTINE bdytide_init  ***
68      !!                     
69      !! ** Purpose : - Read in namelist for tides and initialise external
70      !!                tidal harmonics data
71      !!
72      !!----------------------------------------------------------------------
73      !! namelist variables
74      !!-------------------
75      CHARACTER(len=80)                         ::   filtide             !: Filename root for tidal input files
76      LOGICAL                                   ::   ln_bdytide_2ddta    !: If true, read 2d harmonic data
77      LOGICAL                                   ::   ln_bdytide_conj     !: If true, assume complex conjugate tidal data
78      !!
79      INTEGER                                   ::   ib_bdy, itide, ib   !: dummy loop indices
80      INTEGER                                   ::   ii, ij              !: dummy loop indices
81      INTEGER                                   ::   inum, igrd
82      INTEGER, DIMENSION(3)                     ::   ilen0       !: length of boundary data (from OBC arrays)
83      INTEGER, POINTER, DIMENSION(:)            ::   nblen, nblenrim     ! short cuts
84      INTEGER                                   ::   ios                 ! Local integer output status for namelist read
85      CHARACTER(len=80)                         ::   clfile              !: full file name for tidal input file
86      REAL(wp),ALLOCATABLE, DIMENSION(:,:,:)    ::   dta_read            !: work space to read in tidal harmonics data
87      REAL(wp), POINTER, DIMENSION(:,:)         ::   ztr, zti            !:  "     "    "   "   "   "        "      "
88      !!
89      TYPE(TIDES_DATA),  POINTER                ::   td                  !: local short cut   
90      TYPE(MAP_POINTER), DIMENSION(jpbgrd)      ::   ibmap_ptr           !: array of pointers to nbmap
91      !!
92      NAMELIST/nambdy_tide/filtide, ln_bdytide_2ddta, ln_bdytide_conj
93      !!----------------------------------------------------------------------
94
95      IF( nn_timing == 1 ) CALL timing_start('bdytide_init')
96
97      IF (nb_bdy>0) THEN
98         IF(lwp) WRITE(numout,*)
99         IF(lwp) WRITE(numout,*) 'bdytide_init : initialization of tidal harmonic forcing at open boundaries'
100         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
101      ENDIF
102
103      REWIND(numnam_cfg)
104      REWIND(numnam_ref)   ! slwa
105
106      DO ib_bdy = 1, nb_bdy
107         IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN
108
109            td => tides(ib_bdy)
110            nblen => idx_bdy(ib_bdy)%nblen
111            nblenrim => idx_bdy(ib_bdy)%nblenrim
112
113            ! Namelist nambdy_tide : tidal harmonic forcing at open boundaries
114            filtide(:) = ''
115
116            ! Don't REWIND here - may need to read more than one of these namelists.
117            READ  ( numnam_ref, nambdy_tide, IOSTAT = ios, ERR = 901)
118901         IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_tide in reference namelist', lwp )
119            READ  ( numnam_cfg, nambdy_tide, IOSTAT = ios, ERR = 902 )
120902         IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_tide in configuration namelist', lwp )
121            IF(lwm) WRITE ( numond, nambdy_tide )
122            !                                               ! Parameter control and print
123            IF(lwp) WRITE(numout,*) '  '
124            IF(lwp) WRITE(numout,*) '          Namelist nambdy_tide : tidal harmonic forcing at open boundaries'
125            IF(lwp) WRITE(numout,*) '             read tidal data in 2d files: ', ln_bdytide_2ddta
126            IF(lwp) WRITE(numout,*) '             assume complex conjugate   : ', ln_bdytide_conj
127            IF(lwp) WRITE(numout,*) '             Number of tidal components to read: ', nb_harmo
128            IF(lwp) THEN
129                    WRITE(numout,*) '             Tidal components: ' 
130               DO itide = 1, nb_harmo
131                  WRITE(numout,*)  '                 ', Wave(ntide(itide))%cname_tide 
132               END DO
133            ENDIF
134            IF(lwp) WRITE(numout,*) ' '
135
136            ! Allocate space for tidal harmonics data - get size from OBC data arrays
137            ! -----------------------------------------------------------------------
138
139            ! JC: If FRS scheme is used, we assume that tidal is needed over the whole
140            ! relaxation area     
141            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN
142               ilen0(:)=nblen(:)
143            ELSE
144               ilen0(:)=nblenrim(:)
145            ENDIF
146
147            ALLOCATE( td%ssh0( ilen0(1), nb_harmo, 2 ) )
148            ALLOCATE( td%ssh ( ilen0(1), nb_harmo, 2 ) )
149
150            ALLOCATE( td%u0( ilen0(2), nb_harmo, 2 ) )
151            ALLOCATE( td%u ( ilen0(2), nb_harmo, 2 ) )
152
153            ALLOCATE( td%v0( ilen0(3), nb_harmo, 2 ) )
154            ALLOCATE( td%v ( ilen0(3), nb_harmo, 2 ) )
155
156            td%ssh0(:,:,:) = 0._wp
157            td%ssh (:,:,:) = 0._wp
158            td%u0  (:,:,:) = 0._wp
159            td%u   (:,:,:) = 0._wp
160            td%v0  (:,:,:) = 0._wp
161            td%v   (:,:,:) = 0._wp
162
163            IF (ln_bdytide_2ddta) THEN
164               ! It is assumed that each data file contains all complex harmonic amplitudes
165               ! given on the data domain (ie global, jpidta x jpjdta)
166               !
167               CALL wrk_alloc( jpi, jpj, zti, ztr )
168               !
169               ! SSH fields
170               clfile = TRIM(filtide)//'_grid_T.nc'
171               CALL iom_open (clfile , inum ) 
172               igrd = 1                       ! Everything is at T-points here
173               DO itide = 1, nb_harmo
174                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_z1', ztr(:,:) )
175                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_z2', zti(:,:) ) 
176                  DO ib = 1, ilen0(igrd)
177                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
178                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
179                     td%ssh0(ib,itide,1) = ztr(ii,ij)
180                     td%ssh0(ib,itide,2) = zti(ii,ij)
181                  END DO
182               END DO
183               CALL iom_close( inum )
184               !
185               ! U fields
186               clfile = TRIM(filtide)//'_grid_U.nc'
187               CALL iom_open (clfile , inum ) 
188               igrd = 2                       ! Everything is at U-points here
189               DO itide = 1, nb_harmo
190                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_u1', ztr(:,:) )
191                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_u2', zti(:,:) )
192                  DO ib = 1, ilen0(igrd)
193                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
194                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
195                     td%u0(ib,itide,1) = ztr(ii,ij)
196                     td%u0(ib,itide,2) = zti(ii,ij)
197                  END DO
198               END DO
199               CALL iom_close( inum )
200               !
201               ! V fields
202               clfile = TRIM(filtide)//'_grid_V.nc'
203               CALL iom_open (clfile , inum ) 
204               igrd = 3                       ! Everything is at V-points here
205               DO itide = 1, nb_harmo
206                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_v1', ztr(:,:) )
207                  CALL iom_get  ( inum, jpdom_data, TRIM(Wave(ntide(itide))%cname_tide)//'_v2', zti(:,:) )
208                  DO ib = 1, ilen0(igrd)
209                     ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
210                     ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
211                     td%v0(ib,itide,1) = ztr(ii,ij)
212                     td%v0(ib,itide,2) = zti(ii,ij)
213                  END DO
214               END DO 
215               CALL iom_close( inum )
216               !
217               CALL wrk_dealloc( jpi, jpj, ztr, zti ) 
218               !
219            ELSE           
220               !
221               ! Read tidal data only on bdy segments
222               !
223               ALLOCATE( dta_read( MAXVAL(ilen0(1:3)), 1, 1 ) )
224               !
225               ! Set map structure
226               ibmap_ptr(1)%ptr => idx_bdy(ib_bdy)%nbmap(:,1)
227               ibmap_ptr(1)%ll_unstruc = ln_coords_file(ib_bdy)
228               ibmap_ptr(2)%ptr => idx_bdy(ib_bdy)%nbmap(:,2)
229               ibmap_ptr(2)%ll_unstruc = ln_coords_file(ib_bdy)
230               ibmap_ptr(3)%ptr => idx_bdy(ib_bdy)%nbmap(:,3)
231               ibmap_ptr(3)%ll_unstruc = ln_coords_file(ib_bdy)
232
233               ! Open files and read in tidal forcing data
234               ! -----------------------------------------
235
236               DO itide = 1, nb_harmo
237                  !                                                              ! SSH fields
238                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_T.nc'
239                  CALL iom_open( clfile, inum )
240                  CALL fld_map( inum, 'z1' , dta_read(1:ilen0(1),1:1,1:1) , 1,  ibmap_ptr(1) )
241                  td%ssh0(:,itide,1) = dta_read(1:ilen0(1),1,1)
242                  CALL fld_map( inum, 'z2' , dta_read(1:ilen0(1),1:1,1:1) , 1,  ibmap_ptr(1) )
243                  td%ssh0(:,itide,2) = dta_read(1:ilen0(1),1,1)
244                  CALL iom_close( inum )
245                  !                                                              ! U fields
246                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_U.nc'
247                  CALL iom_open( clfile, inum )
248                  CALL fld_map( inum, 'u1' , dta_read(1:ilen0(2),1:1,1:1) , 1, ibmap_ptr(2) )
249                  td%u0(:,itide,1) = dta_read(1:ilen0(2),1,1)
250                  CALL fld_map( inum, 'u2' , dta_read(1:ilen0(2),1:1,1:1) , 1, ibmap_ptr(2) )
251                  td%u0(:,itide,2) = dta_read(1:ilen0(2),1,1)
252                  CALL iom_close( inum )
253                  !                                                              ! V fields
254                  clfile = TRIM(filtide)//TRIM(Wave(ntide(itide))%cname_tide)//'_grid_V.nc'
255                  CALL iom_open( clfile, inum )
256                  CALL fld_map( inum, 'v1' , dta_read(1:ilen0(3),1:1,1:1) , 1, ibmap_ptr(3) )
257                  td%v0(:,itide,1) = dta_read(1:ilen0(3),1,1)
258                  CALL fld_map( inum, 'v2' , dta_read(1:ilen0(3),1:1,1:1) , 1, ibmap_ptr(3) )
259                  td%v0(:,itide,2) = dta_read(1:ilen0(3),1,1)
260                  CALL iom_close( inum )
261                  !
262               END DO ! end loop on tidal components
263               !
264               DEALLOCATE( dta_read )
265            ENDIF ! ln_bdytide_2ddta=.true.
266            !
267            IF ( ln_bdytide_conj ) THEN ! assume complex conjugate in data files
268               td%ssh0(:,:,2) = - td%ssh0(:,:,2)
269               td%u0  (:,:,2) = - td%u0  (:,:,2)
270               td%v0  (:,:,2) = - td%v0  (:,:,2)
271            ENDIF
272            !
273            IF ( lk_dynspg_ts ) THEN ! Allocate arrays to save slowly varying boundary data during
274                                     ! time splitting integration
275               ALLOCATE( dta_bdy_s(ib_bdy)%ssh ( ilen0(1) ) )
276               ALLOCATE( dta_bdy_s(ib_bdy)%u2d ( ilen0(2) ) )
277               ALLOCATE( dta_bdy_s(ib_bdy)%v2d ( ilen0(3) ) )
278               dta_bdy_s(ib_bdy)%ssh(:) = 0.e0
279               dta_bdy_s(ib_bdy)%u2d(:) = 0.e0
280               dta_bdy_s(ib_bdy)%v2d(:) = 0.e0
281            ENDIF
282            !
283         ENDIF ! nn_dyn2d_dta(ib_bdy) .ge. 2
284         !
285      END DO ! loop on ib_bdy
286
287      IF( nn_timing == 1 ) CALL timing_stop('bdytide_init')
288
289   END SUBROUTINE bdytide_init
290
291   SUBROUTINE bdytide_update ( kt, idx, dta, td, jit, time_offset )
292      !!----------------------------------------------------------------------
293      !!                 ***  SUBROUTINE bdytide_update  ***
294      !!               
295      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
296      !!               
297      !!----------------------------------------------------------------------
298      INTEGER, INTENT( in )            ::   kt          ! Main timestep counter
299      TYPE(OBC_INDEX), INTENT( in )    ::   idx         ! OBC indices
300      TYPE(OBC_DATA),  INTENT(inout)   ::   dta         ! OBC external data
301      TYPE(TIDES_DATA),INTENT( inout ) ::   td          ! tidal harmonics data
302      INTEGER,INTENT(in),OPTIONAL      ::   jit         ! Barotropic timestep counter (for timesplitting option)
303      INTEGER,INTENT( in ), OPTIONAL   ::   time_offset ! time offset in units of timesteps. NB. if jit
304                                                        ! is present then units = subcycle timesteps.
305                                                        ! time_offset = 0  => get data at "now"    time level
306                                                        ! time_offset = -1 => get data at "before" time level
307                                                        ! time_offset = +1 => get data at "after"  time level
308                                                        ! etc.
309      !!
310      INTEGER, DIMENSION(3)            ::   ilen0       !: length of boundary data (from OBC arrays)
311      INTEGER                          :: itide, igrd, ib   ! dummy loop indices
312      INTEGER                          :: time_add          ! time offset in units of timesteps
313      REAL(wp)                         :: z_arg, z_sarg, zflag, zramp     
314      REAL(wp), DIMENSION(jpmax_harmo) :: z_sist, z_cost
315      !!----------------------------------------------------------------------
316
317      IF( nn_timing == 1 ) CALL timing_start('bdytide_update')
318
319      ilen0(1) =  SIZE(td%ssh(:,1,1))
320      ilen0(2) =  SIZE(td%u(:,1,1))
321      ilen0(3) =  SIZE(td%v(:,1,1))
322
323      zflag=1
324      IF ( PRESENT(jit) ) THEN
325        IF ( jit /= 1 ) zflag=0
326      ENDIF
327
328      IF ( nsec_day == NINT(0.5_wp * rdttra(1)) .AND. zflag==1 ) THEN
329        !
330        kt_tide = kt
331        !
332        IF(lwp) THEN
333           WRITE(numout,*)
334           WRITE(numout,*) 'bdytide_update : (re)Initialization of the tidal bdy forcing at kt=',kt
335           WRITE(numout,*) '~~~~~~~~~~~~~~ '
336        ENDIF
337        !
338        CALL tide_init_elevation ( idx, td )
339        CALL tide_init_velocities( idx, td )
340        !
341      ENDIF
342
343      time_add = 0
344      IF( PRESENT(time_offset) ) THEN
345         time_add = time_offset
346      ENDIF
347         
348      IF( PRESENT(jit) ) THEN 
349         z_arg = ((kt-kt_tide) * rdt + (jit+0.5_wp*(time_add-1)) * rdt / REAL(nn_baro,wp) )
350      ELSE                             
351         z_arg = ((kt-kt_tide)+time_add) * rdt
352      ENDIF
353
354      ! Linear ramp on tidal component at open boundaries
355      zramp = 1._wp
356      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg + (kt_tide-nit000)*rdt)/(rdttideramp*rday),0._wp),1._wp)
357
358      DO itide = 1, nb_harmo
359         z_sarg = z_arg * omega_tide(itide)
360         z_cost(itide) = COS( z_sarg )
361         z_sist(itide) = SIN( z_sarg )
362      END DO
363
364      DO itide = 1, nb_harmo
365         igrd=1                              ! SSH on tracer grid
366         DO ib = 1, ilen0(igrd)
367            dta%ssh(ib) = dta%ssh(ib) + zramp*(td%ssh(ib,itide,1)*z_cost(itide) + td%ssh(ib,itide,2)*z_sist(itide))
368         END DO
369         igrd=2                              ! U grid
370         DO ib = 1, ilen0(igrd)
371            dta%u2d(ib) = dta%u2d(ib) + zramp*(td%u  (ib,itide,1)*z_cost(itide) + td%u  (ib,itide,2)*z_sist(itide))
372         END DO
373         igrd=3                              ! V grid
374         DO ib = 1, ilen0(igrd) 
375            dta%v2d(ib) = dta%v2d(ib) + zramp*(td%v  (ib,itide,1)*z_cost(itide) + td%v  (ib,itide,2)*z_sist(itide))
376         END DO
377      END DO
378      !
379      IF( nn_timing == 1 ) CALL timing_stop('bdytide_update')
380      !
381   END SUBROUTINE bdytide_update
382
383   SUBROUTINE bdy_dta_tides( kt, kit, time_offset )
384      !!----------------------------------------------------------------------
385      !!                 ***  SUBROUTINE bdy_dta_tides  ***
386      !!               
387      !! ** Purpose : - Add tidal forcing to ssh, u2d and v2d OBC data arrays.
388      !!               
389      !!----------------------------------------------------------------------
390      INTEGER, INTENT( in )            ::   kt          ! Main timestep counter
391      INTEGER, INTENT( in ),OPTIONAL   ::   kit         ! Barotropic timestep counter (for timesplitting option)
392      INTEGER, INTENT( in ),OPTIONAL   ::   time_offset ! time offset in units of timesteps. NB. if kit
393                                                        ! is present then units = subcycle timesteps.
394                                                        ! time_offset = 0  => get data at "now"    time level
395                                                        ! time_offset = -1 => get data at "before" time level
396                                                        ! time_offset = +1 => get data at "after"  time level
397                                                        ! etc.
398      !!
399      LOGICAL  :: lk_first_btstp  ! =.TRUE. if time splitting and first barotropic step
400      INTEGER,          DIMENSION(jpbgrd) :: ilen0 
401      INTEGER, DIMENSION(1:jpbgrd) :: nblen, nblenrim  ! short cuts
402      INTEGER  :: itide, ib_bdy, ib, igrd                     ! loop indices
403      INTEGER  :: time_add                                    ! time offset in units of timesteps
404      REAL(wp) :: z_arg, z_sarg, zramp, zoff, z_cost, z_sist     
405      !!----------------------------------------------------------------------
406
407      IF( nn_timing == 1 ) CALL timing_start('bdy_dta_tides')
408
409      lk_first_btstp=.TRUE.
410      IF ( PRESENT(kit).AND.( kit /= 1 ) ) THEN ; lk_first_btstp=.FALSE. ; ENDIF
411
412      time_add = 0
413      IF( PRESENT(time_offset) ) THEN
414         time_add = time_offset
415      ENDIF
416     
417      ! Absolute time from model initialization:   
418      IF( PRESENT(kit) ) THEN 
419         z_arg = ( kt + (kit+time_add-1) / REAL(nn_baro,wp) ) * rdt
420      ELSE                             
421         z_arg = ( kt + time_add ) * rdt
422      ENDIF
423
424      ! Linear ramp on tidal component at open boundaries
425      zramp = 1.
426      IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg - nit000*rdt)/(rdttideramp*rday),0.),1.)
427
428      DO ib_bdy = 1,nb_bdy
429
430         IF ( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN
431
432            nblen(1:jpbgrd) = idx_bdy(ib_bdy)%nblen(1:jpbgrd)
433            nblenrim(1:jpbgrd) = idx_bdy(ib_bdy)%nblenrim(1:jpbgrd)
434
435            IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN
436               ilen0(:)=nblen(:)
437            ELSE
438               ilen0(:)=nblenrim(:)
439            ENDIF     
440
441            ! We refresh nodal factors every day below
442            ! This should be done somewhere else
443            IF ( nsec_day == NINT(0.5_wp * rdttra(1)) .AND. lk_first_btstp ) THEN
444               !
445               kt_tide = kt               
446               !
447               IF(lwp) THEN
448               WRITE(numout,*)
449               WRITE(numout,*) 'bdy_tide_dta : Refresh nodal factors for tidal open bdy data at kt=',kt
450               WRITE(numout,*) '~~~~~~~~~~~~~~ '
451               ENDIF
452               !
453               CALL tide_init_elevation ( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
454               CALL tide_init_velocities( idx=idx_bdy(ib_bdy), td=tides(ib_bdy) )
455               !
456            ENDIF
457            zoff = -kt_tide * rdt ! time offset relative to nodal factor computation time
458            !
459            ! If time splitting, save data at first barotropic iteration
460            IF ( PRESENT(kit) ) THEN
461               IF ( lk_first_btstp ) THEN ! Save slow varying open boundary data:
462                  IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy_s(ib_bdy)%ssh(1:ilen0(1)) = dta_bdy(ib_bdy)%ssh(1:ilen0(1))
463                  IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy_s(ib_bdy)%u2d(1:ilen0(2)) = dta_bdy(ib_bdy)%u2d(1:ilen0(2))
464                  IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy_s(ib_bdy)%v2d(1:ilen0(3)) = dta_bdy(ib_bdy)%v2d(1:ilen0(3))
465
466               ELSE ! Initialize arrays from slow varying open boundary data:           
467                  IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy(ib_bdy)%ssh(1:ilen0(1)) = dta_bdy_s(ib_bdy)%ssh(1:ilen0(1))
468                  IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy(ib_bdy)%u2d(1:ilen0(2)) = dta_bdy_s(ib_bdy)%u2d(1:ilen0(2))
469                  IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy(ib_bdy)%v2d(1:ilen0(3)) = dta_bdy_s(ib_bdy)%v2d(1:ilen0(3))
470               ENDIF
471            ENDIF
472            !
473            ! Update open boundary data arrays:
474            DO itide = 1, nb_harmo
475               !
476               z_sarg = (z_arg + zoff) * omega_tide(itide)
477               z_cost = zramp * COS( z_sarg )
478               z_sist = zramp * SIN( z_sarg )
479               !
480               IF ( dta_bdy(ib_bdy)%ll_ssh ) THEN
481                  igrd=1                              ! SSH on tracer grid
482                  DO ib = 1, ilen0(igrd)
483                     dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + &
484                        &                      ( tides(ib_bdy)%ssh(ib,itide,1)*z_cost + &
485                        &                        tides(ib_bdy)%ssh(ib,itide,2)*z_sist )
486                  END DO
487               ENDIF
488               !
489               IF ( dta_bdy(ib_bdy)%ll_u2d ) THEN
490                  igrd=2                              ! U grid
491                  DO ib = 1, ilen0(igrd)
492                     dta_bdy(ib_bdy)%u2d(ib) = dta_bdy(ib_bdy)%u2d(ib) + &
493                        &                      ( tides(ib_bdy)%u(ib,itide,1)*z_cost + &
494                        &                        tides(ib_bdy)%u(ib,itide,2)*z_sist )
495                  END DO
496               ENDIF
497               !
498               IF ( dta_bdy(ib_bdy)%ll_v2d ) THEN
499                  igrd=3                              ! V grid
500                  DO ib = 1, ilen0(igrd) 
501                     dta_bdy(ib_bdy)%v2d(ib) = dta_bdy(ib_bdy)%v2d(ib) + &
502                        &                      ( tides(ib_bdy)%v(ib,itide,1)*z_cost + &
503                        &                        tides(ib_bdy)%v(ib,itide,2)*z_sist )
504                  END DO
505               ENDIF
506            END DO             
507         END IF
508      END DO
509      !
510      IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_tides')
511      !
512   END SUBROUTINE bdy_dta_tides
513
514   SUBROUTINE tide_init_elevation( idx, td )
515      !!----------------------------------------------------------------------
516      !!                 ***  ROUTINE tide_init_elevation  ***
517      !!----------------------------------------------------------------------
518      TYPE(OBC_INDEX), INTENT( in )      ::   idx     ! OBC indices
519      TYPE(TIDES_DATA),INTENT( inout )   ::   td      ! tidal harmonics data
520      !! * Local declarations
521      INTEGER, DIMENSION(1)            ::   ilen0       !: length of boundary data (from OBC arrays)
522      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
523      INTEGER                            ::   itide, igrd, ib      ! dummy loop indices
524
525      igrd=1   
526                              ! SSH on tracer grid.
527   
528      ilen0(1) =  SIZE(td%ssh0(:,1,1))
529
530      ALLOCATE(mod_tide(ilen0(igrd)),phi_tide(ilen0(igrd)))
531
532      DO itide = 1, nb_harmo
533         DO ib = 1, ilen0(igrd)
534            mod_tide(ib)=SQRT(td%ssh0(ib,itide,1)**2.+td%ssh0(ib,itide,2)**2.)
535            phi_tide(ib)=ATAN2(-td%ssh0(ib,itide,2),td%ssh0(ib,itide,1))
536         END DO
537         DO ib = 1 , ilen0(igrd)
538            mod_tide(ib)=mod_tide(ib)*ftide(itide)
539            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
540         ENDDO
541         DO ib = 1 , ilen0(igrd)
542            td%ssh(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
543            td%ssh(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
544         ENDDO
545      END DO
546
547      DEALLOCATE(mod_tide,phi_tide)
548
549   END SUBROUTINE tide_init_elevation
550
551   SUBROUTINE tide_init_velocities( idx, td )
552      !!----------------------------------------------------------------------
553      !!                 ***  ROUTINE tide_init_elevation  ***
554      !!----------------------------------------------------------------------
555      TYPE(OBC_INDEX), INTENT( in )      ::   idx     ! OBC indices
556      TYPE(TIDES_DATA),INTENT( inout )      ::   td      ! tidal harmonics data
557      !! * Local declarations
558      INTEGER, DIMENSION(3)            ::   ilen0       !: length of boundary data (from OBC arrays)
559      REAL(wp),ALLOCATABLE, DIMENSION(:) ::   mod_tide, phi_tide
560      INTEGER                            ::   itide, igrd, ib      ! dummy loop indices
561
562      ilen0(2) =  SIZE(td%u0(:,1,1))
563      ilen0(3) =  SIZE(td%v0(:,1,1))
564
565      igrd=2                                 ! U grid.
566
567      ALLOCATE(mod_tide(ilen0(igrd)),phi_tide(ilen0(igrd)))
568
569      DO itide = 1, nb_harmo
570         DO ib = 1, ilen0(igrd)
571            mod_tide(ib)=SQRT(td%u0(ib,itide,1)**2.+td%u0(ib,itide,2)**2.)
572            phi_tide(ib)=ATAN2(-td%u0(ib,itide,2),td%u0(ib,itide,1))
573         END DO
574         DO ib = 1, ilen0(igrd)
575            mod_tide(ib)=mod_tide(ib)*ftide(itide)
576            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
577         ENDDO
578         DO ib = 1, ilen0(igrd)
579            td%u(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
580            td%u(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
581         ENDDO
582      END DO
583
584      DEALLOCATE(mod_tide,phi_tide)
585
586      igrd=3                                 ! V grid.
587
588      ALLOCATE(mod_tide(ilen0(igrd)),phi_tide(ilen0(igrd)))
589
590      DO itide = 1, nb_harmo
591         DO ib = 1, ilen0(igrd)
592            mod_tide(ib)=SQRT(td%v0(ib,itide,1)**2.+td%v0(ib,itide,2)**2.)
593            phi_tide(ib)=ATAN2(-td%v0(ib,itide,2),td%v0(ib,itide,1))
594         END DO
595         DO ib = 1, ilen0(igrd)
596            mod_tide(ib)=mod_tide(ib)*ftide(itide)
597            phi_tide(ib)=phi_tide(ib)+v0tide(itide)+utide(itide)
598         ENDDO
599         DO ib = 1, ilen0(igrd)
600            td%v(ib,itide,1)= mod_tide(ib)*COS(phi_tide(ib))
601            td%v(ib,itide,2)=-mod_tide(ib)*SIN(phi_tide(ib))
602         ENDDO
603      END DO
604
605      DEALLOCATE(mod_tide,phi_tide)
606
607  END SUBROUTINE tide_init_velocities
608#else
609   !!----------------------------------------------------------------------
610   !!   Dummy module         NO Unstruct Open Boundary Conditions for tides
611   !!----------------------------------------------------------------------
612CONTAINS
613   SUBROUTINE bdytide_init             ! Empty routine
614      WRITE(*,*) 'bdytide_init: You should not have seen this print! error?'
615   END SUBROUTINE bdytide_init
616   SUBROUTINE bdytide_update( kt, jit )   ! Empty routine
617      WRITE(*,*) 'bdytide_update: You should not have seen this print! error?', kt, jit
618   END SUBROUTINE bdytide_update
619   SUBROUTINE bdy_dta_tides( kt, kit, time_offset )     ! Empty routine
620      INTEGER, INTENT( in )            ::   kt          ! Dummy argument empty routine     
621      INTEGER, INTENT( in ),OPTIONAL   ::   kit         ! Dummy argument empty routine
622      INTEGER, INTENT( in ),OPTIONAL   ::   time_offset ! Dummy argument empty routine
623      WRITE(*,*) 'bdy_dta_tides: You should not have seen this print! error?', kt, jit
624   END SUBROUTINE bdy_dta_tides
625#endif
626
627   !!======================================================================
628END MODULE bdytides
629
Note: See TracBrowser for help on using the repository browser.