source: branches/UKMO/dev_r5107_hadgem3_cplseq/NEMOGCM/NEMO/OPA_SRC/BDY/bdylib.F90 @ 5591

Last change on this file since 5591 was 5477, checked in by cguiavarch, 5 years ago

Clear svn keywords from UKMO/dev_r5107_hadgem3_cplseq

File size: 19.8 KB
Line 
1MODULE bdylib
2   !!======================================================================
3   !!                       ***  MODULE  bdylib  ***
4   !! Unstructured Open Boundary Cond. :  Library module of generic boundary algorithms.
5   !!======================================================================
6   !! History :  3.6  !  2013     (D. Storkey) new module
7   !!----------------------------------------------------------------------
8#if defined key_bdy 
9   !!----------------------------------------------------------------------
10   !!   'key_bdy' :                    Unstructured Open Boundary Condition
11   !!----------------------------------------------------------------------
12   !!   bdy_orlanski_2d
13   !!   bdy_orlanski_3d
14   !!----------------------------------------------------------------------
15   USE timing          ! Timing
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE bdy_oce         ! ocean open boundary conditions
19   USE phycst          ! physical constants
20   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
21   USE in_out_manager  !
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   bdy_orlanski_2d     ! routine called where?
27   PUBLIC   bdy_orlanski_3d     ! routine called where?
28
29   !!----------------------------------------------------------------------
30   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
31   !! $Id$
32   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
33   !!----------------------------------------------------------------------
34CONTAINS
35
36   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext, ll_npo )
37      !!----------------------------------------------------------------------
38      !!                 ***  SUBROUTINE bdy_orlanski_2d  ***
39      !!             
40      !!              - Apply Orlanski radiation condition adaptively to 2D fields:
41      !!                  - radiation plus weak nudging at outflow points
42      !!                  - no radiation and strong nudging at inflow points
43      !!
44      !!
45      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
46      !!----------------------------------------------------------------------
47      TYPE(OBC_INDEX),            INTENT(in)     ::   idx      ! BDY indices
48      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
49      REAL(wp), DIMENSION(:,:),   INTENT(in)     ::   phib     ! model before 2D field
50      REAL(wp), DIMENSION(:,:),   INTENT(inout)  ::   phia     ! model after 2D field (to be updated)
51      REAL(wp), DIMENSION(:),     INTENT(in)     ::   phi_ext  ! external forcing data
52      LOGICAL,                    INTENT(in)     ::   ll_npo   ! switch for NPO version
53
54      INTEGER  ::   jb                                     ! dummy loop indices
55      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
56      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
57      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
58      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
59      INTEGER  ::   flagu, flagv                           ! short cuts
60      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
61      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
62      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
63      REAL(wp) ::   zout, zwgt, zdy_centred
64      REAL(wp) ::   zdy_1, zdy_2, zsign_ups
65      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
66      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask      ! land/sea mask for field
67      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_xdif ! land/sea mask for x-derivatives
68      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_ydif ! land/sea mask for y-derivatives
69      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
70      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
71      !!----------------------------------------------------------------------
72
73      IF( nn_timing == 1 ) CALL timing_start('bdy_orlanski_2d')
74
75      ! ----------------------------------!
76      ! Orlanski boundary conditions     :!
77      ! ----------------------------------!
78     
79      SELECT CASE(igrd)
80         CASE(1)
81            pmask => tmask(:,:,1)
82            pmask_xdif => umask(:,:,1)
83            pmask_ydif => vmask(:,:,1)
84            pe_xdif => e1u(:,:)
85            pe_ydif => e2v(:,:)
86            ii_offset = 0
87            ij_offset = 0
88         CASE(2)
89            pmask => umask(:,:,1)
90            pmask_xdif => tmask(:,:,1)
91            pmask_ydif => fmask(:,:,1)
92            pe_xdif => e1t(:,:)
93            pe_ydif => e2f(:,:)
94            ii_offset = 1
95            ij_offset = 0
96         CASE(3)
97            pmask => vmask(:,:,1)
98            pmask_xdif => fmask(:,:,1)
99            pmask_ydif => tmask(:,:,1)
100            pe_xdif => e1f(:,:)
101            pe_ydif => e2t(:,:)
102            ii_offset = 0
103            ij_offset = 1
104         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
105      END SELECT
106      !
107      DO jb = 1, idx%nblenrim(igrd)
108         ii  = idx%nbi(jb,igrd)
109         ij  = idx%nbj(jb,igrd) 
110         flagu = int( idx%flagu(jb,igrd) )
111         flagv = int( idx%flagv(jb,igrd) )
112         !
113         ! Calculate positions of b-1 and b-2 points for this rim point
114         ! also (b-1,j-1) and (b-1,j+1) points
115         iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
116         ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
117          !
118         iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
119         ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
120         !
121         iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
122         ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
123         !
124         ! Calculate scale factors for calculation of spatial derivatives.       
125         zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
126        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
127         zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
128        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
129         zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
130        &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
131         zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
132        &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
133         ! make sure scale factors are nonzero
134         if( zey1 .lt. rsmall ) zey1 = zey2
135         if( zey2 .lt. rsmall ) zey2 = zey1
136         zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall)
137         zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
138         !
139         ! Calculate masks for calculation of spatial derivatives.       
140         zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          )         &
141        &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset) ) 
142         zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
143        &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
144         zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1)                  &
145        &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset) ) 
146
147         ! Calculation of terms required for both versions of the scheme.
148         ! Mask derivatives to ensure correct land boundary conditions for each variable.
149         ! Centred derivative is calculated as average of "left" and "right" derivatives for
150         ! this reason.
151         ! Note no rdt factor in expression for zdt because it cancels in the expressions for
152         ! zrx and zry.
153         zdt = phia(iibm1,ijbm1) - phib(iibm1,ijbm1)
154         zdx = ( ( phia(iibm1,ijbm1) - phia(iibm2,ijbm2) ) / zex2 ) * zmask_x 
155         zdy_1 = ( ( phib(iibm1   ,ijbm1   ) - phib(iibm1jm1,ijbm1jm1) ) / zey1 ) * zmask_y1   
156         zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1) - phib(iibm1   ,ijbm1)    ) / zey2 ) * zmask_y2 
157         zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
158!!$         zdy_centred = phib(iibm1jp1,ijbm1jp1) - phib(iibm1jm1,ijbm1jm1)
159         ! upstream differencing for tangential derivatives
160         zsign_ups = sign( 1., zdt * zdy_centred )
161         zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
162         zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
163         znor2 = zdx * zdx + zdy * zdy
164         znor2 = max(znor2,zepsilon)
165         !
166         zrx = zdt * zdx / ( zex1 * znor2 ) 
167!!$         zrx = min(zrx,2.0_wp)
168         zout = sign( 1., zrx )
169         zout = 0.5*( zout + abs(zout) )
170         zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
171         ! only apply radiation on outflow points
172         if( ll_npo ) then     !! NPO version !!
173            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
174           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
175           &                            + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
176         else                  !! full oblique radiation !!
177            zsign_ups = sign( 1., zdt * zdy )
178            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
179            zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
180            zry = zdt * zdy / ( zey * znor2 ) 
181            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
182           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
183           &                    - zsign_ups      * zry * ( phib(ii   ,ij   ) - phib(iijm1,ijjm1 ) ) &
184           &                    - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1) - phib(ii   ,ij    ) ) &
185           &                    + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
186         end if
187         phia(ii,ij) = phia(ii,ij) * pmask(ii,ij)
188      END DO
189      !
190      IF( nn_timing == 1 ) CALL timing_stop('bdy_orlanski_2d')
191
192   END SUBROUTINE bdy_orlanski_2d
193
194
195   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext, ll_npo )
196      !!----------------------------------------------------------------------
197      !!                 ***  SUBROUTINE bdy_orlanski_3d  ***
198      !!             
199      !!              - Apply Orlanski radiation condition adaptively to 3D fields:
200      !!                  - radiation plus weak nudging at outflow points
201      !!                  - no radiation and strong nudging at inflow points
202      !!
203      !!
204      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
205      !!----------------------------------------------------------------------
206      TYPE(OBC_INDEX),            INTENT(in)     ::   idx      ! BDY indices
207      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
208      REAL(wp), DIMENSION(:,:,:), INTENT(in)     ::   phib     ! model before 3D field
209      REAL(wp), DIMENSION(:,:,:), INTENT(inout)  ::   phia     ! model after 3D field (to be updated)
210      REAL(wp), DIMENSION(:,:),   INTENT(in)     ::   phi_ext  ! external forcing data
211      LOGICAL,                    INTENT(in)     ::   ll_npo   ! switch for NPO version
212
213      INTEGER  ::   jb, jk                                 ! dummy loop indices
214      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
215      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
216      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
217      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
218      INTEGER  ::   flagu, flagv                           ! short cuts
219      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
220      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
221      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
222      REAL(wp) ::   zout, zwgt, zdy_centred
223      REAL(wp) ::   zdy_1, zdy_2,  zsign_ups
224      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
225      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask      ! land/sea mask for field
226      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_xdif ! land/sea mask for x-derivatives
227      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_ydif ! land/sea mask for y-derivatives
228      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
229      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
230      !!----------------------------------------------------------------------
231
232      IF( nn_timing == 1 ) CALL timing_start('bdy_orlanski_3d')
233
234      ! ----------------------------------!
235      ! Orlanski boundary conditions     :!
236      ! ----------------------------------!
237     
238      SELECT CASE(igrd)
239         CASE(1)
240            pmask => tmask(:,:,:)
241            pmask_xdif => umask(:,:,:)
242            pmask_ydif => vmask(:,:,:)
243            pe_xdif => e1u(:,:)
244            pe_ydif => e2v(:,:)
245            ii_offset = 0
246            ij_offset = 0
247         CASE(2)
248            pmask => umask(:,:,:)
249            pmask_xdif => tmask(:,:,:)
250            pmask_ydif => fmask(:,:,:)
251            pe_xdif => e1t(:,:)
252            pe_ydif => e2f(:,:)
253            ii_offset = 1
254            ij_offset = 0
255         CASE(3)
256            pmask => vmask(:,:,:)
257            pmask_xdif => fmask(:,:,:)
258            pmask_ydif => tmask(:,:,:)
259            pe_xdif => e1f(:,:)
260            pe_ydif => e2t(:,:)
261            ii_offset = 0
262            ij_offset = 1
263         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
264      END SELECT
265
266      DO jk = 1, jpk
267         !           
268         DO jb = 1, idx%nblenrim(igrd)
269            ii  = idx%nbi(jb,igrd)
270            ij  = idx%nbj(jb,igrd) 
271            flagu = int( idx%flagu(jb,igrd) )
272            flagv = int( idx%flagv(jb,igrd) )
273            !
274            ! calculate positions of b-1 and b-2 points for this rim point
275            ! also (b-1,j-1) and (b-1,j+1) points
276            iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
277            ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
278            !
279            iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
280            ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
281            !
282            iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
283            ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
284            !
285            ! Calculate scale factors for calculation of spatial derivatives.       
286            zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
287           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
288            zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
289           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
290            zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
291           &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
292            zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
293           &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
294            ! make sure scale factors are nonzero
295            if( zey1 .lt. rsmall ) zey1 = zey2
296            if( zey2 .lt. rsmall ) zey2 = zey1
297            zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall); 
298            zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
299            !
300            ! Calculate masks for calculation of spatial derivatives.       
301            zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          ,jk)          &
302           &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset,jk) ) 
303            zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          ,jk)   & 
304           &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset,jk) ) 
305            zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1          ,jk)         &
306           &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset,jk) ) 
307            !
308            ! Calculate normal (zrx) and tangential (zry) components of radiation velocities.
309            ! Mask derivatives to ensure correct land boundary conditions for each variable.
310            ! Centred derivative is calculated as average of "left" and "right" derivatives for
311            ! this reason.
312            zdt = phia(iibm1,ijbm1,jk) - phib(iibm1,ijbm1,jk)
313            zdx = ( ( phia(iibm1,ijbm1,jk) - phia(iibm2,ijbm2,jk) ) / zex2 ) * zmask_x                 
314            zdy_1 = ( ( phib(iibm1   ,ijbm1   ,jk) - phib(iibm1jm1,ijbm1jm1,jk) ) / zey1 ) * zmask_y1 
315            zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1   ,ijbm1   ,jk) ) / zey2 ) * zmask_y2     
316            zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
317!!$            zdy_centred = phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1jm1,ijbm1jm1,jk)
318            ! upstream differencing for tangential derivatives
319            zsign_ups = sign( 1., zdt * zdy_centred )
320            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
321            zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
322            znor2 = zdx * zdx + zdy * zdy
323            znor2 = max(znor2,zepsilon)
324            !
325            ! update boundary value:
326            zrx = zdt * zdx / ( zex1 * znor2 )
327!!$            zrx = min(zrx,2.0_wp)
328            zout = sign( 1., zrx )
329            zout = 0.5*( zout + abs(zout) )
330            zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
331            ! only apply radiation on outflow points
332            if( ll_npo ) then     !! NPO version !!
333               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) &
334              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                     &
335              &                            + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
336            else                  !! full oblique radiation !!
337               zsign_ups = sign( 1., zdt * zdy )
338               zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
339               zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
340               zry = zdt * zdy / ( zey * znor2 ) 
341               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) )    &
342              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                        &
343              &                       - zsign_ups      * zry * ( phib(ii   ,ij   ,jk) - phib(iijm1,ijjm1,jk) ) &
344              &                       - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1,jk) - phib(ii   ,ij   ,jk) ) &
345              &                       + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
346            end if
347            phia(ii,ij,jk) = phia(ii,ij,jk) * pmask(ii,ij,jk)
348         END DO
349         !
350      END DO
351
352      IF( nn_timing == 1 ) CALL timing_stop('bdy_orlanski_3d')
353
354   END SUBROUTINE bdy_orlanski_3d
355
356
357#else
358   !!----------------------------------------------------------------------
359   !!   Dummy module                   NO Unstruct Open Boundary Conditions
360   !!----------------------------------------------------------------------
361CONTAINS
362   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext  )      ! Empty routine
363      WRITE(*,*) 'bdy_orlanski_2d: You should not have seen this print! error?', kt
364   END SUBROUTINE bdy_orlanski_2d
365   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext  )      ! Empty routine
366      WRITE(*,*) 'bdy_orlanski_3d: You should not have seen this print! error?', kt
367   END SUBROUTINE bdy_orlanski_3d
368#endif
369
370   !!======================================================================
371END MODULE bdylib
Note: See TracBrowser for help on using the repository browser.