| 1 | MODULE closea |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE closea *** |
|---|
| 4 | !! Closed Seas : specific treatments associated with closed seas |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 8.2 ! 00-05 (O. Marti) Original code |
|---|
| 7 | !! 8.5 ! 02-06 (E. Durand, G. Madec) F90 |
|---|
| 8 | !! 9.0 ! 06-07 (G. Madec) add clo_rnf, clo_ups, clo_bat |
|---|
| 9 | !! NEMO 3.4 ! 03-12 (P.G. Fogli) sbc_clo bug fix & mpp reproducibility |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | !! dom_clo : modification of the ocean domain for closed seas cases |
|---|
| 14 | !! sbc_clo : Special handling of closed seas |
|---|
| 15 | !! clo_rnf : set close sea outflows as river mouths (see sbcrnf) |
|---|
| 16 | !! clo_ups : set mixed centered/upstream scheme in closed sea (see traadv_cen2) |
|---|
| 17 | !! clo_bat : set to zero a field over closed sea (see domzrg) |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE oce ! dynamics and tracers |
|---|
| 20 | USE dom_oce ! ocean space and time domain |
|---|
| 21 | USE phycst ! physical constants |
|---|
| 22 | USE in_out_manager ! I/O manager |
|---|
| 23 | USE sbc_oce ! ocean surface boundary conditions |
|---|
| 24 | USE lib_fortran, ONLY: glob_sum, DDPDD |
|---|
| 25 | USE lbclnk ! lateral boundary condition - MPP exchanges |
|---|
| 26 | USE lib_mpp ! MPP library |
|---|
| 27 | USE timing |
|---|
| 28 | |
|---|
| 29 | IMPLICIT NONE |
|---|
| 30 | PRIVATE |
|---|
| 31 | |
|---|
| 32 | PUBLIC dom_clo ! routine called by domain module |
|---|
| 33 | PUBLIC sbc_clo ! routine called by step module |
|---|
| 34 | PUBLIC clo_rnf ! routine called by sbcrnf module |
|---|
| 35 | PUBLIC clo_ups ! routine called in traadv_cen2(_jki) module |
|---|
| 36 | PUBLIC clo_bat ! routine called in domzgr module |
|---|
| 37 | |
|---|
| 38 | INTEGER, PUBLIC, PARAMETER :: jpncs = 4 !: number of closed sea |
|---|
| 39 | INTEGER, PUBLIC, DIMENSION(jpncs) :: ncstt !: Type of closed sea |
|---|
| 40 | INTEGER, PUBLIC, DIMENSION(jpncs) :: ncsi1, ncsj1 !: south-west closed sea limits (i,j) |
|---|
| 41 | INTEGER, PUBLIC, DIMENSION(jpncs) :: ncsi2, ncsj2 !: north-east closed sea limits (i,j) |
|---|
| 42 | INTEGER, PUBLIC, DIMENSION(jpncs) :: ncsnr !: number of point where run-off pours |
|---|
| 43 | INTEGER, PUBLIC, DIMENSION(jpncs,4) :: ncsir, ncsjr !: Location of runoff |
|---|
| 44 | |
|---|
| 45 | REAL(wp), DIMENSION (jpncs+1) :: surf ! closed sea surface |
|---|
| 46 | |
|---|
| 47 | !! * Substitutions |
|---|
| 48 | # include "vectopt_loop_substitute.h90" |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 51 | !! $Id$ |
|---|
| 52 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | CONTAINS |
|---|
| 55 | |
|---|
| 56 | SUBROUTINE dom_clo |
|---|
| 57 | !!--------------------------------------------------------------------- |
|---|
| 58 | !! *** ROUTINE dom_clo *** |
|---|
| 59 | !! |
|---|
| 60 | !! ** Purpose : Closed sea domain initialization |
|---|
| 61 | !! |
|---|
| 62 | !! ** Method : if a closed sea is located only in a model grid point |
|---|
| 63 | !! just the thermodynamic processes are applied. |
|---|
| 64 | !! |
|---|
| 65 | !! ** Action : ncsi1(), ncsj1() : south-west closed sea limits (i,j) |
|---|
| 66 | !! ncsi2(), ncsj2() : north-east Closed sea limits (i,j) |
|---|
| 67 | !! ncsir(), ncsjr() : Location of runoff |
|---|
| 68 | !! ncsnr : number of point where run-off pours |
|---|
| 69 | !! ncstt : Type of closed sea |
|---|
| 70 | !! =0 spread over the world ocean |
|---|
| 71 | !! =2 put at location runoff |
|---|
| 72 | !!---------------------------------------------------------------------- |
|---|
| 73 | INTEGER :: jc ! dummy loop indices |
|---|
| 74 | INTEGER :: isrow ! local index |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | |
|---|
| 77 | IF(lwp) WRITE(numout,*) |
|---|
| 78 | IF(lwp) WRITE(numout,*)'dom_clo : closed seas ' |
|---|
| 79 | IF(lwp) WRITE(numout,*)'~~~~~~~' |
|---|
| 80 | |
|---|
| 81 | ! initial values |
|---|
| 82 | ncsnr(:) = 1 ; ncsi1(:) = 1 ; ncsi2(:) = 1 ; ncsir(:,:) = 1 |
|---|
| 83 | ncstt(:) = 0 ; ncsj1(:) = 1 ; ncsj2(:) = 1 ; ncsjr(:,:) = 1 |
|---|
| 84 | |
|---|
| 85 | ! set the closed seas (in data domain indices) |
|---|
| 86 | ! ------------------- |
|---|
| 87 | |
|---|
| 88 | IF( cp_cfg == "orca" ) THEN |
|---|
| 89 | ! |
|---|
| 90 | SELECT CASE ( jp_cfg ) |
|---|
| 91 | ! ! ======================= |
|---|
| 92 | CASE ( 1 ) ! ORCA_R1 configuration |
|---|
| 93 | ! ! ======================= |
|---|
| 94 | ! This dirty section will be suppressed by simplification process: |
|---|
| 95 | ! all this will come back in input files |
|---|
| 96 | ! Currently these hard-wired indices relate to configuration with |
|---|
| 97 | ! extend grid (jpjglo=332) |
|---|
| 98 | isrow = 332 - jpjglo |
|---|
| 99 | ! |
|---|
| 100 | ncsnr(1) = 1 ; ncstt(1) = 0 ! Caspian Sea |
|---|
| 101 | ncsi1(1) = 332 ; ncsj1(1) = 243 - isrow |
|---|
| 102 | ncsi2(1) = 344 ; ncsj2(1) = 275 - isrow |
|---|
| 103 | ncsir(1,1) = 1 ; ncsjr(1,1) = 1 |
|---|
| 104 | ! |
|---|
| 105 | ! ! ======================= |
|---|
| 106 | CASE ( 2 ) ! ORCA_R2 configuration |
|---|
| 107 | ! ! ======================= |
|---|
| 108 | ! ! Caspian Sea |
|---|
| 109 | ncsnr(1) = 1 ; ncstt(1) = 0 ! spread over the globe |
|---|
| 110 | ncsi1(1) = 11 ; ncsj1(1) = 103 |
|---|
| 111 | ncsi2(1) = 17 ; ncsj2(1) = 112 |
|---|
| 112 | ncsir(1,1) = 1 ; ncsjr(1,1) = 1 |
|---|
| 113 | ! ! Great North American Lakes |
|---|
| 114 | ncsnr(2) = 1 ; ncstt(2) = 2 ! put at St Laurent mouth |
|---|
| 115 | ncsi1(2) = 97 ; ncsj1(2) = 107 |
|---|
| 116 | ncsi2(2) = 103 ; ncsj2(2) = 111 |
|---|
| 117 | ncsir(2,1) = 110 ; ncsjr(2,1) = 111 |
|---|
| 118 | ! ! Black Sea (crossed by the cyclic boundary condition) |
|---|
| 119 | ncsnr(3:4) = 4 ; ncstt(3:4) = 2 ! put in Med Sea (north of Aegean Sea) |
|---|
| 120 | ncsir(3:4,1) = 171; ncsjr(3:4,1) = 106 ! |
|---|
| 121 | ncsir(3:4,2) = 170; ncsjr(3:4,2) = 106 |
|---|
| 122 | ncsir(3:4,3) = 171; ncsjr(3:4,3) = 105 |
|---|
| 123 | ncsir(3:4,4) = 170; ncsjr(3:4,4) = 105 |
|---|
| 124 | ncsi1(3) = 174 ; ncsj1(3) = 107 ! 1 : west part of the Black Sea |
|---|
| 125 | ncsi2(3) = 181 ; ncsj2(3) = 112 ! (ie west of the cyclic b.c.) |
|---|
| 126 | ncsi1(4) = 2 ; ncsj1(4) = 107 ! 2 : east part of the Black Sea |
|---|
| 127 | ncsi2(4) = 6 ; ncsj2(4) = 112 ! (ie east of the cyclic b.c.) |
|---|
| 128 | |
|---|
| 129 | |
|---|
| 130 | |
|---|
| 131 | ! ! ======================= |
|---|
| 132 | CASE ( 4 ) ! ORCA_R4 configuration |
|---|
| 133 | ! ! ======================= |
|---|
| 134 | ! ! Caspian Sea |
|---|
| 135 | ncsnr(1) = 1 ; ncstt(1) = 0 |
|---|
| 136 | ncsi1(1) = 4 ; ncsj1(1) = 53 |
|---|
| 137 | ncsi2(1) = 4 ; ncsj2(1) = 56 |
|---|
| 138 | ncsir(1,1) = 1 ; ncsjr(1,1) = 1 |
|---|
| 139 | ! ! Great North American Lakes |
|---|
| 140 | ncsnr(2) = 1 ; ncstt(2) = 2 |
|---|
| 141 | ncsi1(2) = 49 ; ncsj1(2) = 55 |
|---|
| 142 | ncsi2(2) = 51 ; ncsj2(2) = 56 |
|---|
| 143 | ncsir(2,1) = 57 ; ncsjr(2,1) = 55 |
|---|
| 144 | ! ! Black Sea |
|---|
| 145 | ncsnr(3) = 4 ; ncstt(3) = 2 |
|---|
| 146 | ncsi1(3) = 88 ; ncsj1(3) = 55 |
|---|
| 147 | ncsi2(3) = 91 ; ncsj2(3) = 56 |
|---|
| 148 | ncsir(3,1) = 86 ; ncsjr(3,1) = 53 |
|---|
| 149 | ncsir(3,2) = 87 ; ncsjr(3,2) = 53 |
|---|
| 150 | ncsir(3,3) = 86 ; ncsjr(3,3) = 52 |
|---|
| 151 | ncsir(3,4) = 87 ; ncsjr(3,4) = 52 |
|---|
| 152 | ! ! Baltic Sea |
|---|
| 153 | ncsnr(4) = 1 ; ncstt(4) = 2 |
|---|
| 154 | ncsi1(4) = 75 ; ncsj1(4) = 59 |
|---|
| 155 | ncsi2(4) = 76 ; ncsj2(4) = 61 |
|---|
| 156 | ncsir(4,1) = 84 ; ncsjr(4,1) = 59 |
|---|
| 157 | ! ! ================================ |
|---|
| 158 | CASE ( 025 ) ! ORCA_R025 extended configuration |
|---|
| 159 | ! ! ================================ |
|---|
| 160 | ncsnr(1) = 1 ; ncstt(1) = 0 ! Caspian + Aral sea |
|---|
| 161 | ncsi1(1) = 1330 ; ncsj1(1) = 831 |
|---|
| 162 | ncsi2(1) = 1400 ; ncsj2(1) = 981 |
|---|
| 163 | ncsir(1,1) = 1 ; ncsjr(1,1) = 1 |
|---|
| 164 | ! |
|---|
| 165 | ncsnr(2) = 1 ; ncstt(2) = 0 ! Azov Sea |
|---|
| 166 | ncsi1(2) = 1284 ; ncsj1(2) = 908 |
|---|
| 167 | ncsi2(2) = 1304 ; ncsj2(2) = 933 |
|---|
| 168 | ncsir(2,1) = 1 ; ncsjr(2,1) = 1 |
|---|
| 169 | ! |
|---|
| 170 | ncsnr(3) = 1 ; ncstt(3) = 0 ! North American Great Lakes |
|---|
| 171 | ncsi1(3) = 781 ; ncsj1(3) = 870 |
|---|
| 172 | ncsi2(3) = 847 ; ncsj2(3) = 926 |
|---|
| 173 | ncsir(3,1) = 1 ; ncsjr(3,1) = 1 |
|---|
| 174 | ! |
|---|
| 175 | ncsnr(4) = 1 ; ncstt(4) = 0 ! Lake Victoria |
|---|
| 176 | ncsi1(4) = 1274 ; ncsj1(4) = 672 |
|---|
| 177 | ncsi2(4) = 1289 ; ncsj2(4) = 687 |
|---|
| 178 | ncsir(4,1) = 1 ; ncsjr(4,1) = 1 |
|---|
| 179 | ! |
|---|
| 180 | END SELECT |
|---|
| 181 | ! |
|---|
| 182 | ENDIF |
|---|
| 183 | |
|---|
| 184 | ! convert the position in local domain indices |
|---|
| 185 | ! -------------------------------------------- |
|---|
| 186 | DO jc = 1, jpncs |
|---|
| 187 | ncsi1(jc) = mi0( ncsi1(jc) ) |
|---|
| 188 | ncsj1(jc) = mj0( ncsj1(jc) ) |
|---|
| 189 | |
|---|
| 190 | ncsi2(jc) = mi1( ncsi2(jc) ) |
|---|
| 191 | ncsj2(jc) = mj1( ncsj2(jc) ) |
|---|
| 192 | END DO |
|---|
| 193 | ! |
|---|
| 194 | END SUBROUTINE dom_clo |
|---|
| 195 | |
|---|
| 196 | |
|---|
| 197 | SUBROUTINE sbc_clo( kt ) |
|---|
| 198 | !!--------------------------------------------------------------------- |
|---|
| 199 | !! *** ROUTINE sbc_clo *** |
|---|
| 200 | !! |
|---|
| 201 | !! ** Purpose : Special handling of closed seas |
|---|
| 202 | !! |
|---|
| 203 | !! ** Method : Water flux is forced to zero over closed sea |
|---|
| 204 | !! Excess is shared between remaining ocean, or |
|---|
| 205 | !! put as run-off in open ocean. |
|---|
| 206 | !! |
|---|
| 207 | !! ** Action : emp updated surface freshwater fluxes and associated heat content at kt |
|---|
| 208 | !!---------------------------------------------------------------------- |
|---|
| 209 | INTEGER, INTENT(in) :: kt ! ocean model time step |
|---|
| 210 | ! |
|---|
| 211 | INTEGER :: ji, jj, jc, jn ! dummy loop indices |
|---|
| 212 | REAL(wp), PARAMETER :: rsmall = 1.e-20_wp ! Closed sea correction epsilon |
|---|
| 213 | REAL(wp) :: zze2, ztmp, zcorr ! |
|---|
| 214 | REAL(wp) :: zcoef, zcoef1 ! |
|---|
| 215 | COMPLEX(wp) :: ctmp |
|---|
| 216 | REAL(wp), DIMENSION(jpncs) :: zfwf ! 1D workspace |
|---|
| 217 | !!---------------------------------------------------------------------- |
|---|
| 218 | ! |
|---|
| 219 | IF( nn_timing == 1 ) CALL timing_start('sbc_clo') |
|---|
| 220 | ! !------------------! |
|---|
| 221 | IF( kt == nit000 ) THEN ! Initialisation ! |
|---|
| 222 | ! !------------------! |
|---|
| 223 | IF(lwp) WRITE(numout,*) |
|---|
| 224 | IF(lwp) WRITE(numout,*)'sbc_clo : closed seas ' |
|---|
| 225 | IF(lwp) WRITE(numout,*)'~~~~~~~' |
|---|
| 226 | |
|---|
| 227 | surf(:) = 0.e0_wp |
|---|
| 228 | ! |
|---|
| 229 | surf(jpncs+1) = glob_sum( e1e2t(:,:) ) ! surface of the global ocean |
|---|
| 230 | ! |
|---|
| 231 | ! ! surface of closed seas |
|---|
| 232 | IF( lk_mpp_rep ) THEN ! MPP reproductible calculation |
|---|
| 233 | DO jc = 1, jpncs |
|---|
| 234 | ctmp = CMPLX( 0.e0, 0.e0, wp ) |
|---|
| 235 | DO jj = ncsj1(jc), ncsj2(jc) |
|---|
| 236 | DO ji = ncsi1(jc), ncsi2(jc) |
|---|
| 237 | ztmp = e1e2t(ji,jj) * tmask_i(ji,jj) |
|---|
| 238 | CALL DDPDD( CMPLX( ztmp, 0.e0, wp ), ctmp ) |
|---|
| 239 | END DO |
|---|
| 240 | END DO |
|---|
| 241 | IF( lk_mpp ) CALL mpp_sum( ctmp ) |
|---|
| 242 | surf(jc) = REAL(ctmp,wp) |
|---|
| 243 | END DO |
|---|
| 244 | ELSE ! Standard calculation |
|---|
| 245 | DO jc = 1, jpncs |
|---|
| 246 | DO jj = ncsj1(jc), ncsj2(jc) |
|---|
| 247 | DO ji = ncsi1(jc), ncsi2(jc) |
|---|
| 248 | surf(jc) = surf(jc) + e1e2t(ji,jj) * tmask_i(ji,jj) ! surface of closed seas |
|---|
| 249 | END DO |
|---|
| 250 | END DO |
|---|
| 251 | END DO |
|---|
| 252 | IF( lk_mpp ) CALL mpp_sum ( surf, jpncs ) ! mpp: sum over all the global domain |
|---|
| 253 | ENDIF |
|---|
| 254 | |
|---|
| 255 | IF(lwp) WRITE(numout,*)' Closed sea surfaces' |
|---|
| 256 | DO jc = 1, jpncs |
|---|
| 257 | IF(lwp)WRITE(numout,FMT='(1I3,4I4,5X,F16.2)') jc, ncsi1(jc), ncsi2(jc), ncsj1(jc), ncsj2(jc), surf(jc) |
|---|
| 258 | END DO |
|---|
| 259 | |
|---|
| 260 | ! jpncs+1 : surface of sea, closed seas excluded |
|---|
| 261 | DO jc = 1, jpncs |
|---|
| 262 | surf(jpncs+1) = surf(jpncs+1) - surf(jc) |
|---|
| 263 | END DO |
|---|
| 264 | ! |
|---|
| 265 | ENDIF |
|---|
| 266 | ! !--------------------! |
|---|
| 267 | ! ! update emp ! |
|---|
| 268 | zfwf = 0.e0_wp !--------------------! |
|---|
| 269 | IF( lk_mpp_rep ) THEN ! MPP reproductible calculation |
|---|
| 270 | DO jc = 1, jpncs |
|---|
| 271 | ctmp = CMPLX( 0.e0, 0.e0, wp ) |
|---|
| 272 | DO jj = ncsj1(jc), ncsj2(jc) |
|---|
| 273 | DO ji = ncsi1(jc), ncsi2(jc) |
|---|
| 274 | ztmp = e1e2t(ji,jj) * ( emp(ji,jj)-rnf(ji,jj) ) * tmask_i(ji,jj) |
|---|
| 275 | CALL DDPDD( CMPLX( ztmp, 0.e0, wp ), ctmp ) |
|---|
| 276 | END DO |
|---|
| 277 | END DO |
|---|
| 278 | IF( lk_mpp ) CALL mpp_sum( ctmp ) |
|---|
| 279 | zfwf(jc) = REAL(ctmp,wp) |
|---|
| 280 | END DO |
|---|
| 281 | ELSE ! Standard calculation |
|---|
| 282 | DO jc = 1, jpncs |
|---|
| 283 | DO jj = ncsj1(jc), ncsj2(jc) |
|---|
| 284 | DO ji = ncsi1(jc), ncsi2(jc) |
|---|
| 285 | zfwf(jc) = zfwf(jc) + e1e2t(ji,jj) * ( emp(ji,jj)-rnf(ji,jj) ) * tmask_i(ji,jj) |
|---|
| 286 | END DO |
|---|
| 287 | END DO |
|---|
| 288 | END DO |
|---|
| 289 | IF( lk_mpp ) CALL mpp_sum ( zfwf(:) , jpncs ) ! mpp: sum over all the global domain |
|---|
| 290 | ENDIF |
|---|
| 291 | |
|---|
| 292 | IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN ! Black Sea case for ORCA_R2 configuration |
|---|
| 293 | zze2 = ( zfwf(3) + zfwf(4) ) * 0.5_wp |
|---|
| 294 | zfwf(3) = zze2 |
|---|
| 295 | zfwf(4) = zze2 |
|---|
| 296 | ENDIF |
|---|
| 297 | |
|---|
| 298 | zcorr = 0._wp |
|---|
| 299 | |
|---|
| 300 | DO jc = 1, jpncs |
|---|
| 301 | ! |
|---|
| 302 | ! The following if avoids the redistribution of the round off |
|---|
| 303 | IF ( ABS(zfwf(jc) / surf(jpncs+1) ) > rsmall) THEN |
|---|
| 304 | ! |
|---|
| 305 | IF( ncstt(jc) == 0 ) THEN ! water/evap excess is shared by all open ocean |
|---|
| 306 | zcoef = zfwf(jc) / surf(jpncs+1) |
|---|
| 307 | zcoef1 = rcp * zcoef |
|---|
| 308 | emp(:,:) = emp(:,:) + zcoef |
|---|
| 309 | qns(:,:) = qns(:,:) - zcoef1 * sst_m(:,:) |
|---|
| 310 | ! accumulate closed seas correction |
|---|
| 311 | zcorr = zcorr + zcoef |
|---|
| 312 | ! |
|---|
| 313 | ELSEIF( ncstt(jc) == 1 ) THEN ! Excess water in open sea, at outflow location, excess evap shared |
|---|
| 314 | IF ( zfwf(jc) <= 0.e0_wp ) THEN |
|---|
| 315 | DO jn = 1, ncsnr(jc) |
|---|
| 316 | ji = mi0(ncsir(jc,jn)) |
|---|
| 317 | jj = mj0(ncsjr(jc,jn)) ! Location of outflow in open ocean |
|---|
| 318 | IF ( ji > 1 .AND. ji < jpi & |
|---|
| 319 | .AND. jj > 1 .AND. jj < jpj ) THEN |
|---|
| 320 | zcoef = zfwf(jc) / ( REAL(ncsnr(jc)) * e1e2t(ji,jj) ) |
|---|
| 321 | zcoef1 = rcp * zcoef |
|---|
| 322 | emp(ji,jj) = emp(ji,jj) + zcoef |
|---|
| 323 | qns(ji,jj) = qns(ji,jj) - zcoef1 * sst_m(ji,jj) |
|---|
| 324 | ENDIF |
|---|
| 325 | END DO |
|---|
| 326 | ELSE |
|---|
| 327 | zcoef = zfwf(jc) / surf(jpncs+1) |
|---|
| 328 | zcoef1 = rcp * zcoef |
|---|
| 329 | emp(:,:) = emp(:,:) + zcoef |
|---|
| 330 | qns(:,:) = qns(:,:) - zcoef1 * sst_m(:,:) |
|---|
| 331 | ! accumulate closed seas correction |
|---|
| 332 | zcorr = zcorr + zcoef |
|---|
| 333 | ENDIF |
|---|
| 334 | ELSEIF( ncstt(jc) == 2 ) THEN ! Excess e-p-r (either sign) goes to open ocean, at outflow location |
|---|
| 335 | DO jn = 1, ncsnr(jc) |
|---|
| 336 | ji = mi0(ncsir(jc,jn)) |
|---|
| 337 | jj = mj0(ncsjr(jc,jn)) ! Location of outflow in open ocean |
|---|
| 338 | IF( ji > 1 .AND. ji < jpi & |
|---|
| 339 | .AND. jj > 1 .AND. jj < jpj ) THEN |
|---|
| 340 | zcoef = zfwf(jc) / ( REAL(ncsnr(jc)) * e1e2t(ji,jj) ) |
|---|
| 341 | zcoef1 = rcp * zcoef |
|---|
| 342 | emp(ji,jj) = emp(ji,jj) + zcoef |
|---|
| 343 | qns(ji,jj) = qns(ji,jj) - zcoef1 * sst_m(ji,jj) |
|---|
| 344 | ENDIF |
|---|
| 345 | END DO |
|---|
| 346 | ENDIF |
|---|
| 347 | ! |
|---|
| 348 | DO jj = ncsj1(jc), ncsj2(jc) |
|---|
| 349 | DO ji = ncsi1(jc), ncsi2(jc) |
|---|
| 350 | zcoef = zfwf(jc) / surf(jc) |
|---|
| 351 | zcoef1 = rcp * zcoef |
|---|
| 352 | emp(ji,jj) = emp(ji,jj) - zcoef |
|---|
| 353 | qns(ji,jj) = qns(ji,jj) + zcoef1 * sst_m(ji,jj) |
|---|
| 354 | END DO |
|---|
| 355 | END DO |
|---|
| 356 | ! |
|---|
| 357 | END IF |
|---|
| 358 | END DO |
|---|
| 359 | |
|---|
| 360 | IF ( ABS(zcorr) > rsmall ) THEN ! remove the global correction from the closed seas |
|---|
| 361 | DO jc = 1, jpncs ! only if it is large enough |
|---|
| 362 | DO jj = ncsj1(jc), ncsj2(jc) |
|---|
| 363 | DO ji = ncsi1(jc), ncsi2(jc) |
|---|
| 364 | emp(ji,jj) = emp(ji,jj) - zcorr |
|---|
| 365 | qns(ji,jj) = qns(ji,jj) + rcp * zcorr * sst_m(ji,jj) |
|---|
| 366 | END DO |
|---|
| 367 | END DO |
|---|
| 368 | END DO |
|---|
| 369 | ENDIF |
|---|
| 370 | ! |
|---|
| 371 | emp (:,:) = emp (:,:) * tmask(:,:,1) |
|---|
| 372 | ! |
|---|
| 373 | CALL lbc_lnk( emp , 'T', 1._wp ) |
|---|
| 374 | ! |
|---|
| 375 | IF( nn_timing == 1 ) CALL timing_stop('sbc_clo') |
|---|
| 376 | ! |
|---|
| 377 | END SUBROUTINE sbc_clo |
|---|
| 378 | |
|---|
| 379 | |
|---|
| 380 | SUBROUTINE clo_rnf( p_rnfmsk ) |
|---|
| 381 | !!--------------------------------------------------------------------- |
|---|
| 382 | !! *** ROUTINE sbc_rnf *** |
|---|
| 383 | !! |
|---|
| 384 | !! ** Purpose : allow the treatment of closed sea outflow grid-points |
|---|
| 385 | !! to be the same as river mouth grid-points |
|---|
| 386 | !! |
|---|
| 387 | !! ** Method : set to 1 the runoff mask (mskrnf, see sbcrnf module) |
|---|
| 388 | !! at the closed sea outflow grid-point. |
|---|
| 389 | !! |
|---|
| 390 | !! ** Action : update (p_)mskrnf (set 1 at closed sea outflow) |
|---|
| 391 | !!---------------------------------------------------------------------- |
|---|
| 392 | REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) :: p_rnfmsk ! river runoff mask (rnfmsk array) |
|---|
| 393 | ! |
|---|
| 394 | INTEGER :: jc, jn, ji, jj ! dummy loop indices |
|---|
| 395 | !!---------------------------------------------------------------------- |
|---|
| 396 | ! |
|---|
| 397 | DO jc = 1, jpncs |
|---|
| 398 | IF( ncstt(jc) >= 1 ) THEN ! runoff mask set to 1 at closed sea outflows |
|---|
| 399 | DO jn = 1, 4 |
|---|
| 400 | DO jj = mj0( ncsjr(jc,jn) ), mj1( ncsjr(jc,jn) ) |
|---|
| 401 | DO ji = mi0( ncsir(jc,jn) ), mi1( ncsir(jc,jn) ) |
|---|
| 402 | p_rnfmsk(ji,jj) = MAX( p_rnfmsk(ji,jj), 1.0_wp ) |
|---|
| 403 | END DO |
|---|
| 404 | END DO |
|---|
| 405 | END DO |
|---|
| 406 | ENDIF |
|---|
| 407 | END DO |
|---|
| 408 | ! |
|---|
| 409 | END SUBROUTINE clo_rnf |
|---|
| 410 | |
|---|
| 411 | |
|---|
| 412 | SUBROUTINE clo_ups( p_upsmsk ) |
|---|
| 413 | !!--------------------------------------------------------------------- |
|---|
| 414 | !! *** ROUTINE sbc_rnf *** |
|---|
| 415 | !! |
|---|
| 416 | !! ** Purpose : allow the treatment of closed sea outflow grid-points |
|---|
| 417 | !! to be the same as river mouth grid-points |
|---|
| 418 | !! |
|---|
| 419 | !! ** Method : set to 0.5 the upstream mask (upsmsk, see traadv_cen2 |
|---|
| 420 | !! module) over the closed seas. |
|---|
| 421 | !! |
|---|
| 422 | !! ** Action : update (p_)upsmsk (set 0.5 over closed seas) |
|---|
| 423 | !!---------------------------------------------------------------------- |
|---|
| 424 | REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) :: p_upsmsk ! upstream mask (upsmsk array) |
|---|
| 425 | ! |
|---|
| 426 | INTEGER :: jc, ji, jj ! dummy loop indices |
|---|
| 427 | !!---------------------------------------------------------------------- |
|---|
| 428 | ! |
|---|
| 429 | DO jc = 1, jpncs |
|---|
| 430 | DO jj = ncsj1(jc), ncsj2(jc) |
|---|
| 431 | DO ji = ncsi1(jc), ncsi2(jc) |
|---|
| 432 | p_upsmsk(ji,jj) = 0.5_wp ! mixed upstream/centered scheme over closed seas |
|---|
| 433 | END DO |
|---|
| 434 | END DO |
|---|
| 435 | END DO |
|---|
| 436 | ! |
|---|
| 437 | END SUBROUTINE clo_ups |
|---|
| 438 | |
|---|
| 439 | |
|---|
| 440 | SUBROUTINE clo_bat( pbat, kbat ) |
|---|
| 441 | !!--------------------------------------------------------------------- |
|---|
| 442 | !! *** ROUTINE clo_bat *** |
|---|
| 443 | !! |
|---|
| 444 | !! ** Purpose : suppress closed sea from the domain |
|---|
| 445 | !! |
|---|
| 446 | !! ** Method : set to 0 the meter and level bathymetry (given in |
|---|
| 447 | !! arguments) over the closed seas. |
|---|
| 448 | !! |
|---|
| 449 | !! ** Action : set pbat=0 and kbat=0 over closed seas |
|---|
| 450 | !!---------------------------------------------------------------------- |
|---|
| 451 | REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) :: pbat ! bathymetry in meters (bathy array) |
|---|
| 452 | INTEGER , DIMENSION(jpi,jpj), INTENT(inout) :: kbat ! bathymetry in levels (mbathy array) |
|---|
| 453 | ! |
|---|
| 454 | INTEGER :: jc, ji, jj ! dummy loop indices |
|---|
| 455 | !!---------------------------------------------------------------------- |
|---|
| 456 | ! |
|---|
| 457 | DO jc = 1, jpncs |
|---|
| 458 | DO jj = ncsj1(jc), ncsj2(jc) |
|---|
| 459 | DO ji = ncsi1(jc), ncsi2(jc) |
|---|
| 460 | pbat(ji,jj) = 0._wp |
|---|
| 461 | kbat(ji,jj) = 0 |
|---|
| 462 | END DO |
|---|
| 463 | END DO |
|---|
| 464 | END DO |
|---|
| 465 | ! |
|---|
| 466 | END SUBROUTINE clo_bat |
|---|
| 467 | |
|---|
| 468 | !!====================================================================== |
|---|
| 469 | END MODULE closea |
|---|
| 470 | |
|---|
