| 1 | MODULE zdftmx |
|---|
| 2 | !!======================================================================== |
|---|
| 3 | !! *** MODULE zdftmx *** |
|---|
| 4 | !! Ocean physics: vertical tidal mixing coefficient |
|---|
| 5 | !!======================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
|---|
| 7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
|---|
| 8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | #if defined key_zdftmx |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! 'key_zdftmx' Tidal vertical mixing |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! zdf_tmx : global momentum & tracer Kz with tidal induced Kz |
|---|
| 15 | !! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers variables |
|---|
| 18 | USE dom_oce ! ocean space and time domain variables |
|---|
| 19 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 21 | USE eosbn2 ! ocean equation of state |
|---|
| 22 | USE phycst ! physical constants |
|---|
| 23 | USE prtctl ! Print control |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE iom ! I/O Manager |
|---|
| 26 | USE lib_mpp ! MPP library |
|---|
| 27 | USE wrk_nemo ! work arrays |
|---|
| 28 | USE timing ! Timing |
|---|
| 29 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC zdf_tmx ! called in step module |
|---|
| 35 | PUBLIC zdf_tmx_init ! called in opa module |
|---|
| 36 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
|---|
| 37 | |
|---|
| 38 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag |
|---|
| 39 | |
|---|
| 40 | ! !!* Namelist namzdf_tmx : tidal mixing * |
|---|
| 41 | REAL(wp) :: rn_htmx ! vertical decay scale for turbulence (meters) |
|---|
| 42 | REAL(wp) :: rn_n2min ! threshold of the Brunt-Vaisala frequency (s-1) |
|---|
| 43 | REAL(wp) :: rn_tfe ! tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 44 | REAL(wp) :: rn_me ! mixing efficiency (Osborn 1980) |
|---|
| 45 | LOGICAL :: ln_tmx_itf ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization |
|---|
| 46 | REAL(wp) :: rn_tfe_itf ! ITF tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 47 | |
|---|
| 48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2) |
|---|
| 49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area |
|---|
| 50 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz |
|---|
| 51 | |
|---|
| 52 | !! * Substitutions |
|---|
| 53 | # include "vectopt_loop_substitute.h90" |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
|---|
| 56 | !! $Id$ |
|---|
| 57 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | CONTAINS |
|---|
| 60 | |
|---|
| 61 | INTEGER FUNCTION zdf_tmx_alloc() |
|---|
| 62 | !!---------------------------------------------------------------------- |
|---|
| 63 | !! *** FUNCTION zdf_tmx_alloc *** |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
|---|
| 66 | ! |
|---|
| 67 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
|---|
| 68 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
|---|
| 69 | END FUNCTION zdf_tmx_alloc |
|---|
| 70 | |
|---|
| 71 | |
|---|
| 72 | SUBROUTINE zdf_tmx( kt ) |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | !! *** ROUTINE zdf_tmx *** |
|---|
| 75 | !! |
|---|
| 76 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 77 | !! tidal mixing (Simmons et al 2004). |
|---|
| 78 | !! |
|---|
| 79 | !! ** Method : - tidal-induced vertical mixing is given by: |
|---|
| 80 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 81 | !! where az_tmx is a coefficient that specified the 3D space |
|---|
| 82 | !! distribution of the faction of tidal energy taht is used |
|---|
| 83 | !! for mixing. Its expression is set in zdf_tmx_init routine, |
|---|
| 84 | !! following Simmons et al. 2004. |
|---|
| 85 | !! NB: a specific bounding procedure is performed on av_tide |
|---|
| 86 | !! so that the input tidal energy is actually almost used. The |
|---|
| 87 | !! basic maximum value is 60 cm2/s, but values of 300 cm2/s |
|---|
| 88 | !! can be reached in area where bottom stratification is too |
|---|
| 89 | !! weak. |
|---|
| 90 | !! |
|---|
| 91 | !! - update av_tide in the Indonesian Through Flow area |
|---|
| 92 | !! following Koch-Larrouy et al. (2007) parameterisation |
|---|
| 93 | !! (see tmx_itf routine). |
|---|
| 94 | !! |
|---|
| 95 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 96 | !! avt = avt + av_tides |
|---|
| 97 | !! avm = avm + av_tides |
|---|
| 98 | !! avmu = avmu + mi(av_tides) |
|---|
| 99 | !! avmv = avmv + mj(av_tides) |
|---|
| 100 | !! |
|---|
| 101 | !! ** Action : avt, avm, avmu, avmv increased by tidal mixing |
|---|
| 102 | !! |
|---|
| 103 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 104 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 105 | !!---------------------------------------------------------------------- |
|---|
| 106 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 107 | ! |
|---|
| 108 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 109 | REAL(wp) :: ztpc ! scalar workspace |
|---|
| 110 | REAL(wp), POINTER, DIMENSION(:,:) :: zkz |
|---|
| 111 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zav_tide |
|---|
| 112 | !!---------------------------------------------------------------------- |
|---|
| 113 | ! |
|---|
| 114 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
|---|
| 115 | ! |
|---|
| 116 | CALL wrk_alloc( jpi,jpj, zkz ) |
|---|
| 117 | CALL wrk_alloc( jpi,jpj,jpk, zav_tide ) |
|---|
| 118 | ! |
|---|
| 119 | ! ! ----------------------- ! |
|---|
| 120 | ! ! Standard tidal mixing ! (compute zav_tide) |
|---|
| 121 | ! ! ----------------------- ! |
|---|
| 122 | ! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s |
|---|
| 123 | zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) ) |
|---|
| 124 | |
|---|
| 125 | zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column |
|---|
| 126 | DO jk = 2, jpkm1 |
|---|
| 127 | zkz(:,:) = zkz(:,:) + e3w_n(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk) * wmask(:,:,jk) |
|---|
| 128 | END DO |
|---|
| 129 | |
|---|
| 130 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 131 | DO ji = 1, jpi |
|---|
| 132 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 133 | END DO |
|---|
| 134 | END DO |
|---|
| 135 | |
|---|
| 136 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
|---|
| 137 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) * wmask(:,:,jk) !kz max = 300 cm2/s |
|---|
| 138 | END DO |
|---|
| 139 | |
|---|
| 140 | IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide |
|---|
| 141 | ztpc = 0._wp |
|---|
| 142 | DO jk= 1, jpk |
|---|
| 143 | DO jj= 1, jpj |
|---|
| 144 | DO ji= 1, jpi |
|---|
| 145 | ztpc = ztpc + e3w_n(ji,jj,jk) * e1e2t(ji,jj) & |
|---|
| 146 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 147 | END DO |
|---|
| 148 | END DO |
|---|
| 149 | END DO |
|---|
| 150 | ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc |
|---|
| 151 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
|---|
| 152 | IF(lwp) WRITE(numout,*) |
|---|
| 153 | IF(lwp) WRITE(numout,*) ' N Total power consumption by av_tide : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 154 | ENDIF |
|---|
| 155 | |
|---|
| 156 | ! ! ----------------------- ! |
|---|
| 157 | ! ! ITF tidal mixing ! (update zav_tide) |
|---|
| 158 | ! ! ----------------------- ! |
|---|
| 159 | IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide ) |
|---|
| 160 | |
|---|
| 161 | ! ! ----------------------- ! |
|---|
| 162 | ! ! Update mixing coefs ! |
|---|
| 163 | ! ! ----------------------- ! |
|---|
| 164 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
|---|
| 165 | avt(:,:,jk) = avt(:,:,jk) + zav_tide(:,:,jk) * wmask(:,:,jk) |
|---|
| 166 | avm(:,:,jk) = avm(:,:,jk) + zav_tide(:,:,jk) * wmask(:,:,jk) |
|---|
| 167 | DO jj = 2, jpjm1 |
|---|
| 168 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 169 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * wumask(ji,jj,jk) |
|---|
| 170 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * wvmask(ji,jj,jk) |
|---|
| 171 | END DO |
|---|
| 172 | END DO |
|---|
| 173 | END DO |
|---|
| 174 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
|---|
| 175 | |
|---|
| 176 | ! !* output tidal mixing coefficient |
|---|
| 177 | CALL iom_put( "av_tide", zav_tide ) |
|---|
| 178 | |
|---|
| 179 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
|---|
| 180 | ! |
|---|
| 181 | CALL wrk_dealloc( jpi,jpj, zkz ) |
|---|
| 182 | CALL wrk_dealloc( jpi,jpj,jpk, zav_tide ) |
|---|
| 183 | ! |
|---|
| 184 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
|---|
| 185 | ! |
|---|
| 186 | END SUBROUTINE zdf_tmx |
|---|
| 187 | |
|---|
| 188 | |
|---|
| 189 | SUBROUTINE tmx_itf( kt, pav ) |
|---|
| 190 | !!---------------------------------------------------------------------- |
|---|
| 191 | !! *** ROUTINE tmx_itf *** |
|---|
| 192 | !! |
|---|
| 193 | !! ** Purpose : modify the vertical eddy diffusivity coefficients |
|---|
| 194 | !! (pav) in the Indonesian Through Flow area (ITF). |
|---|
| 195 | !! |
|---|
| 196 | !! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined |
|---|
| 197 | !! by msk_itf (read in a file, see tmx_init), the tidal |
|---|
| 198 | !! mixing coefficient is computed with : |
|---|
| 199 | !! * q=1 (i.e. all the tidal energy remains trapped in |
|---|
| 200 | !! the area and thus is used for mixing) |
|---|
| 201 | !! * the vertical distribution of the tifal energy is a |
|---|
| 202 | !! proportional to N above the thermocline (d(N^2)/dz > 0) |
|---|
| 203 | !! and to N^2 below the thermocline (d(N^2)/dz < 0) |
|---|
| 204 | !! |
|---|
| 205 | !! ** Action : av_tide updated in the ITF area (msk_itf) |
|---|
| 206 | !! |
|---|
| 207 | !! References : Koch-Larrouy et al. 2007, GRL |
|---|
| 208 | !!---------------------------------------------------------------------- |
|---|
| 209 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
|---|
| 210 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef. |
|---|
| 211 | !! |
|---|
| 212 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 213 | REAL(wp) :: zcoef, ztpc ! temporary scalar |
|---|
| 214 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! 2D workspace |
|---|
| 215 | REAL(wp), DIMENSION(:,:) , POINTER :: zsum1 , zsum2 , zsum ! - - |
|---|
| 216 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d_1, zempba_3d_2 ! 3D workspace |
|---|
| 217 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d , zdn2dz ! - - |
|---|
| 218 | REAL(wp), DIMENSION(:,:,:), POINTER :: zavt_itf ! - - |
|---|
| 219 | !!---------------------------------------------------------------------- |
|---|
| 220 | ! |
|---|
| 221 | IF( nn_timing == 1 ) CALL timing_start('tmx_itf') |
|---|
| 222 | ! |
|---|
| 223 | CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 224 | CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 225 | |
|---|
| 226 | ! ! compute the form function using N2 at each time step |
|---|
| 227 | zdn2dz (:,:,jpk) = 0.e0 |
|---|
| 228 | zempba_3d_1(:,:,jpk) = 0.e0 |
|---|
| 229 | zempba_3d_2(:,:,jpk) = 0.e0 |
|---|
| 230 | DO jk = 1, jpkm1 |
|---|
| 231 | zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz |
|---|
| 232 | zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N |
|---|
| 233 | zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2 |
|---|
| 234 | END DO |
|---|
| 235 | ! |
|---|
| 236 | zsum (:,:) = 0.e0 |
|---|
| 237 | zsum1(:,:) = 0.e0 |
|---|
| 238 | zsum2(:,:) = 0.e0 |
|---|
| 239 | DO jk= 2, jpk |
|---|
| 240 | zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * e3w_n(:,:,jk) * wmask(:,:,jk) |
|---|
| 241 | zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * e3w_n(:,:,jk) * wmask(:,:,jk) |
|---|
| 242 | END DO |
|---|
| 243 | DO jj = 1, jpj |
|---|
| 244 | DO ji = 1, jpi |
|---|
| 245 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
|---|
| 246 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
|---|
| 247 | END DO |
|---|
| 248 | END DO |
|---|
| 249 | |
|---|
| 250 | DO jk= 1, jpk |
|---|
| 251 | DO jj = 1, jpj |
|---|
| 252 | DO ji = 1, jpi |
|---|
| 253 | zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise |
|---|
| 254 | ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef & |
|---|
| 255 | & + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef ) |
|---|
| 256 | ! |
|---|
| 257 | zempba_3d(ji,jj,jk) = ztpc |
|---|
| 258 | zsum (ji,jj) = zsum(ji,jj) + ztpc * e3w_n(ji,jj,jk) |
|---|
| 259 | END DO |
|---|
| 260 | END DO |
|---|
| 261 | END DO |
|---|
| 262 | DO jj = 1, jpj |
|---|
| 263 | DO ji = 1, jpi |
|---|
| 264 | IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj) |
|---|
| 265 | END DO |
|---|
| 266 | END DO |
|---|
| 267 | |
|---|
| 268 | ! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min) |
|---|
| 269 | zcoef = rn_tfe_itf / ( rn_tfe * rau0 ) |
|---|
| 270 | DO jk = 1, jpk |
|---|
| 271 | zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) & |
|---|
| 272 | & / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) ) |
|---|
| 273 | END DO |
|---|
| 274 | |
|---|
| 275 | zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column |
|---|
| 276 | DO jk = 2, jpkm1 |
|---|
| 277 | zkz(:,:) = zkz(:,:) + e3w_n(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * wmask(:,:,jk) |
|---|
| 278 | END DO |
|---|
| 279 | |
|---|
| 280 | DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 281 | DO ji = 1, jpi |
|---|
| 282 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj) |
|---|
| 283 | END DO |
|---|
| 284 | END DO |
|---|
| 285 | |
|---|
| 286 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
|---|
| 287 | zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) * wmask(:,:,jk) ! kz max = 120 cm2/s |
|---|
| 288 | END DO |
|---|
| 289 | |
|---|
| 290 | IF( kt == nit000 ) THEN ! diagnose the nergy consumed by zavt_itf |
|---|
| 291 | ztpc = 0.e0 |
|---|
| 292 | DO jk= 1, jpk |
|---|
| 293 | DO jj= 1, jpj |
|---|
| 294 | DO ji= 1, jpi |
|---|
| 295 | ztpc = ztpc + e1e2t(ji,jj) * e3w_n(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) & |
|---|
| 296 | & * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 297 | END DO |
|---|
| 298 | END DO |
|---|
| 299 | END DO |
|---|
| 300 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
|---|
| 301 | ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf ) |
|---|
| 302 | IF(lwp) WRITE(numout,*) ' N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 303 | ENDIF |
|---|
| 304 | |
|---|
| 305 | ! ! Update pav with the ITF mixing coefficient |
|---|
| 306 | DO jk = 2, jpkm1 |
|---|
| 307 | pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) & |
|---|
| 308 | & + zavt_itf(:,:,jk) * mask_itf(:,:) |
|---|
| 309 | END DO |
|---|
| 310 | ! |
|---|
| 311 | CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 312 | CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 313 | ! |
|---|
| 314 | IF( nn_timing == 1 ) CALL timing_stop('tmx_itf') |
|---|
| 315 | ! |
|---|
| 316 | END SUBROUTINE tmx_itf |
|---|
| 317 | |
|---|
| 318 | |
|---|
| 319 | SUBROUTINE zdf_tmx_init |
|---|
| 320 | !!---------------------------------------------------------------------- |
|---|
| 321 | !! *** ROUTINE zdf_tmx_init *** |
|---|
| 322 | !! |
|---|
| 323 | !! ** Purpose : Initialization of the vertical tidal mixing, Reading |
|---|
| 324 | !! of M2 and K1 tidal energy in nc files |
|---|
| 325 | !! |
|---|
| 326 | !! ** Method : - Read the namtmx namelist and check the parameters |
|---|
| 327 | !! |
|---|
| 328 | !! - Read the input data in NetCDF files : |
|---|
| 329 | !! M2 and K1 tidal energy. The total tidal energy, en_tmx, |
|---|
| 330 | !! is the sum of M2, K1 and S2 energy where S2 is assumed |
|---|
| 331 | !! to be: S2=(1/2)^2 * M2 |
|---|
| 332 | !! mask_itf, a mask array that determine where substituing |
|---|
| 333 | !! the standard Simmons et al. (2005) formulation with the |
|---|
| 334 | !! one of Koch_Larrouy et al. (2007). |
|---|
| 335 | !! |
|---|
| 336 | !! - Compute az_tmx, a 3D coefficient that allows to compute |
|---|
| 337 | !! the standard tidal-induced vertical mixing as follows: |
|---|
| 338 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 339 | !! with az_tmx a bottom intensified coefficient is given by: |
|---|
| 340 | !! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx ) |
|---|
| 341 | !! / ( 1. - EXP( - H /rn_htmx ) ) |
|---|
| 342 | !! where rn_htmx the characteristic length scale of the bottom |
|---|
| 343 | !! intensification, en_tmx the tidal energy, and H the ocean depth |
|---|
| 344 | !! |
|---|
| 345 | !! ** input : - Namlist namtmx |
|---|
| 346 | !! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc |
|---|
| 347 | !! |
|---|
| 348 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 349 | !! - defined az_tmx used to compute tidal-induced mixing |
|---|
| 350 | !! |
|---|
| 351 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 352 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 353 | !!---------------------------------------------------------------------- |
|---|
| 354 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 355 | INTEGER :: inum ! local integer |
|---|
| 356 | INTEGER :: ios |
|---|
| 357 | REAL(wp) :: ztpc, ze_z ! local scalars |
|---|
| 358 | REAL(wp), DIMENSION(:,:) , POINTER :: zem2, zek1 ! read M2 and K1 tidal energy |
|---|
| 359 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! total M2, K1 and S2 tidal energy |
|---|
| 360 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! used for vertical structure function |
|---|
| 361 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
|---|
| 362 | REAL(wp), DIMENSION(:,:,:), POINTER :: zpc, zav_tide ! power consumption |
|---|
| 363 | !! |
|---|
| 364 | NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf |
|---|
| 365 | !!---------------------------------------------------------------------- |
|---|
| 366 | ! |
|---|
| 367 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
|---|
| 368 | ! |
|---|
| 369 | CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 370 | CALL wrk_alloc( jpi,jpj,jpk, zpc, zav_tide ) |
|---|
| 371 | ! |
|---|
| 372 | REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Tidal Mixing |
|---|
| 373 | READ ( numnam_ref, namzdf_tmx, IOSTAT = ios, ERR = 901) |
|---|
| 374 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp ) |
|---|
| 375 | ! |
|---|
| 376 | REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Tidal Mixing |
|---|
| 377 | READ ( numnam_cfg, namzdf_tmx, IOSTAT = ios, ERR = 902 ) |
|---|
| 378 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp ) |
|---|
| 379 | IF(lwm) WRITE ( numond, namzdf_tmx ) |
|---|
| 380 | ! |
|---|
| 381 | IF(lwp) THEN ! Control print |
|---|
| 382 | WRITE(numout,*) |
|---|
| 383 | WRITE(numout,*) 'zdf_tmx_init : tidal mixing' |
|---|
| 384 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 385 | WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters' |
|---|
| 386 | WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx |
|---|
| 387 | WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min |
|---|
| 388 | WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe |
|---|
| 389 | WRITE(numout,*) ' Mixing efficiency = ', rn_me |
|---|
| 390 | WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf |
|---|
| 391 | WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf |
|---|
| 392 | ENDIF |
|---|
| 393 | ! ! allocate tmx arrays |
|---|
| 394 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
|---|
| 395 | |
|---|
| 396 | IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask |
|---|
| 397 | CALL iom_open('mask_itf',inum) |
|---|
| 398 | CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) ! |
|---|
| 399 | CALL iom_close(inum) |
|---|
| 400 | ENDIF |
|---|
| 401 | ! ! read M2 tidal energy flux : W/m2 ( zem2 < 0 ) |
|---|
| 402 | CALL iom_open('M2rowdrg',inum) |
|---|
| 403 | CALL iom_get (inum, jpdom_data, 'field',zem2,1) ! |
|---|
| 404 | CALL iom_close(inum) |
|---|
| 405 | ! ! read K1 tidal energy flux : W/m2 ( zek1 < 0 ) |
|---|
| 406 | CALL iom_open('K1rowdrg',inum) |
|---|
| 407 | CALL iom_get (inum, jpdom_data, 'field',zek1,1) ! |
|---|
| 408 | CALL iom_close(inum) |
|---|
| 409 | ! ! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 ) |
|---|
| 410 | ! ! only the energy available for mixing is taken into account, |
|---|
| 411 | ! ! (mixing efficiency tidal dissipation efficiency) |
|---|
| 412 | en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * ssmask(:,:) |
|---|
| 413 | |
|---|
| 414 | !============ |
|---|
| 415 | !TG: Bug for VVL? Should this section be moved out of _init and be updated at every timestep? |
|---|
| 416 | !!gm : you are right, but tidal mixing acts in deep ocean (H>500m) where e3 is O(100m) |
|---|
| 417 | !! the error is thus ~1% which I feel comfortable with, compared to uncertainties in tidal energy dissipation. |
|---|
| 418 | ! ! Vertical structure (az_tmx) |
|---|
| 419 | DO jj = 1, jpj ! part independent of the level |
|---|
| 420 | DO ji = 1, jpi |
|---|
| 421 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 422 | zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) ) |
|---|
| 423 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj) |
|---|
| 424 | END DO |
|---|
| 425 | END DO |
|---|
| 426 | DO jk= 1, jpk ! complete with the level-dependent part |
|---|
| 427 | DO jj = 1, jpj |
|---|
| 428 | DO ji = 1, jpi |
|---|
| 429 | az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-gdepw_0(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk) |
|---|
| 430 | END DO |
|---|
| 431 | END DO |
|---|
| 432 | END DO |
|---|
| 433 | !=========== |
|---|
| 434 | ! |
|---|
| 435 | IF( nprint == 1 .AND. lwp ) THEN |
|---|
| 436 | ! Control print |
|---|
| 437 | ! Total power consumption due to vertical mixing |
|---|
| 438 | ! zpc = rau0 * 1/rn_me * rn2 * zav_tide |
|---|
| 439 | zav_tide(:,:,:) = 0.e0 |
|---|
| 440 | DO jk = 2, jpkm1 |
|---|
| 441 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
|---|
| 442 | END DO |
|---|
| 443 | ! |
|---|
| 444 | ztpc = 0._wp |
|---|
| 445 | zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 446 | DO jk= 2, jpkm1 |
|---|
| 447 | DO jj = 1, jpj |
|---|
| 448 | DO ji = 1, jpi |
|---|
| 449 | ztpc = ztpc + e3w_n(ji,jj,jk) * e1e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 450 | END DO |
|---|
| 451 | END DO |
|---|
| 452 | END DO |
|---|
| 453 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
|---|
| 454 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 455 | ! |
|---|
| 456 | WRITE(numout,*) |
|---|
| 457 | WRITE(numout,*) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 458 | ! |
|---|
| 459 | ! control print 2 |
|---|
| 460 | zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 ) |
|---|
| 461 | zkz(:,:) = 0._wp |
|---|
| 462 | DO jk = 2, jpkm1 |
|---|
| 463 | zkz(:,:) = zkz(:,:) + e3w_n(:,:,jk) * MAX(0.e0, rn2(:,:,jk)) * rau0 * zav_tide(:,:,jk) * wmask(:,:,jk) |
|---|
| 464 | END DO |
|---|
| 465 | ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz |
|---|
| 466 | DO jj = 1, jpj |
|---|
| 467 | DO ji = 1, jpi |
|---|
| 468 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 469 | zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 470 | ENDIF |
|---|
| 471 | END DO |
|---|
| 472 | END DO |
|---|
| 473 | ztpc = 1.e50 |
|---|
| 474 | DO jj = 1, jpj |
|---|
| 475 | DO ji = 1, jpi |
|---|
| 476 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 477 | ztpc = Min( zkz(ji,jj), ztpc) |
|---|
| 478 | ENDIF |
|---|
| 479 | END DO |
|---|
| 480 | END DO |
|---|
| 481 | WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) ) |
|---|
| 482 | ! |
|---|
| 483 | DO jk = 2, jpkm1 |
|---|
| 484 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) * wmask(:,:,jk) !kz max = 300 cm2/s |
|---|
| 485 | END DO |
|---|
| 486 | ztpc = 0._wp |
|---|
| 487 | zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 488 | DO jk= 1, jpk |
|---|
| 489 | DO jj = 1, jpj |
|---|
| 490 | DO ji = 1, jpi |
|---|
| 491 | ztpc = ztpc + e3w_n(ji,jj,jk) * e1e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 492 | END DO |
|---|
| 493 | END DO |
|---|
| 494 | END DO |
|---|
| 495 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
|---|
| 496 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 497 | WRITE(numout,*) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 498 | !!gm bug mpp in these diagnostics |
|---|
| 499 | DO jk = 1, jpk |
|---|
| 500 | ze_z = SUM( e1e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) & |
|---|
| 501 | & / MAX( 1.e-20, SUM( e1e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 502 | ztpc = 1.e50 |
|---|
| 503 | DO jj = 1, jpj |
|---|
| 504 | DO ji = 1, jpi |
|---|
| 505 | IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc = MIN( ztpc, zav_tide(ji,jj,jk) ) |
|---|
| 506 | END DO |
|---|
| 507 | END DO |
|---|
| 508 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4, & |
|---|
| 509 | & 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s' |
|---|
| 510 | END DO |
|---|
| 511 | |
|---|
| 512 | WRITE(numout,*) ' e_tide : ', SUM( e1e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW' |
|---|
| 513 | WRITE(numout,*) |
|---|
| 514 | WRITE(numout,*) ' Initial profile of tidal vertical mixing' |
|---|
| 515 | DO jk = 1, jpk |
|---|
| 516 | DO jj = 1,jpj |
|---|
| 517 | DO ji = 1,jpi |
|---|
| 518 | zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) ) |
|---|
| 519 | END DO |
|---|
| 520 | END DO |
|---|
| 521 | ze_z = SUM( e1e2t(:,:) * zkz (:,:) * tmask_i(:,:) ) & |
|---|
| 522 | & / MAX( 1.e-20, SUM( e1e2t(:,:) * wmask(:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 523 | WRITE(numout,*) ' jk= ', jk,' ', ze_z * 1.e4,' cm2/s' |
|---|
| 524 | END DO |
|---|
| 525 | DO jk = 1, jpk |
|---|
| 526 | zkz(:,:) = az_tmx(:,:,jk) /rn_n2min |
|---|
| 527 | ze_z = SUM( e1e2t(:,:) * zkz (:,:) * tmask_i(:,:) ) & |
|---|
| 528 | & / MAX( 1.e-20, SUM( e1e2t(:,:) * wmask(:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 529 | WRITE(numout,*) |
|---|
| 530 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, & |
|---|
| 531 | & 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s' |
|---|
| 532 | END DO |
|---|
| 533 | !!gm end bug mpp |
|---|
| 534 | ! |
|---|
| 535 | ENDIF |
|---|
| 536 | ! |
|---|
| 537 | CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 538 | CALL wrk_dealloc( jpi,jpj,jpk, zpc, zav_tide ) |
|---|
| 539 | ! |
|---|
| 540 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
|---|
| 541 | ! |
|---|
| 542 | END SUBROUTINE zdf_tmx_init |
|---|
| 543 | |
|---|
| 544 | #elif defined key_zdftmx_new |
|---|
| 545 | !!---------------------------------------------------------------------- |
|---|
| 546 | !! 'key_zdftmx_new' Internal wave-driven vertical mixing |
|---|
| 547 | !!---------------------------------------------------------------------- |
|---|
| 548 | !! zdf_tmx : global momentum & tracer Kz with wave induced Kz |
|---|
| 549 | !! zdf_tmx_init : global momentum & tracer Kz with wave induced Kz |
|---|
| 550 | !!---------------------------------------------------------------------- |
|---|
| 551 | USE oce ! ocean dynamics and tracers variables |
|---|
| 552 | USE dom_oce ! ocean space and time domain variables |
|---|
| 553 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 554 | USE zdfddm ! ocean vertical physics: double diffusive mixing |
|---|
| 555 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 556 | USE eosbn2 ! ocean equation of state |
|---|
| 557 | USE phycst ! physical constants |
|---|
| 558 | USE prtctl ! Print control |
|---|
| 559 | USE in_out_manager ! I/O manager |
|---|
| 560 | USE iom ! I/O Manager |
|---|
| 561 | USE lib_mpp ! MPP library |
|---|
| 562 | USE wrk_nemo ! work arrays |
|---|
| 563 | USE timing ! Timing |
|---|
| 564 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 565 | |
|---|
| 566 | IMPLICIT NONE |
|---|
| 567 | PRIVATE |
|---|
| 568 | |
|---|
| 569 | PUBLIC zdf_tmx ! called in step module |
|---|
| 570 | PUBLIC zdf_tmx_init ! called in nemogcm module |
|---|
| 571 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
|---|
| 572 | |
|---|
| 573 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: wave-driven mixing flag |
|---|
| 574 | |
|---|
| 575 | ! !!* Namelist namzdf_tmx : internal wave-driven mixing * |
|---|
| 576 | INTEGER :: nn_zpyc ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2) |
|---|
| 577 | LOGICAL :: ln_mevar ! variable (=T) or constant (=F) mixing efficiency |
|---|
| 578 | LOGICAL :: ln_tsdiff ! account for differential T/S wave-driven mixing (=T) or not (=F) |
|---|
| 579 | |
|---|
| 580 | REAL(wp) :: r1_6 = 1._wp / 6._wp |
|---|
| 581 | |
|---|
| 582 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ebot_tmx ! power available from high-mode wave breaking (W/m2) |
|---|
| 583 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: epyc_tmx ! power available from low-mode, pycnocline-intensified wave breaking (W/m2) |
|---|
| 584 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ecri_tmx ! power available from low-mode, critical slope wave breaking (W/m2) |
|---|
| 585 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hbot_tmx ! WKB decay scale for high-mode energy dissipation (m) |
|---|
| 586 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hcri_tmx ! decay scale for low-mode critical slope dissipation (m) |
|---|
| 587 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emix_tmx ! local energy density available for mixing (W/kg) |
|---|
| 588 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: bflx_tmx ! buoyancy flux Kz * N^2 (W/kg) |
|---|
| 589 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: pcmap_tmx ! vertically integrated buoyancy flux (W/m2) |
|---|
| 590 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_ratio ! S/T diffusivity ratio (only for ln_tsdiff=T) |
|---|
| 591 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_wave ! Internal wave-induced diffusivity |
|---|
| 592 | |
|---|
| 593 | !! * Substitutions |
|---|
| 594 | # include "zdfddm_substitute.h90" |
|---|
| 595 | # include "vectopt_loop_substitute.h90" |
|---|
| 596 | !!---------------------------------------------------------------------- |
|---|
| 597 | !! NEMO/OPA 4.0 , NEMO Consortium (2016) |
|---|
| 598 | !! $Id$ |
|---|
| 599 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 600 | !!---------------------------------------------------------------------- |
|---|
| 601 | CONTAINS |
|---|
| 602 | |
|---|
| 603 | INTEGER FUNCTION zdf_tmx_alloc() |
|---|
| 604 | !!---------------------------------------------------------------------- |
|---|
| 605 | !! *** FUNCTION zdf_tmx_alloc *** |
|---|
| 606 | !!---------------------------------------------------------------------- |
|---|
| 607 | ALLOCATE( ebot_tmx(jpi,jpj), epyc_tmx(jpi,jpj), ecri_tmx(jpi,jpj) , & |
|---|
| 608 | & hbot_tmx(jpi,jpj), hcri_tmx(jpi,jpj), emix_tmx(jpi,jpj,jpk), & |
|---|
| 609 | & bflx_tmx(jpi,jpj,jpk), pcmap_tmx(jpi,jpj), zav_ratio(jpi,jpj,jpk), & |
|---|
| 610 | & zav_wave(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
|---|
| 611 | ! |
|---|
| 612 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
|---|
| 613 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
|---|
| 614 | END FUNCTION zdf_tmx_alloc |
|---|
| 615 | |
|---|
| 616 | |
|---|
| 617 | SUBROUTINE zdf_tmx( kt ) |
|---|
| 618 | !!---------------------------------------------------------------------- |
|---|
| 619 | !! *** ROUTINE zdf_tmx *** |
|---|
| 620 | !! |
|---|
| 621 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 622 | !! breaking internal waves. |
|---|
| 623 | !! |
|---|
| 624 | !! ** Method : - internal wave-driven vertical mixing is given by: |
|---|
| 625 | !! Kz_wave = min( 100 cm2/s, f( Reb = emix_tmx /( Nu * N^2 ) ) |
|---|
| 626 | !! where emix_tmx is the 3D space distribution of the wave-breaking |
|---|
| 627 | !! energy and Nu the molecular kinematic viscosity. |
|---|
| 628 | !! The function f(Reb) is linear (constant mixing efficiency) |
|---|
| 629 | !! if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T. |
|---|
| 630 | !! |
|---|
| 631 | !! - Compute emix_tmx, the 3D power density that allows to compute |
|---|
| 632 | !! Reb and therefrom the wave-induced vertical diffusivity. |
|---|
| 633 | !! This is divided into three components: |
|---|
| 634 | !! 1. Bottom-intensified low-mode dissipation at critical slopes |
|---|
| 635 | !! emix_tmx(z) = ( ecri_tmx / rau0 ) * EXP( -(H-z)/hcri_tmx ) |
|---|
| 636 | !! / ( 1. - EXP( - H/hcri_tmx ) ) * hcri_tmx |
|---|
| 637 | !! where hcri_tmx is the characteristic length scale of the bottom |
|---|
| 638 | !! intensification, ecri_tmx a map of available power, and H the ocean depth. |
|---|
| 639 | !! 2. Pycnocline-intensified low-mode dissipation |
|---|
| 640 | !! emix_tmx(z) = ( epyc_tmx / rau0 ) * ( sqrt(rn2(z))^nn_zpyc ) |
|---|
| 641 | !! / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) ) |
|---|
| 642 | !! where epyc_tmx is a map of available power, and nn_zpyc |
|---|
| 643 | !! is the chosen stratification-dependence of the internal wave |
|---|
| 644 | !! energy dissipation. |
|---|
| 645 | !! 3. WKB-height dependent high mode dissipation |
|---|
| 646 | !! emix_tmx(z) = ( ebot_tmx / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_tmx) |
|---|
| 647 | !! / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_tmx) * e3w(z) ) |
|---|
| 648 | !! where hbot_tmx is the characteristic length scale of the WKB bottom |
|---|
| 649 | !! intensification, ebot_tmx is a map of available power, and z_wkb is the |
|---|
| 650 | !! WKB-stretched height above bottom defined as |
|---|
| 651 | !! z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) ) |
|---|
| 652 | !! / SUM( sqrt(rn2(z')) * e3w(z') ) |
|---|
| 653 | !! |
|---|
| 654 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 655 | !! avt = avt + av_wave |
|---|
| 656 | !! avm = avm + av_wave |
|---|
| 657 | !! avmu = avmu + mi(av_wave) |
|---|
| 658 | !! avmv = avmv + mj(av_wave) |
|---|
| 659 | !! |
|---|
| 660 | !! - if namelist parameter ln_tsdiff = T, account for differential mixing: |
|---|
| 661 | !! avs = avt + av_wave * diffusivity_ratio(Reb) |
|---|
| 662 | !! |
|---|
| 663 | !! ** Action : - Define emix_tmx used to compute internal wave-induced mixing |
|---|
| 664 | !! - avt, avs, avm, avmu, avmv increased by internal wave-driven mixing |
|---|
| 665 | !! |
|---|
| 666 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
|---|
| 667 | !!---------------------------------------------------------------------- |
|---|
| 668 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 669 | ! |
|---|
| 670 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 671 | REAL(wp) :: ztpc ! scalar workspace |
|---|
| 672 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! Used for vertical structure |
|---|
| 673 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
|---|
| 674 | REAL(wp), DIMENSION(:,:,:), POINTER :: zwkb ! WKB-stretched height above bottom |
|---|
| 675 | REAL(wp), DIMENSION(:,:,:), POINTER :: zweight ! Weight for high mode vertical distribution |
|---|
| 676 | REAL(wp), DIMENSION(:,:,:), POINTER :: znu_t ! Molecular kinematic viscosity (T grid) |
|---|
| 677 | REAL(wp), DIMENSION(:,:,:), POINTER :: znu_w ! Molecular kinematic viscosity (W grid) |
|---|
| 678 | REAL(wp), DIMENSION(:,:,:), POINTER :: zReb ! Turbulence intensity parameter |
|---|
| 679 | !!---------------------------------------------------------------------- |
|---|
| 680 | ! |
|---|
| 681 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
|---|
| 682 | ! |
|---|
| 683 | CALL wrk_alloc( jpi,jpj, zfact, zhdep ) |
|---|
| 684 | CALL wrk_alloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb ) |
|---|
| 685 | |
|---|
| 686 | ! ! ----------------------------- ! |
|---|
| 687 | ! ! Internal wave-driven mixing ! (compute zav_wave) |
|---|
| 688 | ! ! ----------------------------- ! |
|---|
| 689 | ! |
|---|
| 690 | ! !* Critical slope mixing: distribute energy over the time-varying ocean depth, |
|---|
| 691 | ! using an exponential decay from the seafloor. |
|---|
| 692 | DO jj = 1, jpj ! part independent of the level |
|---|
| 693 | DO ji = 1, jpi |
|---|
| 694 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 695 | zfact(ji,jj) = rau0 * ( 1._wp - EXP( -zhdep(ji,jj) / hcri_tmx(ji,jj) ) ) |
|---|
| 696 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ecri_tmx(ji,jj) / zfact(ji,jj) |
|---|
| 697 | END DO |
|---|
| 698 | END DO |
|---|
| 699 | |
|---|
| 700 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 701 | emix_tmx(:,:,jk) = zfact(:,:) * ( EXP( ( gde3w_n(:,:,jk ) - zhdep(:,:) ) / hcri_tmx(:,:) ) & |
|---|
| 702 | & - EXP( ( gde3w_n(:,:,jk-1) - zhdep(:,:) ) / hcri_tmx(:,:) ) ) * wmask(:,:,jk) & |
|---|
| 703 | & / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) ) |
|---|
| 704 | END DO |
|---|
| 705 | |
|---|
| 706 | ! !* Pycnocline-intensified mixing: distribute energy over the time-varying |
|---|
| 707 | ! !* ocean depth as proportional to sqrt(rn2)^nn_zpyc |
|---|
| 708 | |
|---|
| 709 | SELECT CASE ( nn_zpyc ) |
|---|
| 710 | |
|---|
| 711 | CASE ( 1 ) ! Dissipation scales as N (recommended) |
|---|
| 712 | |
|---|
| 713 | zfact(:,:) = 0._wp |
|---|
| 714 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 715 | zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 716 | END DO |
|---|
| 717 | |
|---|
| 718 | DO jj = 1, jpj |
|---|
| 719 | DO ji = 1, jpi |
|---|
| 720 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 721 | END DO |
|---|
| 722 | END DO |
|---|
| 723 | |
|---|
| 724 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 725 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 726 | END DO |
|---|
| 727 | |
|---|
| 728 | CASE ( 2 ) ! Dissipation scales as N^2 |
|---|
| 729 | |
|---|
| 730 | zfact(:,:) = 0._wp |
|---|
| 731 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 732 | zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 733 | END DO |
|---|
| 734 | |
|---|
| 735 | DO jj= 1, jpj |
|---|
| 736 | DO ji = 1, jpi |
|---|
| 737 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 738 | END DO |
|---|
| 739 | END DO |
|---|
| 740 | |
|---|
| 741 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 742 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 743 | END DO |
|---|
| 744 | |
|---|
| 745 | END SELECT |
|---|
| 746 | |
|---|
| 747 | ! !* WKB-height dependent mixing: distribute energy over the time-varying |
|---|
| 748 | ! !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot) |
|---|
| 749 | |
|---|
| 750 | zwkb(:,:,:) = 0._wp |
|---|
| 751 | zfact(:,:) = 0._wp |
|---|
| 752 | DO jk = 2, jpkm1 |
|---|
| 753 | zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 754 | zwkb(:,:,jk) = zfact(:,:) |
|---|
| 755 | END DO |
|---|
| 756 | |
|---|
| 757 | DO jk = 2, jpkm1 |
|---|
| 758 | DO jj = 1, jpj |
|---|
| 759 | DO ji = 1, jpi |
|---|
| 760 | IF( zfact(ji,jj) /= 0 ) zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) ) & |
|---|
| 761 | & * tmask(ji,jj,jk) / zfact(ji,jj) |
|---|
| 762 | END DO |
|---|
| 763 | END DO |
|---|
| 764 | END DO |
|---|
| 765 | zwkb(:,:,1) = zhdep(:,:) * tmask(:,:,1) |
|---|
| 766 | |
|---|
| 767 | zweight(:,:,:) = 0._wp |
|---|
| 768 | DO jk = 2, jpkm1 |
|---|
| 769 | zweight(:,:,jk) = MAX( 0._wp, rn2(:,:,jk) ) * hbot_tmx(:,:) * wmask(:,:,jk) & |
|---|
| 770 | & * ( EXP( -zwkb(:,:,jk) / hbot_tmx(:,:) ) - EXP( -zwkb(:,:,jk-1) / hbot_tmx(:,:) ) ) |
|---|
| 771 | END DO |
|---|
| 772 | |
|---|
| 773 | zfact(:,:) = 0._wp |
|---|
| 774 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 775 | zfact(:,:) = zfact(:,:) + zweight(:,:,jk) |
|---|
| 776 | END DO |
|---|
| 777 | |
|---|
| 778 | DO jj = 1, jpj |
|---|
| 779 | DO ji = 1, jpi |
|---|
| 780 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ebot_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 781 | END DO |
|---|
| 782 | END DO |
|---|
| 783 | |
|---|
| 784 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 785 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk) & |
|---|
| 786 | & / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) ) |
|---|
| 787 | END DO |
|---|
| 788 | |
|---|
| 789 | |
|---|
| 790 | ! Calculate molecular kinematic viscosity |
|---|
| 791 | znu_t(:,:,:) = 1.e-4_wp * ( 17.91_wp - 0.53810_wp * tsn(:,:,:,jp_tem) + 0.00694_wp * tsn(:,:,:,jp_tem) * tsn(:,:,:,jp_tem) & |
|---|
| 792 | & + 0.02305_wp * tsn(:,:,:,jp_sal) ) * tmask(:,:,:) * r1_rau0 |
|---|
| 793 | DO jk = 2, jpkm1 |
|---|
| 794 | znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 795 | END DO |
|---|
| 796 | |
|---|
| 797 | ! Calculate turbulence intensity parameter Reb |
|---|
| 798 | DO jk = 2, jpkm1 |
|---|
| 799 | zReb(:,:,jk) = emix_tmx(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) ) |
|---|
| 800 | END DO |
|---|
| 801 | |
|---|
| 802 | ! Define internal wave-induced diffusivity |
|---|
| 803 | DO jk = 2, jpkm1 |
|---|
| 804 | zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6 ! This corresponds to a constant mixing efficiency of 1/6 |
|---|
| 805 | END DO |
|---|
| 806 | |
|---|
| 807 | IF( ln_mevar ) THEN ! Variable mixing efficiency case : modify zav_wave in the |
|---|
| 808 | DO jk = 2, jpkm1 ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes |
|---|
| 809 | DO jj = 1, jpj |
|---|
| 810 | DO ji = 1, jpi |
|---|
| 811 | IF( zReb(ji,jj,jk) > 480.00_wp ) THEN |
|---|
| 812 | zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 813 | ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN |
|---|
| 814 | zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 815 | ENDIF |
|---|
| 816 | END DO |
|---|
| 817 | END DO |
|---|
| 818 | END DO |
|---|
| 819 | ENDIF |
|---|
| 820 | |
|---|
| 821 | DO jk = 2, jpkm1 ! Bound diffusivity by molecular value and 100 cm2/s |
|---|
| 822 | zav_wave(:,:,jk) = MIN( MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp ) * wmask(:,:,jk) |
|---|
| 823 | END DO |
|---|
| 824 | |
|---|
| 825 | IF( kt == nit000 ) THEN !* Control print at first time-step: diagnose the energy consumed by zav_wave |
|---|
| 826 | ztpc = 0._wp |
|---|
| 827 | DO jk = 2, jpkm1 |
|---|
| 828 | DO jj = 1, jpj |
|---|
| 829 | DO ji = 1, jpi |
|---|
| 830 | ztpc = ztpc + e3w_n(ji,jj,jk) * e1e2t(ji,jj) & |
|---|
| 831 | & * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 832 | END DO |
|---|
| 833 | END DO |
|---|
| 834 | END DO |
|---|
| 835 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
|---|
| 836 | ztpc = rau0 * ztpc ! Global integral of rauo * Kz * N^2 = power contributing to mixing |
|---|
| 837 | |
|---|
| 838 | IF(lwp) THEN |
|---|
| 839 | WRITE(numout,*) |
|---|
| 840 | WRITE(numout,*) 'zdf_tmx : Internal wave-driven mixing (tmx)' |
|---|
| 841 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 842 | WRITE(numout,*) |
|---|
| 843 | WRITE(numout,*) ' Total power consumption by av_wave: ztpc = ', ztpc * 1.e-12_wp, 'TW' |
|---|
| 844 | ENDIF |
|---|
| 845 | ENDIF |
|---|
| 846 | |
|---|
| 847 | ! ! ----------------------- ! |
|---|
| 848 | ! ! Update mixing coefs ! |
|---|
| 849 | ! ! ----------------------- ! |
|---|
| 850 | ! |
|---|
| 851 | IF( ln_tsdiff ) THEN !* Option for differential mixing of salinity and temperature |
|---|
| 852 | DO jk = 2, jpkm1 ! Calculate S/T diffusivity ratio as a function of Reb |
|---|
| 853 | DO jj = 1, jpj |
|---|
| 854 | DO ji = 1, jpi |
|---|
| 855 | zav_ratio(ji,jj,jk) = ( 0.505_wp + 0.495_wp * & |
|---|
| 856 | & TANH( 0.92_wp * ( LOG10( MAX( 1.e-20_wp, zReb(ji,jj,jk) * 5._wp * r1_6 ) ) - 0.60_wp ) ) & |
|---|
| 857 | & ) * wmask(ji,jj,jk) |
|---|
| 858 | END DO |
|---|
| 859 | END DO |
|---|
| 860 | END DO |
|---|
| 861 | CALL iom_put( "av_ratio", zav_ratio ) |
|---|
| 862 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 863 | fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk) |
|---|
| 864 | avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 865 | avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 866 | END DO |
|---|
| 867 | ! |
|---|
| 868 | ELSE !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 869 | DO jk = 2, jpkm1 |
|---|
| 870 | fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 871 | avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 872 | avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 873 | END DO |
|---|
| 874 | ENDIF |
|---|
| 875 | |
|---|
| 876 | DO jk = 2, jpkm1 !* update momentum diffusivity at wu and wv points |
|---|
| 877 | DO jj = 2, jpjm1 |
|---|
| 878 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 879 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji+1,jj ,jk) ) * wumask(ji,jj,jk) |
|---|
| 880 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji ,jj+1,jk) ) * wvmask(ji,jj,jk) |
|---|
| 881 | END DO |
|---|
| 882 | END DO |
|---|
| 883 | END DO |
|---|
| 884 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
|---|
| 885 | |
|---|
| 886 | ! !* output internal wave-driven mixing coefficient |
|---|
| 887 | CALL iom_put( "av_wave", zav_wave ) |
|---|
| 888 | !* output useful diagnostics: N^2, Kz * N^2 (bflx_tmx), |
|---|
| 889 | ! vertical integral of rau0 * Kz * N^2 (pcmap_tmx), energy density (emix_tmx) |
|---|
| 890 | IF( iom_use("bflx_tmx") .OR. iom_use("pcmap_tmx") ) THEN |
|---|
| 891 | bflx_tmx(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:) |
|---|
| 892 | pcmap_tmx(:,:) = 0._wp |
|---|
| 893 | DO jk = 2, jpkm1 |
|---|
| 894 | pcmap_tmx(:,:) = pcmap_tmx(:,:) + e3w_n(:,:,jk) * bflx_tmx(:,:,jk) * wmask(:,:,jk) |
|---|
| 895 | END DO |
|---|
| 896 | pcmap_tmx(:,:) = rau0 * pcmap_tmx(:,:) |
|---|
| 897 | CALL iom_put( "bflx_tmx", bflx_tmx ) |
|---|
| 898 | CALL iom_put( "pcmap_tmx", pcmap_tmx ) |
|---|
| 899 | ENDIF |
|---|
| 900 | CALL iom_put( "bn2", rn2 ) |
|---|
| 901 | CALL iom_put( "emix_tmx", emix_tmx ) |
|---|
| 902 | |
|---|
| 903 | CALL wrk_dealloc( jpi,jpj, zfact, zhdep ) |
|---|
| 904 | CALL wrk_dealloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb ) |
|---|
| 905 | |
|---|
| 906 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' tmx - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
|---|
| 907 | ! |
|---|
| 908 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
|---|
| 909 | ! |
|---|
| 910 | END SUBROUTINE zdf_tmx |
|---|
| 911 | |
|---|
| 912 | |
|---|
| 913 | SUBROUTINE zdf_tmx_init |
|---|
| 914 | !!---------------------------------------------------------------------- |
|---|
| 915 | !! *** ROUTINE zdf_tmx_init *** |
|---|
| 916 | !! |
|---|
| 917 | !! ** Purpose : Initialization of the wave-driven vertical mixing, reading |
|---|
| 918 | !! of input power maps and decay length scales in netcdf files. |
|---|
| 919 | !! |
|---|
| 920 | !! ** Method : - Read the namzdf_tmx namelist and check the parameters |
|---|
| 921 | !! |
|---|
| 922 | !! - Read the input data in NetCDF files : |
|---|
| 923 | !! power available from high-mode wave breaking (mixing_power_bot.nc) |
|---|
| 924 | !! power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc) |
|---|
| 925 | !! power available from critical slope wave-breaking (mixing_power_cri.nc) |
|---|
| 926 | !! WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc) |
|---|
| 927 | !! decay scale for critical slope wave-breaking (decay_scale_cri.nc) |
|---|
| 928 | !! |
|---|
| 929 | !! ** input : - Namlist namzdf_tmx |
|---|
| 930 | !! - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc, |
|---|
| 931 | !! decay_scale_bot.nc decay_scale_cri.nc |
|---|
| 932 | !! |
|---|
| 933 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 934 | !! - Define ebot_tmx, epyc_tmx, ecri_tmx, hbot_tmx, hcri_tmx |
|---|
| 935 | !! |
|---|
| 936 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
|---|
| 937 | !! |
|---|
| 938 | !!---------------------------------------------------------------------- |
|---|
| 939 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 940 | INTEGER :: inum ! local integer |
|---|
| 941 | INTEGER :: ios |
|---|
| 942 | REAL(wp) :: zbot, zpyc, zcri ! local scalars |
|---|
| 943 | !! |
|---|
| 944 | NAMELIST/namzdf_tmx_new/ nn_zpyc, ln_mevar, ln_tsdiff |
|---|
| 945 | !!---------------------------------------------------------------------- |
|---|
| 946 | ! |
|---|
| 947 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
|---|
| 948 | ! |
|---|
| 949 | REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Wave-driven mixing |
|---|
| 950 | READ ( numnam_ref, namzdf_tmx_new, IOSTAT = ios, ERR = 901) |
|---|
| 951 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp ) |
|---|
| 952 | ! |
|---|
| 953 | REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Wave-driven mixing |
|---|
| 954 | READ ( numnam_cfg, namzdf_tmx_new, IOSTAT = ios, ERR = 902 ) |
|---|
| 955 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp ) |
|---|
| 956 | IF(lwm) WRITE ( numond, namzdf_tmx_new ) |
|---|
| 957 | ! |
|---|
| 958 | IF(lwp) THEN ! Control print |
|---|
| 959 | WRITE(numout,*) |
|---|
| 960 | WRITE(numout,*) 'zdf_tmx_init : internal wave-driven mixing' |
|---|
| 961 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 962 | WRITE(numout,*) ' Namelist namzdf_tmx_new : set wave-driven mixing parameters' |
|---|
| 963 | WRITE(numout,*) ' Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc |
|---|
| 964 | WRITE(numout,*) ' Variable (T) or constant (F) mixing efficiency = ', ln_mevar |
|---|
| 965 | WRITE(numout,*) ' Differential internal wave-driven mixing (T) or not (F) = ', ln_tsdiff |
|---|
| 966 | ENDIF |
|---|
| 967 | |
|---|
| 968 | ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and |
|---|
| 969 | ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should |
|---|
| 970 | ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6). |
|---|
| 971 | avmb(:) = 1.4e-6_wp ! viscous molecular value |
|---|
| 972 | avtb(:) = 1.e-10_wp ! very small diffusive minimum (background avt is specified in zdf_tmx) |
|---|
| 973 | avtb_2d(:,:) = 1.e0_wp ! uniform |
|---|
| 974 | IF(lwp) THEN ! Control print |
|---|
| 975 | WRITE(numout,*) |
|---|
| 976 | WRITE(numout,*) ' Force the background value applied to avm & avt in TKE to be everywhere ', & |
|---|
| 977 | & 'the viscous molecular value & a very small diffusive value, resp.' |
|---|
| 978 | ENDIF |
|---|
| 979 | |
|---|
| 980 | IF( .NOT.lk_zdfddm ) CALL ctl_stop( 'STOP', 'zdf_tmx_init_new : key_zdftmx_new requires key_zdfddm' ) |
|---|
| 981 | |
|---|
| 982 | ! ! allocate tmx arrays |
|---|
| 983 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
|---|
| 984 | ! |
|---|
| 985 | ! ! read necessary fields |
|---|
| 986 | CALL iom_open('mixing_power_bot',inum) ! energy flux for high-mode wave breaking [W/m2] |
|---|
| 987 | CALL iom_get (inum, jpdom_data, 'field', ebot_tmx, 1 ) |
|---|
| 988 | CALL iom_close(inum) |
|---|
| 989 | ! |
|---|
| 990 | CALL iom_open('mixing_power_pyc',inum) ! energy flux for pynocline-intensified wave breaking [W/m2] |
|---|
| 991 | CALL iom_get (inum, jpdom_data, 'field', epyc_tmx, 1 ) |
|---|
| 992 | CALL iom_close(inum) |
|---|
| 993 | ! |
|---|
| 994 | CALL iom_open('mixing_power_cri',inum) ! energy flux for critical slope wave breaking [W/m2] |
|---|
| 995 | CALL iom_get (inum, jpdom_data, 'field', ecri_tmx, 1 ) |
|---|
| 996 | CALL iom_close(inum) |
|---|
| 997 | ! |
|---|
| 998 | CALL iom_open('decay_scale_bot',inum) ! spatially variable decay scale for high-mode wave breaking [m] |
|---|
| 999 | CALL iom_get (inum, jpdom_data, 'field', hbot_tmx, 1 ) |
|---|
| 1000 | CALL iom_close(inum) |
|---|
| 1001 | ! |
|---|
| 1002 | CALL iom_open('decay_scale_cri',inum) ! spatially variable decay scale for critical slope wave breaking [m] |
|---|
| 1003 | CALL iom_get (inum, jpdom_data, 'field', hcri_tmx, 1 ) |
|---|
| 1004 | CALL iom_close(inum) |
|---|
| 1005 | |
|---|
| 1006 | ebot_tmx(:,:) = ebot_tmx(:,:) * ssmask(:,:) |
|---|
| 1007 | epyc_tmx(:,:) = epyc_tmx(:,:) * ssmask(:,:) |
|---|
| 1008 | ecri_tmx(:,:) = ecri_tmx(:,:) * ssmask(:,:) |
|---|
| 1009 | |
|---|
| 1010 | ! Set once for all to zero the first and last vertical levels of appropriate variables |
|---|
| 1011 | emix_tmx (:,:, 1 ) = 0._wp |
|---|
| 1012 | emix_tmx (:,:,jpk) = 0._wp |
|---|
| 1013 | zav_ratio(:,:, 1 ) = 0._wp |
|---|
| 1014 | zav_ratio(:,:,jpk) = 0._wp |
|---|
| 1015 | zav_wave (:,:, 1 ) = 0._wp |
|---|
| 1016 | zav_wave (:,:,jpk) = 0._wp |
|---|
| 1017 | |
|---|
| 1018 | zbot = glob_sum( e1e2t(:,:) * ebot_tmx(:,:) ) |
|---|
| 1019 | zpyc = glob_sum( e1e2t(:,:) * epyc_tmx(:,:) ) |
|---|
| 1020 | zcri = glob_sum( e1e2t(:,:) * ecri_tmx(:,:) ) |
|---|
| 1021 | IF(lwp) THEN |
|---|
| 1022 | WRITE(numout,*) ' High-mode wave-breaking energy: ', zbot * 1.e-12_wp, 'TW' |
|---|
| 1023 | WRITE(numout,*) ' Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW' |
|---|
| 1024 | WRITE(numout,*) ' Critical slope wave-breaking energy: ', zcri * 1.e-12_wp, 'TW' |
|---|
| 1025 | ENDIF |
|---|
| 1026 | ! |
|---|
| 1027 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
|---|
| 1028 | ! |
|---|
| 1029 | END SUBROUTINE zdf_tmx_init |
|---|
| 1030 | |
|---|
| 1031 | #else |
|---|
| 1032 | !!---------------------------------------------------------------------- |
|---|
| 1033 | !! Default option Dummy module NO Tidal MiXing |
|---|
| 1034 | !!---------------------------------------------------------------------- |
|---|
| 1035 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag |
|---|
| 1036 | CONTAINS |
|---|
| 1037 | SUBROUTINE zdf_tmx_init ! Dummy routine |
|---|
| 1038 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?' |
|---|
| 1039 | END SUBROUTINE zdf_tmx_init |
|---|
| 1040 | SUBROUTINE zdf_tmx( kt ) ! Dummy routine |
|---|
| 1041 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt |
|---|
| 1042 | END SUBROUTINE zdf_tmx |
|---|
| 1043 | #endif |
|---|
| 1044 | |
|---|
| 1045 | !!====================================================================== |
|---|
| 1046 | END MODULE zdftmx |
|---|
