New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsms.F90 in branches/UKMO/dev_merge_2017_CICE_interface/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/UKMO/dev_merge_2017_CICE_interface/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsms.F90 @ 9499

Last change on this file since 9499 was 9499, checked in by davestorkey, 6 years ago

branches/UKMO/dev_merge_2017_CICE_interface : clear SVN keywords.

File size: 25.1 KB
Line 
1MODULE p4zsms
2   !!======================================================================
3   !!                         ***  MODULE p4zsms  ***
4   !! TOP :   PISCES Source Minus Sink manager
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9   !!   p4z_sms        : Time loop of passive tracers sms
10   !!----------------------------------------------------------------------
11   USE oce_trc         ! shared variables between ocean and passive tracers
12   USE trc             ! passive tracers common variables
13   USE trcdta          !
14   USE sms_pisces      ! PISCES Source Minus Sink variables
15   USE p4zbio          ! Biological model
16   USE p4zche          ! Chemical model
17   USE p4zlys          ! Calcite saturation
18   USE p4zflx          ! Gas exchange
19   USE p4zsbc          ! External source of nutrients
20   USE p4zsed          ! Sedimentation
21   USE p4zint          ! time interpolation
22   USE p4zrem          ! remineralisation
23   USE iom             ! I/O manager
24   USE trd_oce         ! Ocean trends variables
25   USE trdtrc          ! TOP trends variables
26   USE sedmodel        ! Sediment model
27   USE prtctl_trc      ! print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sms_init   ! called in p4zsms.F90
33   PUBLIC   p4z_sms        ! called in p4zsms.F90
34
35   INTEGER ::    numco2, numnut, numnit      ! logical unit for co2 budget
36   REAL(wp) ::   alkbudget, no3budget, silbudget, ferbudget, po4budget
37   REAL(wp) ::   xfact1, xfact2, xfact3
38
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xnegtr     ! Array used to indicate negative tracer values
40
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
43   !! $Id$
44   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE p4z_sms( kt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_sms  ***
51      !!
52      !! ** Purpose :   Managment of the call to Biological sources and sinks
53      !!              routines of PISCES bio-model
54      !!
55      !! ** Method  : - at each new day ...
56      !!              - several calls of bio and sed ???
57      !!              - ...
58      !!---------------------------------------------------------------------
59      !
60      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
61      !!
62      INTEGER ::   ji, jj, jk, jnt, jn, jl
63      REAL(wp) ::  ztra
64      CHARACTER (len=25) :: charout
65      !!---------------------------------------------------------------------
66      !
67      IF( ln_timing )   CALL timing_start('p4z_sms')
68      !
69      IF( kt == nittrc000 ) THEN
70        !
71        ALLOCATE( xnegtr(jpi,jpj,jpk) )
72        !
73        CALL p4z_che                              ! initialize the chemical constants
74        !
75        IF( .NOT. ln_rsttr ) THEN  ;   CALL ahini_for_at(hi)   !  set PH at kt=nit000
76        ELSE                       ;   CALL p4z_rst( nittrc000, 'READ' )  !* read or initialize all required fields
77        ENDIF
78        !
79      ENDIF
80      !
81      IF( ln_pisdmp .AND. MOD( kt - nn_dttrc, nn_pisdmp ) == 0 )   CALL p4z_dmp( kt )      ! Relaxation of some tracers
82      !
83      rfact = r2dttrc
84      !
85      IF( ( ln_top_euler .AND. kt == nittrc000 )  .OR. ( .NOT.ln_top_euler .AND. kt <= nittrc000 + nn_dttrc ) ) THEN
86         rfactr  = 1. / rfact
87         rfact2  = rfact / REAL( nrdttrc, wp )
88         rfact2r = 1. / rfact2
89         xstep = rfact2 / rday         ! Time step duration for biology
90         IF(lwp) WRITE(numout,*) 
91         IF(lwp) WRITE(numout,*) '    Passive Tracer  time step    rfact  = ', rfact, ' rdt = ', rdt
92         IF(lwp) write(numout,*) '    PISCES  Biology time step    rfact2 = ', rfact2
93         IF(lwp) WRITE(numout,*)
94      ENDIF
95
96      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN
97         DO jn = jp_pcs0, jp_pcs1              !   SMS on tracer without Asselin time-filter
98            trb(:,:,:,jn) = trn(:,:,:,jn)
99         END DO
100      ENDIF
101      !
102      IF( ndayflxtr /= nday_year ) THEN      ! New days
103         !
104         ndayflxtr = nday_year
105
106         IF(lwp) write(numout,*)
107         IF(lwp) write(numout,*) ' New chemical constants and various rates for biogeochemistry at new day : ', nday_year
108         IF(lwp) write(numout,*) '~~~~~~'
109
110         CALL p4z_che              ! computation of chemical constants
111         CALL p4z_int( kt )        ! computation of various rates for biogeochemistry
112         !
113      ENDIF
114
115      IF( ll_sbc ) CALL p4z_sbc( kt )   ! external sources of nutrients
116
117      DO jnt = 1, nrdttrc          ! Potential time splitting if requested
118         !
119         CALL p4z_bio( kt, jnt )   ! Biology
120         CALL p4z_lys( kt, jnt )   ! Compute CaCO3 saturation
121         CALL p4z_sed( kt, jnt )   ! Surface and Bottom boundary conditions
122         CALL p4z_flx( kt, jnt )   ! Compute surface fluxes
123         !
124         xnegtr(:,:,:) = 1.e0
125         DO jn = jp_pcs0, jp_pcs1
126            DO jk = 1, jpk
127               DO jj = 1, jpj
128                  DO ji = 1, jpi
129                     IF( ( trb(ji,jj,jk,jn) + tra(ji,jj,jk,jn) ) < 0.e0 ) THEN
130                        ztra             = ABS( trb(ji,jj,jk,jn) ) / ( ABS( tra(ji,jj,jk,jn) ) + rtrn )
131                        xnegtr(ji,jj,jk) = MIN( xnegtr(ji,jj,jk),  ztra )
132                     ENDIF
133                 END DO
134               END DO
135            END DO
136         END DO
137         !                                ! where at least 1 tracer concentration becomes negative
138         !                                !
139         DO jn = jp_pcs0, jp_pcs1
140           trb(:,:,:,jn) = trb(:,:,:,jn) + xnegtr(:,:,:) * tra(:,:,:,jn)
141         END DO
142        !
143         DO jn = jp_pcs0, jp_pcs1
144            tra(:,:,:,jn) = 0._wp
145         END DO
146         !
147         IF( ln_top_euler ) THEN
148            DO jn = jp_pcs0, jp_pcs1
149               trn(:,:,:,jn) = trb(:,:,:,jn)
150            END DO
151         ENDIF
152      END DO
153
154      !
155      IF( l_trdtrc ) THEN
156         DO jn = jp_pcs0, jp_pcs1
157           CALL trd_trc( tra(:,:,:,jn), jn, jptra_sms, kt )   ! save trends
158         END DO
159      END IF
160      !
161      IF( lk_sed ) THEN 
162         !
163         CALL sed_model( kt )     !  Main program of Sediment model
164         !
165      ENDIF
166      !
167      IF( lrst_trc )  CALL p4z_rst( kt, 'WRITE' )  !* Write PISCES informations in restart file
168      !
169
170      IF( lk_iomput .OR. ln_check_mass )  CALL p4z_chk_mass( kt )    ! Mass conservation checking
171
172      IF( lwm .AND. kt == nittrc000    )  CALL FLUSH( numonp )       ! flush output namelist PISCES
173      !
174      IF( ln_timing )  CALL timing_stop('p4z_sms')
175      !
176   END SUBROUTINE p4z_sms
177
178
179   SUBROUTINE p4z_sms_init
180      !!----------------------------------------------------------------------
181      !!                     ***  p4z_sms_init  *** 
182      !!
183      !! ** Purpose :   read PISCES namelist
184      !!
185      !! ** input   :   file 'namelist.trc.s' containing the following
186      !!             namelist: natext, natbio, natsms
187      !!----------------------------------------------------------------------
188      INTEGER :: ios                 ! Local integer output status for namelist read
189      !!
190      NAMELIST/nampisbio/ nrdttrc, wsbio, xkmort, ferat3, wsbio2, wsbio2max, wsbio2scale,    &
191         &                   niter1max, niter2max, wfep, ldocp, ldocz, lthet,  &
192         &                   no3rat3, po4rat3
193         !
194      NAMELIST/nampisdmp/ ln_pisdmp, nn_pisdmp
195      NAMELIST/nampismass/ ln_check_mass
196      !!----------------------------------------------------------------------
197      !
198      IF(lwp) THEN
199         WRITE(numout,*)
200         WRITE(numout,*) 'p4z_sms_init : PISCES initialization'
201         WRITE(numout,*) '~~~~~~~~~~~~'
202      ENDIF
203
204      REWIND( numnatp_ref )              ! Namelist nampisbio in reference namelist : Pisces variables
205      READ  ( numnatp_ref, nampisbio, IOSTAT = ios, ERR = 901)
206901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisbio in reference namelist', lwp )
207      REWIND( numnatp_cfg )              ! Namelist nampisbio in configuration namelist : Pisces variables
208      READ  ( numnatp_cfg, nampisbio, IOSTAT = ios, ERR = 902 )
209902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisbio in configuration namelist', lwp )
210      IF(lwm) WRITE( numonp, nampisbio )
211      !
212      IF(lwp) THEN                         ! control print
213         WRITE(numout,*) '   Namelist : nampisbio'
214         WRITE(numout,*) '      frequency for the biology                 nrdttrc     =', nrdttrc
215         WRITE(numout,*) '      POC sinking speed                         wsbio       =', wsbio
216         WRITE(numout,*) '      half saturation constant for mortality    xkmort      =', xkmort 
217         IF( ln_p5z ) THEN
218            WRITE(numout,*) '      N/C in zooplankton                        no3rat3     =', no3rat3
219            WRITE(numout,*) '      P/C in zooplankton                        po4rat3     =', po4rat3
220         ENDIF
221         WRITE(numout,*) '      Fe/C in zooplankton                       ferat3      =', ferat3
222         WRITE(numout,*) '      Big particles sinking speed               wsbio2      =', wsbio2
223         WRITE(numout,*) '      Big particles maximum sinking speed       wsbio2max   =', wsbio2max
224         WRITE(numout,*) '      Big particles sinking speed length scale  wsbio2scale =', wsbio2scale
225         WRITE(numout,*) '      Maximum number of iterations for POC      niter1max   =', niter1max
226         WRITE(numout,*) '      Maximum number of iterations for GOC      niter2max   =', niter2max
227         IF( ln_ligand ) THEN
228            WRITE(numout,*) '      FeP sinking speed                              wfep   =', wfep
229            IF( ln_p4z ) THEN
230               WRITE(numout,*) '      Phyto ligand production per unit doc           ldocp  =', ldocp
231               WRITE(numout,*) '      Zoo ligand production per unit doc             ldocz  =', ldocz
232               WRITE(numout,*) '      Proportional loss of ligands due to Fe uptake  lthet  =', lthet
233            ENDIF
234         ENDIF
235      ENDIF
236
237
238      REWIND( numnatp_ref )              ! Namelist nampisdmp in reference namelist : Pisces damping
239      READ  ( numnatp_ref, nampisdmp, IOSTAT = ios, ERR = 905)
240905   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisdmp in reference namelist', lwp )
241      REWIND( numnatp_cfg )              ! Namelist nampisdmp in configuration namelist : Pisces damping
242      READ  ( numnatp_cfg, nampisdmp, IOSTAT = ios, ERR = 906 )
243906   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisdmp in configuration namelist', lwp )
244      IF(lwm) WRITE( numonp, nampisdmp )
245      !
246      IF(lwp) THEN                         ! control print
247         WRITE(numout,*)
248         WRITE(numout,*) '   Namelist : nampisdmp --- relaxation to GLODAP'
249         WRITE(numout,*) '      Relaxation of tracer to glodap mean value   ln_pisdmp =', ln_pisdmp
250         WRITE(numout,*) '      Frequency of Relaxation                     nn_pisdmp =', nn_pisdmp
251      ENDIF
252
253      REWIND( numnatp_ref )              ! Namelist nampismass in reference namelist : Pisces mass conservation check
254      READ  ( numnatp_ref, nampismass, IOSTAT = ios, ERR = 907)
255907   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampismass in reference namelist', lwp )
256      REWIND( numnatp_cfg )              ! Namelist nampismass in configuration namelist : Pisces mass conservation check
257      READ  ( numnatp_cfg, nampismass, IOSTAT = ios, ERR = 908 )
258908   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampismass in configuration namelist', lwp )
259      IF(lwm) WRITE( numonp, nampismass )
260
261      IF(lwp) THEN                         ! control print
262         WRITE(numout,*)
263         WRITE(numout,*) '   Namelist : nampismass  --- mass conservation checking'
264         WRITE(numout,*) '      Flag to check mass conservation of NO3/Si/TALK   ln_check_mass = ', ln_check_mass
265      ENDIF
266      !
267   END SUBROUTINE p4z_sms_init
268
269
270   SUBROUTINE p4z_rst( kt, cdrw )
271      !!---------------------------------------------------------------------
272      !!                   ***  ROUTINE p4z_rst  ***
273      !!
274      !!  ** Purpose : Read or write variables in restart file:
275      !!
276      !!  WRITE(READ) mode:
277      !!       kt        : number of time step since the begining of the experiment at the
278      !!                   end of the current(previous) run
279      !!---------------------------------------------------------------------
280      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
281      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
282      !!---------------------------------------------------------------------
283      !
284      IF( TRIM(cdrw) == 'READ' ) THEN
285         !
286         IF(lwp) WRITE(numout,*)
287         IF(lwp) WRITE(numout,*) ' p4z_rst : Read specific variables from pisces model '
288         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
289         !
290         IF( iom_varid( numrtr, 'PH', ldstop = .FALSE. ) > 0 ) THEN
291            CALL iom_get( numrtr, jpdom_autoglo, 'PH' , hi(:,:,:)  )
292         ELSE
293            CALL ahini_for_at(hi)
294         ENDIF
295         CALL iom_get( numrtr, jpdom_autoglo, 'Silicalim', xksi(:,:) )
296         IF( iom_varid( numrtr, 'Silicamax', ldstop = .FALSE. ) > 0 ) THEN
297            CALL iom_get( numrtr, jpdom_autoglo, 'Silicamax' , xksimax(:,:)  )
298         ELSE
299            xksimax(:,:) = xksi(:,:)
300         ENDIF
301         !
302         IF( iom_varid( numrtr, 'tcflxcum', ldstop = .FALSE. ) > 0 ) THEN  ! cumulative total flux of carbon
303            CALL iom_get( numrtr, 'tcflxcum' , t_oce_co2_flx_cum  )
304         ELSE
305            t_oce_co2_flx_cum = 0._wp
306         ENDIF
307         !
308         IF( ln_p5z ) THEN
309            IF( iom_varid( numrtr, 'sized', ldstop = .FALSE. ) > 0 ) THEN
310               CALL iom_get( numrtr, jpdom_autoglo, 'sizep' , sized(:,:,:)  )
311               CALL iom_get( numrtr, jpdom_autoglo, 'sizen' , sized(:,:,:)  )
312               CALL iom_get( numrtr, jpdom_autoglo, 'sized' , sized(:,:,:)  )
313            ELSE
314               sizep(:,:,:) = 1.
315               sizen(:,:,:) = 1.
316               sized(:,:,:) = 1.
317            ENDIF
318        ENDIF
319        !
320      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
321         IF( kt == nitrst ) THEN
322            IF(lwp) WRITE(numout,*)
323            IF(lwp) WRITE(numout,*) 'p4z_rst : write pisces restart file  kt =', kt
324            IF(lwp) WRITE(numout,*) '~~~~~~~'
325         ENDIF
326         CALL iom_rstput( kt, nitrst, numrtw, 'PH', hi(:,:,:) )
327         CALL iom_rstput( kt, nitrst, numrtw, 'Silicalim', xksi(:,:) )
328         CALL iom_rstput( kt, nitrst, numrtw, 'Silicamax', xksimax(:,:) )
329         CALL iom_rstput( kt, nitrst, numrtw, 'tcflxcum', t_oce_co2_flx_cum )
330         IF( ln_p5z ) THEN
331            CALL iom_rstput( kt, nitrst, numrtw, 'sizep', sized(:,:,:) )
332            CALL iom_rstput( kt, nitrst, numrtw, 'sizen', sized(:,:,:) )
333            CALL iom_rstput( kt, nitrst, numrtw, 'sized', sized(:,:,:) )
334         ENDIF
335      ENDIF
336      !
337   END SUBROUTINE p4z_rst
338
339
340   SUBROUTINE p4z_dmp( kt )
341      !!----------------------------------------------------------------------
342      !!                    ***  p4z_dmp  ***
343      !!
344      !! ** purpose  : Relaxation of some tracers
345      !!----------------------------------------------------------------------
346      !
347      INTEGER, INTENT( in )  ::     kt ! time step
348      !
349      REAL(wp) ::  alkmean = 2426.     ! mean value of alkalinity ( Glodap ; for Goyet 2391. )
350      REAL(wp) ::  po4mean = 2.165     ! mean value of phosphates
351      REAL(wp) ::  no3mean = 30.90     ! mean value of nitrate
352      REAL(wp) ::  silmean = 91.51     ! mean value of silicate
353      !
354      REAL(wp) :: zarea, zalksumn, zpo4sumn, zno3sumn, zsilsumn
355      REAL(wp) :: zalksumb, zpo4sumb, zno3sumb, zsilsumb
356      !!---------------------------------------------------------------------
357
358      IF(lwp)  WRITE(numout,*)
359      IF(lwp)  WRITE(numout,*) ' p4z_dmp : Restoring of nutrients at time-step kt = ', kt
360      IF(lwp)  WRITE(numout,*)
361
362      IF( cn_cfg == "orca" .AND. .NOT. lk_c1d ) THEN      ! ORCA configuration (not 1D) !
363         !                                                ! --------------------------- !
364         ! set total alkalinity, phosphate, nitrate & silicate
365         zarea          = 1._wp / glob_sum( cvol(:,:,:) ) * 1e6             
366
367         zalksumn = glob_sum( trn(:,:,:,jptal) * cvol(:,:,:)  ) * zarea
368         zpo4sumn = glob_sum( trn(:,:,:,jppo4) * cvol(:,:,:)  ) * zarea * po4r
369         zno3sumn = glob_sum( trn(:,:,:,jpno3) * cvol(:,:,:)  ) * zarea * rno3
370         zsilsumn = glob_sum( trn(:,:,:,jpsil) * cvol(:,:,:)  ) * zarea
371 
372         IF(lwp) WRITE(numout,*) '       TALKN mean : ', zalksumn
373         trn(:,:,:,jptal) = trn(:,:,:,jptal) * alkmean / zalksumn
374
375         IF(lwp) WRITE(numout,*) '       PO4N  mean : ', zpo4sumn
376         trn(:,:,:,jppo4) = trn(:,:,:,jppo4) * po4mean / zpo4sumn
377
378         IF(lwp) WRITE(numout,*) '       NO3N  mean : ', zno3sumn
379         trn(:,:,:,jpno3) = trn(:,:,:,jpno3) * no3mean / zno3sumn
380
381         IF(lwp) WRITE(numout,*) '       SiO3N mean : ', zsilsumn
382         trn(:,:,:,jpsil) = MIN( 400.e-6,trn(:,:,:,jpsil) * silmean / zsilsumn )
383         !
384         !
385         IF( .NOT. ln_top_euler ) THEN
386            zalksumb = glob_sum( trb(:,:,:,jptal) * cvol(:,:,:)  ) * zarea
387            zpo4sumb = glob_sum( trb(:,:,:,jppo4) * cvol(:,:,:)  ) * zarea * po4r
388            zno3sumb = glob_sum( trb(:,:,:,jpno3) * cvol(:,:,:)  ) * zarea * rno3
389            zsilsumb = glob_sum( trb(:,:,:,jpsil) * cvol(:,:,:)  ) * zarea
390 
391            IF(lwp) WRITE(numout,*) ' '
392            IF(lwp) WRITE(numout,*) '       TALKB mean : ', zalksumb
393            trb(:,:,:,jptal) = trb(:,:,:,jptal) * alkmean / zalksumb
394
395            IF(lwp) WRITE(numout,*) '       PO4B  mean : ', zpo4sumb
396            trb(:,:,:,jppo4) = trb(:,:,:,jppo4) * po4mean / zpo4sumb
397
398            IF(lwp) WRITE(numout,*) '       NO3B  mean : ', zno3sumb
399            trb(:,:,:,jpno3) = trb(:,:,:,jpno3) * no3mean / zno3sumb
400
401            IF(lwp) WRITE(numout,*) '       SiO3B mean : ', zsilsumb
402            trb(:,:,:,jpsil) = MIN( 400.e-6,trb(:,:,:,jpsil) * silmean / zsilsumb )
403        ENDIF
404        !
405      ENDIF
406        !
407   END SUBROUTINE p4z_dmp
408
409
410   SUBROUTINE p4z_chk_mass( kt )
411      !!----------------------------------------------------------------------
412      !!                  ***  ROUTINE p4z_chk_mass  ***
413      !!
414      !! ** Purpose :  Mass conservation check
415      !!
416      !!---------------------------------------------------------------------
417      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
418      REAL(wp)             ::  zrdenittot, zsdenittot, znitrpottot
419      CHARACTER(LEN=100)   ::   cltxt
420      INTEGER :: jk
421      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwork
422      !!----------------------------------------------------------------------
423      !
424      IF( kt == nittrc000 ) THEN
425         xfact1 = rfact2r * 12. / 1.e15 * ryyss    ! conversion molC/kt --> PgC/yr
426         xfact2 = 1.e+3 * rno3 * 14. / 1.e12 * ryyss   ! conversion molC/l/s ----> TgN/m3/yr
427         xfact3 = 1.e+3 * rfact2r * rno3   ! conversion molC/l/kt ----> molN/m3/s
428         IF( ln_check_mass .AND. lwp) THEN      !   Open budget file of NO3, ALK, Si, Fer
429            CALL ctl_opn( numco2, 'carbon.budget'  , 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
430            CALL ctl_opn( numnut, 'nutrient.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
431            CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
432            cltxt='time-step   Alkalinity        Nitrate        Phosphorus         Silicate           Iron'
433            IF( lwp ) WRITE(numnut,*)  TRIM(cltxt)
434            IF( lwp ) WRITE(numnut,*) 
435         ENDIF
436      ENDIF
437
438      IF( iom_use( "pno3tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
439         !   Compute the budget of NO3, ALK, Si, Fer
440         IF( ln_p4z ) THEN
441            zwork(:,:,:) =    trn(:,:,:,jpno3) + trn(:,:,:,jpnh4)                      &
442               &          +   trn(:,:,:,jpphy) + trn(:,:,:,jpdia)                      &
443               &          +   trn(:,:,:,jppoc) + trn(:,:,:,jpgoc)  + trn(:,:,:,jpdoc)  &       
444               &          +   trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) 
445        ELSE
446            zwork(:,:,:) =    trn(:,:,:,jpno3) + trn(:,:,:,jpnh4) + trn(:,:,:,jpnph)   &
447               &          +   trn(:,:,:,jpndi) + trn(:,:,:,jpnpi)                      & 
448               &          +   trn(:,:,:,jppon) + trn(:,:,:,jpgon) + trn(:,:,:,jpdon)   &
449               &          + ( trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) ) * no3rat3 
450        ENDIF
451        !
452        no3budget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  ) 
453        no3budget = no3budget / areatot
454        CALL iom_put( "pno3tot", no3budget )
455      ENDIF
456      !
457      IF( iom_use( "ppo4tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
458         IF( ln_p4z ) THEN
459            zwork(:,:,:) =    trn(:,:,:,jppo4)                                         &
460               &          +   trn(:,:,:,jpphy) + trn(:,:,:,jpdia)                      &
461               &          +   trn(:,:,:,jppoc) + trn(:,:,:,jpgoc)  + trn(:,:,:,jpdoc)  &       
462               &          +   trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) 
463        ELSE
464            zwork(:,:,:) =    trn(:,:,:,jppo4) + trn(:,:,:,jppph)                      &
465               &          +   trn(:,:,:,jppdi) + trn(:,:,:,jpppi)                      & 
466               &          +   trn(:,:,:,jppop) + trn(:,:,:,jpgop) + trn(:,:,:,jpdop)   &
467               &          + ( trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) ) * po4rat3 
468        ENDIF
469        !
470        po4budget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  ) 
471        po4budget = po4budget / areatot
472        CALL iom_put( "ppo4tot", po4budget )
473      ENDIF
474      !
475      IF( iom_use( "psiltot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
476         zwork(:,:,:) =  trn(:,:,:,jpsil) + trn(:,:,:,jpgsi) + trn(:,:,:,jpdsi) 
477         !
478         silbudget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  ) 
479         silbudget = silbudget / areatot
480         CALL iom_put( "psiltot", silbudget )
481      ENDIF
482      !
483      IF( iom_use( "palktot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
484         zwork(:,:,:) =  trn(:,:,:,jpno3) * rno3 + trn(:,:,:,jptal) + trn(:,:,:,jpcal) * 2.             
485         !
486         alkbudget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  )         !
487         alkbudget = alkbudget / areatot
488         CALL iom_put( "palktot", alkbudget )
489      ENDIF
490      !
491      IF( iom_use( "pfertot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
492         zwork(:,:,:) =   trn(:,:,:,jpfer) + trn(:,:,:,jpnfe) + trn(:,:,:,jpdfe)   &
493            &         +   trn(:,:,:,jpbfe) + trn(:,:,:,jpsfe)                      &
494            &         + ( trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) )  * ferat3   
495         IF( ln_ligand)  zwork(:,:,:) = zwork(:,:,:) + trn(:,:,:,jpfep)               
496         !
497         ferbudget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  ) 
498         ferbudget = ferbudget / areatot
499         CALL iom_put( "pfertot", ferbudget )
500      ENDIF
501      !
502      ! Global budget of N SMS : denitrification in the water column and in the sediment
503      !                          nitrogen fixation by the diazotrophs
504      ! --------------------------------------------------------------------------------
505      IF( iom_use( "tnfix" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
506         znitrpottot  = glob_sum ( nitrpot(:,:,:) * nitrfix * cvol(:,:,:) )
507         CALL iom_put( "tnfix"  , znitrpottot * xfact3 )  ! Global  nitrogen fixation molC/l  to molN/m3
508      ENDIF
509      !
510      IF( iom_use( "tdenit" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
511         zrdenittot = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
512         zsdenittot = glob_sum ( sdenit(:,:) * e1e2t(:,:) * tmask(:,:,1) )
513         CALL iom_put( "tdenit" , ( zrdenittot + zsdenittot ) * xfact3 )  ! Total denitrification molC/l to molN/m3
514      ENDIF
515      !
516      IF( ln_check_mass .AND. kt == nitend ) THEN   ! Compute the budget of NO3, ALK, Si, Fer
517         t_atm_co2_flx  = t_atm_co2_flx / glob_sum( e1e2t(:,:) )
518         t_oce_co2_flx  = t_oce_co2_flx         * xfact1 * (-1 )
519         tpp            = tpp           * 1000. * xfact1
520         t_oce_co2_exp  = t_oce_co2_exp * 1000. * xfact1
521         IF( lwp ) WRITE(numco2,9000) ndastp, t_atm_co2_flx, t_oce_co2_flx, tpp, t_oce_co2_exp
522         IF( lwp ) WRITE(numnut,9100) ndastp, alkbudget        * 1.e+06, &
523             &                                no3budget * rno3 * 1.e+06, &
524             &                                po4budget * po4r * 1.e+06, &
525             &                                silbudget        * 1.e+06, &
526             &                                ferbudget        * 1.e+09
527         !
528         IF( lwp ) WRITE(numnit,9200) ndastp, znitrpottot * xfact2  , &
529            &                             zrdenittot  * xfact2  , &
530            &                             zsdenittot  * xfact2
531      ENDIF
532      !
533 9000  FORMAT(i8,f10.5,e18.10,f10.5,f10.5)
534 9100  FORMAT(i8,5e18.10)
535 9200  FORMAT(i8,3f10.5)
536       !
537   END SUBROUTINE p4z_chk_mass
538
539   !!======================================================================
540END MODULE p4zsms 
Note: See TracBrowser for help on using the repository browser.