New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limupdate2.F90 in branches/UKMO/dev_r5107_mld_zint/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/UKMO/dev_r5107_mld_zint/NEMOGCM/NEMO/LIM_SRC_3/limupdate2.F90 @ 5247

Last change on this file since 5247 was 5247, checked in by davestorkey, 9 years ago

UKMO mld_zint branch: clear SVN keywords and remove keyword property.

File size: 13.5 KB
Line 
1MODULE limupdate2
2   !!======================================================================
3   !!                     ***  MODULE  limupdate2  ***
4   !!   LIM-3 : Update of sea-ice global variables at the end of the time step
5   !!======================================================================
6   !! History :  3.0  !  2006-04  (M. Vancoppenolle) Original code
7   !!            3.6  !  2014-06  (C. Rousset)       Complete rewriting/cleaning
8   !!----------------------------------------------------------------------
9#if defined key_lim3
10   !!----------------------------------------------------------------------
11   !!   'key_lim3'                                      LIM3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!    lim_update2   : computes update of sea-ice global variables from trend terms
14   !!----------------------------------------------------------------------
15   USE limrhg          ! ice rheology
16
17   USE dom_oce
18   USE oce             ! dynamics and tracers variables
19   USE in_out_manager
20   USE sbc_oce         ! Surface boundary condition: ocean fields
21   USE sbc_ice         ! Surface boundary condition: ice fields
22   USE dom_ice
23   USE phycst          ! physical constants
24   USE ice
25   USE limdyn
26   USE limtrp
27   USE limthd
28   USE limsbc
29   USE limdiahsb
30   USE limwri
31   USE limrst
32   USE thd_ice         ! LIM thermodynamic sea-ice variables
33   USE par_ice
34   USE limitd_th
35   USE limitd_me
36   USE limvar
37   USE prtctl           ! Print control
38   USE lbclnk           ! lateral boundary condition - MPP exchanges
39   USE wrk_nemo         ! work arrays
40   USE lib_fortran     ! glob_sum
41   USE timing          ! Timing
42   USE limcons        ! conservation tests
43
44   IMPLICIT NONE
45   PRIVATE
46
47   PUBLIC   lim_update2   ! routine called by ice_step
48
49   !! * Substitutions
50#  include "vectopt_loop_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE lim_update2
59      !!-------------------------------------------------------------------
60      !!               ***  ROUTINE lim_update2  ***
61      !!               
62      !! ** Purpose :  Computes update of sea-ice global variables at
63      !!               the end of the time step.
64      !!
65      !!---------------------------------------------------------------------
66      INTEGER  ::   ji, jj, jk, jl    ! dummy loop indices
67      INTEGER  ::   i_ice_switch
68      REAL(wp) ::   zh, zsal
69      !
70      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
71      !!-------------------------------------------------------------------
72      IF( nn_timing == 1 )  CALL timing_start('limupdate2')
73
74      ! conservation test
75      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
76
77      !-----------------
78      ! zap small values
79      !-----------------
80      CALL lim_itd_me_zapsmall
81
82      CALL lim_var_glo2eqv
83
84      !----------------------------------------------------
85      ! Rebin categories with thickness out of bounds
86      !----------------------------------------------------
87      IF ( jpl > 1 )   CALL lim_itd_th_reb(1, jpl)
88
89      !----------------------------------------------------------------------
90      ! Constrain the thickness of the smallest category above hiclim
91      !----------------------------------------------------------------------
92      DO jj = 1, jpj 
93         DO ji = 1, jpi
94            IF( v_i(ji,jj,1) > 0._wp .AND. ht_i(ji,jj,1) < hiclim ) THEN
95               zh             = hiclim / ht_i(ji,jj,1)
96               ht_s(ji,jj,1) = ht_s(ji,jj,1) * zh
97               ht_i(ji,jj,1) = ht_i(ji,jj,1) * zh
98               a_i (ji,jj,1) = a_i(ji,jj,1)  / zh
99            ENDIF
100         END DO
101      END DO
102     
103      !-----------------------------------------------------
104      ! ice concentration should not exceed amax
105      !-----------------------------------------------------
106      at_i(:,:) = 0._wp
107      DO jl = 1, jpl
108         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
109      END DO
110
111      DO jl  = 1, jpl
112         DO jj = 1, jpj
113            DO ji = 1, jpi
114               IF( at_i(ji,jj) > amax .AND. a_i(ji,jj,jl) > 0._wp ) THEN
115                  a_i(ji,jj,jl)  = a_i(ji,jj,jl) * ( 1._wp - ( 1._wp - amax / at_i(ji,jj) ) )
116                  ht_i(ji,jj,jl) = v_i(ji,jj,jl) / a_i(ji,jj,jl)
117               ENDIF
118            END DO
119         END DO
120      END DO
121
122      at_i(:,:) = 0.0
123      DO jl = 1, jpl
124         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
125      END DO
126
127      ! --------------------------------------
128      ! Final thickness distribution rebinning
129      ! --------------------------------------
130      IF ( jpl > 1 ) CALL lim_itd_th_reb( 1, jpl )
131
132      !-----------------
133      ! zap small values
134      !-----------------
135      CALL lim_itd_me_zapsmall
136
137      !---------------------
138      ! 2.11) Ice salinity
139      !---------------------
140      IF (  num_sal == 2  ) THEN
141         DO jl = 1, jpl
142            DO jj = 1, jpj 
143               DO ji = 1, jpi
144                  zsal            = smv_i(ji,jj,jl)
145                  smv_i(ji,jj,jl) = sm_i(ji,jj,jl) * v_i(ji,jj,jl)
146                  ! salinity stays in bounds
147                  i_ice_switch    = 1._wp - MAX( 0._wp, SIGN( 1._wp, - v_i(ji,jj,jl) ) )
148                  smv_i(ji,jj,jl) = i_ice_switch * MAX( MIN( s_i_max * v_i(ji,jj,jl), smv_i(ji,jj,jl) ), s_i_min * v_i(ji,jj,jl) ) !+ s_i_min * ( 1._wp - i_ice_switch ) * v_i(ji,jj,jl)
149                  ! associated salt flux
150                  sfx_res(ji,jj) = sfx_res(ji,jj) - ( smv_i(ji,jj,jl) - zsal ) * rhoic * r1_rdtice
151               END DO ! ji
152            END DO ! jj
153         END DO !jl
154      ENDIF
155
156      !------------------------------------------------------------------------------
157      ! 2) Corrections to avoid wrong values                                        |
158      !------------------------------------------------------------------------------
159      ! Ice drift
160      !------------
161      DO jj = 2, jpjm1
162         DO ji = 2, jpim1
163            IF ( at_i(ji,jj) == 0._wp ) THEN ! what to do if there is no ice
164               IF ( at_i(ji+1,jj) == 0._wp ) u_ice(ji,jj)   = 0._wp ! right side
165               IF ( at_i(ji-1,jj) == 0._wp ) u_ice(ji-1,jj) = 0._wp ! left side
166               IF ( at_i(ji,jj+1) == 0._wp ) v_ice(ji,jj)   = 0._wp ! upper side
167               IF ( at_i(ji,jj-1) == 0._wp ) v_ice(ji,jj-1) = 0._wp ! bottom side
168            ENDIF
169         END DO
170      END DO
171      !lateral boundary conditions
172      CALL lbc_lnk( u_ice(:,:), 'U', -1. )
173      CALL lbc_lnk( v_ice(:,:), 'V', -1. )
174      !mask velocities
175      u_ice(:,:) = u_ice(:,:) * tmu(:,:)
176      v_ice(:,:) = v_ice(:,:) * tmv(:,:)
177 
178      ! -------------------------------------------------
179      ! Diagnostics
180      ! -------------------------------------------------
181      d_a_i_thd(:,:,:)   = a_i(:,:,:)   - a_i_b(:,:,:) 
182      d_v_s_thd(:,:,:)   = v_s(:,:,:)   - v_s_b(:,:,:)
183      d_v_i_thd(:,:,:)   = v_i(:,:,:)   - v_i_b(:,:,:) 
184      d_e_s_thd(:,:,:,:) = e_s(:,:,:,:) - e_s_b(:,:,:,:) 
185      d_e_i_thd(:,:,1:nlay_i,:) = e_i(:,:,1:nlay_i,:) - e_i_b(:,:,1:nlay_i,:)
186      !?? d_oa_i_thd(:,:,:)  = oa_i (:,:,:) - oa_i_b (:,:,:)
187      d_smv_i_thd(:,:,:) = 0._wp
188      IF( num_sal == 2 )   d_smv_i_thd(:,:,:) = smv_i(:,:,:) - smv_i_b(:,:,:)
189      ! diag only (clem)
190      dv_dt_thd(:,:,:) = d_v_i_thd(:,:,:) * r1_rdtice * rday
191
192      ! heat content variation (W.m-2)
193      DO jj = 1, jpj
194         DO ji = 1, jpi           
195            diag_heat_dhc(ji,jj) = ( SUM( d_e_i_trp(ji,jj,1:nlay_i,:) + d_e_i_thd(ji,jj,1:nlay_i,:) ) +  & 
196               &                     SUM( d_e_s_trp(ji,jj,1:nlay_s,:) + d_e_s_thd(ji,jj,1:nlay_s,:) )    &
197               &                   ) * unit_fac * r1_rdtice / area(ji,jj)   
198         END DO
199      END DO
200
201      ! conservation test
202      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limupdate2', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
203
204      IF(ln_ctl) THEN   ! Control print
205         CALL prt_ctl_info(' ')
206         CALL prt_ctl_info(' - Cell values : ')
207         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
208         CALL prt_ctl(tab2d_1=area       , clinfo1=' lim_update2  : cell area   :')
209         CALL prt_ctl(tab2d_1=at_i       , clinfo1=' lim_update2  : at_i        :')
210         CALL prt_ctl(tab2d_1=vt_i       , clinfo1=' lim_update2  : vt_i        :')
211         CALL prt_ctl(tab2d_1=vt_s       , clinfo1=' lim_update2  : vt_s        :')
212         CALL prt_ctl(tab2d_1=strength   , clinfo1=' lim_update2  : strength    :')
213         CALL prt_ctl(tab2d_1=u_ice      , clinfo1=' lim_update2  : u_ice       :', tab2d_2=v_ice      , clinfo2=' v_ice       :')
214         CALL prt_ctl(tab2d_1=u_ice_b    , clinfo1=' lim_update2  : u_ice_b     :', tab2d_2=v_ice_b    , clinfo2=' v_ice_b     :')
215
216         DO jl = 1, jpl
217            CALL prt_ctl_info(' ')
218            CALL prt_ctl_info(' - Category : ', ivar1=jl)
219            CALL prt_ctl_info('   ~~~~~~~~~~')
220            CALL prt_ctl(tab2d_1=ht_i       (:,:,jl)        , clinfo1= ' lim_update2  : ht_i        : ')
221            CALL prt_ctl(tab2d_1=ht_s       (:,:,jl)        , clinfo1= ' lim_update2  : ht_s        : ')
222            CALL prt_ctl(tab2d_1=t_su       (:,:,jl)        , clinfo1= ' lim_update2  : t_su        : ')
223            CALL prt_ctl(tab2d_1=t_s        (:,:,1,jl)      , clinfo1= ' lim_update2  : t_snow      : ')
224            CALL prt_ctl(tab2d_1=sm_i       (:,:,jl)        , clinfo1= ' lim_update2  : sm_i        : ')
225            CALL prt_ctl(tab2d_1=o_i        (:,:,jl)        , clinfo1= ' lim_update2  : o_i         : ')
226            CALL prt_ctl(tab2d_1=a_i        (:,:,jl)        , clinfo1= ' lim_update2  : a_i         : ')
227            CALL prt_ctl(tab2d_1=a_i_b      (:,:,jl)        , clinfo1= ' lim_update2  : a_i_b       : ')
228            CALL prt_ctl(tab2d_1=d_a_i_thd  (:,:,jl)        , clinfo1= ' lim_update2  : d_a_i_thd   : ')
229            CALL prt_ctl(tab2d_1=v_i        (:,:,jl)        , clinfo1= ' lim_update2  : v_i         : ')
230            CALL prt_ctl(tab2d_1=v_i_b      (:,:,jl)        , clinfo1= ' lim_update2  : v_i_b       : ')
231            CALL prt_ctl(tab2d_1=d_v_i_thd  (:,:,jl)        , clinfo1= ' lim_update2  : d_v_i_thd   : ')
232            CALL prt_ctl(tab2d_1=v_s        (:,:,jl)        , clinfo1= ' lim_update2  : v_s         : ')
233            CALL prt_ctl(tab2d_1=v_s_b      (:,:,jl)        , clinfo1= ' lim_update2  : v_s_b       : ')
234            CALL prt_ctl(tab2d_1=d_v_s_thd  (:,:,jl)        , clinfo1= ' lim_update2  : d_v_s_thd   : ')
235            CALL prt_ctl(tab2d_1=e_i        (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : e_i1        : ')
236            CALL prt_ctl(tab2d_1=e_i_b      (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : e_i1_b      : ')
237            CALL prt_ctl(tab2d_1=d_e_i_thd  (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : de_i1_thd   : ')
238            CALL prt_ctl(tab2d_1=e_i        (:,:,2,jl)/1.0e9, clinfo1= ' lim_update2  : e_i2        : ')
239            CALL prt_ctl(tab2d_1=e_i_b      (:,:,2,jl)/1.0e9, clinfo1= ' lim_update2  : e_i2_b      : ')
240            CALL prt_ctl(tab2d_1=d_e_i_thd  (:,:,2,jl)/1.0e9, clinfo1= ' lim_update2  : de_i2_thd   : ')
241            CALL prt_ctl(tab2d_1=e_s        (:,:,1,jl)      , clinfo1= ' lim_update2  : e_snow      : ')
242            CALL prt_ctl(tab2d_1=e_s_b      (:,:,1,jl)      , clinfo1= ' lim_update2  : e_snow_b    : ')
243            CALL prt_ctl(tab2d_1=d_e_s_thd  (:,:,1,jl)/1.0e9, clinfo1= ' lim_update2  : d_e_s_thd   : ')
244            CALL prt_ctl(tab2d_1=smv_i      (:,:,jl)        , clinfo1= ' lim_update2  : smv_i       : ')
245            CALL prt_ctl(tab2d_1=smv_i_b    (:,:,jl)        , clinfo1= ' lim_update2  : smv_i_b     : ')
246            CALL prt_ctl(tab2d_1=d_smv_i_thd(:,:,jl)        , clinfo1= ' lim_update2  : d_smv_i_thd : ')
247            CALL prt_ctl(tab2d_1=oa_i       (:,:,jl)        , clinfo1= ' lim_update2  : oa_i        : ')
248            CALL prt_ctl(tab2d_1=oa_i_b     (:,:,jl)        , clinfo1= ' lim_update2  : oa_i_b      : ')
249            CALL prt_ctl(tab2d_1=d_oa_i_thd (:,:,jl)        , clinfo1= ' lim_update2  : d_oa_i_thd  : ')
250
251            DO jk = 1, nlay_i
252               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
253               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_update2  : t_i       : ')
254            END DO
255         END DO
256
257         CALL prt_ctl_info(' ')
258         CALL prt_ctl_info(' - Heat / FW fluxes : ')
259         CALL prt_ctl_info('   ~~~~~~~~~~~~~~~~~~ ')
260         CALL prt_ctl(tab2d_1=sst_m  , clinfo1= ' lim_update2 : sst   : ', tab2d_2=sss_m     , clinfo2= ' sss       : ')
261
262         CALL prt_ctl_info(' ')
263         CALL prt_ctl_info(' - Stresses : ')
264         CALL prt_ctl_info('   ~~~~~~~~~~ ')
265         CALL prt_ctl(tab2d_1=utau       , clinfo1= ' lim_update2 : utau      : ', tab2d_2=vtau       , clinfo2= ' vtau      : ')
266         CALL prt_ctl(tab2d_1=utau_ice   , clinfo1= ' lim_update2 : utau_ice  : ', tab2d_2=vtau_ice   , clinfo2= ' vtau_ice  : ')
267         CALL prt_ctl(tab2d_1=u_oce      , clinfo1= ' lim_update2 : u_oce     : ', tab2d_2=v_oce      , clinfo2= ' v_oce     : ')
268      ENDIF
269   
270      IF( nn_timing == 1 )  CALL timing_stop('limupdate2')
271
272   END SUBROUTINE lim_update2
273#else
274   !!----------------------------------------------------------------------
275   !!   Default option         Empty Module               No sea-ice model
276   !!----------------------------------------------------------------------
277CONTAINS
278   SUBROUTINE lim_update2     ! Empty routine
279   END SUBROUTINE lim_update2
280
281#endif
282
283END MODULE limupdate2
Note: See TracBrowser for help on using the repository browser.