New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynldf_bilap.F90 in branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/GO6_dyn_vrt_diag/NEMOGCM/NEMO/OPA_SRC/DYN/dynldf_bilap.F90 @ 7845

Last change on this file since 7845 was 7845, checked in by glong, 7 years ago

Split dyn_vrt_diag in divcur.F90 into two parts - and changed calls in dynhpg.F90, dynkeg.F90, dynldf_bilap.F90, dynvor.F90, dynzad.F90. Added calls to dyn_vrt_diag in dynspg_ts.F90. Also added call in dynzdf.F90 but this is more of a place holder as it is not currently correct.
File size: 9.9 KB
Line 
1MODULE dynldf_bilap
2   !!======================================================================
3   !!                     ***  MODULE  dynldf_bilap  ***
4   !! Ocean dynamics:  lateral viscosity trend
5   !!======================================================================
6   !! History :  OPA  ! 1990-09  (G. Madec)  Original code
7   !!            4.0  ! 1993-03  (M. Guyon)  symetrical conditions (M. Guyon)
8   !!            6.0  ! 1996-01  (G. Madec)  statement function for e3
9   !!            8.0  ! 1997-07  (G. Madec)  lbc calls
10   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and module
11   !!            2.0  ! 2004-08  (C. Talandier) New trends organization
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dyn_ldf_bilap : update the momentum trend with the lateral diffusion
16   !!                   using an iso-level bilaplacian operator
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE ldfdyn_oce      ! ocean dynamics: lateral physics
21   USE divcur          ! for dyn_vrt_dia_3d
22   !
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE wrk_nemo        ! Memory Allocation
26   USE timing          ! Timing
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   dyn_ldf_bilap   ! called by step.F90
32
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35#  include "ldfdyn_substitute.h90"
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE dyn_ldf_bilap( kt )
45      !!----------------------------------------------------------------------
46      !!                     ***  ROUTINE dyn_ldf_bilap  ***
47      !!
48      !! ** Purpose :   Compute the before trend of the lateral momentum
49      !!      diffusion and add it to the general trend of momentum equation.
50      !!
51      !! ** Method  :   The before horizontal momentum diffusion trend is a
52      !!      bi-harmonic operator (bilaplacian type) which separates the
53      !!      divergent and rotational parts of the flow.
54      !!      Its horizontal components are computed as follow:
55      !!      laplacian:
56      !!          zlu = 1/e1u di[ hdivb ] - 1/(e2u*e3u) dj-1[ e3f rotb ]
57      !!          zlv = 1/e2v dj[ hdivb ] + 1/(e1v*e3v) di-1[ e3f rotb ]
58      !!      third derivative:
59      !!       * multiply by the eddy viscosity coef. at u-, v-point, resp.
60      !!          zlu = ahmu * zlu
61      !!          zlv = ahmv * zlv
62      !!       * curl and divergence of the laplacian
63      !!          zuf = 1/(e1f*e2f) ( di[e2v zlv] - dj[e1u zlu] )
64      !!          zut = 1/(e1t*e2t*e3t) ( di[e2u*e3u zlu] + dj[e1v*e3v zlv] )
65      !!      bilaplacian:
66      !!              diffu = 1/e1u di[ zut ] - 1/(e2u*e3u) dj-1[ e3f zuf ]
67      !!              diffv = 1/e2v dj[ zut ] + 1/(e1v*e3v) di-1[ e3f zuf ]
68      !!      If ln_sco=F and ln_zps=F, the vertical scale factors in the
69      !!      rotational part of the diffusion are simplified
70      !!      Add this before trend to the general trend (ua,va):
71      !!            (ua,va) = (ua,va) + (diffu,diffv)
72      !!
73      !! ** Action : - Update (ua,va) with the before iso-level biharmonic
74      !!               mixing trend.
75      !!----------------------------------------------------------------------
76      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
77      !
78      INTEGER  :: id_dia_vrt_ldf_int  = 1      ! TODO remove once flags set properly
79      INTEGER  :: id_dia_vrt_ldf_mean = 1      ! TODO remove once flags set properly
80      INTEGER  ::   ji, jj, jk                  ! dummy loop indices
81      REAL(wp) ::   zbt, ze2u, ze2v             ! temporary scalar
82      REAL(wp), POINTER, DIMENSION(:,:  ) :: zcu, zcv
83      REAL(wp), POINTER, DIMENSION(:,:,:) :: zuf, zut, zlu, zlv, zua, zva
84      !!----------------------------------------------------------------------
85      !
86      IF( nn_timing == 1 )  CALL timing_start('dyn_ldf_bilap')
87      !
88      CALL wrk_alloc( jpi, jpj,      zcu, zcv           )
89      CALL wrk_alloc( jpi, jpj, jpk, zuf, zut, zlu, zlv, zua, zva ) 
90      !
91      IF( kt == nit000 .AND. lwp ) THEN
92         WRITE(numout,*)
93         WRITE(numout,*) 'dyn_ldf_bilap : iso-level bilaplacian operator'
94         WRITE(numout,*) '~~~~~~~~~~~~~'
95      ENDIF
96
97!!bug gm this should be enough
98!!$      zuf(:,:,jpk) = 0.e0
99!!$      zut(:,:,jpk) = 0.e0
100!!$      zlu(:,:,jpk) = 0.e0
101!!$      zlv(:,:,jpk) = 0.e0
102      zuf(:,:,:) = 0._wp
103      zut(:,:,:) = 0._wp
104      zlu(:,:,:) = 0._wp
105      zlv(:,:,:) = 0._wp
106
107      !                                                ! ===============
108      DO jk = 1, jpkm1                                 ! Horizontal slab
109         !                                             ! ===============
110         ! Laplacian
111         ! ---------
112
113         IF( ln_sco .OR. ln_zps ) THEN   ! s-coordinate or z-coordinate with partial steps
114            zuf(:,:,jk) = rotb(:,:,jk) * fse3f(:,:,jk)
115            DO jj = 2, jpjm1
116               DO ji = fs_2, fs_jpim1   ! vector opt.
117                  zlu(ji,jj,jk) = - ( zuf(ji,jj,jk) - zuf(ji,jj-1,jk) ) / ( e2u(ji,jj) * fse3u(ji,jj,jk) )   &
118                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj,jk) ) / e1u(ji,jj)
119   
120                  zlv(ji,jj,jk) = + ( zuf(ji,jj,jk) - zuf(ji-1,jj,jk) ) / ( e1v(ji,jj) * fse3v(ji,jj,jk) )   &
121                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji,jj,jk) ) / e2v(ji,jj)
122               END DO
123            END DO
124         ELSE                            ! z-coordinate - full step
125            DO jj = 2, jpjm1
126               DO ji = fs_2, fs_jpim1   ! vector opt.
127                  zlu(ji,jj,jk) = - ( rotb (ji  ,jj,jk) - rotb (ji,jj-1,jk) ) / e2u(ji,jj)   &
128                     &         + ( hdivb(ji+1,jj,jk) - hdivb(ji,jj  ,jk) ) / e1u(ji,jj)
129   
130                  zlv(ji,jj,jk) = + ( rotb (ji,jj  ,jk) - rotb (ji-1,jj,jk) ) / e1v(ji,jj)   &
131                     &         + ( hdivb(ji,jj+1,jk) - hdivb(ji  ,jj,jk) ) / e2v(ji,jj)
132               END DO 
133            END DO 
134         ENDIF
135      END DO
136      CALL lbc_lnk( zlu, 'U', -1. )   ;   CALL lbc_lnk( zlv, 'V', -1. )   ! Boundary conditions
137
138         
139      DO jk = 1, jpkm1
140   
141         ! Third derivative
142         ! ----------------
143         
144         ! Multiply by the eddy viscosity coef. (at u- and v-points)
145         zlu(:,:,jk) = zlu(:,:,jk) * ( fsahmu(:,:,jk) * (1-nkahm_smag) + nkahm_smag)
146
147         zlv(:,:,jk) = zlv(:,:,jk) * ( fsahmv(:,:,jk) * (1-nkahm_smag) + nkahm_smag)
148         
149         ! Contravariant "laplacian"
150         zcu(:,:) = e1u(:,:) * zlu(:,:,jk)
151         zcv(:,:) = e2v(:,:) * zlv(:,:,jk)
152         
153         ! Laplacian curl ( * e3f if s-coordinates or z-coordinate with partial steps)
154         DO jj = 1, jpjm1
155            DO ji = 1, fs_jpim1   ! vector opt.
156               zuf(ji,jj,jk) = fmask(ji,jj,jk) * (  zcv(ji+1,jj  ) - zcv(ji,jj)      &
157                  &                            - zcu(ji  ,jj+1) + zcu(ji,jj)  )   &
158                  &       * fse3f(ji,jj,jk) / ( e1f(ji,jj)*e2f(ji,jj) )
159            END DO 
160         END DO 
161
162         ! Laplacian Horizontal fluxes
163         DO jj = 1, jpjm1
164            DO ji = 1, fs_jpim1   ! vector opt.
165               zlu(ji,jj,jk) = e2u(ji,jj) * fse3u(ji,jj,jk) * zlu(ji,jj,jk)
166               zlv(ji,jj,jk) = e1v(ji,jj) * fse3v(ji,jj,jk) * zlv(ji,jj,jk)
167            END DO
168         END DO
169
170         ! Laplacian divergence
171         DO jj = 2, jpj
172            DO ji = fs_2, jpi   ! vector opt.
173               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk)
174               zut(ji,jj,jk) = (  zlu(ji,jj,jk) - zlu(ji-1,jj  ,jk)   &
175                  &             + zlv(ji,jj,jk) - zlv(ji  ,jj-1,jk) ) / zbt
176            END DO
177         END DO
178      END DO
179
180
181      ! boundary conditions on the laplacian curl and div (zuf,zut)
182!!bug gm no need to do this 2 following lbc...
183      CALL lbc_lnk( zuf, 'F', 1. )
184      CALL lbc_lnk( zut, 'T', 1. )
185
186      DO jk = 1, jpkm1     
187   
188         ! Bilaplacian
189         ! -----------
190
191         DO jj = 2, jpjm1
192            DO ji = fs_2, fs_jpim1   ! vector opt.
193               ze2u = e2u(ji,jj) * fse3u(ji,jj,jk)
194               ze2v = e1v(ji,jj) * fse3v(ji,jj,jk)
195               ! horizontal biharmonic diffusive trends
196               zua(ji,jj,jk) = - ( zuf(ji  ,jj,jk) - zuf(ji,jj-1,jk) ) / ze2u   &
197                  &  + ( zut(ji+1,jj,jk) - zut(ji,jj  ,jk) ) / e1u(ji,jj)       &
198                  &  * ( fsahmu(ji,jj,jk)*nkahm_smag +(1 -nkahm_smag ))
199               zva(ji,jj,jk) = + ( zuf(ji,jj  ,jk) - zuf(ji-1,jj,jk) ) / ze2v   &
200                  &  + ( zut(ji,jj+1,jk) - zut(ji  ,jj,jk) ) / e2v(ji,jj)       &
201                  &  * ( fsahmv(ji,jj,jk)*nkahm_smag +(1 -nkahm_smag ))
202               ! add it to the general momentum trends
203               ua(ji,jj,jk) = ua(ji,jj,jk) + zua(ji,jj,jk)
204               va(ji,jj,jk) = va(ji,jj,jk) + zva(ji,jj,jk)
205            END DO
206         END DO
207
208         !                                             ! ===============
209      END DO                                           !   End of slab
210      !                                                ! ===============
211      IF ( ( id_dia_vrt_ldf_int == 1 ) .or. ( id_dia_vrt_ldf_mean == 1 ) ) THEN
212          CALL dyn_vrt_dia_3d(zua, zva, id_dia_vrt_ldf_int, id_dia_vrt_ldf_mean)
213      END IF
214      !
215      CALL wrk_dealloc( jpi, jpj,      zcu, zcv           )
216      CALL wrk_dealloc( jpi, jpj, jpk, zuf, zut, zlu, zlv, zua, zva ) 
217      !
218      IF( nn_timing == 1 )  CALL timing_stop('dyn_ldf_bilap')
219      !
220   END SUBROUTINE dyn_ldf_bilap
221
222   !!======================================================================
223END MODULE dynldf_bilap
Note: See TracBrowser for help on using the repository browser.