New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsbc.F90 in branches/UKMO/dev_r5107_eorca025_closea/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/UKMO/dev_r5107_eorca025_closea/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zsbc.F90 @ 5535

Last change on this file since 5535 was 5535, checked in by davestorkey, 9 years ago

Update UKMO/dev_r5107_eorca025_closea branch to rev 5518 of trunk
(= branching point of NEMO 3.6_stable).

File size: 25.7 KB
Line 
1MODULE p4zsbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   'key_pisces'                                       PISCES bio-model
11   !!----------------------------------------------------------------------
12   !!   p4z_sbc        :  Read and interpolate time-varying nutrients fluxes
13   !!   p4z_sbc_init   :  Initialization of p4z_sbc
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE iom             !  I/O manager
19   USE fldread         !  time interpolation
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   p4z_sbc
25   PUBLIC   p4z_sbc_init   
26
27   !! * Shared module variables
28   LOGICAL , PUBLIC  :: ln_dust     !: boolean for dust input from the atmosphere
29   LOGICAL , PUBLIC  :: ln_solub    !: boolean for variable solubility of atmospheric iron
30   LOGICAL , PUBLIC  :: ln_river    !: boolean for river input of nutrients
31   LOGICAL , PUBLIC  :: ln_ndepo    !: boolean for atmospheric deposition of N
32   LOGICAL , PUBLIC  :: ln_ironsed  !: boolean for Fe input from sediments
33   LOGICAL , PUBLIC  :: ln_hydrofe  !: boolean for Fe input from hydrothermal vents
34   LOGICAL , PUBLIC  :: ln_ironice  !: boolean for Fe input from sea ice
35   REAL(wp), PUBLIC  :: sedfeinput  !: Coastal release of Iron
36   REAL(wp), PUBLIC  :: dustsolub   !: Solubility of the dust
37   REAL(wp), PUBLIC  :: mfrac       !: Mineral Content of the dust
38   REAL(wp), PUBLIC  :: icefeinput  !: Iron concentration in sea ice
39   REAL(wp), PUBLIC  :: wdust       !: Sinking speed of the dust
40   REAL(wp), PUBLIC  :: nitrfix     !: Nitrogen fixation rate   
41   REAL(wp), PUBLIC  :: diazolight  !: Nitrogen fixation sensitivty to light
42   REAL(wp), PUBLIC  :: concfediaz  !: Fe half-saturation Cste for diazotrophs
43   REAL(wp)          :: hratio      !: Fe:3He ratio assumed for vent iron supply
44
45   LOGICAL , PUBLIC  :: ll_sbc
46
47   !! * Module variables
48   LOGICAL  ::  ll_solub
49
50   INTEGER , PARAMETER  :: jpriv  = 7   !: Maximum number of river input fields
51   INTEGER , PARAMETER  :: jr_dic = 1   !: index of dissolved inorganic carbon
52   INTEGER , PARAMETER  :: jr_doc = 2   !: index of dissolved organic carbon
53   INTEGER , PARAMETER  :: jr_din = 3   !: index of dissolved inorganic nitrogen
54   INTEGER , PARAMETER  :: jr_don = 4   !: index of dissolved organic nitrogen
55   INTEGER , PARAMETER  :: jr_dip = 5   !: index of dissolved inorganic phosporus
56   INTEGER , PARAMETER  :: jr_dop = 6   !: index of dissolved organic phosphorus
57   INTEGER , PARAMETER  :: jr_dsi = 7   !: index of dissolved silicate
58
59
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_solub      ! structure of input dust
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_river  ! structure of input riverdic
63   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ndepo     ! structure of input nitrogen deposition
64   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
65   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from hydrothermal vents
66
67   INTEGER , PARAMETER :: nbtimes = 365  !: maximum number of times record in a file
68   INTEGER  :: ntimes_dust, ntimes_riv, ntimes_ndep       ! number of time steps in a file
69   INTEGER  :: ntimes_solub, ntimes_hydro                 ! number of time steps in a file
70
71   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: dust, solub       !: dust fields
72   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdic, rivalk    !: river input fields
73   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdin, rivdip    !: river input fields
74   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: rivdsi    !: river input fields
75   REAL(wp), PUBLIC, ALLOCATABLE, SAVE,   DIMENSION(:,:) :: nitdep    !: atmospheric N deposition
76   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ironsed   !: Coastal supply of iron
77   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: hydrofe   !: Hydrothermal vent supply of iron
78
79   REAL(wp), PUBLIC :: sumdepsi, rivalkinput, rivdicinput, nitdepinput
80   REAL(wp), PUBLIC :: rivdininput, rivdipinput, rivdsiinput
81
82
83   !!* Substitution
84#  include "top_substitute.h90"
85   !!----------------------------------------------------------------------
86   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
87   !! $Id$
88   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
89   !!----------------------------------------------------------------------
90
91CONTAINS
92
93   SUBROUTINE p4z_sbc( kt )
94      !!----------------------------------------------------------------------
95      !!                  ***  routine p4z_sbc  ***
96      !!
97      !! ** purpose :   read and interpolate the external sources of nutrients
98      !!
99      !! ** method  :   read the files and interpolate the appropriate variables
100      !!
101      !! ** input   :   external netcdf files
102      !!
103      !!----------------------------------------------------------------------
104      !! * arguments
105      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
106
107      !! * local declarations
108      INTEGER  :: ji,jj 
109      REAL(wp) :: zcoef, zyyss
110      !!---------------------------------------------------------------------
111      !
112      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc')
113
114      !
115      ! Compute dust at nit000 or only if there is more than 1 time record in dust file
116      IF( ln_dust ) THEN
117         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_dust > 1 ) ) THEN
118            CALL fld_read( kt, 1, sf_dust )
119            IF( nn_ice_tr == -1 .AND. .NOT. ln_ironice ) THEN
120               dust(:,:) = sf_dust(1)%fnow(:,:,1)
121            ELSE
122               dust(:,:) = sf_dust(1)%fnow(:,:,1) * ( 1.0 - fr_i(:,:) )
123            ENDIF
124         ENDIF
125      ENDIF
126
127      IF( ll_solub ) THEN
128         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_solub > 1 ) ) THEN
129            CALL fld_read( kt, 1, sf_solub )
130            solub(:,:) = sf_solub(1)%fnow(:,:,1)
131         ENDIF
132      ENDIF
133
134      ! N/P and Si releases due to coastal rivers
135      ! Compute river at nit000 or only if there is more than 1 time record in river file
136      ! -----------------------------------------
137      IF( ln_river ) THEN
138         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_riv > 1 ) ) THEN
139            CALL fld_read( kt, 1, sf_river )
140            DO jj = 1, jpj
141               DO ji = 1, jpi
142                  zcoef = ryyss * e1e2t(ji,jj) * h_rnf(ji,jj) 
143                  rivalk(ji,jj) =   sf_river(jr_dic)%fnow(ji,jj,1)                                    &
144                     &              * 1.E3        / ( 12. * zcoef + rtrn )
145                  rivdic(ji,jj) = ( sf_river(jr_dic)%fnow(ji,jj,1) + sf_river(jr_doc)%fnow(ji,jj,1) ) &
146                     &              * 1.E3         / ( 12. * zcoef + rtrn )
147                  rivdin(ji,jj) = ( sf_river(jr_din)%fnow(ji,jj,1) + sf_river(jr_don)%fnow(ji,jj,1) ) &
148                     &              * 1.E3 / rno3 / ( 14. * zcoef + rtrn )
149                  rivdip(ji,jj) = ( sf_river(jr_dip)%fnow(ji,jj,1) + sf_river(jr_dop)%fnow(ji,jj,1) ) &
150                     &              * 1.E3 / po4r / ( 31. * zcoef + rtrn )
151                  rivdsi(ji,jj) =   sf_river(jr_dsi)%fnow(ji,jj,1)                                    &
152                     &              * 1.E3        / ( 28.1 * zcoef + rtrn )
153               END DO
154            END DO
155         ENDIF
156      ENDIF
157
158      ! Compute N deposition at nit000 or only if there is more than 1 time record in N deposition file
159      IF( ln_ndepo ) THEN
160         IF( kt == nit000 .OR. ( kt /= nit000 .AND. ntimes_ndep > 1 ) ) THEN
161            CALL fld_read( kt, 1, sf_ndepo )
162            DO jj = 1, jpj
163               DO ji = 1, jpi
164                  nitdep(ji,jj) = sf_ndepo(1)%fnow(ji,jj,1) / rno3 / ( 14E6 * ryyss * fse3t(ji,jj,1) + rtrn )
165               END DO
166            END DO
167         ENDIF
168      ENDIF
169      !
170      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc')
171      !
172   END SUBROUTINE p4z_sbc
173
174   SUBROUTINE p4z_sbc_init
175
176      !!----------------------------------------------------------------------
177      !!                  ***  routine p4z_sbc_init  ***
178      !!
179      !! ** purpose :   initialization of the external sources of nutrients
180      !!
181      !! ** method  :   read the files and compute the budget
182      !!                called at the first timestep (nittrc000)
183      !!
184      !! ** input   :   external netcdf files
185      !!
186      !!----------------------------------------------------------------------
187      !
188      INTEGER  :: ji, jj, jk, jm, ifpr
189      INTEGER  :: ii0, ii1, ij0, ij1
190      INTEGER  :: numdust, numsolub, numriv, numiron, numdepo, numhydro
191      INTEGER  :: ierr, ierr1, ierr2, ierr3
192      INTEGER  :: ios                 ! Local integer output status for namelist read
193      INTEGER  :: ik50                !  last level where depth less than 50 m
194      INTEGER  :: isrow             ! index for ORCA1 starting row
195      REAL(wp) :: zexpide, zdenitide, zmaskt
196      REAL(wp) :: ztimes_dust, ztimes_riv, ztimes_ndep 
197      REAL(wp), DIMENSION(nbtimes) :: zsteps                 ! times records
198      REAL(wp), DIMENSION(:), ALLOCATABLE :: rivinput
199      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zdust, zndepo, zriver, zcmask
200      !
201      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
202      TYPE(FLD_N), DIMENSION(jpriv) ::  slf_river    ! array of namelist informations on the fields to read
203      TYPE(FLD_N) ::   sn_dust, sn_solub, sn_ndepo, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
204      TYPE(FLD_N) ::   sn_riverdoc, sn_riverdic, sn_riverdsi   ! informations about the fields to be read
205      TYPE(FLD_N) ::   sn_riverdin, sn_riverdon, sn_riverdip, sn_riverdop
206      !
207      NAMELIST/nampissbc/cn_dir, sn_dust, sn_solub, sn_riverdic, sn_riverdoc, sn_riverdin, sn_riverdon,     &
208        &                sn_riverdip, sn_riverdop, sn_riverdsi, sn_ndepo, sn_ironsed, sn_hydrofe, &
209        &                ln_dust, ln_solub, ln_river, ln_ndepo, ln_ironsed, ln_ironice, ln_hydrofe,    &
210        &                sedfeinput, dustsolub, icefeinput, wdust, mfrac, nitrfix, diazolight, concfediaz, hratio
211      !!----------------------------------------------------------------------
212      !
213      IF( nn_timing == 1 )  CALL timing_start('p4z_sbc_init')
214      !
215      !                            !* set file information
216      REWIND( numnatp_ref )              ! Namelist nampissbc in reference namelist : Pisces external sources of nutrients
217      READ  ( numnatp_ref, nampissbc, IOSTAT = ios, ERR = 901)
218901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in reference namelist', lwp )
219
220      REWIND( numnatp_cfg )              ! Namelist nampissbc in configuration namelist : Pisces external sources of nutrients
221      READ  ( numnatp_cfg, nampissbc, IOSTAT = ios, ERR = 902 )
222902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampissbc in configuration namelist', lwp )
223      IF(lwm) WRITE ( numonp, nampissbc )
224
225      IF ( ( nn_ice_tr >= 0 ) .AND. ln_ironice ) THEN
226         IF(lwp) THEN
227            WRITE(numout,*) ' ln_ironice incompatible with nn_ice_tr = ', nn_ice_tr
228            WRITE(numout,*) ' Specify your sea ice iron concentration in nampisice instead '
229            WRITE(numout,*) ' ln_ironice is forced to .FALSE. '
230            ln_ironice = .FALSE.
231         ENDIF
232      ENDIF
233
234      IF(lwp) THEN
235         WRITE(numout,*) ' '
236         WRITE(numout,*) ' namelist : nampissbc '
237         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~ '
238         WRITE(numout,*) '    dust input from the atmosphere           ln_dust     = ', ln_dust
239         WRITE(numout,*) '    Variable solubility of iron input        ln_solub    = ', ln_solub
240         WRITE(numout,*) '    river input of nutrients                 ln_river    = ', ln_river
241         WRITE(numout,*) '    atmospheric deposition of n              ln_ndepo    = ', ln_ndepo
242         WRITE(numout,*) '    Fe input from sediments                  ln_ironsed  = ', ln_ironsed
243         WRITE(numout,*) '    Fe input from seaice                     ln_ironice  = ', ln_ironice
244         WRITE(numout,*) '    fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
245         WRITE(numout,*) '    coastal release of iron                  sedfeinput  = ', sedfeinput
246         WRITE(numout,*) '    solubility of the dust                   dustsolub   = ', dustsolub
247         WRITE(numout,*) '    Mineral Fe content of the dust           mfrac       = ', mfrac
248         WRITE(numout,*) '    Iron concentration in sea ice            icefeinput  = ', icefeinput
249         WRITE(numout,*) '    sinking speed of the dust                wdust       = ', wdust
250         WRITE(numout,*) '    nitrogen fixation rate                   nitrfix     = ', nitrfix
251         WRITE(numout,*) '    nitrogen fixation sensitivty to light    diazolight  = ', diazolight
252         WRITE(numout,*) '    fe half-saturation cste for diazotrophs  concfediaz  = ', concfediaz
253         WRITE(numout,*) '    Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
254      END IF
255
256      IF( ln_dust .OR. ln_river .OR. ln_ndepo ) THEN  ;  ll_sbc = .TRUE.
257      ELSE                                            ;  ll_sbc = .FALSE.
258      ENDIF
259
260      IF( ln_dust .AND. ln_solub ) THEN               ;  ll_solub = .TRUE.
261      ELSE                                            ;  ll_solub = .FALSE.
262      ENDIF
263
264      ! set the number of level over which river runoffs are applied
265      ! online configuration : computed in sbcrnf
266      IF( lk_offline ) THEN
267        nk_rnf(:,:) = 1
268        h_rnf (:,:) = fsdept(:,:,1)
269      ENDIF
270
271      ! dust input from the atmosphere
272      ! ------------------------------
273      IF( ln_dust ) THEN 
274         !
275         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
276         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
277         !
278         ALLOCATE( dust(jpi,jpj) )    ! allocation
279         !
280         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
281         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
282         !
283         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
284                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
285         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
286         !
287         IF( Agrif_Root() ) THEN   !  Only on the master grid
288            ! Get total input dust ; need to compute total atmospheric supply of Si in a year
289            CALL iom_open (  TRIM( sn_dust%clname ) , numdust )
290            CALL iom_gettime( numdust, zsteps, kntime=ntimes_dust)  ! get number of record in file
291            ALLOCATE( zdust(jpi,jpj,ntimes_dust) )
292            DO jm = 1, ntimes_dust
293               CALL iom_get( numdust, jpdom_data, TRIM( sn_dust%clvar ), zdust(:,:,jm), jm )
294            END DO
295            CALL iom_close( numdust )
296            ztimes_dust = 1._wp / FLOAT( ntimes_dust ) 
297            sumdepsi = 0.e0
298            DO jm = 1, ntimes_dust
299               sumdepsi = sumdepsi + glob_sum( zdust(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_dust )
300            ENDDO
301            sumdepsi = sumdepsi / ( nyear_len(1) * rday ) * 12. * 8.8 * 0.075 * mfrac / 28.1 
302            DEALLOCATE( zdust)
303         ENDIF
304      ELSE
305         sumdepsi  = 0._wp
306      END IF
307
308      ! Solubility of dust deposition of iron
309      ! Only if ln_dust and ln_solubility set to true (ll_solub = .true.)
310      ! -----------------------------------------------------------------
311      IF( ll_solub ) THEN
312         !
313         IF(lwp) WRITE(numout,*) '    initialize variable solubility of Fe '
314         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
315         !
316         ALLOCATE( solub(jpi,jpj) )    ! allocation
317         !
318         ALLOCATE( sf_solub(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
319         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_solub structure' )
320         !
321         CALL fld_fill( sf_solub, (/ sn_solub /), cn_dir, 'p4z_sed_init', 'Solubility of atm. iron ', 'nampissed' )
322                                   ALLOCATE( sf_solub(1)%fnow(jpi,jpj,1)   )
323         IF( sn_solub%ln_tint )    ALLOCATE( sf_solub(1)%fdta(jpi,jpj,1,2) )
324         ! get number of record in file
325         CALL iom_open (  TRIM( sn_solub%clname ) , numsolub )
326         CALL iom_gettime( numsolub, zsteps, kntime=ntimes_solub)  ! get number of record in file
327         CALL iom_close( numsolub )
328      ENDIF
329
330      ! nutrient input from rivers
331      ! --------------------------
332      IF( ln_river ) THEN
333         !
334         slf_river(jr_dic) = sn_riverdic  ;  slf_river(jr_doc) = sn_riverdoc  ;  slf_river(jr_din) = sn_riverdin 
335         slf_river(jr_don) = sn_riverdon  ;  slf_river(jr_dip) = sn_riverdip  ;  slf_river(jr_dop) = sn_riverdop
336         slf_river(jr_dsi) = sn_riverdsi 
337         !
338         ALLOCATE( rivdic(jpi,jpj), rivalk(jpi,jpj), rivdin(jpi,jpj), rivdip(jpi,jpj), rivdsi(jpi,jpj) ) 
339         !
340         ALLOCATE( sf_river(jpriv), rivinput(jpriv), STAT=ierr1 )           !* allocate and fill sf_river (forcing structure) with sn_river_
341         rivinput(:) = 0.0
342
343         IF( ierr1 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_irver structure' )
344         !
345         CALL fld_fill( sf_river, slf_river, cn_dir, 'p4z_sed_init', 'Input from river ', 'nampissed' )
346         DO ifpr = 1, jpriv
347                                          ALLOCATE( sf_river(ifpr)%fnow(jpi,jpj,1  ) )
348            IF( slf_river(ifpr)%ln_tint ) ALLOCATE( sf_river(ifpr)%fdta(jpi,jpj,1,2) )
349         END DO
350         IF( Agrif_Root() ) THEN   !  Only on the master grid
351            ! Get total input rivers ; need to compute total river supply in a year
352            DO ifpr = 1, jpriv
353               CALL iom_open ( TRIM( slf_river(ifpr)%clname ), numriv )
354               CALL iom_gettime( numriv, zsteps, kntime=ntimes_riv)
355               ALLOCATE( zriver(jpi,jpj,ntimes_riv) )
356               DO jm = 1, ntimes_riv
357                  CALL iom_get( numriv, jpdom_data, TRIM( slf_river(ifpr)%clvar ), zriver(:,:,jm), jm )
358               END DO
359               CALL iom_close( numriv )
360               ztimes_riv = 1._wp / FLOAT(ntimes_riv) 
361               DO jm = 1, ntimes_riv
362                  rivinput(ifpr) = rivinput(ifpr) + glob_sum( zriver(:,:,jm) * tmask(:,:,1) * ztimes_riv ) 
363               END DO
364               DEALLOCATE( zriver)
365            END DO
366            ! N/P and Si releases due to coastal rivers
367            ! -----------------------------------------
368            rivdicinput = (rivinput(jr_dic) + rivinput(jr_doc) ) * 1E3 / 12._wp
369            rivdininput = (rivinput(jr_din) + rivinput(jr_don) ) * 1E3 / rno3 / 14._wp
370            rivdipinput = (rivinput(jr_dip) + rivinput(jr_dop) ) * 1E3 / po4r / 31._wp
371            rivdsiinput = rivinput(jr_dsi) * 1E3 / 28.1_wp
372            rivalkinput = rivinput(jr_dic) * 1E3 / 12._wp
373            !
374         ENDIF
375      ELSE
376         rivdicinput = 0._wp
377         rivdininput = 0._wp
378         rivdipinput = 0._wp
379         rivdsiinput = 0._wp
380         rivalkinput = 0._wp
381      END IF 
382      ! nutrient input from dust
383      ! ------------------------
384      IF( ln_ndepo ) THEN
385         !
386         IF(lwp) WRITE(numout,*) '    initialize the nutrient input by dust from ndeposition.orca.nc'
387         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
388         !
389         ALLOCATE( nitdep(jpi,jpj) )    ! allocation
390         !
391         ALLOCATE( sf_ndepo(1), STAT=ierr3 )           !* allocate and fill sf_sst (forcing structure) with sn_sst
392         IF( ierr3 > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_ndepo structure' )
393         !
394         CALL fld_fill( sf_ndepo, (/ sn_ndepo /), cn_dir, 'p4z_sed_init', 'Nutrient atmospheric depositon ', 'nampissed' )
395                                   ALLOCATE( sf_ndepo(1)%fnow(jpi,jpj,1)   )
396         IF( sn_ndepo%ln_tint )    ALLOCATE( sf_ndepo(1)%fdta(jpi,jpj,1,2) )
397         !
398         IF( Agrif_Root() ) THEN   !  Only on the master grid
399            ! Get total input dust ; need to compute total atmospheric supply of N in a year
400            CALL iom_open ( TRIM( sn_ndepo%clname ), numdepo )
401            CALL iom_gettime( numdepo, zsteps, kntime=ntimes_ndep)
402            ALLOCATE( zndepo(jpi,jpj,ntimes_ndep) )
403            DO jm = 1, ntimes_ndep
404               CALL iom_get( numdepo, jpdom_data, TRIM( sn_ndepo%clvar ), zndepo(:,:,jm), jm )
405            END DO
406            CALL iom_close( numdepo )
407            ztimes_ndep = 1._wp / FLOAT( ntimes_ndep ) 
408            nitdepinput = 0._wp
409            DO jm = 1, ntimes_ndep
410              nitdepinput = nitdepinput + glob_sum( zndepo(:,:,jm) * e1e2t(:,:) * tmask(:,:,1) * ztimes_ndep )
411            ENDDO
412            nitdepinput = nitdepinput / rno3 / 14E6 
413            DEALLOCATE( zndepo)
414         ENDIF
415      ELSE
416         nitdepinput = 0._wp
417      ENDIF
418
419      ! coastal and island masks
420      ! ------------------------
421      IF( ln_ironsed ) THEN     
422         !
423         IF(lwp) WRITE(numout,*) '    computation of an island mask to enhance coastal supply of iron'
424         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
425         !
426         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
427         !
428         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
429         ALLOCATE( zcmask(jpi,jpj,jpk) )
430         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
431         CALL iom_close( numiron )
432         !
433         ik50 = 5        !  last level where depth less than 50 m
434         DO jk = jpkm1, 1, -1
435            IF( gdept_1d(jk) > 50. )  ik50 = jk - 1
436         END DO
437         IF (lwp) WRITE(numout,*)
438         IF (lwp) WRITE(numout,*) ' Level corresponding to 50m depth ',  ik50,' ', gdept_1d(ik50+1)
439         IF (lwp) WRITE(numout,*)
440         DO jk = 1, ik50
441            DO jj = 2, jpjm1
442               DO ji = fs_2, fs_jpim1
443                  IF( tmask(ji,jj,jk) /= 0. ) THEN
444                     zmaskt = tmask(ji+1,jj,jk) * tmask(ji-1,jj,jk) * tmask(ji,jj+1,jk)    &
445                        &                       * tmask(ji,jj-1,jk) * tmask(ji,jj,jk+1)
446                     IF( zmaskt == 0. )   zcmask(ji,jj,jk ) = MAX( 0.1, zcmask(ji,jj,jk) ) 
447                  END IF
448               END DO
449            END DO
450         END DO
451         !
452         CALL lbc_lnk( zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
453         !
454         DO jk = 1, jpk
455            DO jj = 1, jpj
456               DO ji = 1, jpi
457                  zexpide   = MIN( 8.,( fsdept(ji,jj,jk) / 500. )**(-1.5) )
458                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
459                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
460               END DO
461            END DO
462         END DO
463         ! Coastal supply of iron
464         ! -------------------------
465         ironsed(:,:,jpk) = 0._wp
466         DO jk = 1, jpkm1
467            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( fse3t(:,:,jk) * rday )
468         END DO
469         DEALLOCATE( zcmask)
470      ENDIF
471      !
472      ! Iron from Hydrothermal vents
473      ! ------------------------
474      IF( ln_hydrofe ) THEN
475         !
476         IF(lwp) WRITE(numout,*) '    Input of iron from hydrothermal vents '
477         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
478         !
479         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
480         !
481         CALL iom_open ( TRIM( sn_hydrofe%clname ), numhydro )
482         CALL iom_get  ( numhydro, jpdom_data, TRIM( sn_hydrofe%clvar ), hydrofe(:,:,:), 1 )
483         CALL iom_close( numhydro )
484         !
485         hydrofe(:,:,:) = ( hydrofe(:,:,:) * hratio ) / ( cvol(:,:,:) * ryyss + rtrn ) / 1000._wp
486         !
487      ENDIF
488      !
489      IF( ll_sbc ) CALL p4z_sbc( nit000 ) 
490      !
491      IF(lwp) THEN
492         WRITE(numout,*)
493         WRITE(numout,*) '    Total input of elements from river supply'
494         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
495         WRITE(numout,*) '    N Supply   : ', rivdininput*rno3*1E3/1E12*14.,' TgN/yr'
496         WRITE(numout,*) '    Si Supply  : ', rivdsiinput*1E3/1E12*28.1,' TgSi/yr'
497         WRITE(numout,*) '    P Supply   : ', rivdipinput*1E3*po4r/1E12*31.,' TgP/yr'
498         WRITE(numout,*) '    Alk Supply : ', rivalkinput*1E3/1E12,' Teq/yr'
499         WRITE(numout,*) '    DIC Supply : ', rivdicinput*1E3*12./1E12,'TgC/yr'
500         WRITE(numout,*) 
501         WRITE(numout,*) '    Total input of elements from atmospheric supply'
502         WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
503         WRITE(numout,*) '    N Supply   : ', nitdepinput*rno3*1E3/1E12*14.,' TgN/yr'
504         WRITE(numout,*) 
505      ENDIF
506      !
507      IF( nn_timing == 1 )  CALL timing_stop('p4z_sbc_init')
508      !
509   END SUBROUTINE p4z_sbc_init
510
511#else
512   !!======================================================================
513   !!  Dummy module :                                   No PISCES bio-model
514   !!======================================================================
515CONTAINS
516   SUBROUTINE p4z_sbc                         ! Empty routine
517   END SUBROUTINE p4z_sbc
518#endif 
519
520   !!======================================================================
521END MODULE  p4zsbc
Note: See TracBrowser for help on using the repository browser.