New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trdtra.F90 in branches/UKMO/dev_r5107_hadgem3_cplfld/trunk/NEMOGCM/NEMO/OPA_SRC/TRD – NEMO

source: branches/UKMO/dev_r5107_hadgem3_cplfld/trunk/NEMOGCM/NEMO/OPA_SRC/TRD/trdtra.F90 @ 5473

Last change on this file since 5473 was 5473, checked in by cguiavarch, 9 years ago

Clear svn keywords from UKMO/dev_r5107_hadgem3_cplfld

File size: 19.3 KB
Line 
1MODULE trdtra
2   !!======================================================================
3   !!                       ***  MODULE  trdtra  ***
4   !! Ocean diagnostics:  ocean tracers trends pre-processing
5   !!=====================================================================
6   !! History :  3.3  !  2010-06  (C. Ethe) creation for the TRA/TRC merge
7   !!            3.5  !  2012-02  (G. Madec) update the comments
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   trd_tra       : pre-process the tracer trends
12   !!   trd_tra_adv   : transform a div(U.T) trend into a U.grad(T) trend
13   !!   trd_tra_mng   : tracer trend manager: dispatch to the diagnostic modules
14   !!   trd_tra_iom   : output 3D tracer trends using IOM
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers variables
17   USE dom_oce        ! ocean domain
18   USE sbc_oce        ! surface boundary condition: ocean
19   USE zdf_oce        ! ocean vertical physics
20   USE trd_oce        ! trends: ocean variables
21   USE trdtrc         ! ocean passive mixed layer tracers trends
22   USE trdglo         ! trends: global domain averaged
23   USE trdpen         ! trends: Potential ENergy
24   USE trdmxl         ! ocean active mixed layer tracers trends
25   USE ldftra_oce     ! ocean active tracers lateral physics
26   USE zdfddm         ! vertical physics: double diffusion
27   USE phycst         ! physical constants
28   USE in_out_manager ! I/O manager
29   USE iom            ! I/O manager library
30   USE lib_mpp        ! MPP library
31   USE wrk_nemo       ! Memory allocation
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   trd_tra   ! called by all tra_... modules
37
38   REAL(wp) ::   r2dt   ! time-step, = 2 rdttra except at nit000 (=rdttra) if neuler=0
39
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   trdtx, trdty, trdt   ! use to store the temperature trends
41
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44#  include "zdfddm_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   INTEGER FUNCTION trd_tra_alloc()
54      !!---------------------------------------------------------------------
55      !!                  ***  FUNCTION trd_tra_alloc  ***
56      !!---------------------------------------------------------------------
57      ALLOCATE( trdtx(jpi,jpj,jpk) , trdty(jpi,jpj,jpk) , trdt(jpi,jpj,jpk) , STAT= trd_tra_alloc )
58      !
59      IF( lk_mpp             )   CALL mpp_sum ( trd_tra_alloc )
60      IF( trd_tra_alloc /= 0 )   CALL ctl_warn('trd_tra_alloc: failed to allocate arrays')
61   END FUNCTION trd_tra_alloc
62
63
64   SUBROUTINE trd_tra( kt, ctype, ktra, ktrd, ptrd, pun, ptra )
65      !!---------------------------------------------------------------------
66      !!                  ***  ROUTINE trd_tra  ***
67      !!
68      !! ** Purpose : pre-process tracer trends
69      !!
70      !! ** Method  : - mask the trend
71      !!              - advection (ptra present) converte the incoming flux (U.T)
72      !!              into trend (U.T => -U.grat(T)=div(U.T)-T.div(U)) through a
73      !!              call to trd_tra_adv
74      !!              - 'TRA' case : regroup T & S trends
75      !!              - send the trends to trd_tra_mng (trdtrc) for further processing
76      !!----------------------------------------------------------------------
77      INTEGER                         , INTENT(in)           ::   kt      ! time step
78      CHARACTER(len=3)                , INTENT(in)           ::   ctype   ! tracers trends type 'TRA'/'TRC'
79      INTEGER                         , INTENT(in)           ::   ktra    ! tracer index
80      INTEGER                         , INTENT(in)           ::   ktrd    ! tracer trend index
81      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in)           ::   ptrd    ! tracer trend  or flux
82      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL ::   pun     ! now velocity
83      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL ::   ptra    ! now tracer variable
84      !
85      INTEGER  ::   jk   ! loop indices
86      REAL(wp), POINTER, DIMENSION(:,:,:)  ::   zwt, zws, ztrdt, ztrds   ! 3D workspace
87      !!----------------------------------------------------------------------
88      !
89      CALL wrk_alloc( jpi, jpj, jpk, ztrds )
90      !     
91      IF( .NOT. ALLOCATED( trdtx ) ) THEN      ! allocate trdtra arrays
92         IF( trd_tra_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'trd_tra : unable to allocate arrays' )
93      ENDIF
94
95      IF( ctype == 'TRA' .AND. ktra == jp_tem ) THEN   !==  Temperature trend  ==!
96         !
97         SELECT CASE( ktrd )
98         !                            ! advection: transform the advective flux into a trend
99         CASE( jptra_xad )   ;   CALL trd_tra_adv( ptrd, pun, ptra, 'X', trdtx ) 
100         CASE( jptra_yad )   ;   CALL trd_tra_adv( ptrd, pun, ptra, 'Y', trdty ) 
101         CASE( jptra_zad )   ;   CALL trd_tra_adv( ptrd, pun, ptra, 'Z', trdt  ) 
102         CASE( jptra_bbc,    &        ! qsr, bbc: on temperature only, send to trd_tra_mng
103            &  jptra_qsr )   ;   trdt(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
104                                 ztrds(:,:,:) = 0._wp
105                                 CALL trd_tra_mng( trdt, ztrds, ktrd, kt )
106         CASE DEFAULT                 ! other trends: masked trends
107            trdt(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)              ! mask & store
108         END SELECT
109         !
110      ENDIF
111
112      IF( ctype == 'TRA' .AND. ktra == jp_sal ) THEN      !==  Salinity trends  ==!
113         !
114         SELECT CASE( ktrd )
115         !                            ! advection: transform the advective flux into a trend
116         !                            !            and send T & S trends to trd_tra_mng
117         CASE( jptra_xad  )   ;   CALL trd_tra_adv( ptrd , pun  , ptra, 'X'  , ztrds ) 
118                                  CALL trd_tra_mng( trdtx, ztrds, ktrd, kt   )
119         CASE( jptra_yad  )   ;   CALL trd_tra_adv( ptrd , pun  , ptra, 'Y'  , ztrds ) 
120                                  CALL trd_tra_mng( trdty, ztrds, ktrd, kt   )
121         CASE( jptra_zad  )   ;   CALL trd_tra_adv( ptrd , pun  , ptra, 'Z'  , ztrds ) 
122                                  CALL trd_tra_mng( trdt , ztrds, ktrd, kt   )
123         CASE( jptra_zdfp )           ! diagnose the "PURE" Kz trend (here: just before the swap)
124            !                         ! iso-neutral diffusion case otherwise jptra_zdf is "PURE"
125            CALL wrk_alloc( jpi, jpj, jpk, zwt, zws, ztrdt )
126            !
127            zwt(:,:, 1 ) = 0._wp   ;   zws(:,:, 1 ) = 0._wp            ! vertical diffusive fluxes
128            zwt(:,:,jpk) = 0._wp   ;   zws(:,:,jpk) = 0._wp
129            DO jk = 2, jpk
130               zwt(:,:,jk) =   avt(:,:,jk) * ( tsa(:,:,jk-1,jp_tem) - tsa(:,:,jk,jp_tem) ) / fse3w(:,:,jk) * tmask(:,:,jk)
131               zws(:,:,jk) = fsavs(:,:,jk) * ( tsa(:,:,jk-1,jp_sal) - tsa(:,:,jk,jp_sal) ) / fse3w(:,:,jk) * tmask(:,:,jk)
132            END DO
133            !
134            ztrdt(:,:,jpk) = 0._wp   ;   ztrds(:,:,jpk) = 0._wp
135            DO jk = 1, jpkm1
136               ztrdt(:,:,jk) = ( zwt(:,:,jk) - zwt(:,:,jk+1) ) / fse3t(:,:,jk)
137               ztrds(:,:,jk) = ( zws(:,:,jk) - zws(:,:,jk+1) ) / fse3t(:,:,jk) 
138            END DO
139            CALL trd_tra_mng( ztrdt, ztrds, jptra_zdfp, kt ) 
140            !
141            CALL wrk_dealloc( jpi, jpj, jpk, zwt, zws, ztrdt )
142            !
143         CASE DEFAULT                 ! other trends: mask and send T & S trends to trd_tra_mng
144            ztrds(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
145            CALL trd_tra_mng( trdt, ztrds, ktrd, kt ) 
146         END SELECT
147      ENDIF
148
149      IF( ctype == 'TRC' ) THEN                           !==  passive tracer trend  ==!
150         !
151         SELECT CASE( ktrd )
152         !                            ! advection: transform the advective flux into a masked trend
153         CASE( jptra_xad )   ;   CALL trd_tra_adv( ptrd , pun , ptra, 'X', ztrds ) 
154         CASE( jptra_yad )   ;   CALL trd_tra_adv( ptrd , pun , ptra, 'Y', ztrds ) 
155         CASE( jptra_zad )   ;   CALL trd_tra_adv( ptrd , pun , ptra, 'Z', ztrds ) 
156         CASE DEFAULT                 ! other trends: just masked
157                                 ztrds(:,:,:) = ptrd(:,:,:) * tmask(:,:,:)
158         END SELECT
159         !                            ! send trend to trd_trc
160         CALL trd_trc( ztrds, ktra, ktrd, kt ) 
161         !
162      ENDIF
163      !
164      CALL wrk_dealloc( jpi, jpj, jpk, ztrds )
165      !
166   END SUBROUTINE trd_tra
167
168
169   SUBROUTINE trd_tra_adv( pf, pun, ptn, cdir, ptrd )
170      !!---------------------------------------------------------------------
171      !!                  ***  ROUTINE trd_tra_adv  ***
172      !!
173      !! ** Purpose :   transformed a advective flux into a masked advective trends
174      !!
175      !! ** Method  :   use the following transformation: -div(U.T) = - U grad(T) + T.div(U)
176      !!       i-advective trends = -un. di-1[T] = -( di-1[fi] - tn di-1[un] )
177      !!       j-advective trends = -un. di-1[T] = -( dj-1[fi] - tn dj-1[un] )
178      !!       k-advective trends = -un. di+1[T] = -( dk+1[fi] - tn dk+1[un] )
179      !!                where fi is the incoming advective flux.
180      !!----------------------------------------------------------------------
181      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pf      ! advective flux in one direction
182      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pun     ! now velocity   in one direction
183      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   ptn     ! now or before tracer
184      CHARACTER(len=1)                , INTENT(in   ) ::   cdir    ! X/Y/Z direction
185      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   ptrd    ! advective trend in one direction
186      !
187      INTEGER  ::   ji, jj, jk   ! dummy loop indices
188      INTEGER  ::   ii, ij, ik   ! index shift as function of the direction
189      !!----------------------------------------------------------------------
190      !
191      SELECT CASE( cdir )      ! shift depending on the direction
192      CASE( 'X' )   ;   ii = 1   ;   ij = 0   ;   ik = 0      ! i-trend
193      CASE( 'Y' )   ;   ii = 0   ;   ij = 1   ;   ik = 0      ! j-trend
194      CASE( 'Z' )   ;   ii = 0   ;   ij = 0   ;   ik =-1      ! k-trend
195      END SELECT
196      !
197      !                        ! set to zero uncomputed values
198      ptrd(jpi,:,:) = 0._wp   ;   ptrd(1,:,:) = 0._wp
199      ptrd(:,jpj,:) = 0._wp   ;   ptrd(:,1,:) = 0._wp
200      ptrd(:,:,jpk) = 0._wp
201      !
202      DO jk = 1, jpkm1         ! advective trend
203         DO jj = 2, jpjm1
204            DO ji = fs_2, fs_jpim1   ! vector opt.
205               ptrd(ji,jj,jk) = - (     pf (ji,jj,jk) - pf (ji-ii,jj-ij,jk-ik)                        &
206                 &                  - ( pun(ji,jj,jk) - pun(ji-ii,jj-ij,jk-ik) ) * ptn(ji,jj,jk)  )   &
207                 &              / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )  * tmask(ji,jj,jk)
208            END DO
209         END DO
210      END DO
211      !
212   END SUBROUTINE trd_tra_adv
213
214
215   SUBROUTINE trd_tra_mng( ptrdx, ptrdy, ktrd, kt )
216      !!---------------------------------------------------------------------
217      !!                  ***  ROUTINE trd_tra_mng  ***
218      !!
219      !! ** Purpose :   Dispatch all tracer trends computation, e.g. 3D output,
220      !!                integral constraints, potential energy, and/or
221      !!                mixed layer budget.
222      !!----------------------------------------------------------------------
223      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdx   ! Temperature or U trend
224      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdy   ! Salinity    or V trend
225      INTEGER                   , INTENT(in   ) ::   ktrd    ! tracer trend index
226      INTEGER                   , INTENT(in   ) ::   kt      ! time step
227      !!----------------------------------------------------------------------
228
229      IF( neuler == 0 .AND. kt == nit000    ) THEN   ;   r2dt =      rdt      ! = rdtra (restart with Euler time stepping)
230      ELSEIF(               kt <= nit000 + 1) THEN   ;   r2dt = 2. * rdt      ! = 2 rdttra (leapfrog)
231      ENDIF
232
233      !                   ! 3D output of tracers trends using IOM interface
234      IF( ln_tra_trd )   CALL trd_tra_iom ( ptrdx, ptrdy, ktrd, kt )
235
236      !                   ! Integral Constraints Properties for tracers trends                                       !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
237      IF( ln_glo_trd )   CALL trd_glo( ptrdx, ptrdy, ktrd, 'TRA', kt )
238
239      !                   ! Potential ENergy trends
240      IF( ln_PE_trd  )   CALL trd_pen( ptrdx, ptrdy, ktrd, kt, r2dt )
241
242      !                   ! Mixed layer trends for active tracers
243      IF( ln_tra_mxl )   THEN   
244         !-----------------------------------------------------------------------------------------------
245         ! W.A.R.N.I.N.G :
246         ! jptra_ldf : called by traldf.F90
247         !                 at this stage we store:
248         !                  - the lateral geopotential diffusion (here, lateral = horizontal)
249         !                  - and the iso-neutral diffusion if activated
250         ! jptra_zdf : called by trazdf.F90
251         !                 * in case of iso-neutral diffusion we store the vertical diffusion component in the
252         !                   lateral trend including the K_z contrib, which will be removed later (see trd_mxl)
253         !-----------------------------------------------------------------------------------------------
254
255         SELECT CASE ( ktrd )
256         CASE ( jptra_xad )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_xad, '3D' )   ! zonal    advection
257         CASE ( jptra_yad )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_yad, '3D' )   ! merid.   advection
258         CASE ( jptra_zad )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_zad, '3D' )   ! vertical advection
259         CASE ( jptra_ldf )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_ldf, '3D' )   ! lateral  diffusion
260         CASE ( jptra_bbl )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_bbl, '3D' )   ! bottom boundary layer
261         CASE ( jptra_zdf )
262            IF( ln_traldf_iso ) THEN ; CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_ldf, '3D' )   ! lateral  diffusion (K_z)
263            ELSE                   ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_zdf, '3D' )   ! vertical diffusion (K_z)
264            ENDIF
265         CASE ( jptra_dmp )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_dmp, '3D' )   ! internal 3D restoring (tradmp)
266         CASE ( jptra_qsr )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_for, '3D' )   ! air-sea : penetrative sol radiat
267         CASE ( jptra_nsr )        ;   ptrdx(:,:,2:jpk) = 0._wp   ;   ptrdy(:,:,2:jpk) = 0._wp
268                                       CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_for, '2D' )   ! air-sea : non penetr sol radiation
269         CASE ( jptra_bbc )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_bbc, '3D' )   ! bottom bound cond (geoth flux)
270         CASE ( jptra_npc )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_npc, '3D' )   ! non penetr convect adjustment
271         CASE ( jptra_atf )        ;   CALL trd_mxl_zint( ptrdx, ptrdy, jpmxl_atf, '3D' )   ! asselin time filter (last trend)
272                                   !
273                                       CALL trd_mxl( kt, r2dt )                             ! trends: Mixed-layer (output)
274         END SELECT
275         !
276      ENDIF
277      !
278   END SUBROUTINE trd_tra_mng
279
280
281   SUBROUTINE trd_tra_iom( ptrdx, ptrdy, ktrd, kt )
282      !!---------------------------------------------------------------------
283      !!                  ***  ROUTINE trd_tra_iom  ***
284      !!
285      !! ** Purpose :   output 3D tracer trends using IOM
286      !!----------------------------------------------------------------------
287      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdx   ! Temperature or U trend
288      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   ptrdy   ! Salinity    or V trend
289      INTEGER                   , INTENT(in   ) ::   ktrd    ! tracer trend index
290      INTEGER                   , INTENT(in   ) ::   kt      ! time step
291      !!
292      INTEGER ::   ji, jj, jk   ! dummy loop indices
293      INTEGER ::   ikbu, ikbv   ! local integers
294      REAL(wp), POINTER, DIMENSION(:,:)   ::   z2dx, z2dy   ! 2D workspace
295      !!----------------------------------------------------------------------
296      !
297!!gm Rq: mask the trends already masked in trd_tra, but lbc_lnk should probably be added
298      !
299      SELECT CASE( ktrd )
300      CASE( jptra_xad  )   ;   CALL iom_put( "ttrd_xad" , ptrdx )        ! x- horizontal advection
301                               CALL iom_put( "strd_xad" , ptrdy )
302      CASE( jptra_yad  )   ;   CALL iom_put( "ttrd_yad" , ptrdx )        ! y- horizontal advection
303                               CALL iom_put( "strd_yad" , ptrdy )
304      CASE( jptra_zad  )   ;   CALL iom_put( "ttrd_zad" , ptrdx )        ! z- vertical   advection
305                               CALL iom_put( "strd_zad" , ptrdy )
306                               IF( .NOT. lk_vvl ) THEN                   ! cst volume : adv flux through z=0 surface
307                                  CALL wrk_alloc( jpi, jpj, z2dx, z2dy )
308                                  z2dx(:,:) = wn(:,:,1) * tsn(:,:,1,jp_tem) / fse3t(:,:,1)
309                                  z2dy(:,:) = wn(:,:,1) * tsn(:,:,1,jp_sal) / fse3t(:,:,1)
310                                  CALL iom_put( "ttrd_sad", z2dx )
311                                  CALL iom_put( "strd_sad", z2dy )
312                                  CALL wrk_dealloc( jpi, jpj, z2dx, z2dy )
313                               ENDIF
314      CASE( jptra_ldf  )   ;   CALL iom_put( "ttrd_ldf" , ptrdx )        ! lateral diffusion
315                               CALL iom_put( "strd_ldf" , ptrdy )
316      CASE( jptra_zdf  )   ;   CALL iom_put( "ttrd_zdf" , ptrdx )        ! vertical diffusion (including Kz contribution)
317                               CALL iom_put( "strd_zdf" , ptrdy )
318      CASE( jptra_zdfp )   ;   CALL iom_put( "ttrd_zdfp", ptrdx )        ! PURE vertical diffusion (no isoneutral contribution)
319                               CALL iom_put( "strd_zdfp", ptrdy )
320      CASE( jptra_dmp  )   ;   CALL iom_put( "ttrd_dmp" , ptrdx )        ! internal restoring (damping)
321                               CALL iom_put( "strd_dmp" , ptrdy )
322      CASE( jptra_bbl  )   ;   CALL iom_put( "ttrd_bbl" , ptrdx )        ! bottom boundary layer
323                               CALL iom_put( "strd_bbl" , ptrdy )
324      CASE( jptra_npc  )   ;   CALL iom_put( "ttrd_npc" , ptrdx )        ! static instability mixing
325                               CALL iom_put( "strd_npc" , ptrdy )
326      CASE( jptra_nsr  )   ;   CALL iom_put( "ttrd_qns" , ptrdx )        ! surface forcing + runoff (ln_rnf=T)
327                               CALL iom_put( "strd_cdt" , ptrdy )
328      CASE( jptra_qsr  )   ;   CALL iom_put( "ttrd_qsr" , ptrdx )        ! penetrative solar radiat. (only on temperature)
329      CASE( jptra_bbc  )   ;   CALL iom_put( "ttrd_bbc" , ptrdx )        ! geothermal heating   (only on temperature)
330      CASE( jptra_atf  )   ;   CALL iom_put( "ttrd_atf" , ptrdx )        ! asselin time Filter
331                               CALL iom_put( "strd_atf" , ptrdy )
332      END SELECT
333      !
334   END SUBROUTINE trd_tra_iom
335
336   !!======================================================================
337END MODULE trdtra
Note: See TracBrowser for help on using the repository browser.