New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcnxt.F90 in branches/UKMO/dev_merge_2017_GC_couple_pkg/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/UKMO/dev_merge_2017_GC_couple_pkg/NEMOGCM/NEMO/TOP_SRC/TRP/trcnxt.F90 @ 9677

Last change on this file since 9677 was 9677, checked in by dancopsey, 6 years ago

Strip out SVN keywords.

File size: 10.6 KB
Line 
1MODULE trcnxt
2   !!======================================================================
3   !!                       ***  MODULE  trcnxt  ***
4   !! Ocean passive tracers:  time stepping on passives tracers
5   !!======================================================================
6   !! History :  7.0  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-02  (M. Levy)   passive tracers
9   !!                 !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
10   !!            8.0  !  1996-04  (A. Weaver)  Euler forward step
11   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
12   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!                 !  2002-08  (G. Madec)  F90: Free form and module
14   !!                 !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
15   !!                 !  2004-03  (C. Ethe) passive tracers
16   !!                 !  2007-02  (C. Deltel) Diagnose ML trends for passive tracers
17   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
18   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
19   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
20   !!            3.3  !  2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
21   !!----------------------------------------------------------------------
22#if defined key_top
23   !!----------------------------------------------------------------------
24   !!   'key_top'                                                TOP models
25   !!----------------------------------------------------------------------
26   !!   trc_nxt     : time stepping on passive tracers
27   !!----------------------------------------------------------------------
28   USE oce_trc         ! ocean dynamics and tracers variables
29   USE trc             ! ocean passive tracers variables
30   USE trd_oce
31   USE trdtra
32   USE tranxt
33   USE bdy_oce   , ONLY: ln_bdy
34   USE trcbdy          ! BDY open boundaries
35# if defined key_agrif
36   USE agrif_top_interp
37# endif
38   !
39   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
40   USE prtctl_trc      ! Print control for debbuging
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   trc_nxt   ! routine called by step.F90
46
47   REAL(wp) ::   rfact1, rfact2
48
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE trc_nxt( kt )
57      !!----------------------------------------------------------------------
58      !!                   ***  ROUTINE trcnxt  ***
59      !!
60      !! ** Purpose :   Compute the passive tracers fields at the
61      !!      next time-step from their temporal trends and swap the fields.
62      !!
63      !! ** Method  :   Apply lateral boundary conditions on (ua,va) through
64      !!      call to lbc_lnk routine
65      !!   default:
66      !!      arrays swap
67      !!         (trn) = (tra) ; (tra) = (0,0)
68      !!         (trb) = (trn)
69      !!
70      !!   For Arakawa or TVD Scheme :
71      !!      A Asselin time filter applied on now tracers (trn) to avoid
72      !!      the divergence of two consecutive time-steps and tr arrays
73      !!      to prepare the next time_step:
74      !!         (trb) = (trn) + atfp [ (trb) + (tra) - 2 (trn) ]
75      !!         (trn) = (tra) ; (tra) = (0,0)
76      !!
77      !!
78      !! ** Action  : - update trb, trn
79      !!----------------------------------------------------------------------
80      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
81      !
82      INTEGER  ::   jk, jn   ! dummy loop indices
83      REAL(wp) ::   zfact            ! temporary scalar
84      CHARACTER (len=22) :: charout
85      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrdt    ! 4D workspace
86      !!----------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('trc_nxt')
89      !
90      IF( kt == nittrc000 .AND. lwp ) THEN
91         WRITE(numout,*)
92         WRITE(numout,*) 'trc_nxt : time stepping on passive tracers'
93      ENDIF
94      !
95#if defined key_agrif
96      CALL Agrif_trc                   ! AGRIF zoom boundaries
97#endif
98      ! Update after tracer on domain lateral boundaries
99      CALL lbc_lnk( tra(:,:,:,:), 'T', 1. )   
100
101      IF( ln_bdy )  CALL trc_bdy( kt )
102
103      IF( l_trdtrc )  THEN             ! trends: store now fields before the Asselin filter application
104         ALLOCATE( ztrdt(jpi,jpj,jpk,jptra) )
105         ztrdt(:,:,:,:)  = trn(:,:,:,:)
106      ENDIF
107      !                                ! Leap-Frog + Asselin filter time stepping
108      IF( (neuler == 0 .AND. kt == nittrc000) .OR. ln_top_euler ) THEN    ! Euler time-stepping (only swap)
109         DO jn = 1, jptra
110            DO jk = 1, jpkm1
111               trn(:,:,jk,jn) = tra(:,:,jk,jn)
112               trb(:,:,jk,jn) = trn(:,:,jk,jn) 
113            END DO
114         END DO
115      ELSE     
116         IF( .NOT. l_offline ) THEN ! Leap-Frog + Asselin filter time stepping
117            IF( ln_linssh ) THEN   ;   CALL tra_nxt_fix( kt, nittrc000,         'TRC', trb, trn, tra, jptra )  !     linear ssh
118            ELSE                   ;   CALL tra_nxt_vvl( kt, nittrc000, rdttrc, 'TRC', trb, trn, tra,      &
119              &                                                                   sbc_trc, sbc_trc_b, jptra )  ! non-linear ssh
120            ENDIF
121         ELSE
122                                       CALL trc_nxt_off( kt )       ! offline
123         ENDIF
124         !
125         CALL lbc_lnk_multi( trb(:,:,:,:), 'T', 1._wp, trn(:,:,:,:), 'T', 1._wp, tra(:,:,:,:), 'T', 1._wp )
126      ENDIF
127      !
128      IF( l_trdtrc ) THEN              ! trends: send Asselin filter trends to trdtra manager for further diagnostics
129         DO jn = 1, jptra
130            DO jk = 1, jpkm1
131               zfact = 1._wp / r2dttrc 
132               ztrdt(:,:,jk,jn) = ( trb(:,:,jk,jn) - ztrdt(:,:,jk,jn) ) * zfact 
133               CALL trd_tra( kt, 'TRC', jn, jptra_atf, ztrdt )
134            END DO
135         END DO
136         DEALLOCATE( ztrdt ) 
137      END IF
138      !
139      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
140         WRITE(charout, FMT="('nxt')")
141         CALL prt_ctl_trc_info(charout)
142         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
143      ENDIF
144      !
145      IF( ln_timing )   CALL timing_stop('trc_nxt')
146      !
147   END SUBROUTINE trc_nxt
148
149
150   SUBROUTINE trc_nxt_off( kt )
151      !!----------------------------------------------------------------------
152      !!                   ***  ROUTINE tra_nxt_vvl  ***
153      !!
154      !! ** Purpose :   Time varying volume: apply the Asselin time filter 
155      !!                and swap the tracer fields.
156      !!
157      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
158      !!              - save in (ta,sa) a thickness weighted average over the three
159      !!             time levels which will be used to compute rdn and thus the semi-
160      !!             implicit hydrostatic pressure gradient (ln_dynhpg_imp = T)
161      !!              - swap tracer fields to prepare the next time_step.
162      !!                This can be summurized for tempearture as:
163      !!             ztm = ( e3t_n*tn + rbcp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )   ln_dynhpg_imp = T
164      !!                  /( e3t_n    + rbcp*[ e3t_b    - 2 e3t_n    + e3t_a    ] )   
165      !!             ztm = 0                                                       otherwise
166      !!             tb  = ( e3t_n*tn + atfp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )
167      !!                  /( e3t_n    + atfp*[ e3t_b    - 2 e3t_n    + e3t_a    ] )
168      !!             tn  = ta
169      !!             ta  = zt        (NB: reset to 0 after eos_bn2 call)
170      !!
171      !! ** Action  : - (tb,sb) and (tn,sn) ready for the next time step
172      !!              - (ta,sa) time averaged (t,s)   (ln_dynhpg_imp = T)
173      !!----------------------------------------------------------------------
174      INTEGER , INTENT(in   )   ::  kt       ! ocean time-step index
175      !!     
176      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
177      REAL(wp) ::   ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
178      REAL(wp) ::   ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d   !   -      -
179      !!----------------------------------------------------------------------
180      !
181      IF( kt == nittrc000 )  THEN
182         IF(lwp) WRITE(numout,*)
183         IF(lwp) WRITE(numout,*) 'trc_nxt_off : time stepping'
184         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
185         IF( .NOT. ln_linssh ) THEN
186            rfact1 = atfp * rdttrc
187            rfact2 = rfact1 / rau0
188         ENDIF
189       
190      ENDIF
191      !
192      DO jn = 1, jptra     
193         DO jk = 1, jpkm1
194            DO jj = 1, jpj
195               DO ji = 1, jpi
196                  ze3t_b = e3t_b(ji,jj,jk)
197                  ze3t_n = e3t_n(ji,jj,jk)
198                  ze3t_a = e3t_a(ji,jj,jk)
199                  !                                         ! tracer content at Before, now and after
200                  ztc_b  = trb(ji,jj,jk,jn) * ze3t_b
201                  ztc_n  = trn(ji,jj,jk,jn) * ze3t_n
202                  ztc_a  = tra(ji,jj,jk,jn) * ze3t_a
203                  !
204                  ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
205                  ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
206                  !
207                  ze3t_f = ze3t_n + atfp * ze3t_d
208                  ztc_f  = ztc_n  + atfp * ztc_d
209                  !
210                  IF( .NOT. ln_linssh .AND. jk == mikt(ji,jj) ) THEN           ! first level
211                     ze3t_f = ze3t_f - rfact2 * ( emp_b(ji,jj)      - emp(ji,jj)   ) 
212                     ztc_f  = ztc_f  - rfact1 * ( sbc_trc(ji,jj,jn) - sbc_trc_b(ji,jj,jn) )
213                  ENDIF
214
215                  ze3t_f = 1.e0 / ze3t_f
216                  trb(ji,jj,jk,jn) = ztc_f * ze3t_f       ! ptb <-- ptn filtered
217                  trn(ji,jj,jk,jn) = tra(ji,jj,jk,jn)     ! ptn <-- pta
218                  !
219               END DO
220            END DO
221         END DO
222         !
223      END DO
224      !
225   END SUBROUTINE trc_nxt_off
226
227#else
228   !!----------------------------------------------------------------------
229   !!   Default option                                         Empty module
230   !!----------------------------------------------------------------------
231CONTAINS
232   SUBROUTINE trc_nxt( kt ) 
233      INTEGER, INTENT(in) :: kt
234      WRITE(*,*) 'trc_nxt: You should not have seen this print! error?', kt
235   END SUBROUTINE trc_nxt
236#endif
237   !!======================================================================
238END MODULE trcnxt
Note: See TracBrowser for help on using the repository browser.