New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

dynhpg.F90 in branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

Context Navigation

source: branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 8197

Last change on this file since 8197 was 8197, checked in by glong, 7 years ago
Changed id's to be chars e.g. hpg to more easily identify output (and updated field_def.xml accordingly). Also rearranged scaling factors in dyn_vrt_dia subroutines in divcur.F90
File size: 70.7 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!!----------------------------------------------------------------------
20
21	!!----------------------------------------------------------------------
22	!! dyn_hpg : update the momentum trend with the now horizontal
23	!! gradient of the hydrostatic pressure
24	!! dyn_hpg_init : initialisation and control of options
25	!! hpg_zco : z-coordinate scheme
26	!! hpg_zps : z-coordinate plus partial steps (interpolation)
27	!! hpg_sco : s-coordinate (standard jacobian formulation)
28	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
29	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
30	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
31	!!----------------------------------------------------------------------
32	USE oce ! ocean dynamics and tracers
33	USE sbc_oce ! surface variable (only for the flag with ice shelf)
34	USE dom_oce ! ocean space and time domain
35	USE phycst ! physical constants
36	USE trd_oce ! trends: ocean variables
37	USE trddyn ! trend manager: dynamics
38	USE divcur ! for dyn_vrt_dia_3d
39	!
40	USE in_out_manager ! I/O manager
41	USE prtctl ! Print control
42	USE lbclnk ! lateral boundary condition
43	USE lib_mpp ! MPP library
44	USE eosbn2 ! compute density
45	USE wrk_nemo ! Memory Allocation
46	USE timing ! Timing
47
48	IMPLICIT NONE
49	PRIVATE
50
51	PUBLIC dyn_hpg ! routine called by step module
52	PUBLIC dyn_hpg_init ! routine called by opa module
53
54	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55	LOGICAL , PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
56	LOGICAL , PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
57	LOGICAL , PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
58	LOGICAL , PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
59	LOGICAL , PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
60	LOGICAL , PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
61	LOGICAL , PUBLIC :: ln_dynhpg_imp !: semi-implicite hpg flag
62
63	INTEGER , PUBLIC :: nhpg = 0 ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65	!! * Substitutions
66	# include "domzgr_substitute.h90"
67	# include "vectopt_loop_substitute.h90"
68	!!----------------------------------------------------------------------
69	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
70	!! $Id$
71	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
72	!!----------------------------------------------------------------------
73	CONTAINS
74
75	SUBROUTINE dyn_hpg( kt )
76	!!---------------------------------------------------------------------
77	!! * ROUTINE dyn_hpg *
78	!!
79	!! ** Method : Call the hydrostatic pressure gradient routine
80	!! using the scheme defined in the namelist
81	!!
82	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84	!!----------------------------------------------------------------------
85	INTEGER, INTENT(in) :: kt ! ocean time-step index
86	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv
87	!!----------------------------------------------------------------------
88	!
89	IF( nn_timing == 1 ) CALL timing_start('dyn_hpg')
90	!
91	IF( l_trddyn ) THEN ! Temporary saving of ua and va trends (l_trddyn)
92	CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93	ztrdu(:,:,:) = ua(:,:,:)
94	ztrdv(:,:,:) = va(:,:,:)
95	ENDIF
96	!
97	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
98	CASE ( 0 ) ; CALL hpg_zco ( kt ) ! z-coordinate
99	CASE ( 1 ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
100	CASE ( 2 ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
101	CASE ( 3 ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
102	CASE ( 4 ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
103	CASE ( 5 ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
104	END SELECT
105	!
106	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107	ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108	ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110	CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111	ENDIF
112	!
113	IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg - Ua: ', mask1=umask, &
114	& tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
115	!
116	IF( nn_timing == 1 ) CALL timing_stop('dyn_hpg')
117	!
118	END SUBROUTINE dyn_hpg
119
120
121	SUBROUTINE dyn_hpg_init
122	!!----------------------------------------------------------------------
123	!! * ROUTINE dyn_hpg_init *
124	!!
125	!! ** Purpose : initializations for the hydrostatic pressure gradient
126	!! computation and consistency control
127	!!
128	!! ** Action : Read the namelist namdyn_hpg and check the consistency
129	!! with the type of vertical coordinate used (zco, zps, sco)
130	!!----------------------------------------------------------------------
131	INTEGER :: ioptio = 0 ! temporary integer
132	INTEGER :: ios ! Local integer output status for namelist read
133	!!
134	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
135	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
136	!!----------------------------------------------------------------------
137	!
138	REWIND( numnam_ref ) ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
139	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
140	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
141
142	REWIND( numnam_cfg ) ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
143	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
144	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
145	IF(lwm) WRITE ( numond, namdyn_hpg )
146	!
147	IF(lwp) THEN ! Control print
148	WRITE(numout,*)
149	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
150	WRITE(numout,*) '~~~~~~~~~~~~'
151	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
152	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
153	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
154	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
155	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
156	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
157	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
158	WRITE(numout,*) ' time stepping: centered (F) or semi-implicit (T) ln_dynhpg_imp = ', ln_dynhpg_imp
159	ENDIF
160	!
161	IF( ln_hpg_djc ) &
162	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
163	& currently disabled (bugs under investigation). Please select &
164	& either ln_hpg_sco or ln_hpg_prj instead')
165	!
166	IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
167	& CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
168	& the standard jacobian formulation hpg_sco or &
169	& the pressure jacobian formulation hpg_prj')
170
171	IF( ln_hpg_isf .AND. .NOT. ln_isfcav ) &
172	& CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
173	IF( .NOT. ln_hpg_isf .AND. ln_isfcav ) &
174	& CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
175	!
176	! ! Set nhpg from ln_hpg_... flags
177	IF( ln_hpg_zco ) nhpg = 0
178	IF( ln_hpg_zps ) nhpg = 1
179	IF( ln_hpg_sco ) nhpg = 2
180	IF( ln_hpg_djc ) nhpg = 3
181	IF( ln_hpg_prj ) nhpg = 4
182	IF( ln_hpg_isf ) nhpg = 5
183	!
184	! ! Consistency check
185	ioptio = 0
186	IF( ln_hpg_zco ) ioptio = ioptio + 1
187	IF( ln_hpg_zps ) ioptio = ioptio + 1
188	IF( ln_hpg_sco ) ioptio = ioptio + 1
189	IF( ln_hpg_djc ) ioptio = ioptio + 1
190	IF( ln_hpg_prj ) ioptio = ioptio + 1
191	IF( ln_hpg_isf ) ioptio = ioptio + 1
192	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
193	!
194	! initialisation of ice load
195	riceload(:,:)=0.0
196	!
197	END SUBROUTINE dyn_hpg_init
198
199
200	SUBROUTINE hpg_zco( kt )
201	!!---------------------------------------------------------------------
202	!! * ROUTINE hpg_zco *
203	!!
204	!! ** Method : z-coordinate case, levels are horizontal surfaces.
205	!! The now hydrostatic pressure gradient at a given level, jk,
206	!! is computed by taking the vertical integral of the in-situ
207	!! density gradient along the model level from the suface to that
208	!! level: zhpi = grav .....
209	!! zhpj = grav .....
210	!! add it to the general momentum trend (ua,va).
211	!! ua = ua - 1/e1u * zhpi
212	!! va = va - 1/e2v * zhpj
213	!!
214	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
215	!!----------------------------------------------------------------------
216	INTEGER, INTENT(in) :: kt ! ocean time-step index
217	!!
218	INTEGER :: ji, jj, jk ! dummy loop indices
219	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
220	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
221	!!----------------------------------------------------------------------
222	!
223	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
224	!
225	IF( kt == nit000 ) THEN
226	IF(lwp) WRITE(numout,*)
227	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
228	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
229	ENDIF
230
231	zcoef0 = - grav * 0.5_wp ! Local constant initialization
232
233	! Surface value
234	DO jj = 2, jpjm1
235	DO ji = fs_2, fs_jpim1 ! vector opt.
236	zcoef1 = zcoef0 * fse3w(ji,jj,1)
237	! hydrostatic pressure gradient
238	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
239	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
240	! add to the general momentum trend
241	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
242	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
243	END DO
244	END DO
245
246	!
247	! interior value (2=<jk=<jpkm1)
248	DO jk = 2, jpkm1
249	DO jj = 2, jpjm1
250	DO ji = fs_2, fs_jpim1 ! vector opt.
251	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
252	! hydrostatic pressure gradient
253	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
254	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
255	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
256
257	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
258	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
259	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
260	! add to the general momentum trend
261	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
262	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
263	END DO
264	END DO
265	END DO
266	!
267	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
268	!
269	END SUBROUTINE hpg_zco
270
271
272	SUBROUTINE hpg_zps( kt )
273	!!---------------------------------------------------------------------
274	!! * ROUTINE hpg_zps *
275	!!
276	!! ** Method : z-coordinate plus partial steps case. blahblah...
277	!!
278	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
279	!!----------------------------------------------------------------------
280	INTEGER, INTENT(in) :: kt ! ocean time-step index
281	!!
282	INTEGER :: ji, jj, jk ! dummy loop indices
283	INTEGER :: iku, ikv ! temporary integers
284	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
285	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
286	!!----------------------------------------------------------------------
287	!
288	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
289	!
290	IF( kt == nit000 ) THEN
291	IF(lwp) WRITE(numout,*)
292	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
293	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
294	ENDIF
295
296
297	! Local constant initialization
298	zcoef0 = - grav * 0.5_wp
299
300	! Surface value (also valid in partial step case)
301	DO jj = 2, jpjm1
302	DO ji = fs_2, fs_jpim1 ! vector opt.
303	zcoef1 = zcoef0 * fse3w(ji,jj,1)
304	! hydrostatic pressure gradient
305	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
306	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
307	! add to the general momentum trend
308	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
309	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
310	END DO
311	END DO
312
313
314	! interior value (2=<jk=<jpkm1)
315	DO jk = 2, jpkm1
316	DO jj = 2, jpjm1
317	DO ji = fs_2, fs_jpim1 ! vector opt.
318	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
319	! hydrostatic pressure gradient
320	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
321	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
322	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
323
324	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
325	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
326	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
327	! add to the general momentum trend
328	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
329	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
330	END DO
331	END DO
332	END DO
333
334
335	! partial steps correction at the last level (use gru & grv computed in zpshde.F90)
336	DO jj = 2, jpjm1
337	DO ji = 2, jpim1
338	iku = mbku(ji,jj)
339	ikv = mbkv(ji,jj)
340	zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj ,iku) )
341	zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji ,jj+1,ikv) )
342	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
343	ua (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) ! subtract old value
344	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
345	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
346	ua (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
347	ENDIF
348	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
349	va (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) ! subtract old value
350	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
351	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
352	va (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
353	ENDIF
354	END DO
355	END DO
356	!
357	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
358	!
359	END SUBROUTINE hpg_zps
360
361	SUBROUTINE hpg_sco( kt )
362	!!---------------------------------------------------------------------
363	!! * ROUTINE hpg_sco *
364	!!
365	!! ** Method : s-coordinate case. Jacobian scheme.
366	!! The now hydrostatic pressure gradient at a given level, jk,
367	!! is computed by taking the vertical integral of the in-situ
368	!! density gradient along the model level from the suface to that
369	!! level. s-coordinates (ln_sco): a corrective term is added
370	!! to the horizontal pressure gradient :
371	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
372	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
373	!! add it to the general momentum trend (ua,va).
374	!! ua = ua - 1/e1u * zhpi
375	!! va = va - 1/e2v * zhpj
376	!!
377	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
378	!!----------------------------------------------------------------------
379	INTEGER, INTENT(in) :: kt ! ocean time-step index
380	!!
381	CHARACTER(len=3) :: id_vrt_dia_hpg = "hpg" ! TODO remove once flags set properly
382	INTEGER :: ji, jj, jk ! dummy loop indices
383	REAL(wp) :: zcoef0, zuap, zvap, znad ! temporary scalars
384	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
385	REAL(wp), POINTER, DIMENSION(:,:,:) :: zuhpg, zvhpg
386	!!----------------------------------------------------------------------
387	!
388	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
389	CALL wrk_alloc( jpi,jpj,jpk, zuhpg, zvhpg )
390	!
391	IF( kt == nit000 ) THEN
392	IF(lwp) WRITE(numout,*)
393	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
394	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
395	ENDIF
396
397	! Local constant initialization
398	zcoef0 = - grav * 0.5_wp
399	! To use density and not density anomaly
400	IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
401	ELSE ; znad = 0._wp ! Fixed volume
402	ENDIF
403
404	! Surface value
405	DO jj = 2, jpjm1
406	DO ji = fs_2, fs_jpim1 ! vector opt.
407	! hydrostatic pressure gradient along s-surfaces
408	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj ,1) * ( znad + rhd(ji+1,jj ,1) ) &
409	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
410	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji ,jj+1,1) * ( znad + rhd(ji ,jj+1,1) ) &
411	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
412	! s-coordinate pressure gradient correction
413	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
414	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
415	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
416	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
417	! combine gradient and correction
418	zuhpg(ji,jj,1) = zhpi(ji,jj,1) + zuap
419	zvhpg(ji,jj,1) = zhpj(ji,jj,1) + zvap
420	! add to the general momentum trend
421	ua(ji,jj,1) = ua(ji,jj,1) + zuhpg(ji,jj,1)
422	va(ji,jj,1) = va(ji,jj,1) + zvhpg(ji,jj,1)
423	END DO
424	END DO
425
426	! interior value (2=<jk=<jpkm1)
427	DO jk = 2, jpkm1
428	DO jj = 2, jpjm1
429	DO ji = fs_2, fs_jpim1 ! vector opt.
430	! hydrostatic pressure gradient along s-surfaces
431	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
432	& * ( fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
433	& - fse3w(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
434	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
435	& * ( fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
436	& - fse3w(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
437	! s-coordinate pressure gradient correction
438	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
439	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
440	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
441	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
442	! combine gradient and correction
443	zuhpg(ji,jj,jk) = zhpi(ji,jj,jk) + zuap
444	zvhpg(ji,jj,jk) = zhpj(ji,jj,jk) + zvap
445	! add to the general momentum trend
446	ua(ji,jj,jk) = ua(ji,jj,jk) + zuhpg(ji,jj,jk)
447	va(ji,jj,jk) = va(ji,jj,jk) + zvhpg(ji,jj,jk)
448	END DO
449	END DO
450	END DO
451	!
452	! calculate dia_vor_int & dia_vor_mn if required
453	IF ( id_vrt_dia_hpg == "hpg" ) THEN
454	! TODO - remove kt only used for validation
455	CALL dyn_vrt_dia_3d(zuhpg, zvhpg, id_vrt_dia_hpg, kt)
456	END IF
457	!
458	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
459	!
460	END SUBROUTINE hpg_sco
461
462	SUBROUTINE hpg_isf( kt )
463	!!---------------------------------------------------------------------
464	!! * ROUTINE hpg_sco *
465	!!
466	!! ** Method : s-coordinate case. Jacobian scheme.
467	!! The now hydrostatic pressure gradient at a given level, jk,
468	!! is computed by taking the vertical integral of the in-situ
469	!! density gradient along the model level from the suface to that
470	!! level. s-coordinates (ln_sco): a corrective term is added
471	!! to the horizontal pressure gradient :
472	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
473	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
474	!! add it to the general momentum trend (ua,va).
475	!! ua = ua - 1/e1u * zhpi
476	!! va = va - 1/e2v * zhpj
477	!! iceload is added and partial cell case are added to the top and bottom
478	!!
479	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
480	!!----------------------------------------------------------------------
481	INTEGER, INTENT(in) :: kt ! ocean time-step index
482	!!
483	INTEGER :: ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j ! dummy loop indices
484	REAL(wp) :: zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1 ! temporary scalars
485	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj, zrhd
486	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztstop
487	REAL(wp), POINTER, DIMENSION(:,:) :: ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
488	!!----------------------------------------------------------------------
489	!
490	CALL wrk_alloc( jpi,jpj, 2, ztstop)
491	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
492	CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
493	!
494	IF( kt == nit000 ) THEN
495	IF(lwp) WRITE(numout,*)
496	IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
497	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
498	ENDIF
499
500	! Local constant initialization
501	zcoef0 = - grav * 0.5_wp
502	! To use density and not density anomaly
503	! IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
504	! ELSE ; znad = 0._wp ! Fixed volume
505	! ENDIF
506	znad=1._wp
507	! iniitialised to 0. zhpi zhpi
508	zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
509
510	!==================================================================================
511	!=====Compute iceload and contribution of the half first wet layer =================
512	!===================================================================================
513
514	! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
515	ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
516
517	! compute density of the water displaced by the ice shelf
518	zrhd = rhd ! save rhd
519	DO jk = 1, jpk
520	zdept(:,:)=gdept_1d(jk)
521	CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
522	END DO
523	WHERE ( tmask(:,:,:) == 1._wp)
524	rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
525	END WHERE
526
527	! compute rhd at the ice/oce interface (ice shelf side)
528	CALL eos(ztstop,risfdep,zrhdtop_isf)
529
530	! compute rhd at the ice/oce interface (ocean side)
531	DO ji=1,jpi
532	DO jj=1,jpj
533	ikt=mikt(ji,jj)
534	ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
535	ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
536	END DO
537	END DO
538	CALL eos(ztstop,risfdep,zrhdtop_oce)
539	!
540	! Surface value + ice shelf gradient
541	! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
542	ziceload = 0._wp
543	DO jj = 1, jpj
544	DO ji = 1, jpi ! vector opt.
545	ikt=mikt(ji,jj)
546	ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
547	DO jk=2,ikt-1
548	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
549	& * (1._wp - tmask(ji,jj,jk))
550	END DO
551	IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
552	& * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
553	END DO
554	END DO
555	riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:) ! need to be saved for diaar5
556	! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
557	DO jj = 2, jpjm1
558	DO ji = fs_2, fs_jpim1 ! vector opt.
559	ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
560	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
561	! we assume ISF is in isostatic equilibrium
562	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj ,iktp1i) &
563	& * ( 2._wp * znad + rhd(ji+1,jj ,iktp1i) + zrhdtop_oce(ji+1,jj ) ) &
564	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
565	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
566	& + ( ziceload(ji+1,jj) - ziceload(ji,jj)) )
567	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji ,jj+1,iktp1j) &
568	& * ( 2._wp * znad + rhd(ji ,jj+1,iktp1j) + zrhdtop_oce(ji ,jj+1) ) &
569	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
570	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
571	& + ( ziceload(ji,jj+1) - ziceload(ji,jj) ) )
572	! s-coordinate pressure gradient correction (=0 if z coordinate)
573	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
574	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
575	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
576	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
577	! add to the general momentum trend
578	ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
579	va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
580	END DO
581	END DO
582	!==================================================================================
583	!===== Compute partial cell contribution for the top cell =========================
584	!==================================================================================
585	DO jj = 2, jpjm1
586	DO ji = fs_2, fs_jpim1 ! vector opt.
587	iku = miku(ji,jj) ;
588	zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
589	ze3wu = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
590	! u direction
591	IF ( iku .GT. 1 ) THEN
592	! case iku
593	zhpi(ji,jj,iku) = zcoef0 / e1u(ji,jj) * ze3wu &
594	& * ( rhd (ji+1,jj,iku) + rhd (ji,jj,iku) &
595	& + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
596	! corrective term ( = 0 if z coordinate )
597	zuap = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
598	! zhpi will be added in interior loop
599	ua(ji,jj,iku) = ua(ji,jj,iku) + zuap
600	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
601	IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj) = zhpi(ji,jj,iku)
602
603	! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
604	zhpiint = zcoef0 / e1u(ji,jj) &
605	& * ( fse3w(ji+1,jj ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad) &
606	& + (rhd(ji+1,jj,iku ) + znad) ) * tmask(ji+1,jj,iku) &
607	& - fse3w(ji ,jj ,iku+1) * ( (rhd(ji ,jj,iku+1) + znad) &
608	& + (rhd(ji ,jj,iku ) + znad) ) * tmask(ji ,jj,iku) )
609	zhpi(ji,jj,iku+1) = zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint
610	END IF
611
612	! v direction
613	ikv = mikv(ji,jj)
614	ze3wv = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
615	IF ( ikv .GT. 1 ) THEN
616	! case ikv
617	zhpj(ji,jj,ikv) = zcoef0 / e2v(ji,jj) * ze3wv &
618	& * ( rhd(ji,jj+1,ikv) + rhd (ji,jj,ikv) &
619	& + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
620	! corrective term ( = 0 if z coordinate )
621	zvap = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
622	! zhpi will be added in interior loop
623	va(ji,jj,ikv) = va(ji,jj,ikv) + zvap
624	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
625	IF (mbkv(ji,jj) == ikv + 1) zpshpj(ji,jj) = zhpj(ji,jj,ikv)
626
627	! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
628	zhpjint = zcoef0 / e2v(ji,jj) &
629	& * ( fse3w(ji ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad) &
630	& + (rhd(ji,jj+1,ikv ) + znad) ) * tmask(ji,jj+1,ikv) &
631	& - fse3w(ji ,jj ,ikv+1) * ( (rhd(ji,jj ,ikv+1) + znad) &
632	& + (rhd(ji,jj ,ikv ) + znad) ) * tmask(ji,jj ,ikv) )
633	zhpj(ji,jj,ikv+1) = zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
634	END IF
635	END DO
636	END DO
637
638	!==================================================================================
639	!===== Compute interior value =====================================================
640	!==================================================================================
641
642	DO jj = 2, jpjm1
643	DO ji = fs_2, fs_jpim1 ! vector opt.
644	iku=miku(ji,jj); ikv=mikv(ji,jj)
645	DO jk = 2, jpkm1
646	! hydrostatic pressure gradient along s-surfaces
647	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
648	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1) &
649	& + zcoef0 / e1u(ji,jj) &
650	& * ( fse3w(ji+1,jj ,jk) * ( (rhd(ji+1,jj,jk ) + znad) &
651	& + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1) &
652	& - fse3w(ji ,jj ,jk) * ( (rhd(ji ,jj,jk ) + znad) &
653	& + (rhd(ji ,jj,jk-1) + znad) ) * tmask(ji ,jj,jk-1) )
654	! s-coordinate pressure gradient correction
655	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
656	zuap = - zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
657	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
658	ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
659
660	! hydrostatic pressure gradient along s-surfaces
661	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
662	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1) &
663	& + zcoef0 / e2v(ji,jj) &
664	& * ( fse3w(ji ,jj+1,jk) * ( (rhd(ji,jj+1,jk ) + znad) &
665	& + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1) &
666	& - fse3w(ji ,jj ,jk) * ( (rhd(ji,jj ,jk ) + znad) &
667	& + (rhd(ji,jj ,jk-1) + znad) ) * tmask(ji,jj ,jk-1) )
668	! s-coordinate pressure gradient correction
669	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
670	zvap = - zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
671	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
672	! add to the general momentum trend
673	va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
674	END DO
675	END DO
676	END DO
677
678	!==================================================================================
679	!===== Compute bottom cell contribution (partial cell) ============================
680	!==================================================================================
681
682	DO jj = 2, jpjm1
683	DO ji = 2, jpim1
684	iku = mbku(ji,jj)
685	ikv = mbkv(ji,jj)
686
687	IF (iku .GT. 1) THEN
688	! remove old value (interior case)
689	zuap = -zcoef0 * ( rhd (ji+1,jj ,iku) + rhd (ji,jj,iku) + 2._wp * znad ) &
690	& * ( fsde3w(ji+1,jj ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
691	ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
692	! put new value
693	! -zpshpi to avoid double contribution of the partial step in the top layer
694	zuap = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj) / e1u(ji,jj)
695	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj)
696	ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
697	END IF
698	! v direction
699	IF (ikv .GT. 1) THEN
700	! remove old value (interior case)
701	zvap = -zcoef0 * ( rhd (ji ,jj+1,ikv) + rhd (ji,jj,ikv) + 2._wp * znad ) &
702	& * ( fsde3w(ji ,jj+1,ikv) - fsde3w(ji,jj,ikv) ) / e2v(ji,jj)
703	va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
704	! put new value
705	! -zpshpj to avoid double contribution of the partial step in the top layer
706	zvap = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj) / e2v(ji,jj)
707	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)
708	va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
709	END IF
710	END DO
711	END DO
712
713	! set back to original density value into the ice shelf cell (maybe useless because it is masked)
714	rhd = zrhd
715	!
716	CALL wrk_dealloc( jpi,jpj,2, ztstop)
717	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
718	CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
719	!
720	END SUBROUTINE hpg_isf
721
722
723	SUBROUTINE hpg_djc( kt )
724	!!---------------------------------------------------------------------
725	!! * ROUTINE hpg_djc *
726	!!
727	!! ** Method : Density Jacobian with Cubic polynomial scheme
728	!!
729	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
730	!!----------------------------------------------------------------------
731	INTEGER, INTENT(in) :: kt ! ocean time-step index
732	!!
733	INTEGER :: ji, jj, jk ! dummy loop indices
734	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
735	REAL(wp) :: z1_10, cffu, cffx ! " "
736	REAL(wp) :: z1_12, cffv, cffy ! " "
737	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
738	REAL(wp), POINTER, DIMENSION(:,:,:) :: dzx, dzy, dzz, dzu, dzv, dzw
739	REAL(wp), POINTER, DIMENSION(:,:,:) :: drhox, drhoy, drhoz, drhou, drhov, drhow
740	REAL(wp), POINTER, DIMENSION(:,:,:) :: rho_i, rho_j, rho_k
741	!!----------------------------------------------------------------------
742	!
743	CALL wrk_alloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
744	CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
745	CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
746	!
747
748	IF( kt == nit000 ) THEN
749	IF(lwp) WRITE(numout,*)
750	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
751	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
752	ENDIF
753
754	! Local constant initialization
755	zcoef0 = - grav * 0.5_wp
756	z1_10 = 1._wp / 10._wp
757	z1_12 = 1._wp / 12._wp
758
759	!----------------------------------------------------------------------------------------
760	! compute and store in provisional arrays elementary vertical and horizontal differences
761	!----------------------------------------------------------------------------------------
762
763	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
764
765	DO jk = 2, jpkm1
766	DO jj = 2, jpjm1
767	DO ji = fs_2, fs_jpim1 ! vector opt.
768	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
769	dzz (ji,jj,jk) = fsde3w(ji ,jj ,jk) - fsde3w(ji,jj,jk-1)
770	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
771	dzx (ji,jj,jk) = fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk )
772	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
773	dzy (ji,jj,jk) = fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk )
774	END DO
775	END DO
776	END DO
777
778	!-------------------------------------------------------------------------
779	! compute harmonic averages using eq. 5.18
780	!-------------------------------------------------------------------------
781	zep = 1.e-15
782
783	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
784	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
785
786	DO jk = 2, jpkm1
787	DO jj = 2, jpjm1
788	DO ji = fs_2, fs_jpim1 ! vector opt.
789	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
790
791	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
792	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
793
794	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
795	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
796
797	IF( cffw > zep) THEN
798	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
799	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
800	ELSE
801	drhow(ji,jj,jk) = 0._wp
802	ENDIF
803
804	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
805	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
806
807	IF( cffu > zep ) THEN
808	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
809	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
810	ELSE
811	drhou(ji,jj,jk ) = 0._wp
812	ENDIF
813
814	IF( cffx > zep ) THEN
815	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
816	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
817	ELSE
818	dzu(ji,jj,jk) = 0._wp
819	ENDIF
820
821	IF( cffv > zep ) THEN
822	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
823	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
824	ELSE
825	drhov(ji,jj,jk) = 0._wp
826	ENDIF
827
828	IF( cffy > zep ) THEN
829	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
830	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
831	ELSE
832	dzv(ji,jj,jk) = 0._wp
833	ENDIF
834
835	END DO
836	END DO
837	END DO
838
839	!----------------------------------------------------------------------------------
840	! apply boundary conditions at top and bottom using 5.36-5.37
841	!----------------------------------------------------------------------------------
842	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
843	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
844	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
845
846	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
847	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
848	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
849
850
851	!--------------------------------------------------------------
852	! Upper half of top-most grid box, compute and store
853	!-------------------------------------------------------------
854
855	!!bug gm : e3w-de3w = 0.5*e3w .... and de3w(2)-de3w(1)=e3w(2) .... to be verified
856	! true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
857
858	DO jj = 2, jpjm1
859	DO ji = fs_2, fs_jpim1 ! vector opt.
860	rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) ) &
861	& * ( rhd(ji,jj,1) &
862	& + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) ) &
863	& * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) ) &
864	& / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) ) )
865	END DO
866	END DO
867
868	!!bug gm : here also, simplification is possible
869	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
870
871	DO jk = 2, jpkm1
872	DO jj = 2, jpjm1
873	DO ji = fs_2, fs_jpim1 ! vector opt.
874
875	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
876	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) ) &
877	& - grav * z1_10 * ( &
878	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
879	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
880	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
881	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
882	& )
883
884	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
885	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) ) &
886	& - grav* z1_10 * ( &
887	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
888	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
889	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
890	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
891	& )
892
893	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
894	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) ) &
895	& - grav* z1_10 * ( &
896	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
897	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
898	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
899	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
900	& )
901
902	END DO
903	END DO
904	END DO
905	CALL lbc_lnk(rho_k,'W',1.)
906	CALL lbc_lnk(rho_i,'U',1.)
907	CALL lbc_lnk(rho_j,'V',1.)
908
909
910	! ---------------
911	! Surface value
912	! ---------------
913	DO jj = 2, jpjm1
914	DO ji = fs_2, fs_jpim1 ! vector opt.
915	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
916	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
917	! add to the general momentum trend
918	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
919	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
920	END DO
921	END DO
922
923	! ----------------
924	! interior value (2=<jk=<jpkm1)
925	! ----------------
926	DO jk = 2, jpkm1
927	DO jj = 2, jpjm1
928	DO ji = fs_2, fs_jpim1 ! vector opt.
929	! hydrostatic pressure gradient along s-surfaces
930	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
931	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
932	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) / e1u(ji,jj)
933	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
934	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
935	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) / e2v(ji,jj)
936	! add to the general momentum trend
937	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
938	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
939	END DO
940	END DO
941	END DO
942	!
943	CALL wrk_dealloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
944	CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
945	CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
946	!
947	END SUBROUTINE hpg_djc
948
949
950	SUBROUTINE hpg_prj( kt )
951	!!---------------------------------------------------------------------
952	!! * ROUTINE hpg_prj *
953	!!
954	!! ** Method : s-coordinate case.
955	!! A Pressure-Jacobian horizontal pressure gradient method
956	!! based on the constrained cubic-spline interpolation for
957	!! all vertical coordinate systems
958	!!
959	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
960	!!----------------------------------------------------------------------
961	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
962	INTEGER, INTENT(in) :: kt ! ocean time-step index
963	!!
964	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
965	REAL(wp) :: zcoef0, znad ! temporary scalars
966	!!
967	!! The local variables for the correction term
968	INTEGER :: jk1, jis, jid, jjs, jjd
969	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
970	REAL(wp) :: zrhdt1
971	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
972	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdept, zrhh
973	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
974	REAL(wp), POINTER, DIMENSION(:,:) :: zsshu_n, zsshv_n
975	!!----------------------------------------------------------------------
976	!
977	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
978	CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
979	CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
980	!
981	IF( kt == nit000 ) THEN
982	IF(lwp) WRITE(numout,*)
983	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
984	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
985	ENDIF
986
987	!!----------------------------------------------------------------------
988	! Local constant initialization
989	zcoef0 = - grav
990	znad = 0.0_wp
991	IF( lk_vvl ) znad = 1._wp
992
993	! Clean 3-D work arrays
994	zhpi(:,:,:) = 0._wp
995	zrhh(:,:,:) = rhd(:,:,:)
996
997	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
998	DO jj = 1, jpj
999	DO ji = 1, jpi
1000	jk = mbathy(ji,jj)
1001	IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1002	ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1003	ELSE IF(jk < jpkm1) THEN
1004	DO jkk = jk+1, jpk
1005	zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk), fsde3w(ji,jj,jkk-1), &
1006	fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1007	END DO
1008	ENDIF
1009	END DO
1010	END DO
1011
1012	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1013	DO jj = 1, jpj
1014	DO ji = 1, jpi
1015	zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1016	END DO
1017	END DO
1018
1019	DO jk = 2, jpk
1020	DO jj = 1, jpj
1021	DO ji = 1, jpi
1022	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1023	END DO
1024	END DO
1025	END DO
1026
1027	fsp(:,:,:) = zrhh (:,:,:)
1028	xsp(:,:,:) = zdept(:,:,:)
1029
1030	! Construct the vertical density profile with the
1031	! constrained cubic spline interpolation
1032	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1033	CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1034
1035	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1036	DO jj = 2, jpj
1037	DO ji = 2, jpi
1038	zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1039	bsp(ji,jj,1), csp(ji,jj,1), &
1040	dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1041
1042	! assuming linear profile across the top half surface layer
1043	zhpi(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) * zrhdt1
1044	END DO
1045	END DO
1046
1047	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1048	DO jk = 2, jpkm1
1049	DO jj = 2, jpj
1050	DO ji = 2, jpi
1051	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1052	integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1053	asp(ji,jj,jk-1), bsp(ji,jj,jk-1), &
1054	csp(ji,jj,jk-1), dsp(ji,jj,jk-1))
1055	END DO
1056	END DO
1057	END DO
1058
1059	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1060
1061	! Prepare zsshu_n and zsshv_n
1062	DO jj = 2, jpjm1
1063	DO ji = 2, jpim1
1064	zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1065	& r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1066	zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1067	& r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1068	END DO
1069	END DO
1070
1071	DO jj = 2, jpjm1
1072	DO ji = 2, jpim1
1073	zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad)
1074	zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1075	END DO
1076	END DO
1077
1078	DO jk = 2, jpkm1
1079	DO jj = 2, jpjm1
1080	DO ji = 2, jpim1
1081	zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1082	zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1083	END DO
1084	END DO
1085	END DO
1086
1087	DO jk = 1, jpkm1
1088	DO jj = 2, jpjm1
1089	DO ji = 2, jpim1
1090	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1091	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1092	END DO
1093	END DO
1094	END DO
1095
1096	DO jk = 1, jpkm1
1097	DO jj = 2, jpjm1
1098	DO ji = 2, jpim1
1099	zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1100	zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1101	zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1102	zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1103	END DO
1104	END DO
1105	END DO
1106
1107
1108	DO jk = 1, jpkm1
1109	DO jj = 2, jpjm1
1110	DO ji = 2, jpim1
1111	zpwes = 0._wp; zpwed = 0._wp
1112	zpnss = 0._wp; zpnsd = 0._wp
1113	zuijk = zu(ji,jj,jk)
1114	zvijk = zv(ji,jj,jk)
1115
1116	!!!!! for u equation
1117	IF( jk <= mbku(ji,jj) ) THEN
1118	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1119	jis = ji + 1; jid = ji
1120	ELSE
1121	jis = ji; jid = ji +1
1122	ENDIF
1123
1124	! integrate the pressure on the shallow side
1125	jk1 = jk
1126	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1127	IF( jk1 == mbku(ji,jj) ) THEN
1128	zuijk = -zdept(jis,jj,jk1)
1129	EXIT
1130	ENDIF
1131	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1132	zpwes = zpwes + &
1133	integ_spline(zdept(jis,jj,jk1), zdeps, &
1134	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1135	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1136	jk1 = jk1 + 1
1137	END DO
1138
1139	! integrate the pressure on the deep side
1140	jk1 = jk
1141	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1142	IF( jk1 == 1 ) THEN
1143	zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1144	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1145	bsp(jid,jj,1), csp(jid,jj,1), &
1146	dsp(jid,jj,1)) * zdeps
1147	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1148	EXIT
1149	ENDIF
1150	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1151	zpwed = zpwed + &
1152	integ_spline(zdeps, zdept(jid,jj,jk1), &
1153	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1154	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1155	jk1 = jk1 - 1
1156	END DO
1157
1158	! update the momentum trends in u direction
1159
1160	zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1161	IF( lk_vvl ) THEN
1162	zdpdx2 = zcoef0 / e1u(ji,jj) * &
1163	( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1164	ELSE
1165	zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1166	ENDIF
1167
1168	ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1169	& umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1170	ENDIF
1171
1172	!!!!! for v equation
1173	IF( jk <= mbkv(ji,jj) ) THEN
1174	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1175	jjs = jj + 1; jjd = jj
1176	ELSE
1177	jjs = jj ; jjd = jj + 1
1178	ENDIF
1179
1180	! integrate the pressure on the shallow side
1181	jk1 = jk
1182	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1183	IF( jk1 == mbkv(ji,jj) ) THEN
1184	zvijk = -zdept(ji,jjs,jk1)
1185	EXIT
1186	ENDIF
1187	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1188	zpnss = zpnss + &
1189	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1190	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1191	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1192	jk1 = jk1 + 1
1193	END DO
1194
1195	! integrate the pressure on the deep side
1196	jk1 = jk
1197	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1198	IF( jk1 == 1 ) THEN
1199	zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1200	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1201	bsp(ji,jjd,1), csp(ji,jjd,1), &
1202	dsp(ji,jjd,1) ) * zdeps
1203	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1204	EXIT
1205	ENDIF
1206	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1207	zpnsd = zpnsd + &
1208	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1209	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1210	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1211	jk1 = jk1 - 1
1212	END DO
1213
1214
1215	! update the momentum trends in v direction
1216
1217	zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1218	IF( lk_vvl ) THEN
1219	zdpdy2 = zcoef0 / e2v(ji,jj) * &
1220	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1221	ELSE
1222	zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1223	ENDIF
1224
1225	va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1226	& vmask(ji,jj,jk)tmask(ji,jj,jk)tmask(ji,jj+1,jk)
1227	ENDIF
1228
1229
1230	END DO
1231	END DO
1232	END DO
1233	!
1234	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1235	CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1236	CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1237	!
1238	END SUBROUTINE hpg_prj
1239
1240
1241	SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1242	!!----------------------------------------------------------------------
1243	!! * ROUTINE cspline *
1244	!!
1245	!! ** Purpose : constrained cubic spline interpolation
1246	!!
1247	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1248	!!
1249	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1250	!!----------------------------------------------------------------------
1251	IMPLICIT NONE
1252	REAL(wp), DIMENSION(:,:,:), INTENT(in) :: fsp, xsp ! value and coordinate
1253	REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1254	! the interpoated function
1255	INTEGER, INTENT(in) :: polynomial_type ! 1: cubic spline
1256	! 2: Linear
1257	!
1258	INTEGER :: ji, jj, jk ! dummy loop indices
1259	INTEGER :: jpi, jpj, jpkm1
1260	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1261	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1262	REAL(wp) :: zdf(size(fsp,3))
1263	!!----------------------------------------------------------------------
1264
1265	jpi = size(fsp,1)
1266	jpj = size(fsp,2)
1267	jpkm1 = size(fsp,3) - 1
1268
1269
1270	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1271	DO ji = 1, jpi
1272	DO jj = 1, jpj
1273	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1274	! DO jk = 2, jpkm1-1
1275	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1276	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1277	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1278	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1279	!
1280	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1281	!
1282	! IF(zdf1 * zdf2 <= 0._wp) THEN
1283	! zdf(jk) = 0._wp
1284	! ELSE
1285	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1286	! ENDIF
1287	! END DO
1288
1289	!!Simply geometric average
1290	DO jk = 2, jpkm1-1
1291	zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1292	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1293
1294	IF(zdf1 * zdf2 <= 0._wp) THEN
1295	zdf(jk) = 0._wp
1296	ELSE
1297	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1298	ENDIF
1299	END DO
1300
1301	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1302	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1303	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1304	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1305	& 0.5_wp * zdf(jpkm1 - 1)
1306
1307	DO jk = 1, jpkm1 - 1
1308	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1309	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1310	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1311	zddf1 = -2._wp * ztmp1 + ztmp2
1312	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1313	zddf2 = 2._wp * ztmp1 - ztmp2
1314
1315	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1316	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1317	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1318	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1319	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1320	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1321	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1322	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1323	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1324	END DO
1325	END DO
1326	END DO
1327
1328	ELSE IF (polynomial_type == 2) THEN ! Linear
1329	DO ji = 1, jpi
1330	DO jj = 1, jpj
1331	DO jk = 1, jpkm1-1
1332	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1333	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1334
1335	dsp(ji,jj,jk) = 0._wp
1336	csp(ji,jj,jk) = 0._wp
1337	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1338	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1339	END DO
1340	END DO
1341	END DO
1342
1343	ELSE
1344	CALL ctl_stop( 'invalid polynomial type in cspline' )
1345	ENDIF
1346
1347	END SUBROUTINE cspline
1348
1349
1350	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1351	!!----------------------------------------------------------------------
1352	!! * ROUTINE interp1 *
1353	!!
1354	!! ** Purpose : 1-d linear interpolation
1355	!!
1356	!! ** Method : interpolation is straight forward
1357	!! extrapolation is also permitted (no value limit)
1358	!!----------------------------------------------------------------------
1359	IMPLICIT NONE
1360	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1361	REAL(wp) :: f ! result of the interpolation (extrapolation)
1362	REAL(wp) :: zdeltx
1363	!!----------------------------------------------------------------------
1364
1365	zdeltx = xr - xl
1366	IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1367	f = 0.5_wp * (fl + fr)
1368	ELSE
1369	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1370	ENDIF
1371
1372	END FUNCTION interp1
1373
1374
1375	FUNCTION interp2(x, a, b, c, d) RESULT(f)
1376	!!----------------------------------------------------------------------
1377	!! * ROUTINE interp1 *
1378	!!
1379	!! ** Purpose : 1-d constrained cubic spline interpolation
1380	!!
1381	!! ** Method : cubic spline interpolation
1382	!!
1383	!!----------------------------------------------------------------------
1384	IMPLICIT NONE
1385	REAL(wp), INTENT(in) :: x, a, b, c, d
1386	REAL(wp) :: f ! value from the interpolation
1387	!!----------------------------------------------------------------------
1388
1389	f = a + x* ( b + x * ( c + d * x ) )
1390
1391	END FUNCTION interp2
1392
1393
1394	FUNCTION interp3(x, a, b, c, d) RESULT(f)
1395	!!----------------------------------------------------------------------
1396	!! * ROUTINE interp1 *
1397	!!
1398	!! ** Purpose : Calculate the first order of deriavtive of
1399	!! a cubic spline function y=a+bx+cx^2+d*x^3
1400	!!
1401	!! ** Method : f=dy/dx=b+2cx+3dx^2
1402	!!
1403	!!----------------------------------------------------------------------
1404	IMPLICIT NONE
1405	REAL(wp), INTENT(in) :: x, a, b, c, d
1406	REAL(wp) :: f ! value from the interpolation
1407	!!----------------------------------------------------------------------
1408
1409	f = b + x * ( 2._wp * c + 3._wp * d * x)
1410
1411	END FUNCTION interp3
1412
1413
1414	FUNCTION integ_spline(xl, xr, a, b, c, d) RESULT(f)
1415	!!----------------------------------------------------------------------
1416	!! * ROUTINE interp1 *
1417	!!
1418	!! ** Purpose : 1-d constrained cubic spline integration
1419	!!
1420	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1421	!!
1422	!!----------------------------------------------------------------------
1423	IMPLICIT NONE
1424	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1425	REAL(wp) :: za1, za2, za3
1426	REAL(wp) :: f ! integration result
1427	!!----------------------------------------------------------------------
1428
1429	za1 = 0.5_wp * b
1430	za2 = c / 3.0_wp
1431	za3 = 0.25_wp * d
1432
1433	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1434	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1435
1436	END FUNCTION integ_spline
1437
1438	!!======================================================================
1439	END MODULE dynhpg
1440

Note: See TracBrowser for help on using the repository browser.

Download in other formats: