New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/UKMO/dev_r5107_restart_func_and_date/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/UKMO/dev_r5107_restart_func_and_date/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 5498

Last change on this file since 5498 was 5498, checked in by dancopsey, 9 years ago

Merged in changes from revision 5493 to 5497 of branches/UKMO/dev_r5107_restart_date
  • Property svn:keywords set to Id
File size: 14.9 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   rst_opn    : open the ocean restart file
15   !!   rst_write  : write the ocean restart file
16   !!   rst_read   : read the ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE phycst          ! physical constants
21   USE in_out_manager  ! I/O manager
22   USE iom             ! I/O module
23   USE ioipsl, ONLY : ju2ymds    ! for calendar
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   USE divcur          ! hor. divergence and curl      (div & cur routines)
27   USE sbc_ice, ONLY : lk_lim3
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   rst_opn         ! routine called by step module
33   PUBLIC   rst_write       ! routine called by step module
34   PUBLIC   rst_read        ! routine called by istate module
35   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
36
37   !! * Substitutions
38#  include "domzgr_substitute.h90"
39#  include "vectopt_loop_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE rst_opn( kt )
48      !!---------------------------------------------------------------------
49      !!                   ***  ROUTINE rst_opn  ***
50      !!                     
51      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
52      !!              + open the restart when we are one time step before nitrst
53      !!                   - restart header is defined when kt = nitrst-1
54      !!                   - restart data  are written when kt = nitrst
55      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt     ! ocean time-step
58      INTEGER             ::   iyear, imonth, iday 
59      REAL (wp)           ::   zsec
60      !!
61      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
62      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
63      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
64      !!----------------------------------------------------------------------
65      !
66      IF( kt == nit000 ) THEN   ! default definitions
67         lrst_oce = .FALSE.   
68         IF( ln_rst_list ) THEN
69            nrst_lst = 1
70            nitrst = nstocklist( nrst_lst )
71         ELSE
72            nitrst = nitend
73         ENDIF
74      ENDIF
75
76      ! frequency-based restart dumping (nn_stock)
77      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
78         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
79         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
80         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
81      ENDIF
82      ! to get better performances with NetCDF format:
83      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
84      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
85      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
86         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
87            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
88            IF ( ln_rstdate ) THEN
89               CALL ju2ymds( fjulday + rdttra(1) / rday, iyear, imonth, iday, zsec )           
90               WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday 
91            ELSE
92               IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst 
93               ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst 
94               ENDIF
95            ENDIF
96            ! create the file
97            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
98            clpath = TRIM(cn_ocerst_outdir)
99            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
100            IF(lwp) THEN
101               WRITE(numout,*)
102               SELECT CASE ( jprstlib )
103               CASE ( jprstdimg )   ;   WRITE(numout,*)                            &
104                   '             open ocean restart binary file: ',TRIM(clpath)//clname
105               CASE DEFAULT         ;   WRITE(numout,*)                            &
106                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
107               END SELECT
108               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
109               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
110               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
111               ENDIF
112            ENDIF
113            !
114            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
115            lrst_oce = .TRUE.
116         ENDIF
117      ENDIF
118      !
119   END SUBROUTINE rst_opn
120
121
122   SUBROUTINE rst_write( kt )
123      !!---------------------------------------------------------------------
124      !!                   ***  ROUTINE rstwrite  ***
125      !!                     
126      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
127      !!
128      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
129      !!              file, save fields which are necessary for restart
130      !!----------------------------------------------------------------------
131      INTEGER, INTENT(in) ::   kt   ! ocean time-step
132      !!----------------------------------------------------------------------
133
134                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
135                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
136
137                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
138                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
139                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
140                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
141                     CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb      )
142                     CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb     )
143                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
144                     !
145      IF( lk_lim3 )  CALL iom_rstput( kt, nitrst, numrow, 'fse3t_b', fse3t_b(:,:,:) )
146                     !
147                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
148                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
149                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
150                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
151                     CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn      )
152                     CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn     )
153                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
154                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
155#if defined key_zdfkpp
156                     CALL iom_rstput( kt, nitrst, numrow, 'rhd'    , rhd       )
157#endif
158                  IF( lk_lim3 ) THEN
159                     CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev'  , fraqsr_1lev     ) !clem modif
160                  ENDIF
161      IF( kt == nitrst ) THEN
162         CALL iom_close( numrow )     ! close the restart file (only at last time step)
163!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
164!!gm  not sure what to do here   ===>>>  ask to Sebastian
165         lrst_oce = .FALSE.
166            IF( ln_rst_list ) THEN
167               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
168               nitrst = nstocklist( nrst_lst )
169            ENDIF
170            lrst_oce = .FALSE.
171      ENDIF
172      !
173   END SUBROUTINE rst_write
174
175
176   SUBROUTINE rst_read_open
177      !!----------------------------------------------------------------------
178      !!                   ***  ROUTINE rst_read_open  ***
179      !!
180      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
181      !!
182      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
183      !!                the file has already been opened
184      !!----------------------------------------------------------------------
185      INTEGER        ::   jlibalt = jprstlib
186      LOGICAL        ::   llok
187      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
188      !!----------------------------------------------------------------------
189      !
190      IF( numror <= 0 ) THEN
191         IF(lwp) THEN                                             ! Contol prints
192            WRITE(numout,*)
193            SELECT CASE ( jprstlib )
194            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
195            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
196            END SELECT
197            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
198            WRITE(numout,*) '~~~~~~~~'
199         ENDIF
200
201         clpath = TRIM(cn_ocerst_indir)
202         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
203         IF ( jprstlib == jprstdimg ) THEN
204           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
205           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
206           INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
207           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
208         ENDIF
209         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
210      ENDIF
211   END SUBROUTINE rst_read_open
212
213   SUBROUTINE rst_read
214      !!----------------------------------------------------------------------
215      !!                   ***  ROUTINE rst_read  ***
216      !!
217      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
218      !!
219      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
220      !!----------------------------------------------------------------------
221      REAL(wp) ::   zrdt, zrdttra1
222      INTEGER  ::   jk
223      LOGICAL  ::   llok
224      !!----------------------------------------------------------------------
225
226      CALL rst_read_open           ! open restart for reading (if not already opened)
227
228      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
229      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
230         CALL iom_get( numror, 'rdt', zrdt )
231         IF( zrdt /= rdt )   neuler = 0
232      ENDIF
233      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
234         CALL iom_get( numror, 'rdttra1', zrdttra1 )
235         IF( zrdttra1 /= rdttra(1) )   neuler = 0
236      ENDIF
237      !
238      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
239         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
240         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
241         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
242         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
243         CALL iom_get( numror, jpdom_autoglo, 'rotb'   , rotb    )
244         CALL iom_get( numror, jpdom_autoglo, 'hdivb'  , hdivb   )
245         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
246         IF( lk_lim3 )   CALL iom_get( numror, jpdom_autoglo, 'fse3t_b', fse3t_b(:,:,:) )
247      ELSE
248         neuler = 0
249      ENDIF
250      !
251      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
252      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
253      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
254      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
255      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
256      IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
257         CALL iom_get( numror, jpdom_autoglo, 'rotn'   , rotn    )
258         CALL iom_get( numror, jpdom_autoglo, 'hdivn'  , hdivn   )
259      ELSE
260         CALL div_cur( 0 )                              ! Horizontal divergence & Relative vorticity
261      ENDIF
262      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
263         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
264      ELSE
265         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )   
266      ENDIF
267#if defined key_zdfkpp
268      IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
269         CALL iom_get( numror, jpdom_autoglo, 'rhd'    , rhd     )   ! now    in situ density anomaly
270      ELSE
271         CALL eos( tsn, rhd, fsdept_n(:,:,:) )   ! compute rhd
272      ENDIF
273#endif
274      !
275      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
276         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
277         ub   (:,:,:)   = un   (:,:,:)
278         vb   (:,:,:)   = vn   (:,:,:)
279         rotb (:,:,:)   = rotn (:,:,:)
280         hdivb(:,:,:)   = hdivn(:,:,:)
281         sshb (:,:)     = sshn (:,:)
282
283         IF( lk_vvl ) THEN
284            DO jk = 1, jpk
285               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
286            END DO
287         ENDIF
288
289         IF( lk_lim3 .AND. .NOT. lk_vvl ) THEN
290            DO jk = 1, jpk
291               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
292            END DO
293         ENDIF
294
295      ENDIF
296      !
297      IF( lk_lim3 ) THEN
298         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev' , fraqsr_1lev )
299      ENDIF
300      !
301   END SUBROUTINE rst_read
302
303   !!=====================================================================
304END MODULE restart
Note: See TracBrowser for help on using the repository browser.