New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/UKMO/dev_r10171_test_crs_AMM7/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/dev_r10171_test_crs_AMM7/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 10207

Last change on this file since 10207 was 10207, checked in by cmao, 6 years ago

remove svn keyword
File size: 34.4 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE diaptr         ! poleward transport diagnostics
29   USE phycst
30   !
31   USE lib_mpp        ! MPP library
32   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
33   USE in_out_manager ! I/O manager
34   USE wrk_nemo       ! Memory Allocation
35   USE timing         ! Timing
36   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
37   USE iom
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
43   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
44
45   LOGICAL ::   l_trd   ! flag to compute trends
46   LOGICAL ::   l_trans   ! flag to output vertically integrated transports
47
48   !! * Substitutions
49#  include "domzgr_substitute.h90"
50#  include "vectopt_loop_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
59      &                                       ptb, ptn, pta, kjpt )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE tra_adv_tvd  ***
62      !!
63      !! **  Purpose :   Compute the now trend due to total advection of
64      !!       tracers and add it to the general trend of tracer equations
65      !!
66      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
67      !!       corrected flux (monotonic correction)
68      !!       note: - this advection scheme needs a leap-frog time scheme
69      !!
70      !! ** Action : - update (pta) with the now advective tracer trends
71      !!             - save the trends
72      !!----------------------------------------------------------------------
73      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
74      !
75      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
77      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
78      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
79      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
80      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
83      !
84      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
85      INTEGER  ::   ik 
86      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
87      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
88      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
89      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
90      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz, zptry
91      REAL(wp), POINTER, DIMENSION(:,:)   :: z2d
92      !!----------------------------------------------------------------------
93      !
94      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
95      !
96      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
97      !
98      IF( kt == kit000 )  THEN
99         IF(lwp) WRITE(numout,*)
100         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
101         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
102         !
103      ENDIF
104
105      l_trd = .FALSE.
106      l_trans = .FALSE.
107      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
108      IF( cdtype == 'TRA' .AND. (iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") ) ) l_trans = .TRUE.
109      !
110      IF( l_trd .OR. l_trans )  THEN
111         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
112         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
113         CALL wrk_alloc( jpi, jpj, z2d )
114      ENDIF
115      !
116      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
117         CALL wrk_alloc( jpi, jpj, jpk, zptry )
118         zptry(:,:,:) = 0._wp
119      ENDIF
120      !
121      zwi(:,:,:) = 0.e0 ; 
122      !
123      !                                                          ! ===========
124      DO jn = 1, kjpt                                            ! tracer loop
125         !                                                       ! ===========
126         ! 1. Bottom and k=1 value : flux set to zero
127         ! ----------------------------------
128         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
129         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
130         
131         zwz(:,:,1  ) = 0._wp
132         ! 2. upstream advection with initial mass fluxes & intermediate update
133         ! --------------------------------------------------------------------
134         ! upstream tracer flux in the i and j direction
135         DO jk = 1, jpkm1
136            DO jj = 1, jpjm1
137               DO ji = 1, fs_jpim1   ! vector opt.
138                  ! upstream scheme
139                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
140                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
141                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
142                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
143                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
144                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
145               END DO
146            END DO
147         END DO
148
149         ! upstream tracer flux in the k direction
150         ! Interior value
151         DO jk = 2, jpkm1
152            DO jj = 1, jpj
153               DO ji = 1, jpi
154                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
155                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
156                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
157               END DO
158            END DO
159         END DO
160         ! Surface value
161         IF( lk_vvl ) THEN   
162            IF ( ln_isfcav ) THEN
163               DO jj = 1, jpj
164                  DO ji = 1, jpi
165                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable
166                  END DO
167               END DO
168            ELSE
169               zwz(:,:,1) = 0.e0          ! volume variable
170            END IF
171         ELSE               
172            IF ( ln_isfcav ) THEN
173               DO jj = 1, jpj
174                  DO ji = 1, jpi
175                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
176                  END DO
177               END DO   
178            ELSE
179               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
180            END IF
181         ENDIF
182
183         ! total advective trend
184         DO jk = 1, jpkm1
185            z2dtt = p2dt(jk)
186            DO jj = 2, jpjm1
187               DO ji = fs_2, fs_jpim1   ! vector opt.
188                  ! total intermediate advective trends
189                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
190                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
191                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) / e1e2t(ji,jj)
192                  ! update and guess with monotonic sheme
193                  pta(ji,jj,jk,jn) =                       pta(ji,jj,jk,jn) +         ztra   / fse3t_n(ji,jj,jk) * tmask(ji,jj,jk)
194                  zwi(ji,jj,jk)    = ( fse3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + z2dtt * ztra ) / fse3t_a(ji,jj,jk) * tmask(ji,jj,jk)
195               END DO
196            END DO
197         END DO
198         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
199         CALL lbc_lnk( zwi, 'T', 1. ) 
200
201         !                                 ! trend diagnostics (contribution of upstream fluxes)
202         IF( l_trd .OR. l_trans )  THEN 
203            ! store intermediate advective trends
204            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
205         END IF
206         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
207         IF( cdtype == 'TRA' .AND. ln_diaptr )    zptry(:,:,:) = zwy(:,:,:) 
208
209         ! 3. antidiffusive flux : high order minus low order
210         ! --------------------------------------------------
211         ! antidiffusive flux on i and j
212         DO jk = 1, jpkm1
213            DO jj = 1, jpjm1
214               DO ji = 1, fs_jpim1   ! vector opt.
215                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
216                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
217               END DO
218            END DO
219         END DO
220     
221         ! antidiffusive flux on k
222         ! Interior value
223         DO jk = 2, jpkm1                   
224            DO jj = 1, jpj
225               DO ji = 1, jpi
226                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
227               END DO
228            END DO
229         END DO
230         ! surface value
231         IF ( ln_isfcav ) THEN
232            DO jj = 1, jpj
233               DO ji = 1, jpi
234                  zwz(ji,jj,mikt(ji,jj)) = 0.e0
235               END DO
236            END DO
237         ELSE
238            zwz(:,:,1) = 0.e0
239         END IF
240         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
241         CALL lbc_lnk( zwz, 'W',  1. )
242
243         ! 4. monotonicity algorithm
244         ! -------------------------
245         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
246
247
248         ! 5. final trend with corrected fluxes
249         ! ------------------------------------
250         DO jk = 1, jpkm1
251            DO jj = 2, jpjm1
252               DO ji = fs_2, fs_jpim1   ! vector opt. 
253                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
254                  ! total advective trends
255                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
256                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
257                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
258                  ! add them to the general tracer trends
259                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
260               END DO
261            END DO
262         END DO
263
264         !                                 ! trend diagnostics (contribution of upstream fluxes)
265         IF( l_trd .OR. l_trans )  THEN
266            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
267            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
268            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
269         ENDIF
270         
271         IF( l_trd ) THEN
272            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
273            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
274            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
275         END IF
276
277         IF( l_trans .AND. jn==jp_tem ) THEN
278            z2d(:,:) = 0._wp 
279            DO jk = 1, jpkm1
280               DO jj = 2, jpjm1
281                  DO ji = fs_2, fs_jpim1   ! vector opt.
282                     z2d(ji,jj) = z2d(ji,jj) + ztrdx(ji,jj,jk) 
283                  END DO
284               END DO
285            END DO
286            CALL lbc_lnk( z2d, 'U', -1. )
287            CALL iom_put( "uadv_heattr", rau0_rcp * z2d )       ! heat transport in i-direction
288              !
289            z2d(:,:) = 0._wp 
290            DO jk = 1, jpkm1
291               DO jj = 2, jpjm1
292                  DO ji = fs_2, fs_jpim1   ! vector opt.
293                     z2d(ji,jj) = z2d(ji,jj) + ztrdy(ji,jj,jk) 
294                  END DO
295               END DO
296            END DO
297            CALL lbc_lnk( z2d, 'V', -1. )
298            CALL iom_put( "vadv_heattr", rau0_rcp * z2d )       ! heat transport in j-direction
299         ENDIF
300         ! "Poleward" heat and salt transports (contribution of upstream fluxes)
301         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
302            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
303            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
304         ENDIF
305         !
306      END DO
307      !
308      CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
309      IF( l_trd .OR. l_trans )  THEN
310         CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
311         CALL wrk_dealloc( jpi, jpj, z2d )
312      ENDIF
313      IF( cdtype == 'TRA' .AND. ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, zptry )
314      !
315      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
316      !
317   END SUBROUTINE tra_adv_tvd
318
319   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
320      &                                       ptb, ptn, pta, kjpt )
321      !!----------------------------------------------------------------------
322      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
323      !!
324      !! **  Purpose :   Compute the now trend due to total advection of
325      !!       tracers and add it to the general trend of tracer equations
326      !!
327      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
328      !!       corrected flux (monotonic correction). This version use sub-
329      !!       timestepping for the vertical advection which increases stability
330      !!       when vertical metrics are small.
331      !!       note: - this advection scheme needs a leap-frog time scheme
332      !!
333      !! ** Action : - update (pta) with the now advective tracer trends
334      !!             - save the trends
335      !!----------------------------------------------------------------------
336      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
337      !
338      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
339      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
340      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
341      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
342      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
343      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
344      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
345      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
346      !
347      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
348      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
349      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
350      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
351      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
352      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
353      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
354      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
355      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
356      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
357      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
358      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
359      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
360      REAL(wp), POINTER, DIMENSION(:,:,:) :: zptry
361      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
362      !!----------------------------------------------------------------------
363      !
364      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
365      !
366      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
367      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
368      CALL wrk_alloc( jpi, jpj, jpk, kjpt+1, ztrs )
369      !
370      IF( kt == kit000 )  THEN
371         IF(lwp) WRITE(numout,*)
372         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
373         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
374      ENDIF
375      !
376      l_trd = .FALSE.
377      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
378      !
379      IF( l_trd )  THEN
380         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
381         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
382      ENDIF
383      !
384      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
385         CALL wrk_alloc( jpi, jpj,jpk, zptry )
386         zptry(:,:,:) = 0._wp
387      ENDIF
388      !
389      zwi(:,:,:) = 0._wp
390      z_rzts = 1._wp / REAL( jnzts, wp )
391      zr_p2dt(:) = 1._wp / p2dt(:)
392      !
393      !                                                          ! ===========
394      DO jn = 1, kjpt                                            ! tracer loop
395         !                                                       ! ===========
396         ! 1. Bottom value : flux set to zero
397         ! ----------------------------------
398         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
399         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
400
401         ! 2. upstream advection with initial mass fluxes & intermediate update
402         ! --------------------------------------------------------------------
403         ! upstream tracer flux in the i and j direction
404         DO jk = 1, jpkm1
405            DO jj = 1, jpjm1
406               DO ji = 1, fs_jpim1   ! vector opt.
407                  ! upstream scheme
408                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
409                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
410                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
411                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
412                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
413                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
414               END DO
415            END DO
416         END DO
417
418         ! upstream tracer flux in the k direction
419         ! Interior value
420         DO jk = 2, jpkm1
421            DO jj = 1, jpj
422               DO ji = 1, jpi
423                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
424                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
425                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
426               END DO
427            END DO
428         END DO
429         ! Surface value
430         IF( lk_vvl ) THEN
431            IF ( ln_isfcav ) THEN
432               DO jj = 1, jpj
433                  DO ji = 1, jpi
434                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable +    isf
435                  END DO
436               END DO
437            ELSE
438               zwz(:,:,1) = 0.e0                              ! volume variable + no isf
439            END IF
440         ELSE
441            IF ( ln_isfcav ) THEN
442               DO jj = 1, jpj
443                  DO ji = 1, jpi
444                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface +    isf
445                  END DO
446               END DO
447            ELSE
448               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)                                               ! linear free surface + no isf
449            END IF
450         ENDIF
451
452         ! total advective trend
453         DO jk = 1, jpkm1
454            z2dtt = p2dt(jk)
455            DO jj = 2, jpjm1
456               DO ji = fs_2, fs_jpim1   ! vector opt.
457                  ! total intermediate advective trends
458                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
459                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
460                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) / e1e2t(ji,jj)
461                  ! update and guess with monotonic sheme
462                  pta(ji,jj,jk,jn) =                       pta(ji,jj,jk,jn) +         ztra   / fse3t_n(ji,jj,jk) * tmask(ji,jj,jk)
463                  zwi(ji,jj,jk)    = ( fse3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + z2dtt * ztra ) / fse3t_a(ji,jj,jk) * tmask(ji,jj,jk)
464               END DO
465            END DO
466         END DO
467         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
468         CALL lbc_lnk( zwi, 'T', 1. ) 
469
470         !                                 ! trend diagnostics (contribution of upstream fluxes)
471         IF( l_trd )  THEN 
472            ! store intermediate advective trends
473            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
474         END IF
475         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
476         IF( cdtype == 'TRA' .AND. ln_diaptr )  zptry(:,:,:) = zwy(:,:,:)
477
478         ! 3. antidiffusive flux : high order minus low order
479         ! --------------------------------------------------
480         ! antidiffusive flux on i and j
481         !
482         DO jk = 1, jpkm1
483            !
484            DO jj = 1, jpjm1
485               DO ji = 1, fs_jpim1   ! vector opt.
486                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
487                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
488
489                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
490                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
491               END DO
492            END DO
493
494            DO jj = 2, jpjm1         ! partial horizontal divergence
495               DO ji = fs_2, fs_jpim1
496                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
497                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
498               END DO
499            END DO
500
501            DO jj = 1, jpjm1
502               DO ji = 1, fs_jpim1   ! vector opt.
503                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
504                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
505               END DO
506            END DO
507         END DO
508     
509         ! antidiffusive flux on k
510         zwz(:,:,1) = 0._wp        ! Surface value
511         zwz_sav(:,:,:) = zwz(:,:,:)
512         !
513         ztrs(:,:,:,1) = ptb(:,:,:,jn)
514         ztrs(:,:,1,2) = ptb(:,:,1,jn)
515         ztrs(:,:,1,3) = ptb(:,:,1,jn)
516         zwzts(:,:,:) = 0._wp
517
518         DO jl = 1, jnzts                   ! Start of sub timestepping loop
519
520            IF( jl == 1 ) THEN              ! Euler forward to kick things off
521              jtb = 1   ;   jtn = 1   ;   jta = 2
522              zts(:) = p2dt(:) * z_rzts
523              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
524                                            ! starting at jl =1 if jnzts is odd;
525                                            ! starting at jl =2 otherwise
526            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
527              jtb = 1   ;   jtn = 2   ;   jta = 3
528              zts(:) = 2._wp * p2dt(:) * z_rzts
529            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
530              jtb = MOD(jtb,3) + 1
531              jtn = MOD(jtn,3) + 1
532              jta = MOD(jta,3) + 1
533            ENDIF
534            DO jk = 2, jpkm1          ! Interior value
535               DO jj = 2, jpjm1
536                  DO ji = fs_2, fs_jpim1
537                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
538                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
539                  END DO
540               END DO
541            END DO
542
543            jtaken = MOD( jtaken + 1 , 2 )
544
545            DO jk = 2, jpkm1          ! Interior value
546               DO jj = 2, jpjm1
547                  DO ji = fs_2, fs_jpim1
548                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
549                     ! total advective trends
550                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
551                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
552                  END DO
553               END DO
554            END DO
555
556         END DO
557
558         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
559            DO jj = 2, jpjm1
560               DO ji = fs_2, fs_jpim1
561                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
562               END DO
563            END DO
564         END DO
565         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
566         CALL lbc_lnk( zwz, 'W',  1. )
567
568         ! 4. monotonicity algorithm
569         ! -------------------------
570         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
571
572
573         ! 5. final trend with corrected fluxes
574         ! ------------------------------------
575         DO jk = 1, jpkm1
576            DO jj = 2, jpjm1
577               DO ji = fs_2, fs_jpim1   ! vector opt. 
578                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
579                  ! total advective trends
580                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
581                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
582                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
583                  ! add them to the general tracer trends
584                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
585               END DO
586            END DO
587         END DO
588
589         !                                 ! trend diagnostics (contribution of upstream fluxes)
590         IF( l_trd )  THEN
591            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
592            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
593            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
594           
595            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
596            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
597            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
598         END IF
599         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
600         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
601            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:) 
602            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
603         ENDIF
604         !
605      END DO
606      !
607                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
608                   CALL wrk_dealloc( jpi, jpj, jpk, kjpt+1, ztrs )
609                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
610      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
611      IF( cdtype == 'TRA' .AND. ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, zptry )
612      !
613      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
614      !
615   END SUBROUTINE tra_adv_tvd_zts
616
617
618   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
619      !!---------------------------------------------------------------------
620      !!                    ***  ROUTINE nonosc  ***
621      !!     
622      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
623      !!       scheme and the before field by a nonoscillatory algorithm
624      !!
625      !! **  Method  :   ... ???
626      !!       warning : pbef and paft must be masked, but the boundaries
627      !!       conditions on the fluxes are not necessary zalezak (1979)
628      !!       drange (1995) multi-dimensional forward-in-time and upstream-
629      !!       in-space based differencing for fluid
630      !!----------------------------------------------------------------------
631      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
632      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
633      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
634      !
635      INTEGER  ::   ji, jj, jk   ! dummy loop indices
636      INTEGER  ::   ikm1         ! local integer
637      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
638      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
639      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
640      !!----------------------------------------------------------------------
641      !
642      IF( nn_timing == 1 )  CALL timing_start('nonosc')
643      !
644      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
645      !
646      zbig  = 1.e+40_wp
647      zrtrn = 1.e-15_wp
648      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
649
650      ! Search local extrema
651      ! --------------------
652      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
653      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
654         &        paft * tmask - zbig * ( 1._wp - tmask )  )
655      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
656         &        paft * tmask + zbig * ( 1._wp - tmask )  )
657
658      DO jk = 1, jpkm1
659         ikm1 = MAX(jk-1,1)
660         z2dtt = p2dt(jk)
661         DO jj = 2, jpjm1
662            DO ji = fs_2, fs_jpim1   ! vector opt.
663
664               ! search maximum in neighbourhood
665               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
666                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
667                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
668                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
669
670               ! search minimum in neighbourhood
671               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
672                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
673                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
674                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
675
676               ! positive part of the flux
677               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
678                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
679                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
680
681               ! negative part of the flux
682               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
683                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
684                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
685
686               ! up & down beta terms
687               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
688               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
689               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
690            END DO
691         END DO
692      END DO
693      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
694
695      ! 3. monotonic flux in the i & j direction (paa & pbb)
696      ! ----------------------------------------
697      DO jk = 1, jpkm1
698         DO jj = 2, jpjm1
699            DO ji = fs_2, fs_jpim1   ! vector opt.
700               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
701               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
702               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
703               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
704
705               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
706               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
707               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
708               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
709
710      ! monotonic flux in the k direction, i.e. pcc
711      ! -------------------------------------------
712               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
713               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
714               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
715               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
716            END DO
717         END DO
718      END DO
719      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
720      !
721      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
722      !
723      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
724      !
725   END SUBROUTINE nonosc
726
727   !!======================================================================
728END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.