New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtatsd.f90 in branches/UKMO/dev_merge_2017_CICE_interface/NEMOGCM/TOOLS/DOMAINcfg/src – NEMO

source: branches/UKMO/dev_merge_2017_CICE_interface/NEMOGCM/TOOLS/DOMAINcfg/src/dtatsd.f90 @ 9499

Last change on this file since 9499 was 9499, checked in by davestorkey, 6 years ago

branches/UKMO/dev_merge_2017_CICE_interface : clear SVN keywords.

File size: 13.5 KB
Line 
1MODULE dtatsd
2   !!======================================================================
3   !!                     ***  MODULE  dtatsd  ***
4   !! Ocean data  :  read ocean Temperature & Salinity Data from gridded data
5   !!======================================================================
6   !! History :  OPA  ! 1991-03  ()  Original code
7   !!             -   ! 1992-07  (M. Imbard)
8   !!            8.0  ! 1999-10  (M.A. Foujols, M. Imbard)  NetCDF FORMAT
9   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
10   !!            3.3  ! 2010-10  (C. Bricaud, S. Masson)  use of fldread
11   !!            3.4  ! 2010-11  (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   dta_tsd      : read and time interpolated ocean Temperature & Salinity Data
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers
18   USE dom_oce         ! ocean space and time domain
19   USE fldread         ! read input fields
20   USE in_out_manager  ! I/O manager
21   USE phycst          ! physical constants
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   dta_tsd_init   ! called by opa.F90
30   PUBLIC   dta_tsd        ! called by istate.F90 and tradmp.90
31
32   LOGICAL , PUBLIC ::   ln_tsd_init      !: T & S data flag
33   LOGICAL , PUBLIC ::   ln_tsd_tradmp    !: internal damping toward input data flag
34
35   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tsd   ! structure of input SST (file informations, fields read)
36
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE dta_tsd_init( ld_tradmp )
45      !!----------------------------------------------------------------------
46      !!                   ***  ROUTINE dta_tsd_init  ***
47      !!                   
48      !! ** Purpose :   initialisation of T & S input data
49      !!
50      !! ** Method  : - Read namtsd namelist
51      !!              - allocates T & S data structure
52      !!----------------------------------------------------------------------
53      LOGICAL, INTENT(in), OPTIONAL ::   ld_tradmp   ! force the initialization when tradp is used
54      !
55      INTEGER ::   ierr0, ierr1, ierr2, ierr3   ! temporary integers
56      !
57      CHARACTER(len=100)            ::   cn_dir          ! Root directory for location of ssr files
58      TYPE(FLD_N), DIMENSION( jpts) ::   slf_i           ! array of namelist informations on the fields to read
59      TYPE(FLD_N)                   ::   sn_tem, sn_sal
60      !!
61      NAMELIST/namtsd/   ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal
62      INTEGER  ::   ios
63      !!----------------------------------------------------------------------
64      !
65      IF( nn_timing == 1 )  CALL timing_start('dta_tsd_init')
66      !
67      !  Initialisation
68      ierr0 = 0  ;  ierr1 = 0  ;  ierr2 = 0  ;  ierr3 = 0
69      !
70      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
71      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
72901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in reference namelist', lwp )
73
74      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
75      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
76902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in configuration namelist', lwp )
77      IF(lwm) WRITE ( numond, namtsd )
78
79      IF( PRESENT( ld_tradmp ) )   ln_tsd_tradmp = .TRUE.     ! forces the initialization when tradmp is used
80     
81      IF(lwp) THEN                  ! control print
82         WRITE(numout,*)
83         WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data '
84         WRITE(numout,*) '~~~~~~~~~~~~ '
85         WRITE(numout,*) '   Namelist namtsd'
86         WRITE(numout,*) '      Initialisation of ocean T & S with T &S input data   ln_tsd_init   = ', ln_tsd_init
87         WRITE(numout,*) '      damping of ocean T & S toward T &S input data        ln_tsd_tradmp = ', ln_tsd_tradmp
88         WRITE(numout,*)
89         IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN
90            WRITE(numout,*)
91            WRITE(numout,*) '   T & S data not used'
92         ENDIF
93      ENDIF
94      !
95      IF( ln_rstart .AND. ln_tsd_init ) THEN
96         CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ',   &
97            &           'we keep the restart T & S values and set ln_tsd_init to FALSE' )
98         ln_tsd_init = .FALSE.
99      ENDIF
100      !
101      !                             ! allocate the arrays (if necessary)
102      IF(  ln_tsd_init .OR. ln_tsd_tradmp  ) THEN
103         !
104         ALLOCATE( sf_tsd(jpts), STAT=ierr0 )
105         IF( ierr0 > 0 ) THEN
106            CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' )   ;   RETURN
107         ENDIF
108         !
109                                ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
110         IF( sn_tem%ln_tint )   ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
111                                ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
112         IF( sn_sal%ln_tint )   ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
113         !
114         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
115            CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' )   ;   RETURN
116         ENDIF
117         !                         ! fill sf_tsd with sn_tem & sn_sal and control print
118         slf_i(jp_tem) = sn_tem   ;   slf_i(jp_sal) = sn_sal
119         CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' )
120         !
121      ENDIF
122      !
123      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd_init')
124      !
125   END SUBROUTINE dta_tsd_init
126
127
128   SUBROUTINE dta_tsd( kt, ptsd )
129      !!----------------------------------------------------------------------
130      !!                   ***  ROUTINE dta_tsd  ***
131      !!                   
132      !! ** Purpose :   provides T and S data at kt
133      !!
134      !! ** Method  : - call fldread routine
135      !!              - ORCA_R2: add some hand made alteration to read data 
136      !!              - 'key_orca_lev10' interpolates on 10 times more levels
137      !!              - s- or mixed z-s coordinate: vertical interpolation on model mesh
138      !!              - ln_tsd_tradmp=F: deallocates the T-S data structure
139      !!                as T-S data are no are used
140      !!
141      !! ** Action  :   ptsd   T-S data on medl mesh and interpolated at time-step kt
142      !!----------------------------------------------------------------------
143      INTEGER                              , INTENT(in   ) ::   kt     ! ocean time-step
144      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(  out) ::   ptsd   ! T & S data
145      !
146      INTEGER ::   ji, jj, jk, jl, jkk   ! dummy loop indicies
147      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1   ! local integers
148      REAL(wp)::   zl, zi
149      REAL(wp), POINTER, DIMENSION(:) ::  ztp, zsp   ! 1D workspace
150      !!----------------------------------------------------------------------
151      !
152      IF( nn_timing == 1 )  CALL timing_start('dta_tsd')
153      !
154      CALL fld_read( kt, 1, sf_tsd )      !==   read T & S data at kt time step   ==!
155      !
156      !
157      !                                   !==   ORCA_R2 configuration and T & S damping   ==!
158      IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN    ! some hand made alterations
159         !
160         ij0 = 101   ;   ij1 = 109                       ! Reduced T & S in the Alboran Sea
161         ii0 = 141   ;   ii1 = 155
162         DO jj = mj0(ij0), mj1(ij1)
163            DO ji = mi0(ii0), mi1(ii1)
164               sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp
165               sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp
166               sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp
167               !
168               sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp
169               sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp
170               sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp
171               sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp
172            END DO
173         END DO
174         ij0 =  87   ;   ij1 =  96                          ! Reduced temperature in Red Sea
175         ii0 = 148   ;   ii1 = 160
176         sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) ,  4:10 ) = 7.0_wp
177         sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp
178         sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp
179      ENDIF
180      !
181      ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:)    ! NO mask
182      ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) 
183      !
184      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
185         !
186         CALL wrk_alloc( jpk, ztp, zsp )
187         !
188         IF( kt == nit000 .AND. lwp )THEN
189            WRITE(numout,*)
190            WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh'
191         ENDIF
192         !
193         DO jj = 1, jpj                         ! vertical interpolation of T & S
194            DO ji = 1, jpi
195               DO jk = 1, jpk                        ! determines the intepolated T-S profiles at each (i,j) points
196                  zl = gdept_0(ji,jj,jk)
197                  IF(     zl < gdept_1d(1  ) ) THEN          ! above the first level of data
198                     ztp(jk) =  ptsd(ji,jj,1    ,jp_tem)
199                     zsp(jk) =  ptsd(ji,jj,1    ,jp_sal)
200                  ELSEIF( zl > gdept_1d(jpk) ) THEN          ! below the last level of data
201                     ztp(jk) =  ptsd(ji,jj,jpkm1,jp_tem)
202                     zsp(jk) =  ptsd(ji,jj,jpkm1,jp_sal)
203                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
204                     DO jkk = 1, jpkm1                                  ! when  gdept(jkk) < zl < gdept(jkk+1)
205                        IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
206                           zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
207                           ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi 
208                           zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi
209                        ENDIF
210                     END DO
211                  ENDIF
212               END DO
213               DO jk = 1, jpkm1
214                  ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk)     ! mask required for mixed zps-s-coord
215                  ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk)
216               END DO
217               ptsd(ji,jj,jpk,jp_tem) = 0._wp
218               ptsd(ji,jj,jpk,jp_sal) = 0._wp
219            END DO
220         END DO
221         !
222         CALL wrk_dealloc( jpk, ztp, zsp )
223         !
224      ELSE                                !==   z- or zps- coordinate   ==!
225         !                             
226         ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:)    ! Mask
227         ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:)
228         !
229         IF( ln_zps ) THEN                      ! zps-coordinate (partial steps) interpolation at the last ocean level
230            DO jj = 1, jpj
231               DO ji = 1, jpi
232                  ik = mbkt(ji,jj) 
233                  IF( ik > 1 ) THEN
234                     zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
235                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem)
236                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal)
237                  ENDIF
238                  ik = mikt(ji,jj)
239                  IF( ik > 1 ) THEN
240                     zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) 
241                     ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem)
242                     ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal)
243                  END IF
244               END DO
245            END DO
246         ENDIF
247         !
248      ENDIF
249      !
250      IF( .NOT.ln_tsd_tradmp ) THEN                   !==   deallocate T & S structure   ==!
251         !                                              (data used only for initialisation)
252         IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run'
253                                        DEALLOCATE( sf_tsd(jp_tem)%fnow )     ! T arrays in the structure
254         IF( sf_tsd(jp_tem)%ln_tint )   DEALLOCATE( sf_tsd(jp_tem)%fdta )
255                                        DEALLOCATE( sf_tsd(jp_sal)%fnow )     ! S arrays in the structure
256         IF( sf_tsd(jp_sal)%ln_tint )   DEALLOCATE( sf_tsd(jp_sal)%fdta )
257                                        DEALLOCATE( sf_tsd              )     ! the structure itself
258      ENDIF
259      !
260      IF( nn_timing == 1 )  CALL timing_stop('dta_tsd')
261      !
262   END SUBROUTINE dta_tsd
263
264   !!======================================================================
265END MODULE dtatsd
Note: See TracBrowser for help on using the repository browser.