New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynkeg.F90 in branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN/dynkeg.F90 @ 8168

Last change on this file since 8168 was 8168, checked in by glong, 7 years ago

changes as of eod 13/16/17

File size: 8.0 KB
Line 
1MODULE dynkeg
2   !!======================================================================
3   !!                       ***  MODULE  dynkeg  ***
4   !! Ocean dynamics:  kinetic energy gradient trend
5   !!======================================================================
6   !! History :  1.0  !  1987-09  (P. Andrich, M.-A. Foujols)  Original code
7   !!            7.0  !  1997-05  (G. Madec)  Split dynber into dynkeg and dynhpg
8   !!  NEMO      1.0  !  2002-07  (G. Madec)  F90: Free form and module
9   !!            3.6  !  2015-05  (N. Ducousso, G. Madec)  add Hollingsworth scheme as an option
10   !!----------------------------------------------------------------------
11   
12   !!----------------------------------------------------------------------
13   !!   dyn_keg      : update the momentum trend with the horizontal tke
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE trd_oce         ! trends: ocean variables
18   USE trddyn          ! trend manager: dynamics
19   USE divcur          ! for dyn_vrt_dia_3d
20   !
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE prtctl          ! Print control
25   USE wrk_nemo        ! Memory Allocation
26   USE timing          ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   dyn_keg    ! routine called by step module
32   
33   INTEGER, PARAMETER, PUBLIC  ::   nkeg_C2  = 0   !: 2nd order centered scheme (standard scheme)
34   INTEGER, PARAMETER, PUBLIC  ::   nkeg_HW  = 1   !: Hollingsworth et al., QJRMS, 1983
35   !
36   REAL(wp) ::   r1_48 = 1._wp / 48._wp   !: =1/(4*2*6)
37   
38   !! * Substitutions
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.6 , NEMO Consortium (2015)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE dyn_keg( kt, kscheme )
48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE dyn_keg  ***
50      !!
51      !! ** Purpose :   Compute the now momentum trend due to the horizontal
52      !!      gradient of the horizontal kinetic energy and add it to the
53      !!      general momentum trend.
54      !!
55      !! ** Method  : * kscheme = nkeg_C2 : 2nd order centered scheme that
56      !!      conserve kinetic energy. Compute the now horizontal kinetic energy
57      !!         zhke = 1/2 [ mi-1( un^2 ) + mj-1( vn^2 ) ]
58      !!              * kscheme = nkeg_HW : Hollingsworth correction following
59      !!      Arakawa (2001). The now horizontal kinetic energy is given by:
60      !!         zhke = 1/6 [ mi-1(  2 * un^2 + ((un(j+1)+un(j-1))/2)^2  )
61      !!                    + mj-1(  2 * vn^2 + ((vn(i+1)+vn(i-1))/2)^2  ) ]
62      !!     
63      !!      Take its horizontal gradient and add it to the general momentum
64      !!      trend (ua,va).
65      !!         ua = ua - 1/e1u di[ zhke ]
66      !!         va = va - 1/e2v dj[ zhke ]
67      !!
68      !! ** Action : - Update the (ua, va) with the hor. ke gradient trend
69      !!             - send this trends to trd_dyn (l_trddyn=T) for post-processing
70      !!
71      !! ** References : Arakawa, A., International Geophysics 2001.
72      !!                 Hollingsworth et al., Quart. J. Roy. Meteor. Soc., 1983.
73      !!----------------------------------------------------------------------
74      INTEGER, INTENT( in ) ::   kt         ! ocean time-step index
75      INTEGER, INTENT( in ) ::   kscheme    ! =0/1   type of KEG scheme
76      !
77      INTEGER  ::  id_dia_vrt_keg_int  = 21 ! TODO remove once flags set properly
78      INTEGER  ::  id_dia_vrt_keg_mean = 22 ! TODO remove once flags set properly
79      INTEGER  ::  ji, jj, jk               ! dummy loop indices
80      REAL(wp) ::  zu, zv                   ! temporary scalars
81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zhke, zhkei, zhkej
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv 
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )   CALL timing_start('dyn_keg')
86      !
87      CALL wrk_alloc( jpi,jpj,jpk,   zhke, zhkei, zhkej )
88      !
89      IF( kt == nit000 ) THEN
90         IF(lwp) WRITE(numout,*)
91         IF(lwp) WRITE(numout,*) 'dyn_keg : kinetic energy gradient trend, scheme number=', kscheme
92         IF(lwp) WRITE(numout,*) '~~~~~~~'
93      ENDIF
94
95      IF( l_trddyn ) THEN           ! Save ua and va trends
96         CALL wrk_alloc( jpi,jpj,jpk,   ztrdu, ztrdv )
97         ztrdu(:,:,:) = ua(:,:,:) 
98         ztrdv(:,:,:) = va(:,:,:) 
99      ENDIF
100     
101      zhke(:,:,jpk) = 0._wp
102     
103      SELECT CASE ( kscheme )             !== Horizontal kinetic energy at T-point  ==!
104      !
105      CASE ( nkeg_C2 )                          !--  Standard scheme  --!
106         DO jk = 1, jpkm1
107            DO jj = 2, jpj
108               DO ji = fs_2, jpi   ! vector opt.
109                  zu =    un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)   &
110                     &  + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk)
111                  zv =    vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)   &
112                     &  + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk)
113                  zhke(ji,jj,jk) = 0.25_wp * ( zv + zu )
114               END DO 
115            END DO
116         END DO
117         !
118      CASE ( nkeg_HW )                          !--  Hollingsworth scheme  --!
119         DO jk = 1, jpkm1
120            DO jj = 2, jpjm1       
121               DO ji = fs_2, jpim1   ! vector opt.
122                  zu = 8._wp * ( un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)    &
123                     &         + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk) )  &
124                     &   +     ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) ) * ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) )   &
125                     &   +     ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) ) * ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) )
126                     !
127                  zv = 8._wp * ( vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)    &
128                     &         + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk) )  &
129                     &  +      ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) ) * ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) )   &
130                     &  +      ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) ) * ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) )
131                  zhke(ji,jj,jk) = r1_48 * ( zv + zu )
132               END DO 
133            END DO
134         END DO
135         CALL lbc_lnk( zhke, 'T', 1. )
136         !
137      END SELECT
138      !
139      DO jk = 1, jpkm1                    !==  grad( KE ) added to the general momentum trends  ==!
140         DO jj = 2, jpjm1
141            DO ji = fs_2, fs_jpim1   ! vector opt.
142               zhkei(ji,jj,jk) = - ( zhke(ji+1,jj  ,jk) - zhke(ji,jj,jk) ) / e1u(ji,jj)
143               zhkej(ji,jj,jk) = - ( zhke(ji  ,jj+1,jk) - zhke(ji,jj,jk) ) / e2v(ji,jj)
144               ua(ji,jj,jk) = ua(ji,jj,jk) + zhkei(ji,jj,jk)
145               va(ji,jj,jk) = va(ji,jj,jk) + zhkej(ji,jj,jk)
146            END DO
147         END DO
148      END DO
149      !
150      IF ( ( id_dia_vrt_keg_int == 21 ) .or. ( id_dia_vrt_keg_mean == 22 ) ) THEN
151          ! TODO - remove kt only used for validation
152          CALL dyn_vrt_dia_3d(zhkei, zhkej, id_dia_vrt_keg_int, id_dia_vrt_keg_mean, kt)
153      END IF
154      !
155      IF( l_trddyn ) THEN                 ! save the Kinetic Energy trends for diagnostic
156         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
157         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
158         CALL trd_dyn( ztrdu, ztrdv, jpdyn_keg, kt )
159         CALL wrk_dealloc( jpi,jpj,jpk,   ztrdu, ztrdv )
160      ENDIF
161      !
162      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' keg  - Ua: ', mask1=umask,   &
163         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
164      !
165      CALL wrk_dealloc( jpi,jpj,jpk,   zhke, zhkei, zhkej )
166      !
167      IF( nn_timing == 1 )   CALL timing_stop('dyn_keg')
168      !
169   END SUBROUTINE dyn_keg
170
171   !!======================================================================
172END MODULE dynkeg
Note: See TracBrowser for help on using the repository browser.