New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 8168

Last change on this file since 8168 was 8168, checked in by glong, 7 years ago

changes as of eod 13/16/17

File size: 70.8 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   USE divcur          ! for dyn_vrt_dia_3d
39   !
40   USE in_out_manager  ! I/O manager
41   USE prtctl          ! Print control
42   USE lbclnk          ! lateral boundary condition
43   USE lib_mpp         ! MPP library
44   USE eosbn2          ! compute density
45   USE wrk_nemo        ! Memory Allocation
46   USE timing          ! Timing
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
90      !
91      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
92         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93         ztrdu(:,:,:) = ua(:,:,:)
94         ztrdv(:,:,:) = va(:,:,:)
95      ENDIF
96      !
97      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
98      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
99      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
100      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
101      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
102      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
103      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
104      END SELECT
105      !
106      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111      ENDIF
112      !
113      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
114         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
115      !
116      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
117      !
118   END SUBROUTINE dyn_hpg
119
120
121   SUBROUTINE dyn_hpg_init
122      !!----------------------------------------------------------------------
123      !!                 ***  ROUTINE dyn_hpg_init  ***
124      !!
125      !! ** Purpose :   initializations for the hydrostatic pressure gradient
126      !!              computation and consistency control
127      !!
128      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
129      !!      with the type of vertical coordinate used (zco, zps, sco)
130      !!----------------------------------------------------------------------
131      INTEGER ::   ioptio = 0      ! temporary integer
132      INTEGER ::   ios             ! Local integer output status for namelist read
133      !!
134      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
135         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
136      !!----------------------------------------------------------------------
137      !
138      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
139      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
140901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
141
142      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
143      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
144902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
145      IF(lwm) WRITE ( numond, namdyn_hpg )
146      !
147      IF(lwp) THEN                   ! Control print
148         WRITE(numout,*)
149         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
150         WRITE(numout,*) '~~~~~~~~~~~~'
151         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
152         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
153         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
154         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
155         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
156         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
157         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
158         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
159      ENDIF
160      !
161      IF( ln_hpg_djc )   &
162         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
163                           & currently disabled (bugs under investigation). Please select &
164                           & either  ln_hpg_sco or  ln_hpg_prj instead')
165      !
166      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
167         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
168                           & the standard jacobian formulation hpg_sco or &
169                           & the pressure jacobian formulation hpg_prj')
170
171      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
172         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
173      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
174         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
175      !
176      !                               ! Set nhpg from ln_hpg_... flags
177      IF( ln_hpg_zco )   nhpg = 0
178      IF( ln_hpg_zps )   nhpg = 1
179      IF( ln_hpg_sco )   nhpg = 2
180      IF( ln_hpg_djc )   nhpg = 3
181      IF( ln_hpg_prj )   nhpg = 4
182      IF( ln_hpg_isf )   nhpg = 5
183      !
184      !                               ! Consistency check
185      ioptio = 0
186      IF( ln_hpg_zco )   ioptio = ioptio + 1
187      IF( ln_hpg_zps )   ioptio = ioptio + 1
188      IF( ln_hpg_sco )   ioptio = ioptio + 1
189      IF( ln_hpg_djc )   ioptio = ioptio + 1
190      IF( ln_hpg_prj )   ioptio = ioptio + 1
191      IF( ln_hpg_isf )   ioptio = ioptio + 1
192      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
193      !
194      ! initialisation of ice load
195      riceload(:,:)=0.0
196      !
197   END SUBROUTINE dyn_hpg_init
198
199
200   SUBROUTINE hpg_zco( kt )
201      !!---------------------------------------------------------------------
202      !!                  ***  ROUTINE hpg_zco  ***
203      !!
204      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
205      !!      The now hydrostatic pressure gradient at a given level, jk,
206      !!      is computed by taking the vertical integral of the in-situ
207      !!      density gradient along the model level from the suface to that
208      !!      level:    zhpi = grav .....
209      !!                zhpj = grav .....
210      !!      add it to the general momentum trend (ua,va).
211      !!            ua = ua - 1/e1u * zhpi
212      !!            va = va - 1/e2v * zhpj
213      !!
214      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
215      !!----------------------------------------------------------------------
216      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
217      !!
218      INTEGER  ::   ji, jj, jk       ! dummy loop indices
219      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
220      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
221      !!----------------------------------------------------------------------
222      !
223      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
224      !
225      IF( kt == nit000 ) THEN
226         IF(lwp) WRITE(numout,*)
227         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
228         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
229      ENDIF
230
231      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
232
233      ! Surface value
234      DO jj = 2, jpjm1
235         DO ji = fs_2, fs_jpim1   ! vector opt.
236            zcoef1 = zcoef0 * fse3w(ji,jj,1)
237            ! hydrostatic pressure gradient
238            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
239            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
240            ! add to the general momentum trend
241            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
242            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
243         END DO
244      END DO
245
246      !
247      ! interior value (2=<jk=<jpkm1)
248      DO jk = 2, jpkm1
249         DO jj = 2, jpjm1
250            DO ji = fs_2, fs_jpim1   ! vector opt.
251               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
252               ! hydrostatic pressure gradient
253               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
254                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
255                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
256
257               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
258                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
259                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
260               ! add to the general momentum trend
261               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
262               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
263            END DO
264         END DO
265      END DO
266      !
267      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
268      !
269   END SUBROUTINE hpg_zco
270
271
272   SUBROUTINE hpg_zps( kt )
273      !!---------------------------------------------------------------------
274      !!                 ***  ROUTINE hpg_zps  ***
275      !!
276      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
277      !!
278      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
279      !!----------------------------------------------------------------------
280      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
281      !!
282      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
283      INTEGER  ::   iku, ikv                         ! temporary integers
284      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
285      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
286      !!----------------------------------------------------------------------
287      !
288      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
289      !
290      IF( kt == nit000 ) THEN
291         IF(lwp) WRITE(numout,*)
292         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
293         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
294      ENDIF
295
296
297      ! Local constant initialization
298      zcoef0 = - grav * 0.5_wp
299
300      !  Surface value (also valid in partial step case)
301      DO jj = 2, jpjm1
302         DO ji = fs_2, fs_jpim1   ! vector opt.
303            zcoef1 = zcoef0 * fse3w(ji,jj,1)
304            ! hydrostatic pressure gradient
305            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
306            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
307            ! add to the general momentum trend
308            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
309            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
310         END DO
311      END DO
312
313
314      ! interior value (2=<jk=<jpkm1)
315      DO jk = 2, jpkm1
316         DO jj = 2, jpjm1
317            DO ji = fs_2, fs_jpim1   ! vector opt.
318               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
319               ! hydrostatic pressure gradient
320               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
321                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
322                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
323
324               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
325                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
326                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
327               ! add to the general momentum trend
328               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
329               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
330            END DO
331         END DO
332      END DO
333
334
335      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
336      DO jj = 2, jpjm1
337         DO ji = 2, jpim1
338            iku = mbku(ji,jj)
339            ikv = mbkv(ji,jj)
340            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
341            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
342            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
343               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
344               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
345                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
346               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
347            ENDIF
348            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
349               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
350               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
351                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
352               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
353            ENDIF
354         END DO
355      END DO
356      !
357      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
358      !
359   END SUBROUTINE hpg_zps
360
361   SUBROUTINE hpg_sco( kt )
362      !!---------------------------------------------------------------------
363      !!                  ***  ROUTINE hpg_sco  ***
364      !!
365      !! ** Method  :   s-coordinate case. Jacobian scheme.
366      !!      The now hydrostatic pressure gradient at a given level, jk,
367      !!      is computed by taking the vertical integral of the in-situ
368      !!      density gradient along the model level from the suface to that
369      !!      level. s-coordinates (ln_sco): a corrective term is added
370      !!      to the horizontal pressure gradient :
371      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
372      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
373      !!      add it to the general momentum trend (ua,va).
374      !!         ua = ua - 1/e1u * zhpi
375      !!         va = va - 1/e2v * zhpj
376      !!
377      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
378      !!----------------------------------------------------------------------
379      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
380      !!
381      INTEGER  ::   id_dia_vrt_hpg_int  = 11   ! TODO remove once flags set properly
382      INTEGER  ::   id_dia_vrt_hpg_mean = 12   ! TODO remove once flags set properly
383      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
384      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
385      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
386      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zuhpg, zvhpg
387      !!----------------------------------------------------------------------
388      !
389      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
390      CALL wrk_alloc( jpi,jpj,jpk, zuhpg, zvhpg )
391      !
392      IF( kt == nit000 ) THEN
393         IF(lwp) WRITE(numout,*)
394         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
395         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
396      ENDIF
397
398      ! Local constant initialization
399      zcoef0 = - grav * 0.5_wp
400      ! To use density and not density anomaly
401      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
402      ELSE                 ;     znad = 0._wp         ! Fixed volume
403      ENDIF
404
405      ! Surface value
406      DO jj = 2, jpjm1
407         DO ji = fs_2, fs_jpim1   ! vector opt.
408            ! hydrostatic pressure gradient along s-surfaces
409            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
410               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
411            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
412               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
413            ! s-coordinate pressure gradient correction
414            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
415               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
416            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
417               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
418            ! combine gradient and corerction
419            zuhpg(ji,jj,1) = zhpi(ji,jj,1) + zuap
420            zvhpg(ji,jj,1) = zhpj(ji,jj,1) + zvap
421            ! add to the general momentum trend
422            ua(ji,jj,1) = ua(ji,jj,1) + zuhpg(ji,jj,1)
423            va(ji,jj,1) = va(ji,jj,1) + zvhpg(ji,jj,1)
424         END DO
425      END DO
426
427      ! interior value (2=<jk=<jpkm1)
428      DO jk = 2, jpkm1
429         DO jj = 2, jpjm1
430            DO ji = fs_2, fs_jpim1   ! vector opt.
431               ! hydrostatic pressure gradient along s-surfaces
432               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
433                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
434                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
435               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
436                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
437                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
438               ! s-coordinate pressure gradient correction
439               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
440                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
441               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
442                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
443               ! combine gradient and corerction
444               zuhpg(ji,jj,jk) = zhpi(ji,jj,jk) + zuap
445               zvhpg(ji,jj,jk) = zhpj(ji,jj,jk) + zvap
446               ! add to the general momentum trend
447               ua(ji,jj,jk) = ua(ji,jj,jk) + zuhpg(ji,jj,jk)
448               va(ji,jj,jk) = va(ji,jj,jk) + zvhpg(ji,jj,jk)
449            END DO
450         END DO
451      END DO
452      !
453      ! calculate dia_vor_int & dia_vor_mn if required
454      IF ( ( id_dia_vrt_hpg_int == 11 ) .or. ( id_dia_vrt_hpg_mean == 12 ) ) THEN
455          ! TODO - remove kt only used for validation
456          CALL dyn_vrt_dia_3d(zuhpg, zvhpg, id_dia_vrt_hpg_int, id_dia_vrt_hpg_mean, kt)
457      END IF
458      !
459      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
460      !
461   END SUBROUTINE hpg_sco
462
463   SUBROUTINE hpg_isf( kt )
464      !!---------------------------------------------------------------------
465      !!                  ***  ROUTINE hpg_sco  ***
466      !!
467      !! ** Method  :   s-coordinate case. Jacobian scheme.
468      !!      The now hydrostatic pressure gradient at a given level, jk,
469      !!      is computed by taking the vertical integral of the in-situ
470      !!      density gradient along the model level from the suface to that
471      !!      level. s-coordinates (ln_sco): a corrective term is added
472      !!      to the horizontal pressure gradient :
473      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
474      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
475      !!      add it to the general momentum trend (ua,va).
476      !!         ua = ua - 1/e1u * zhpi
477      !!         va = va - 1/e2v * zhpj
478      !!      iceload is added and partial cell case are added to the top and bottom
479      !!     
480      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
481      !!----------------------------------------------------------------------
482      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
483      !!
484      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
485      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
486      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
487      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
488      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
489      !!----------------------------------------------------------------------
490      !
491      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
492      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
493      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
494      !
495     IF( kt == nit000 ) THEN
496         IF(lwp) WRITE(numout,*)
497         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
498         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
499      ENDIF
500
501      ! Local constant initialization
502      zcoef0 = - grav * 0.5_wp
503      ! To use density and not density anomaly
504!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
505!      ELSE                 ;     znad = 0._wp         ! Fixed volume
506!      ENDIF
507      znad=1._wp
508      ! iniitialised to 0. zhpi zhpi
509      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
510
511!==================================================================================     
512!=====Compute iceload and contribution of the half first wet layer =================
513!===================================================================================
514
515      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
516      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
517
518      ! compute density of the water displaced by the ice shelf
519      zrhd = rhd ! save rhd
520      DO jk = 1, jpk
521           zdept(:,:)=gdept_1d(jk)
522           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
523      END DO
524      WHERE ( tmask(:,:,:) == 1._wp)
525        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
526      END WHERE
527     
528      ! compute rhd at the ice/oce interface (ice shelf side)
529      CALL eos(ztstop,risfdep,zrhdtop_isf)
530
531      ! compute rhd at the ice/oce interface (ocean side)
532      DO ji=1,jpi
533        DO jj=1,jpj
534          ikt=mikt(ji,jj)
535          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
536          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
537        END DO
538      END DO
539      CALL eos(ztstop,risfdep,zrhdtop_oce)
540      !
541      ! Surface value + ice shelf gradient
542      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
543      ziceload = 0._wp
544      DO jj = 1, jpj
545         DO ji = 1, jpi   ! vector opt.
546            ikt=mikt(ji,jj)
547            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
548            DO jk=2,ikt-1
549               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
550                  &                              * (1._wp - tmask(ji,jj,jk))
551            END DO
552            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
553                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
554         END DO
555      END DO
556      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
557      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
558      DO jj = 2, jpjm1
559         DO ji = fs_2, fs_jpim1   ! vector opt.
560            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
561            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
562            ! we assume ISF is in isostatic equilibrium
563            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
564               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
565               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
566               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
567               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
568            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
569               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
570               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
571               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
572               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
573            ! s-coordinate pressure gradient correction (=0 if z coordinate)
574            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
575               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
576            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
577               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
578            ! add to the general momentum trend
579            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
580            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
581         END DO
582      END DO
583!==================================================================================     
584!===== Compute partial cell contribution for the top cell =========================
585!==================================================================================
586      DO jj = 2, jpjm1
587         DO ji = fs_2, fs_jpim1   ! vector opt.
588            iku = miku(ji,jj) ; 
589            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
590            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
591            ! u direction
592            IF ( iku .GT. 1 ) THEN
593               ! case iku
594               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
595                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
596                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
597               ! corrective term ( = 0 if z coordinate )
598               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
599               ! zhpi will be added in interior loop
600               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
601               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
602               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
603
604               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
605               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
606                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
607                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
608                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
609                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
610               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
611            END IF
612               
613            ! v direction
614            ikv = mikv(ji,jj)
615            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
616            IF ( ikv .GT. 1 ) THEN
617               ! case ikv
618               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
619                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
620                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
621               ! corrective term ( = 0 if z coordinate )
622               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
623               ! zhpi will be added in interior loop
624               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
625               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
626               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
627               
628               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
629               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
630                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
631                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
632                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
633                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
634               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
635            END IF
636         END DO
637      END DO
638
639!==================================================================================     
640!===== Compute interior value =====================================================
641!==================================================================================
642
643      DO jj = 2, jpjm1
644         DO ji = fs_2, fs_jpim1   ! vector opt.
645            iku=miku(ji,jj); ikv=mikv(ji,jj)
646            DO jk = 2, jpkm1
647               ! hydrostatic pressure gradient along s-surfaces
648               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
649               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
650                  &                            + zcoef0 / e1u(ji,jj)                                                           &
651                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
652                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
653                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
654                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
655               ! s-coordinate pressure gradient correction
656               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
657               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
658                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
659               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
660
661               ! hydrostatic pressure gradient along s-surfaces
662               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
663               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
664                  &                            + zcoef0 / e2v(ji,jj)                                                           &
665                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
666                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
667                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
668                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
669               ! s-coordinate pressure gradient correction
670               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
671               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
672                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
673               ! add to the general momentum trend
674               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
675            END DO
676         END DO
677      END DO
678
679!==================================================================================     
680!===== Compute bottom cell contribution (partial cell) ============================
681!==================================================================================
682
683      DO jj = 2, jpjm1
684         DO ji = 2, jpim1
685            iku = mbku(ji,jj)
686            ikv = mbkv(ji,jj)
687
688            IF (iku .GT. 1) THEN
689               ! remove old value (interior case)
690               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
691                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
692               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
693               ! put new value
694               ! -zpshpi to avoid double contribution of the partial step in the top layer
695               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
696               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
697               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
698            END IF
699            ! v direction
700            IF (ikv .GT. 1) THEN
701               ! remove old value (interior case)
702               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
703                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
704               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
705               ! put new value
706               ! -zpshpj to avoid double contribution of the partial step in the top layer
707               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
708               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
709               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
710            END IF
711         END DO
712      END DO
713     
714      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
715      rhd = zrhd
716      !
717      CALL wrk_dealloc( jpi,jpj,2, ztstop)
718      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
719      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
720      !
721   END SUBROUTINE hpg_isf
722
723
724   SUBROUTINE hpg_djc( kt )
725      !!---------------------------------------------------------------------
726      !!                  ***  ROUTINE hpg_djc  ***
727      !!
728      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
729      !!
730      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
731      !!----------------------------------------------------------------------
732      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
733      !!
734      INTEGER  ::   ji, jj, jk          ! dummy loop indices
735      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
736      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
737      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
738      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
739      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
740      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
741      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
742      !!----------------------------------------------------------------------
743      !
744      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
745      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
746      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
747      !
748
749      IF( kt == nit000 ) THEN
750         IF(lwp) WRITE(numout,*)
751         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
752         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
753      ENDIF
754
755      ! Local constant initialization
756      zcoef0 = - grav * 0.5_wp
757      z1_10  = 1._wp / 10._wp
758      z1_12  = 1._wp / 12._wp
759
760      !----------------------------------------------------------------------------------------
761      !  compute and store in provisional arrays elementary vertical and horizontal differences
762      !----------------------------------------------------------------------------------------
763
764!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
765
766      DO jk = 2, jpkm1
767         DO jj = 2, jpjm1
768            DO ji = fs_2, fs_jpim1   ! vector opt.
769               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
770               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
771               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
772               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
773               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
774               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
775            END DO
776         END DO
777      END DO
778
779      !-------------------------------------------------------------------------
780      ! compute harmonic averages using eq. 5.18
781      !-------------------------------------------------------------------------
782      zep = 1.e-15
783
784!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
785!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
786
787      DO jk = 2, jpkm1
788         DO jj = 2, jpjm1
789            DO ji = fs_2, fs_jpim1   ! vector opt.
790               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
791
792               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
793               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
794
795               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
796               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
797
798               IF( cffw > zep) THEN
799                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
800                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
801               ELSE
802                  drhow(ji,jj,jk) = 0._wp
803               ENDIF
804
805               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
806                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
807
808               IF( cffu > zep ) THEN
809                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
810                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
811               ELSE
812                  drhou(ji,jj,jk ) = 0._wp
813               ENDIF
814
815               IF( cffx > zep ) THEN
816                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
817                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
818               ELSE
819                  dzu(ji,jj,jk) = 0._wp
820               ENDIF
821
822               IF( cffv > zep ) THEN
823                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
824                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
825               ELSE
826                  drhov(ji,jj,jk) = 0._wp
827               ENDIF
828
829               IF( cffy > zep ) THEN
830                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
831                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
832               ELSE
833                  dzv(ji,jj,jk) = 0._wp
834               ENDIF
835
836            END DO
837         END DO
838      END DO
839
840      !----------------------------------------------------------------------------------
841      ! apply boundary conditions at top and bottom using 5.36-5.37
842      !----------------------------------------------------------------------------------
843      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
844      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
845      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
846
847      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
848      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
849      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
850
851
852      !--------------------------------------------------------------
853      ! Upper half of top-most grid box, compute and store
854      !-------------------------------------------------------------
855
856!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
857!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
858
859      DO jj = 2, jpjm1
860         DO ji = fs_2, fs_jpim1   ! vector opt.
861            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
862               &                   * (  rhd(ji,jj,1)                                    &
863               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
864               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
865               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
866         END DO
867      END DO
868
869!!bug gm    : here also, simplification is possible
870!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
871
872      DO jk = 2, jpkm1
873         DO jj = 2, jpjm1
874            DO ji = fs_2, fs_jpim1   ! vector opt.
875
876               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
877                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
878                  &            - grav * z1_10 * (                                                                     &
879                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
880                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
881                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
882                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
883                  &                             )
884
885               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
886                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
887                  &            - grav* z1_10 * (                                                                      &
888                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
889                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
890                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
891                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
892                  &                            )
893
894               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
895                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
896                  &            - grav* z1_10 * (                                                                      &
897                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
898                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
899                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
900                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
901                  &                            )
902
903            END DO
904         END DO
905      END DO
906      CALL lbc_lnk(rho_k,'W',1.)
907      CALL lbc_lnk(rho_i,'U',1.)
908      CALL lbc_lnk(rho_j,'V',1.)
909
910
911      ! ---------------
912      !  Surface value
913      ! ---------------
914      DO jj = 2, jpjm1
915         DO ji = fs_2, fs_jpim1   ! vector opt.
916            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
917            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
918            ! add to the general momentum trend
919            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
920            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
921         END DO
922      END DO
923
924      ! ----------------
925      !  interior value   (2=<jk=<jpkm1)
926      ! ----------------
927      DO jk = 2, jpkm1
928         DO jj = 2, jpjm1
929            DO ji = fs_2, fs_jpim1   ! vector opt.
930               ! hydrostatic pressure gradient along s-surfaces
931               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
932                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
933                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
934               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
935                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
936                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
937               ! add to the general momentum trend
938               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
939               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
940            END DO
941         END DO
942      END DO
943      !
944      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
945      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
946      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
947      !
948   END SUBROUTINE hpg_djc
949
950
951   SUBROUTINE hpg_prj( kt )
952      !!---------------------------------------------------------------------
953      !!                  ***  ROUTINE hpg_prj  ***
954      !!
955      !! ** Method  :   s-coordinate case.
956      !!      A Pressure-Jacobian horizontal pressure gradient method
957      !!      based on the constrained cubic-spline interpolation for
958      !!      all vertical coordinate systems
959      !!
960      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
961      !!----------------------------------------------------------------------
962      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
963      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
964      !!
965      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
966      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
967      !!
968      !! The local variables for the correction term
969      INTEGER  :: jk1, jis, jid, jjs, jjd
970      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
971      REAL(wp) :: zrhdt1
972      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
973      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
974      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
975      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
976      !!----------------------------------------------------------------------
977      !
978      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
979      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
980      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
981      !
982      IF( kt == nit000 ) THEN
983         IF(lwp) WRITE(numout,*)
984         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
985         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
986      ENDIF
987
988      !!----------------------------------------------------------------------
989      ! Local constant initialization
990      zcoef0 = - grav
991      znad = 0.0_wp
992      IF( lk_vvl ) znad = 1._wp
993
994      ! Clean 3-D work arrays
995      zhpi(:,:,:) = 0._wp
996      zrhh(:,:,:) = rhd(:,:,:)
997
998      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
999      DO jj = 1, jpj
1000        DO ji = 1, jpi
1001          jk = mbathy(ji,jj)
1002          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1003          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1004          ELSE IF(jk < jpkm1) THEN
1005             DO jkk = jk+1, jpk
1006                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
1007                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1008             END DO
1009          ENDIF
1010        END DO
1011      END DO
1012
1013      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1014      DO jj = 1, jpj
1015         DO ji = 1, jpi
1016            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1017         END DO
1018      END DO
1019
1020      DO jk = 2, jpk
1021         DO jj = 1, jpj
1022            DO ji = 1, jpi
1023               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1024            END DO
1025         END DO
1026      END DO
1027
1028      fsp(:,:,:) = zrhh (:,:,:)
1029      xsp(:,:,:) = zdept(:,:,:)
1030
1031      ! Construct the vertical density profile with the
1032      ! constrained cubic spline interpolation
1033      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1034      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1035
1036      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1037      DO jj = 2, jpj
1038        DO ji = 2, jpi
1039          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1040                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1041                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1042
1043          ! assuming linear profile across the top half surface layer
1044          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1045        END DO
1046      END DO
1047
1048      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1049      DO jk = 2, jpkm1
1050        DO jj = 2, jpj
1051          DO ji = 2, jpi
1052            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1053                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1054                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1055                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1056          END DO
1057        END DO
1058      END DO
1059
1060      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1061
1062      ! Prepare zsshu_n and zsshv_n
1063      DO jj = 2, jpjm1
1064        DO ji = 2, jpim1
1065          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1066                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
1067          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1068                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
1069        END DO
1070      END DO
1071
1072      DO jj = 2, jpjm1
1073        DO ji = 2, jpim1
1074          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
1075          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1076        END DO
1077      END DO
1078
1079      DO jk = 2, jpkm1
1080        DO jj = 2, jpjm1
1081          DO ji = 2, jpim1
1082            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1083            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1084          END DO
1085        END DO
1086      END DO
1087
1088      DO jk = 1, jpkm1
1089        DO jj = 2, jpjm1
1090          DO ji = 2, jpim1
1091            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1092            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1093          END DO
1094        END DO
1095      END DO
1096
1097      DO jk = 1, jpkm1
1098        DO jj = 2, jpjm1
1099          DO ji = 2, jpim1
1100            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1101            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1102            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1103            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1104          END DO
1105        END DO
1106      END DO
1107
1108
1109      DO jk = 1, jpkm1
1110        DO jj = 2, jpjm1
1111          DO ji = 2, jpim1
1112            zpwes = 0._wp; zpwed = 0._wp
1113            zpnss = 0._wp; zpnsd = 0._wp
1114            zuijk = zu(ji,jj,jk)
1115            zvijk = zv(ji,jj,jk)
1116
1117            !!!!!     for u equation
1118            IF( jk <= mbku(ji,jj) ) THEN
1119               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1120                 jis = ji + 1; jid = ji
1121               ELSE
1122                 jis = ji;     jid = ji +1
1123               ENDIF
1124
1125               ! integrate the pressure on the shallow side
1126               jk1 = jk
1127               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1128                 IF( jk1 == mbku(ji,jj) ) THEN
1129                   zuijk = -zdept(jis,jj,jk1)
1130                   EXIT
1131                 ENDIF
1132                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1133                 zpwes = zpwes +                                    &
1134                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1135                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1136                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1137                 jk1 = jk1 + 1
1138               END DO
1139
1140               ! integrate the pressure on the deep side
1141               jk1 = jk
1142               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1143                 IF( jk1 == 1 ) THEN
1144                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1145                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1146                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1147                                                     dsp(jid,jj,1)) * zdeps
1148                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1149                   EXIT
1150                 ENDIF
1151                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1152                 zpwed = zpwed +                                        &
1153                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1154                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1155                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1156                 jk1 = jk1 - 1
1157               END DO
1158
1159               ! update the momentum trends in u direction
1160
1161               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1162               IF( lk_vvl ) THEN
1163                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1164                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1165                ELSE
1166                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1167               ENDIF
1168
1169               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1170               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1171            ENDIF
1172
1173            !!!!!     for v equation
1174            IF( jk <= mbkv(ji,jj) ) THEN
1175               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1176                 jjs = jj + 1; jjd = jj
1177               ELSE
1178                 jjs = jj    ; jjd = jj + 1
1179               ENDIF
1180
1181               ! integrate the pressure on the shallow side
1182               jk1 = jk
1183               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1184                 IF( jk1 == mbkv(ji,jj) ) THEN
1185                   zvijk = -zdept(ji,jjs,jk1)
1186                   EXIT
1187                 ENDIF
1188                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1189                 zpnss = zpnss +                                      &
1190                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1191                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1192                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1193                 jk1 = jk1 + 1
1194               END DO
1195
1196               ! integrate the pressure on the deep side
1197               jk1 = jk
1198               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1199                 IF( jk1 == 1 ) THEN
1200                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1201                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1202                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1203                                                     dsp(ji,jjd,1) ) * zdeps
1204                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1205                   EXIT
1206                 ENDIF
1207                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1208                 zpnsd = zpnsd +                                        &
1209                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1210                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1211                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1212                 jk1 = jk1 - 1
1213               END DO
1214
1215
1216               ! update the momentum trends in v direction
1217
1218               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1219               IF( lk_vvl ) THEN
1220                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1221                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1222               ELSE
1223                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1224               ENDIF
1225
1226               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1227               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1228            ENDIF
1229
1230
1231           END DO
1232        END DO
1233      END DO
1234      !
1235      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1236      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1237      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1238      !
1239   END SUBROUTINE hpg_prj
1240
1241
1242   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1243      !!----------------------------------------------------------------------
1244      !!                 ***  ROUTINE cspline  ***
1245      !!
1246      !! ** Purpose :   constrained cubic spline interpolation
1247      !!
1248      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1249      !!
1250      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1251      !!----------------------------------------------------------------------
1252      IMPLICIT NONE
1253      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1254      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1255                                                                    ! the interpoated function
1256      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1257                                                                    ! 2: Linear
1258      !
1259      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1260      INTEGER  ::   jpi, jpj, jpkm1
1261      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1262      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1263      REAL(wp) ::   zdf(size(fsp,3))
1264      !!----------------------------------------------------------------------
1265
1266      jpi   = size(fsp,1)
1267      jpj   = size(fsp,2)
1268      jpkm1 = size(fsp,3) - 1
1269
1270
1271      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1272         DO ji = 1, jpi
1273            DO jj = 1, jpj
1274           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1275           !    DO jk = 2, jpkm1-1
1276           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1277           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1278           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1279           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1280           !
1281           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1282           !
1283           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1284           !           zdf(jk) = 0._wp
1285           !       ELSE
1286           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1287           !       ENDIF
1288           !    END DO
1289
1290           !!Simply geometric average
1291               DO jk = 2, jpkm1-1
1292                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1293                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1294
1295                  IF(zdf1 * zdf2 <= 0._wp) THEN
1296                     zdf(jk) = 0._wp
1297                  ELSE
1298                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1299                  ENDIF
1300               END DO
1301
1302               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1303                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1304               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1305                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1306                          & 0.5_wp * zdf(jpkm1 - 1)
1307
1308               DO jk = 1, jpkm1 - 1
1309                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1310                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1311                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1312                 zddf1  = -2._wp * ztmp1 + ztmp2
1313                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1314                 zddf2  =  2._wp * ztmp1 - ztmp2
1315
1316                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1317                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1318                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1319                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1320                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1321                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1322                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1323                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1324                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1325               END DO
1326            END DO
1327         END DO
1328
1329      ELSE IF (polynomial_type == 2) THEN     ! Linear
1330         DO ji = 1, jpi
1331            DO jj = 1, jpj
1332               DO jk = 1, jpkm1-1
1333                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1334                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1335
1336                  dsp(ji,jj,jk) = 0._wp
1337                  csp(ji,jj,jk) = 0._wp
1338                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1339                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1340               END DO
1341            END DO
1342         END DO
1343
1344      ELSE
1345           CALL ctl_stop( 'invalid polynomial type in cspline' )
1346      ENDIF
1347
1348   END SUBROUTINE cspline
1349
1350
1351   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1352      !!----------------------------------------------------------------------
1353      !!                 ***  ROUTINE interp1  ***
1354      !!
1355      !! ** Purpose :   1-d linear interpolation
1356      !!
1357      !! ** Method  :   interpolation is straight forward
1358      !!                extrapolation is also permitted (no value limit)
1359      !!----------------------------------------------------------------------
1360      IMPLICIT NONE
1361      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1362      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1363      REAL(wp)             ::  zdeltx
1364      !!----------------------------------------------------------------------
1365
1366      zdeltx = xr - xl
1367      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1368        f = 0.5_wp * (fl + fr)
1369      ELSE
1370        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1371      ENDIF
1372
1373   END FUNCTION interp1
1374
1375
1376   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1377      !!----------------------------------------------------------------------
1378      !!                 ***  ROUTINE interp1  ***
1379      !!
1380      !! ** Purpose :   1-d constrained cubic spline interpolation
1381      !!
1382      !! ** Method  :  cubic spline interpolation
1383      !!
1384      !!----------------------------------------------------------------------
1385      IMPLICIT NONE
1386      REAL(wp), INTENT(in) ::  x, a, b, c, d
1387      REAL(wp)             ::  f ! value from the interpolation
1388      !!----------------------------------------------------------------------
1389
1390      f = a + x* ( b + x * ( c + d * x ) )
1391
1392   END FUNCTION interp2
1393
1394
1395   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1396      !!----------------------------------------------------------------------
1397      !!                 ***  ROUTINE interp1  ***
1398      !!
1399      !! ** Purpose :   Calculate the first order of deriavtive of
1400      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1401      !!
1402      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1403      !!
1404      !!----------------------------------------------------------------------
1405      IMPLICIT NONE
1406      REAL(wp), INTENT(in) ::  x, a, b, c, d
1407      REAL(wp)             ::  f ! value from the interpolation
1408      !!----------------------------------------------------------------------
1409
1410      f = b + x * ( 2._wp * c + 3._wp * d * x)
1411
1412   END FUNCTION interp3
1413
1414
1415   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1416      !!----------------------------------------------------------------------
1417      !!                 ***  ROUTINE interp1  ***
1418      !!
1419      !! ** Purpose :   1-d constrained cubic spline integration
1420      !!
1421      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1422      !!
1423      !!----------------------------------------------------------------------
1424      IMPLICIT NONE
1425      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1426      REAL(wp)             ::  za1, za2, za3
1427      REAL(wp)             ::  f                   ! integration result
1428      !!----------------------------------------------------------------------
1429
1430      za1 = 0.5_wp * b
1431      za2 = c / 3.0_wp
1432      za3 = 0.25_wp * d
1433
1434      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1435         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1436
1437   END FUNCTION integ_spline
1438
1439   !!======================================================================
1440END MODULE dynhpg
1441
Note: See TracBrowser for help on using the repository browser.