New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsink.F90 in branches/UKMO/dev_r10171_test_crs_AMM7/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/UKMO/dev_r10171_test_crs_AMM7/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsink.F90 @ 10207

Last change on this file since 10207 was 10207, checked in by cmao, 5 years ago

remove svn keyword

File size: 40.8 KB
Line 
1MODULE p4zsink
2   !!======================================================================
3   !!                         ***  MODULE p4zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!             3.5  !  2012-07  (O. Aumont) Introduce potential time-splitting
10   !!----------------------------------------------------------------------
11#if defined key_pisces
12   !!----------------------------------------------------------------------
13   !!   p4z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
14   !!   p4z_sink_init  :  Unitialisation of sinking speed parameters
15   !!   p4z_sink_alloc :  Allocate sinking speed variables
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE prtctl_trc, ONLY: prt_ctl_trc_info,prt_ctl_trc      !  print control for debugging
20   USE lib_mpp, ONLY: mpp_max
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p4z_sink         ! called in p4zbio.F90
26   PUBLIC   p4z_sink_init    ! called in trcsms_pisces.F90
27   PUBLIC   p4z_sink_alloc
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio3   !: POC sinking speed
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio4   !: GOC sinking speed
31   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wscal    !: Calcite and BSi sinking speeds
32
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
34   !                                                          !  (different meanings depending on the parameterization)
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
37#if ! defined key_kriest
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
39#endif
40
41   INTEGER  :: ik100
42
43#if  defined key_kriest
44   REAL(wp) ::  xkr_sfact    !: Sinking factor
45   REAL(wp) ::  xkr_stick    !: Stickiness
46   REAL(wp) ::  xkr_nnano    !: Nbr of cell in nano size class
47   REAL(wp) ::  xkr_ndiat    !: Nbr of cell in diatoms size class
48   REAL(wp) ::  xkr_nmicro   !: Nbr of cell in microzoo size class
49   REAL(wp) ::  xkr_nmeso    !: Nbr of cell in mesozoo  size class
50   REAL(wp) ::  xkr_naggr    !: Nbr of cell in aggregates  size class
51
52   REAL(wp) ::  xkr_frac 
53
54   REAL(wp), PUBLIC ::  xkr_dnano       !: Size of particles in nano pool
55   REAL(wp), PUBLIC ::  xkr_ddiat       !: Size of particles in diatoms pool
56   REAL(wp), PUBLIC ::  xkr_dmicro      !: Size of particles in microzoo pool
57   REAL(wp), PUBLIC ::  xkr_dmeso       !: Size of particles in mesozoo pool
58   REAL(wp), PUBLIC ::  xkr_daggr       !: Size of particles in aggregates pool
59   REAL(wp), PUBLIC ::  xkr_wsbio_min   !: min vertical particle speed
60   REAL(wp), PUBLIC ::  xkr_wsbio_max   !: max vertical particle speed
61
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) ::   xnumm   !:  maximum number of particles in aggregates
63#endif
64
65   !!* Substitution
66#  include "top_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74#if ! defined key_kriest
75   !!----------------------------------------------------------------------
76   !!   'standard sinking parameterisation'                  ???
77   !!----------------------------------------------------------------------
78
79   SUBROUTINE p4z_sink ( kt, knt )
80      !!---------------------------------------------------------------------
81      !!                     ***  ROUTINE p4z_sink  ***
82      !!
83      !! ** Purpose :   Compute vertical flux of particulate matter due to
84      !!                gravitational sinking
85      !!
86      !! ** Method  : - ???
87      !!---------------------------------------------------------------------
88      INTEGER, INTENT(in) :: kt, knt
89      INTEGER  ::   ji, jj, jk, jit
90      INTEGER  ::   iiter1, iiter2
91      REAL(wp) ::   zagg1, zagg2, zagg3, zagg4
92      REAL(wp) ::   zagg , zaggfe, zaggdoc, zaggdoc2, zaggdoc3
93      REAL(wp) ::   zfact, zwsmax, zmax, zstep
94      CHARACTER (len=25) :: charout
95      REAL(wp), POINTER, DIMENSION(:,:,:) :: zw3d
96      REAL(wp), POINTER, DIMENSION(:,:  ) :: zw2d
97      !!---------------------------------------------------------------------
98      !
99      IF( nn_timing == 1 )  CALL timing_start('p4z_sink')
100      !
101      !    Sinking speeds of detritus is increased with depth as shown
102      !    by data and from the coagulation theory
103      !    -----------------------------------------------------------
104      DO jk = 1, jpkm1
105         DO jj = 1, jpj
106            DO ji = 1,jpi
107               zmax  = MAX( heup(ji,jj), hmld(ji,jj) )
108               zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 5000._wp
109               wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact
110            END DO
111         END DO
112      END DO
113
114      ! limit the values of the sinking speeds to avoid numerical instabilities 
115      wsbio3(:,:,:) = wsbio
116      wscal (:,:,:) = wsbio4(:,:,:)
117      !
118      ! OA This is (I hope) a temporary solution for the problem that may
119      ! OA arise in specific situation where the CFL criterion is broken
120      ! OA for vertical sedimentation of particles. To avoid this, a time
121      ! OA splitting algorithm has been coded. A specific maximum
122      ! OA iteration number is provided and may be specified in the namelist
123      ! OA This is to avoid very large iteration number when explicit free
124      ! OA surface is used (for instance). When niter?max is set to 1,
125      ! OA this computation is skipped. The crude old threshold method is
126      ! OA then applied. This also happens when niter exceeds nitermax.
127      IF( MAX( niter1max, niter2max ) == 1 ) THEN
128        iiter1 = 1
129        iiter2 = 1
130      ELSE
131        iiter1 = 1
132        iiter2 = 1
133        DO jk = 1, jpkm1
134          DO jj = 1, jpj
135             DO ji = 1, jpi
136                IF( tmask(ji,jj,jk) == 1) THEN
137#if defined key_crs
138                   zwsmax =  0.5 * e3t_max_crs(ji,jj,jk) / xstep
139#else
140                   zwsmax =  0.5 * fse3t(ji,jj,jk) / xstep
141#endif
142                   iiter1 =  MAX( iiter1, INT( wsbio3(ji,jj,jk) / zwsmax ) )
143                   iiter2 =  MAX( iiter2, INT( wsbio4(ji,jj,jk) / zwsmax ) )
144                ENDIF
145             END DO
146          END DO
147        END DO
148        IF( lk_mpp ) THEN
149           CALL mpp_max( iiter1 )
150           CALL mpp_max( iiter2 )
151        ENDIF
152        iiter1 = MIN( iiter1, niter1max )
153        iiter2 = MIN( iiter2, niter2max )
154      ENDIF
155
156      DO jk = 1,jpkm1
157         DO jj = 1, jpj
158            DO ji = 1, jpi
159               IF( tmask(ji,jj,jk) == 1 ) THEN
160                 zwsmax =  0.5 * fse3t(ji,jj,jk) / xstep
161                 wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax * FLOAT( iiter1 ) )
162                 wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax * FLOAT( iiter2 ) )
163               ENDIF
164            END DO
165         END DO
166      END DO
167
168      !  Initializa to zero all the sinking arrays
169      !   -----------------------------------------
170      sinking (:,:,:) = 0.e0
171      sinking2(:,:,:) = 0.e0
172      sinkcal (:,:,:) = 0.e0
173      sinkfer (:,:,:) = 0.e0
174      sinksil (:,:,:) = 0.e0
175      sinkfer2(:,:,:) = 0.e0
176
177      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
178      !   -----------------------------------------------------
179      DO jit = 1, iiter1
180        CALL p4z_sink2( wsbio3, sinking , jppoc, iiter1 )
181        CALL p4z_sink2( wsbio3, sinkfer , jpsfe, iiter1 )
182      END DO
183
184      DO jit = 1, iiter2
185        CALL p4z_sink2( wsbio4, sinking2, jpgoc, iiter2 )
186        CALL p4z_sink2( wsbio4, sinkfer2, jpbfe, iiter2 )
187        CALL p4z_sink2( wsbio4, sinksil , jpgsi, iiter2 )
188        CALL p4z_sink2( wscal , sinkcal , jpcal, iiter2 )
189      END DO
190
191      !  Exchange between organic matter compartments due to coagulation/disaggregation
192      !  ---------------------------------------------------
193      DO jk = 1, jpkm1
194         DO jj = 1, jpj
195            DO ji = 1, jpi
196               !
197               zstep = xstep 
198# if defined key_degrad
199               zstep = zstep * facvol(ji,jj,jk)
200# endif
201               zfact = zstep * xdiss(ji,jj,jk)
202               !  Part I : Coagulation dependent on turbulence
203               zagg1 = 25.9  * zfact * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jppoc)
204               zagg2 = 4452. * zfact * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpgoc)
205
206               ! Part II : Differential settling
207
208               !  Aggregation of small into large particles
209               zagg3 =  47.1 * zstep * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpgoc)
210               zagg4 =  3.3  * zstep * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jppoc)
211
212               zagg   = zagg1 + zagg2 + zagg3 + zagg4
213               zaggfe = zagg * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn )
214
215               ! Aggregation of DOC to POC :
216               ! 1st term is shear aggregation of DOC-DOC
217               ! 2nd term is shear aggregation of DOC-POC
218               ! 3rd term is differential settling of DOC-POC
219               zaggdoc  = ( ( 0.369 * 0.3 * trb(ji,jj,jk,jpdoc) + 102.4 * trb(ji,jj,jk,jppoc) ) * zfact       &
220               &            + 2.4 * zstep * trb(ji,jj,jk,jppoc) ) * 0.3 * trb(ji,jj,jk,jpdoc)
221               ! transfer of DOC to GOC :
222               ! 1st term is shear aggregation
223               ! 2nd term is differential settling
224               zaggdoc2 = ( 3.53E3 * zfact + 0.1 * zstep ) * trb(ji,jj,jk,jpgoc) * 0.3 * trb(ji,jj,jk,jpdoc)
225               ! tranfer of DOC to POC due to brownian motion
226               zaggdoc3 =  ( 5095. * trb(ji,jj,jk,jppoc) + 114. * 0.3 * trb(ji,jj,jk,jpdoc) ) *zstep * 0.3 * trb(ji,jj,jk,jpdoc)
227
228               !  Update the trends
229               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc + zaggdoc3
230               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2
231               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
232               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
233               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2 - zaggdoc3
234               !
235            END DO
236         END DO
237      END DO
238
239
240     ! Total carbon export per year
241     IF( iom_use( "tcexp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
242        &   t_oce_co2_exp = glob_sum( ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * e1e2t(:,:) * tmask(:,:,1) )
243     !
244     IF( lk_iomput ) THEN
245       IF( knt == nrdttrc ) THEN
246          CALL wrk_alloc( jpi, jpj,      zw2d )
247          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
248          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
249          !
250          IF( iom_use( "EPC100" ) )  THEN
251              zw2d(:,:) = ( sinking(:,:,ik100) + sinking2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of carbon at 100m
252              CALL iom_put( "EPC100"  , zw2d )
253          ENDIF
254          IF( iom_use( "EPFE100" ) )  THEN
255              zw2d(:,:) = ( sinkfer(:,:,ik100) + sinkfer2(:,:,ik100) ) * zfact * tmask(:,:,1) ! Export of iron at 100m
256              CALL iom_put( "EPFE100"  , zw2d )
257          ENDIF
258          IF( iom_use( "EPCAL100" ) )  THEN
259              zw2d(:,:) = sinkcal(:,:,ik100) * zfact * tmask(:,:,1) ! Export of calcite at 100m
260              CALL iom_put( "EPCAL100"  , zw2d )
261          ENDIF
262          IF( iom_use( "EPSI100" ) )  THEN
263              zw2d(:,:) =  sinksil(:,:,ik100) * zfact * tmask(:,:,1) ! Export of bigenic silica at 100m
264              CALL iom_put( "EPSI100"  , zw2d )
265          ENDIF
266          IF( iom_use( "EXPC" ) )  THEN
267              zw3d(:,:,:) = ( sinking(:,:,:) + sinking2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of carbon in the water column
268              CALL iom_put( "EXPC"  , zw3d )
269          ENDIF
270          IF( iom_use( "EXPFE" ) )  THEN
271              zw3d(:,:,:) = ( sinkfer(:,:,:) + sinkfer2(:,:,:) ) * zfact * tmask(:,:,:) ! Export of iron
272              CALL iom_put( "EXPFE"  , zw3d )
273          ENDIF
274          IF( iom_use( "EXPCAL" ) )  THEN
275              zw3d(:,:,:) = sinkcal(:,:,:) * zfact * tmask(:,:,:) ! Export of calcite
276              CALL iom_put( "EXPCAL"  , zw3d )
277          ENDIF
278          IF( iom_use( "EXPSI" ) )  THEN
279              zw3d(:,:,:) = sinksil(:,:,:) * zfact * tmask(:,:,:) ! Export of bigenic silica
280              CALL iom_put( "EXPSI"  , zw3d )
281          ENDIF
282          IF( iom_use( "tcexp" ) )  CALL iom_put( "tcexp" , t_oce_co2_exp * zfact )   ! molC/s
283          !
284          CALL wrk_dealloc( jpi, jpj,      zw2d )
285          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
286        ENDIF
287      ELSE
288         IF( ln_diatrc ) THEN
289            zfact = 1.e3 * rfact2r
290            trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik100) * zfact * tmask(:,:,1)
291            trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik100) * zfact * tmask(:,:,1)
292            trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik100) * zfact * tmask(:,:,1)
293            trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik100) * zfact * tmask(:,:,1)
294            trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik100) * zfact * tmask(:,:,1)
295            trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik100) * zfact * tmask(:,:,1)
296         ENDIF
297      ENDIF
298      !
299      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
300         WRITE(charout, FMT="('sink')")
301         CALL prt_ctl_trc_info(charout)
302         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
303      ENDIF
304      !
305      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink')
306      !
307   END SUBROUTINE p4z_sink
308
309   SUBROUTINE p4z_sink_init
310      !!----------------------------------------------------------------------
311      !!                  ***  ROUTINE p4z_sink_init  ***
312      !!----------------------------------------------------------------------
313      INTEGER :: jk
314
315      ik100 = 10        !  last level where depth less than 100 m
316      DO jk = jpkm1, 1, -1
317         IF( gdept_1d(jk) > 100. )  ik100 = jk - 1
318      END DO
319      IF (lwp) WRITE(numout,*)
320      IF (lwp) WRITE(numout,*) ' Level corresponding to 100m depth ',  ik100 + 1
321      IF (lwp) WRITE(numout,*)
322      !
323      t_oce_co2_exp = 0._wp
324      !
325   END SUBROUTINE p4z_sink_init
326
327#else
328   !!----------------------------------------------------------------------
329   !!   'Kriest sinking parameterisation'        key_kriest          ???
330   !!----------------------------------------------------------------------
331
332   SUBROUTINE p4z_sink ( kt, knt )
333      !!---------------------------------------------------------------------
334      !!                ***  ROUTINE p4z_sink  ***
335      !!
336      !! ** Purpose :   Compute vertical flux of particulate matter due to
337      !!              gravitational sinking - Kriest parameterization
338      !!
339      !! ** Method  : - ???
340      !!---------------------------------------------------------------------
341      !
342      INTEGER, INTENT(in) :: kt, knt
343      !
344      INTEGER  :: ji, jj, jk, jit, niter1, niter2
345      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zfract, zaggsi, zaggsh
346      REAL(wp) :: zagg , zaggdoc, zaggdoc1, znumdoc
347      REAL(wp) :: znum , zeps, zfm, zgm, zsm
348      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
349      REAL(wp) :: zval1, zval2, zval3, zval4
350      REAL(wp) :: zfact
351      INTEGER  :: ik1
352      CHARACTER (len=25) :: charout
353      REAL(wp), POINTER, DIMENSION(:,:,:) :: znum3d 
354      REAL(wp), POINTER, DIMENSION(:,:,:) :: zw3d
355      REAL(wp), POINTER, DIMENSION(:,:  ) :: zw2d
356      !!---------------------------------------------------------------------
357      !
358      IF( nn_timing == 1 )  CALL timing_start('p4z_sink')
359      !
360      CALL wrk_alloc( jpi, jpj, jpk, znum3d )
361      !
362      !     Initialisation of variables used to compute Sinking Speed
363      !     ---------------------------------------------------------
364
365      znum3d(:,:,:) = 0.e0
366      zval1 = 1. + xkr_zeta
367      zval2 = 1. + xkr_zeta + xkr_eta
368      zval3 = 1. + xkr_eta
369
370      !     Computation of the vertical sinking speed : Kriest et Evans, 2000
371      !     -----------------------------------------------------------------
372
373      DO jk = 1, jpkm1
374         DO jj = 1, jpj
375            DO ji = 1, jpi
376               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
377                  znum = trb(ji,jj,jk,jppoc) / ( trb(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
378                  ! -------------- To avoid sinking speed over 50 m/day -------
379                  znum  = MIN( xnumm(jk), znum )
380                  znum  = MAX( 1.1      , znum )
381                  znum3d(ji,jj,jk) = znum
382                  !------------------------------------------------------------
383                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
384                  zfm   = xkr_frac**( 1. - zeps )
385                  zgm   = xkr_frac**( zval1 - zeps )
386                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
387                  zdiv1 = zeps - zval3
388                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
389                     &             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
390                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
391                     &             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
392                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
393               ENDIF
394            END DO
395         END DO
396      END DO
397
398      wscal(:,:,:) = MAX( wsbio3(:,:,:), 30._wp )
399
400      !   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
401      !   -----------------------------------------
402
403      sinking (:,:,:) = 0.e0
404      sinking2(:,:,:) = 0.e0
405      sinkcal (:,:,:) = 0.e0
406      sinkfer (:,:,:) = 0.e0
407      sinksil (:,:,:) = 0.e0
408
409     !   Compute the sedimentation term using p4zsink2 for all the sinking particles
410     !   -----------------------------------------------------
411
412      niter1 = niter1max
413      niter2 = niter2max
414
415      DO jit = 1, niter1
416        CALL p4z_sink2( wsbio3, sinking , jppoc, niter1 )
417        CALL p4z_sink2( wsbio3, sinkfer , jpsfe, niter1 )
418        CALL p4z_sink2( wscal , sinksil , jpgsi, niter1 )
419        CALL p4z_sink2( wscal , sinkcal , jpcal, niter1 )
420      END DO
421
422      DO jit = 1, niter2
423        CALL p4z_sink2( wsbio4, sinking2, jpnum, niter2 )
424      END DO
425
426     !  Exchange between organic matter compartments due to coagulation/disaggregation
427     !  ---------------------------------------------------
428
429      zval1 = 1. + xkr_zeta
430      zval2 = 1. + xkr_eta
431      zval3 = 3. + xkr_eta
432      zval4 = 4. + xkr_eta
433
434      DO jk = 1,jpkm1
435         DO jj = 1,jpj
436            DO ji = 1,jpi
437               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
438
439                  znum = trb(ji,jj,jk,jppoc)/(trb(ji,jj,jk,jpnum)+rtrn) / xkr_massp
440                  !-------------- To avoid sinking speed over 50 m/day -------
441                  znum  = min(xnumm(jk),znum)
442                  znum  = MAX( 1.1,znum)
443                  !------------------------------------------------------------
444                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
445                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
446                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
447                  zdiv2 = zeps - 2.
448                  zdiv3 = zeps - 3.
449                  zdiv4 = zeps - zval2
450                  zdiv5 = 2.* zeps - zval4
451                  zfm   = xkr_frac**( 1.- zeps )
452                  zsm   = xkr_frac**xkr_eta
453
454                  !    Part I : Coagulation dependant on turbulence
455                  !    ----------------------------------------------
456
457                  zagg1 =  0.163 * trb(ji,jj,jk,jpnum)**2               &
458                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
459                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
460                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
461                     &            * (zeps-1.)**2/(zdiv2*zdiv3)) 
462                  zagg2 =  2*0.163*trb(ji,jj,jk,jpnum)**2*zfm*                       &
463                     &                   ((xkr_mass_max**3+3.*(xkr_mass_max**2          &
464                     &                    *xkr_mass_min*(zeps-1.)/zdiv2                 &
465                     &                    +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
466                     &                    +xkr_mass_min**3*(zeps-1)/zdiv1)                  &
467                     &                    -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/           &
468                     &                    (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))   
469
470                  zagg3 =  0.163*trb(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3 
471                 
472                 !    Aggregation of small into large particles
473                 !    Part II : Differential settling
474                 !    ----------------------------------------------
475
476                  zagg4 =  2.*3.141*0.125*trb(ji,jj,jk,jpnum)**2*                       &
477                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
478                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
479                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
480                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
481                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )   
482
483                  zagg5 =   2.*3.141*0.125*trb(ji,jj,jk,jpnum)**2                         &
484                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
485                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
486                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
487                     &                 /zdiv) 
488
489                  !
490                  !     Fractionnation by swimming organisms
491                  !     ------------------------------------
492
493                  zfract = 2.*3.141*0.125*trb(ji,jj,jk,jpmes)*12./0.12/0.06**3*trb(ji,jj,jk,jpnum)  &
494                    &      * (0.01/xkr_mass_min)**(1.-zeps)*0.1**2  &
495                    &      * 10000.*xstep
496
497                  !     Aggregation of DOC to small particles
498                  !     --------------------------------------
499
500                  zaggdoc = 0.83 * trb(ji,jj,jk,jpdoc) * xstep * xdiss(ji,jj,jk) * trb(ji,jj,jk,jpdoc)   &
501                     &        + 0.005 * 231. * trb(ji,jj,jk,jpdoc) * xstep * trb(ji,jj,jk,jpdoc)
502                  zaggdoc1 = 271. * trb(ji,jj,jk,jppoc) * xstep * xdiss(ji,jj,jk) * trb(ji,jj,jk,jpdoc)  &
503                     &  + 0.02 * 16706. * trb(ji,jj,jk,jppoc) * xstep * trb(ji,jj,jk,jpdoc)
504
505# if defined key_degrad
506                   zagg1   = zagg1   * facvol(ji,jj,jk)                 
507                   zagg2   = zagg2   * facvol(ji,jj,jk)                 
508                   zagg3   = zagg3   * facvol(ji,jj,jk)                 
509                   zagg4   = zagg4   * facvol(ji,jj,jk)                 
510                   zagg5   = zagg5   * facvol(ji,jj,jk)                 
511                   zaggdoc = zaggdoc * facvol(ji,jj,jk)                 
512                   zaggdoc1 = zaggdoc1 * facvol(ji,jj,jk)
513# endif
514                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
515                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
516                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
517                  !
518                  znumdoc = trb(ji,jj,jk,jpnum) / ( trb(ji,jj,jk,jppoc) + rtrn )
519                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc + zaggdoc1
520                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zfract + zaggdoc / xkr_massp - zagg
521                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc1
522
523               ENDIF
524            END DO
525         END DO
526      END DO
527
528     ! Total primary production per year
529     t_oce_co2_exp = t_oce_co2_exp + glob_sum( ( sinking(:,:,ik100) * e1e2t(:,:) * tmask(:,:,1) )
530     !
531     IF( lk_iomput ) THEN
532        IF( knt == nrdttrc ) THEN
533          CALL wrk_alloc( jpi, jpj,      zw2d )
534          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
535          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
536          !
537          IF( iom_use( "EPC100" ) )  THEN
538              zw2d(:,:) = sinking(:,:,ik100) * zfact * tmask(:,:,1) ! Export of carbon at 100m
539              CALL iom_put( "EPC100"  , zw2d )
540          ENDIF
541          IF( iom_use( "EPN100" ) )  THEN
542              zw2d(:,:) = sinking2(:,:,ik100) * zfact * tmask(:,:,1) ! Export of number of aggregates ?
543              CALL iom_put( "EPN100"  , zw2d )
544          ENDIF
545          IF( iom_use( "EPCAL100" ) )  THEN
546              zw2d(:,:) = sinkcal(:,:,ik100) * zfact * tmask(:,:,1) ! Export of calcite at 100m
547              CALL iom_put( "EPCAL100"  , zw2d )
548          ENDIF
549          IF( iom_use( "EPSI100" ) )  THEN
550              zw2d(:,:) = sinksil(:,:,ik100) * zfact * tmask(:,:,1) ! Export of bigenic silica at 100m
551              CALL iom_put( "EPSI100"  , zw2d )
552          ENDIF
553          IF( iom_use( "EXPC" ) )  THEN
554              zw3d(:,:,:) = sinking(:,:,:) * zfact * tmask(:,:,:) ! Export of carbon in the water column
555              CALL iom_put( "EXPC"  , zw3d )
556          ENDIF
557          IF( iom_use( "EXPN" ) )  THEN
558              zw3d(:,:,:) = sinking(:,:,:) * zfact * tmask(:,:,:) ! Export of carbon in the water column
559              CALL iom_put( "EXPN"  , zw3d )
560          ENDIF
561          IF( iom_use( "EXPCAL" ) )  THEN
562              zw3d(:,:,:) = sinkcal(:,:,:) * zfact * tmask(:,:,:) ! Export of calcite
563              CALL iom_put( "EXPCAL"  , zw3d )
564          ENDIF
565          IF( iom_use( "EXPSI" ) )  THEN
566              zw3d(:,:,:) = sinksil(:,:,:) * zfact * tmask(:,:,:) ! Export of bigenic silica
567              CALL iom_put( "EXPSI"  , zw3d )
568          ENDIF
569          IF( iom_use( "XNUM" ) )  THEN
570              zw3d(:,:,:) =  znum3d(:,:,:) * tmask(:,:,:) !  Number of particles on aggregats
571              CALL iom_put( "XNUM"  , zw3d )
572          ENDIF
573          IF( iom_use( "WSC" ) )  THEN
574              zw3d(:,:,:) = wsbio3(:,:,:) * tmask(:,:,:) ! Sinking speed of carbon particles
575              CALL iom_put( "WSC"  , zw3d )
576          ENDIF
577          IF( iom_use( "WSN" ) )  THEN
578              zw3d(:,:,:) = wsbio4(:,:,:) * tmask(:,:,:) ! Sinking speed of particles number
579              CALL iom_put( "WSN"  , zw3d )
580          ENDIF
581          !
582          CALL wrk_dealloc( jpi, jpj,      zw2d )
583          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
584      ELSE
585         IF( ln_diatrc ) THEN
586            zfact = 1.e3 * rfact2r
587            trc2d(:,:  ,jp_pcs0_2d + 4)  = sinking (:,:,ik100)  * zfact * tmask(:,:,1)
588            trc2d(:,:  ,jp_pcs0_2d + 5)  = sinking2(:,:,ik100)  * zfact * tmask(:,:,1)
589            trc2d(:,:  ,jp_pcs0_2d + 6)  = sinkfer (:,:,ik100)  * zfact * tmask(:,:,1)
590            trc2d(:,:  ,jp_pcs0_2d + 7)  = sinksil (:,:,ik100)  * zfact * tmask(:,:,1)
591            trc2d(:,:  ,jp_pcs0_2d + 8)  = sinkcal (:,:,ik100)  * zfact * tmask(:,:,1)
592            trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)      * zfact * tmask(:,:,:)
593            trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)      * zfact * tmask(:,:,:)
594            trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)      * zfact * tmask(:,:,:)
595            trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)      * zfact * tmask(:,:,:)
596            trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)              * tmask(:,:,:)
597            trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)              * tmask(:,:,:)
598            trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)              * tmask(:,:,:)
599         ENDIF
600      ENDIF
601
602      !
603      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
604         WRITE(charout, FMT="('sink')")
605         CALL prt_ctl_trc_info(charout)
606         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
607      ENDIF
608      !
609      CALL wrk_dealloc( jpi, jpj, jpk, znum3d )
610      !
611      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink')
612      !
613   END SUBROUTINE p4z_sink
614
615
616   SUBROUTINE p4z_sink_init
617      !!----------------------------------------------------------------------
618      !!                  ***  ROUTINE p4z_sink_init  ***
619      !!
620      !! ** Purpose :   Initialization of sinking parameters
621      !!                Kriest parameterization only
622      !!
623      !! ** Method  :   Read the nampiskrs namelist and check the parameters
624      !!      called at the first timestep
625      !!
626      !! ** input   :   Namelist nampiskrs
627      !!----------------------------------------------------------------------
628      INTEGER  ::   jk, jn, kiter
629      INTEGER  ::   ios                 ! Local integer output status for namelist read
630      REAL(wp) ::   znum, zdiv
631      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
632      REAL(wp) ::   zmin, zmax, zl, zr, xacc
633      !
634      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
635         &                xkr_nnano, xkr_ndiat, xkr_nmicro, xkr_nmeso, xkr_naggr
636      !!----------------------------------------------------------------------
637      !
638      IF( nn_timing == 1 )  CALL timing_start('p4z_sink_init')
639      !
640
641      REWIND( numnatp_ref )              ! Namelist nampiskrs in reference namelist : Pisces sinking Kriest
642      READ  ( numnatp_ref, nampiskrs, IOSTAT = ios, ERR = 901)
643901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiskrs in reference namelist', lwp )
644
645      REWIND( numnatp_cfg )              ! Namelist nampiskrs in configuration namelist : Pisces sinking Kriest
646      READ  ( numnatp_cfg, nampiskrs, IOSTAT = ios, ERR = 902 )
647902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiskrs in configuration namelist', lwp )
648      IF(lwm) WRITE ( numonp, nampiskrs )
649
650      IF(lwp) THEN
651         WRITE(numout,*)
652         WRITE(numout,*) ' Namelist : nampiskrs'
653         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
654         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
655         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
656         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
657         WRITE(numout,*) '    Nbr of cell in microzoo size class       xkr_nmicro   = ', xkr_nmicro
658         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
659         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
660      ENDIF
661
662
663      ! max and min vertical particle speed
664      xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
665      xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
666      IF (lwp) WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
667
668      !
669      !    effect of the sizes of the different living pools on particle numbers
670      !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
671      !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
672      !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
673      !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
674      !    doc aggregates = 1um
675      ! ----------------------------------------------------------
676
677      xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
678      xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
679      xkr_dmicro = 1. / ( xkr_massp * xkr_nmicro )
680      xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
681      xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
682
683      !!---------------------------------------------------------------------
684      !!    'key_kriest'                                                  ???
685      !!---------------------------------------------------------------------
686      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
687      !  Search of the maximum number of particles in aggregates for each k-level.
688      !  Bissection Method
689      !--------------------------------------------------------------------
690      IF (lwp) THEN
691        WRITE(numout,*)
692        WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
693      ENDIF
694
695      xacc     =  0.001_wp
696      kiter    = 50
697      zmin     =  1.10_wp
698      zmax     = xkr_mass_max / xkr_mass_min
699      xkr_frac = zmax
700
701      DO jk = 1,jpk
702         zl = zmin
703         zr = zmax
704         wmax = 0.5 * fse3t(1,1,jk) * rday * float(niter1max) / rfact2
705         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
706         znum = zl - 1.
707         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
708            & - ( xkr_wsbio_max * xkr_eta * znum * &
709            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
710            & - wmax
711
712         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
713         znum = zr - 1.
714         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
715            & - ( xkr_wsbio_max * xkr_eta * znum * &
716            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
717            & - wmax
718iflag:   DO jn = 1, kiter
719            IF    ( zwl == 0._wp ) THEN   ;   znummax = zl
720            ELSEIF( zwr == 0._wp ) THEN   ;   znummax = zr
721            ELSE
722               znummax = ( zr + zl ) / 2.
723               zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
724               znum = znummax - 1.
725               zws =  xkr_wsbio_min * xkr_zeta / zdiv &
726                  & - ( xkr_wsbio_max * xkr_eta * znum * &
727                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
728                  & - wmax
729               IF( zws * zwl < 0. ) THEN   ;   zr = znummax
730               ELSE                        ;   zl = znummax
731               ENDIF
732               zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
733               znum = zl - 1.
734               zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
735                  & - ( xkr_wsbio_max * xkr_eta * znum * &
736                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
737                  & - wmax
738
739               zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
740               znum = zr - 1.
741               zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
742                  & - ( xkr_wsbio_max * xkr_eta * znum * &
743                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
744                  & - wmax
745               !
746               IF ( ABS ( zws )  <= xacc ) EXIT iflag
747               !
748            ENDIF
749            !
750         END DO iflag
751
752         xnumm(jk) = znummax
753         IF (lwp) WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
754         !
755      END DO
756      !
757      ik100 = 10        !  last level where depth less than 100 m
758      DO jk = jpkm1, 1, -1
759         IF( gdept_1d(jk) > 100. )  iksed = jk - 1
760      END DO
761      IF (lwp) WRITE(numout,*)
762      IF (lwp) WRITE(numout,*) ' Level corresponding to 100m depth ',  ik100 + 1
763      IF (lwp) WRITE(numout,*)
764      !
765      t_oce_co2_exp = 0._wp
766      !
767      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink_init')
768      !
769  END SUBROUTINE p4z_sink_init
770
771#endif
772
773   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra, kiter )
774      !!---------------------------------------------------------------------
775      !!                     ***  ROUTINE p4z_sink2  ***
776      !!
777      !! ** Purpose :   Compute the sedimentation terms for the various sinking
778      !!     particles. The scheme used to compute the trends is based
779      !!     on MUSCL.
780      !!
781      !! ** Method  : - this ROUTINE compute not exactly the advection but the
782      !!      transport term, i.e.  div(u*tra).
783      !!---------------------------------------------------------------------
784      !
785      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
786      INTEGER , INTENT(in   )                         ::   kiter     ! number of iterations for time-splitting
787      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
788      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
789      !!
790      INTEGER  ::   ji, jj, jk, jn
791      REAL(wp) ::   zigma,zew,zign, zflx, zstep
792      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztraz, zakz, zwsink2, ztrb 
793      !!---------------------------------------------------------------------
794      !
795      IF( nn_timing == 1 )  CALL timing_start('p4z_sink2')
796      !
797      ! Allocate temporary workspace
798      CALL wrk_alloc( jpi, jpj, jpk, ztraz, zakz, zwsink2, ztrb )
799
800      zstep = rfact2 / FLOAT( kiter ) / 2.
801
802      ztraz(:,:,:) = 0.e0
803      zakz (:,:,:) = 0.e0
804      ztrb (:,:,:) = trb(:,:,:,jp_tra)
805
806      DO jk = 1, jpkm1
807         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
808      END DO
809      zwsink2(:,:,1) = 0.e0
810      IF( lk_degrad ) THEN
811         zwsink2(:,:,:) = zwsink2(:,:,:) * facvol(:,:,:)
812      ENDIF
813
814
815      ! Vertical advective flux
816      DO jn = 1, 2
817         !  first guess of the slopes interior values
818         DO jk = 2, jpkm1
819            ztraz(:,:,jk) = ( trb(:,:,jk-1,jp_tra) - trb(:,:,jk,jp_tra) ) * tmask(:,:,jk)
820         END DO
821         ztraz(:,:,1  ) = 0.0
822         ztraz(:,:,jpk) = 0.0
823
824         ! slopes
825         DO jk = 2, jpkm1
826            DO jj = 1,jpj
827               DO ji = 1, jpi
828                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
829                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
830               END DO
831            END DO
832         END DO
833         
834         ! Slopes limitation
835         DO jk = 2, jpkm1
836            DO jj = 1, jpj
837               DO ji = 1, jpi
838                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
839                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
840               END DO
841            END DO
842         END DO
843         
844         ! vertical advective flux
845         DO jk = 1, jpkm1
846            DO jj = 1, jpj     
847               DO ji = 1, jpi   
848#if defined key_crs
849                  zigma = zwsink2(ji,jj,jk+1) * zstep / e3w_max_crs(ji,jj,jk+1)
850#else
851                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
852#endif
853                  zew   = zwsink2(ji,jj,jk+1)
854                  psinkflx(ji,jj,jk+1) = -zew * ( trb(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
855               END DO
856            END DO
857         END DO
858         !
859         ! Boundary conditions
860         psinkflx(:,:,1  ) = 0.e0
861         psinkflx(:,:,jpk) = 0.e0
862         
863         DO jk=1,jpkm1
864            DO jj = 1,jpj
865               DO ji = 1, jpi
866#if defined key_crs
867                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t_max_crs(ji,jj,jk)
868#else
869                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
870#endif
871                  trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + zflx
872               END DO
873            END DO
874         END DO
875
876      ENDDO
877
878      DO jk = 1,jpkm1
879         DO jj = 1,jpj
880            DO ji = 1, jpi
881#if defined key_crs
882               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / e3t_max_crs(ji,jj,jk)
883#else
884               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
885#endif
886               ztrb(ji,jj,jk) = ztrb(ji,jj,jk) + 2. * zflx
887            END DO
888         END DO
889      END DO
890
891      trb(:,:,:,jp_tra) = ztrb(:,:,:)
892      psinkflx(:,:,:)   = 2. * psinkflx(:,:,:)
893      !
894      CALL wrk_dealloc( jpi, jpj, jpk, ztraz, zakz, zwsink2, ztrb )
895      !
896      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink2')
897      !
898   END SUBROUTINE p4z_sink2
899
900
901   INTEGER FUNCTION p4z_sink_alloc()
902      !!----------------------------------------------------------------------
903      !!                     ***  ROUTINE p4z_sink_alloc  ***
904      !!----------------------------------------------------------------------
905      ALLOCATE( wsbio3 (jpi,jpj,jpk) , wsbio4  (jpi,jpj,jpk) , wscal(jpi,jpj,jpk) ,     &
906         &      sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)                      ,     &               
907         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)                      ,     &               
908#if defined key_kriest
909         &      xnumm(jpk)                                                        ,     &               
910#else
911         &      sinkfer2(jpi,jpj,jpk)                                             ,     &               
912#endif
913         &      sinkfer(jpi,jpj,jpk)                                              , STAT=p4z_sink_alloc )               
914         !
915      IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.')
916      !
917   END FUNCTION p4z_sink_alloc
918   
919#else
920   !!======================================================================
921   !!  Dummy module :                                   No PISCES bio-model
922   !!======================================================================
923CONTAINS
924   SUBROUTINE p4z_sink                    ! Empty routine
925   END SUBROUTINE p4z_sink
926#endif 
927
928   !!======================================================================
929END MODULE p4zsink
Note: See TracBrowser for help on using the repository browser.