New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfevd.F90 in branches/UKMO/dev_1d_bugfixes/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/UKMO/dev_1d_bugfixes/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfevd.F90 @ 13088

Last change on this file since 13088 was 13088, checked in by jwhile, 4 years ago

Bug fixes for 1D running

File size: 6.7 KB
Line 
1MODULE zdfevd
2   !!======================================================================
3   !!                       ***  MODULE  zdfevd  ***
4   !! Ocean physics: parameterization of convection through an enhancement
5   !!                of vertical eddy mixing coefficient
6   !!======================================================================
7   !! History :  OPA  !  1997-06  (G. Madec, A. Lazar)  Original code
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!             -   !  2005-06  (C. Ethe) KPP parameterization
10   !!            3.2  !  2009-03  (M. Leclair, G. Madec, R. Benshila) test on both before & after
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_evd      : increase the momentum and tracer Kz at the location of
15   !!                  statically unstable portion of the water column (ln_zdfevd=T)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE zdf_oce         ! ocean vertical physics variables
20   USE zdfkpp          ! KPP vertical mixing
21   USE trd_oce         ! trends: ocean variables
22   USE trdtra          ! trends manager: tracers
23   USE in_out_manager  ! I/O manager
24   USE iom             ! for iom_put
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE timing          ! Timing
27   USE stopack
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   zdf_evd    ! called by step.F90
33   REAL(wp), SAVE, ALLOCATABLE, DIMENSION(:,:) :: rn_avevd0
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE zdf_evd( kt )
45      !!----------------------------------------------------------------------
46      !!                  ***  ROUTINE zdf_evd  ***
47      !!
48      !! ** Purpose :   Local increased the vertical eddy viscosity and diffu-
49      !!      sivity coefficients when a static instability is encountered.
50      !!
51      !! ** Method  :   avt, avm, and the 4 neighbouring avmu, avmv coefficients
52      !!      are set to avevd (namelist parameter) if the water column is
53      !!      statically unstable (i.e. if rn2 < -1.e-12 )
54      !!
55      !! ** Action  :   avt, avm, avmu, avmv updted in static instability cases
56      !!
57      !! References :   Lazar, A., these de l'universite Paris VI, France, 1997
58      !!----------------------------------------------------------------------
59      USE oce,   zavt_evd => ua , zavm_evd => va  ! (ua,va) used ua workspace
60      !
61      INTEGER, INTENT( in ) ::   kt   ! ocean time-step indexocean time step
62      !
63      INTEGER ::   ji, jj, jk   ! dummy loop indices
64      !!----------------------------------------------------------------------
65      !
66      IF( nn_timing == 1 )  CALL timing_start('zdf_evd')
67      !
68      IF( kt == nit000 ) THEN
69         IF(lwp) WRITE(numout,*)
70         IF(lwp) WRITE(numout,*) 'zdf_evd : Enhanced Vertical Diffusion (evd)'
71         IF(lwp) WRITE(numout,*) '~~~~~~~ '
72         IF(lwp) WRITE(numout,*)
73         ALLOCATE ( rn_avevd0(jpi,jpj) )
74         rn_avevd0(:,:) = rn_avevd
75      ENDIF
76
77      zavt_evd(:,:,:) = avt(:,:,:)           ! set avt prior to evd application
78
79#if defined key_traldf_c2d || key_traldf_c3d
80      IF( ln_stopack .AND. ( nn_spp_aevd > 0 ) ) THEN
81         rn_avevd0(:,:) = rn_avevd
82         CALL spp_gen(kt, rn_avevd0, nn_spp_aevd, rn_aevd_sd, jk_spp_aevd)
83      ENDIF
84#else
85      IF ( ln_stopack .AND. ( nn_spp_aevd > 0 ) ) &
86         & CALL ctl_stop( 'zdf_evd: parameter perturbation will only work with '// &
87                          'key_traldf_c2d or key_traldf_c3d')
88#endif
89
90      SELECT CASE ( nn_evdm )
91      !
92      CASE ( 1 )           ! enhance vertical eddy viscosity and diffusivity (if rn2<-1.e-12)
93         !
94         zavm_evd(:,:,:) = avm(:,:,:)           ! set avm prior to evd application
95         !
96         DO jk = 1, jpkm1
97            DO jj = 2, jpj             ! no vector opt.
98               DO ji = 2, jpi
99#if defined key_zdfkpp
100                  ! no evd mixing in the boundary layer with KPP
101                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12  .AND.  fsdepw(ji,jj,jk) > hkpp(ji,jj)  ) THEN
102#else
103                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 ) THEN
104#endif
105                     avt (ji  ,jj  ,jk) = rn_avevd0(ji,jj) * tmask(ji  ,jj  ,jk)
106                     avm (ji  ,jj  ,jk) = rn_avevd0(ji,jj) * tmask(ji  ,jj  ,jk)
107                     avmu(ji  ,jj  ,jk) = rn_avevd0(ji,jj) * umask(ji  ,jj  ,jk)
108                     avmu(ji-1,jj  ,jk) = rn_avevd0(ji,jj) * umask(ji-1,jj  ,jk)
109                     avmv(ji  ,jj  ,jk) = rn_avevd0(ji,jj) * vmask(ji  ,jj  ,jk)
110                     avmv(ji  ,jj-1,jk) = rn_avevd0(ji,jj) * vmask(ji  ,jj-1,jk)
111                  ENDIF
112               END DO
113            END DO
114         END DO
115         CALL lbc_lnk( avt , 'W', 1. )   ;   CALL lbc_lnk( avm , 'W', 1. )   ! Lateral boundary conditions
116         CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
117         !
118         zavm_evd(:,:,:) = avm(:,:,:) - zavm_evd(:,:,:)   ! change in avm due to evd
119         CALL iom_put( "avm_evd", zavm_evd )              ! output this change
120         !
121      CASE DEFAULT         ! enhance vertical eddy diffusivity only (if rn2<-1.e-12)
122         DO jk = 1, jpkm1
123!!!         WHERE( rn2(:,:,jk) <= -1.e-12 ) avt(:,:,jk) = tmask(:,:,jk) * avevd   ! agissant sur T SEUL!
124            DO jj = 1, jpj             ! loop over the whole domain (no lbc_lnk call)
125               DO ji = 1, jpi
126#if defined key_zdfkpp
127                  ! no evd mixing in the boundary layer with KPP
128                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12  .AND.  fsdepw(ji,jj,jk) > hkpp(ji,jj)  )   &
129#else
130                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 )   &
131#endif
132                     avt(ji,jj,jk) = rn_avevd0(ji,jj) * tmask(ji,jj,jk)
133               END DO
134            END DO
135         END DO
136         !
137      END SELECT
138
139      zavt_evd(:,:,:) = avt(:,:,:) - zavt_evd(:,:,:)   ! change in avt due to evd
140      CALL iom_put( "avt_evd", zavt_evd )              ! output this change
141      IF( l_trdtra ) CALL trd_tra( kt, 'TRA', jp_tem, jptra_evd, zavt_evd )
142      !
143      IF( nn_timing == 1 )  CALL timing_stop('zdf_evd')
144      !
145   END SUBROUTINE zdf_evd
146
147   !!======================================================================
148END MODULE zdfevd
Note: See TracBrowser for help on using the repository browser.