New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/UKMO/dev_r5107_restart_func_and_date/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/UKMO/dev_r5107_restart_func_and_date/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 5500

Last change on this file since 5500 was 5500, checked in by dancopsey, 9 years ago

Removed SVN keywords.

File size: 39.1 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48#if defined key_nemocice_decomp
49   USE ice_domain_size, only: nx_global, ny_global
50#endif
51   USE tideini         ! tidal components initialization   (tide_ini routine)
52   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
53   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
54   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
55   USE istate          ! initial state setting          (istate_init routine)
56   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
57   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
58   USE zdfini          ! vertical physics setting          (zdf_init routine)
59   USE phycst          ! physical constant                  (par_cst routine)
60   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
61   USE asminc          ! assimilation increments     
62   USE asmbkg          ! writing out state trajectory
63   USE diaptr          ! poleward transports           (dia_ptr_init routine)
64   USE diadct          ! sections transports           (dia_dct_init routine)
65   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
66   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
67   USE step            ! NEMO time-stepping                 (stp     routine)
68   USE icbini          ! handle bergs, initialisation
69   USE icbstp          ! handle bergs, calving, themodynamics and transport
70   USE cpl_oasis3      ! OASIS3 coupling
71   USE c1d             ! 1D configuration
72   USE step_c1d        ! Time stepping loop for the 1D configuration
73   USE dyndmp          ! Momentum damping
74#if defined key_top
75   USE trcini          ! passive tracer initialisation
76#endif
77   USE lib_mpp         ! distributed memory computing
78#if defined key_iomput
79   USE xios
80#endif
81   USE sbctide, ONLY: lk_tide
82   USE crsini          ! initialise grid coarsening utility
83   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
84   USE stopar
85   USE stopts
86
87   IMPLICIT NONE
88   PRIVATE
89
90   PUBLIC   nemo_gcm    ! called by model.F90
91   PUBLIC   nemo_init   ! needed by AGRIF
92   PUBLIC   nemo_alloc  ! needed by TAM
93
94   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
95
96   !!----------------------------------------------------------------------
97   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
98   !! $Id$
99   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
100   !!----------------------------------------------------------------------
101CONTAINS
102
103   SUBROUTINE nemo_gcm
104      !!----------------------------------------------------------------------
105      !!                     ***  ROUTINE nemo_gcm  ***
106      !!
107      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
108      !!              curvilinear mesh on the sphere.
109      !!
110      !! ** Method  : - model general initialization
111      !!              - launch the time-stepping (stp routine)
112      !!              - finalize the run by closing files and communications
113      !!
114      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
115      !!              Madec, 2008, internal report, IPSL.
116      !!----------------------------------------------------------------------
117      INTEGER ::   istp       ! time step index
118      !!----------------------------------------------------------------------
119      !
120#if defined key_agrif
121      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
122#endif
123
124      !                            !-----------------------!
125      CALL nemo_init               !==  Initialisations  ==!
126      !                            !-----------------------!
127#if defined key_agrif
128      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
129      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
130# if defined key_top
131      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
132# endif
133# if defined key_lim2
134      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
135# endif
136#endif
137      ! check that all process are still there... If some process have an error,
138      ! they will never enter in step and other processes will wait until the end of the cpu time!
139      IF( lk_mpp )   CALL mpp_max( nstop )
140
141      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
142
143      !                            !-----------------------!
144      !                            !==   time stepping   ==!
145      !                            !-----------------------!
146      istp = nit000
147#if defined key_c1d
148         DO WHILE ( istp <= nitend .AND. nstop == 0 )
149            CALL stp_c1d( istp )
150            istp = istp + 1
151         END DO
152#else
153          IF( lk_asminc ) THEN
154             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
155             IF( ln_asmdin ) THEN                        ! Direct initialization
156                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
157                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
158                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
159             ENDIF
160          ENDIF
161
162         DO WHILE ( istp <= nitend .AND. nstop == 0 )
163#if defined key_agrif
164            CALL Agrif_Step( stp )           ! AGRIF: time stepping
165#else
166            CALL stp( istp )                 ! standard time stepping
167#endif
168            istp = istp + 1
169            IF( lk_mpp )   CALL mpp_max( nstop )
170         END DO
171#endif
172
173      IF( lk_diaobs   )   CALL dia_obs_wri
174      !
175      IF( ln_icebergs )   CALL icb_end( nitend )
176
177      !                            !------------------------!
178      !                            !==  finalize the run  ==!
179      !                            !------------------------!
180      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
181      !
182      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
183         WRITE(numout,cform_err)
184         WRITE(numout,*) nstop, ' error have been found'
185      ENDIF
186      !
187#if defined key_agrif
188      CALL Agrif_ParentGrid_To_ChildGrid()
189      IF( lk_diaobs ) CALL dia_obs_wri
190      IF( nn_timing == 1 )   CALL timing_finalize
191      CALL Agrif_ChildGrid_To_ParentGrid()
192#endif
193      IF( nn_timing == 1 )   CALL timing_finalize
194      !
195      CALL nemo_closefile
196      !
197#if defined key_iomput
198      CALL xios_finalize                ! end mpp communications with xios
199      IF( lk_cpl ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
200#else
201      IF( lk_cpl ) THEN
202         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
203      ELSE
204         IF( lk_mpp )   CALL mppstop    ! end mpp communications
205      ENDIF
206#endif
207      !
208   END SUBROUTINE nemo_gcm
209
210
211   SUBROUTINE nemo_init
212      !!----------------------------------------------------------------------
213      !!                     ***  ROUTINE nemo_init  ***
214      !!
215      !! ** Purpose :   initialization of the NEMO GCM
216      !!----------------------------------------------------------------------
217      INTEGER ::   ji            ! dummy loop indices
218      INTEGER ::   ilocal_comm   ! local integer
219      INTEGER ::   ios
220      CHARACTER(len=80), DIMENSION(16) ::   cltxt
221      !
222      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
223         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
224         &             nn_bench, nn_timing
225      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
226         &             jpizoom, jpjzoom, jperio, ln_use_jattr
227      !!----------------------------------------------------------------------
228      !
229      cltxt = ''
230      !
231      !                             ! Open reference namelist and configuration namelist files
232      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
233      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
234      !
235      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
236      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
237901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
238
239      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
240      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
241902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
242
243      !
244      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
245      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
246903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
247
248      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
249      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
250904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
251
252! Force values for AGRIF zoom (cf. agrif_user.F90)
253#if defined key_agrif
254   IF( .NOT. Agrif_Root() ) THEN
255      jpiglo  = nbcellsx + 2 + 2*nbghostcells
256      jpjglo  = nbcellsy + 2 + 2*nbghostcells
257      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
258      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
259      jpidta  = jpiglo
260      jpjdta  = jpjglo
261      jpizoom = 1
262      jpjzoom = 1
263      nperio  = 0
264      jperio  = 0
265      ln_use_jattr = .false.
266   ENDIF
267#endif
268      !
269      !                             !--------------------------------------------!
270      !                             !  set communicator & select the local node  !
271      !                             !  NB: mynode also opens output.namelist.dyn !
272      !                             !      on unit number numond on first proc   !
273      !                             !--------------------------------------------!
274#if defined key_iomput
275      IF( Agrif_Root() ) THEN
276         IF( lk_cpl ) THEN
277            CALL cpl_init( ilocal_comm )                               ! nemo local communicator given by oasis
278            CALL xios_initialize( "oceanx",local_comm=ilocal_comm )    ! send nemo communicator to xios
279         ELSE
280            CALL  xios_initialize( "nemo",return_comm=ilocal_comm )    ! nemo local communicator given by xios
281         ENDIF
282      ENDIF
283      narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
284#else
285      IF( lk_cpl ) THEN
286         IF( Agrif_Root() ) THEN
287            CALL cpl_init( ilocal_comm )                       ! nemo local communicator given by oasis
288         ENDIF
289         narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection (control print return in cltxt)
290      ELSE
291         ilocal_comm = 0
292         narea = mynode( cltxt, numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
293      ENDIF
294#endif
295      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
296
297      lwm = (narea == 1)                                    ! control of output namelists
298      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
299
300      IF(lwm) THEN
301         ! write merged namelists from earlier to output namelist now that the
302         ! file has been opened in call to mynode. nammpp has already been
303         ! written in mynode (if lk_mpp_mpi)
304         WRITE( numond, namctl )
305         WRITE( numond, namcfg )
306      ENDIF
307
308      ! If dimensions of processor grid weren't specified in the namelist file
309      ! then we calculate them here now that we have our communicator size
310      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
311#if   defined key_mpp_mpi
312         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
313#else
314         jpni  = 1
315         jpnj  = 1
316         jpnij = jpni*jpnj
317#endif
318      END IF
319
320      ! Calculate domain dimensions given calculated jpni and jpnj
321      ! This used to be done in par_oce.F90 when they were parameters rather
322      ! than variables
323      IF( Agrif_Root() ) THEN
324#if defined key_nemocice_decomp
325         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
326         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
327#else
328         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
329         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
330#endif
331      ENDIF
332         jpk = jpkdta                                             ! third dim
333         jpim1 = jpi-1                                            ! inner domain indices
334         jpjm1 = jpj-1                                            !   "           "
335         jpkm1 = jpk-1                                            !   "           "
336         jpij  = jpi*jpj                                          !  jpi x j
337
338      IF(lwp) THEN                            ! open listing units
339         !
340         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
341         !
342         WRITE(numout,*)
343         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
344         WRITE(numout,*) '                       NEMO team'
345         WRITE(numout,*) '            Ocean General Circulation Model'
346         WRITE(numout,*) '                  version 3.6  (2015) '
347         WRITE(numout,*)
348         WRITE(numout,*)
349         DO ji = 1, SIZE(cltxt)
350            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
351         END DO
352         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
353         !
354      ENDIF
355
356      ! Now we know the dimensions of the grid and numout has been set we can
357      ! allocate arrays
358      CALL nemo_alloc()
359
360      !                             !-------------------------------!
361      !                             !  NEMO general initialization  !
362      !                             !-------------------------------!
363
364      CALL nemo_ctl                          ! Control prints & Benchmark
365
366      !                                      ! Domain decomposition
367      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
368      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
369      ENDIF
370      !
371      IF( nn_timing == 1 )  CALL timing_init
372      !
373      !                                      ! General initialization
374                            CALL     phy_cst    ! Physical constants
375                            CALL     eos_init   ! Equation of state
376      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
377                            CALL     dom_cfg    ! Domain configuration
378                            CALL     dom_init   ! Domain
379
380      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
381
382      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
383
384                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
385
386      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
387
388                            CALL     sbc_init   ! Forcings : surface module (clem: moved here for bdy purpose)
389
390      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
391      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
392      IF( lk_bdy .AND. lk_tide )   &
393         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
394
395                            CALL dyn_nept_init  ! simplified form of Neptune effect
396      !     
397      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
398      !
399                                ! Ocean physics
400      !                                         ! Vertical physics
401                            CALL     zdf_init      ! namelist read
402                            CALL zdf_bfr_init      ! bottom friction
403      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
404      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
405      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
406      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
407      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
408      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
409         &                  CALL zdf_ddm_init      ! double diffusive mixing
410      !                                         ! Lateral physics
411                            CALL ldf_tra_init      ! Lateral ocean tracer physics
412                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
413      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
414
415      !                                     ! Active tracers
416                            CALL tra_qsr_init   ! penetrative solar radiation qsr
417                            CALL tra_bbc_init   ! bottom heat flux
418      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
419                            CALL tra_dmp_init   ! internal damping trends- tracers
420                            CALL tra_adv_init   ! horizontal & vertical advection
421                            CALL tra_ldf_init   ! lateral mixing
422                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
423
424      !                                     ! Dynamics
425      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
426                            CALL dyn_adv_init   ! advection (vector or flux form)
427                            CALL dyn_vor_init   ! vorticity term including Coriolis
428                            CALL dyn_ldf_init   ! lateral mixing
429                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
430                            CALL dyn_zdf_init   ! vertical diffusion
431                            CALL dyn_spg_init   ! surface pressure gradient
432
433      !                                     ! Misc. options
434      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
435                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
436                            CALL sto_par_init   ! Stochastic parametrization
437      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
438     
439#if defined key_top
440      !                                     ! Passive tracers
441                            CALL     trc_init
442#endif
443      !                                     ! Diagnostics
444      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
445      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
446                            CALL dia_ptr_init   ! Poleward TRansports initialization
447      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
448                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
449                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
450      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
451                            CALL dia_obs_init            ! Initialize observational data
452                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
453      ENDIF
454
455      !                                     ! Assimilation increments
456      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
457      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
458      !
459   END SUBROUTINE nemo_init
460
461
462   SUBROUTINE nemo_ctl
463      !!----------------------------------------------------------------------
464      !!                     ***  ROUTINE nemo_ctl  ***
465      !!
466      !! ** Purpose :   control print setting
467      !!
468      !! ** Method  : - print namctl information and check some consistencies
469      !!----------------------------------------------------------------------
470      !
471      IF(lwp) THEN                  ! control print
472         WRITE(numout,*)
473         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
474         WRITE(numout,*) '~~~~~~~ '
475         WRITE(numout,*) '   Namelist namctl'
476         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
477         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
478         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
479         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
480         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
481         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
482         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
483         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
484         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
485         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
486      ENDIF
487      !
488      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
489      nictls    = nn_ictls
490      nictle    = nn_ictle
491      njctls    = nn_jctls
492      njctle    = nn_jctle
493      isplt     = nn_isplt
494      jsplt     = nn_jsplt
495      nbench    = nn_bench
496
497      IF(lwp) THEN                  ! control print
498         WRITE(numout,*)
499         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
500         WRITE(numout,*) '~~~~~~~ '
501         WRITE(numout,*) '   Namelist namcfg'
502         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
503         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
504         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
505         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
506         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
507         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
508         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
509         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
510         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
511         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
512         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
513         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
514      ENDIF
515      !                             ! Parameter control
516      !
517      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
518         IF( lk_mpp .AND. jpnij > 1 ) THEN
519            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
520         ELSE
521            IF( isplt == 1 .AND. jsplt == 1  ) THEN
522               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
523                  &           ' - the print control will be done over the whole domain' )
524            ENDIF
525            ijsplt = isplt * jsplt            ! total number of processors ijsplt
526         ENDIF
527         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
528         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
529         !
530         !                              ! indices used for the SUM control
531         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
532            lsp_area = .FALSE.
533         ELSE                                             ! print control done over a specific  area
534            lsp_area = .TRUE.
535            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
536               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
537               nictls = 1
538            ENDIF
539            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
540               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
541               nictle = jpiglo
542            ENDIF
543            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
544               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
545               njctls = 1
546            ENDIF
547            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
548               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
549               njctle = jpjglo
550            ENDIF
551         ENDIF
552      ENDIF
553      !
554      IF( nbench == 1 ) THEN              ! Benchmark
555         SELECT CASE ( cp_cfg )
556         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
557         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
558            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
559         END SELECT
560      ENDIF
561      !
562      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
563         &                                               'f2003 standard. '                              ,  &
564         &                                               'Compile with key_nosignedzero enabled' )
565      !
566   END SUBROUTINE nemo_ctl
567
568
569   SUBROUTINE nemo_closefile
570      !!----------------------------------------------------------------------
571      !!                     ***  ROUTINE nemo_closefile  ***
572      !!
573      !! ** Purpose :   Close the files
574      !!----------------------------------------------------------------------
575      !
576      IF( lk_mpp )   CALL mppsync
577      !
578      CALL iom_close                                 ! close all input/output files managed by iom_*
579      !
580      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
581      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
582      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
583      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
584      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
585      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
586      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
587      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
588      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
589      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
590      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
591      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
592      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
593
594      !
595      numout = 6                                     ! redefine numout in case it is used after this point...
596      !
597   END SUBROUTINE nemo_closefile
598
599
600   SUBROUTINE nemo_alloc
601      !!----------------------------------------------------------------------
602      !!                     ***  ROUTINE nemo_alloc  ***
603      !!
604      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
605      !!
606      !! ** Method  :
607      !!----------------------------------------------------------------------
608      USE diawri    , ONLY: dia_wri_alloc
609      USE dom_oce   , ONLY: dom_oce_alloc
610      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
611      USE ldftra_oce, ONLY: ldftra_oce_alloc
612      USE trc_oce   , ONLY: trc_oce_alloc
613#if defined key_diadct 
614      USE diadct    , ONLY: diadct_alloc 
615#endif 
616#if defined key_bdy
617      USE bdy_oce   , ONLY: bdy_oce_alloc
618#endif
619      !
620      INTEGER :: ierr
621      !!----------------------------------------------------------------------
622      !
623      ierr =        oce_alloc       ()          ! ocean
624      ierr = ierr + dia_wri_alloc   ()
625      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
626      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
627      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
628      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
629      !
630      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
631      !
632#if defined key_diadct 
633      ierr = ierr + diadct_alloc    ()          !
634#endif 
635#if defined key_bdy
636      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
637#endif
638      !
639      IF( lk_mpp    )   CALL mpp_sum( ierr )
640      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
641      !
642   END SUBROUTINE nemo_alloc
643
644
645   SUBROUTINE nemo_partition( num_pes )
646      !!----------------------------------------------------------------------
647      !!                 ***  ROUTINE nemo_partition  ***
648      !!
649      !! ** Purpose :
650      !!
651      !! ** Method  :
652      !!----------------------------------------------------------------------
653      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
654      !
655      INTEGER, PARAMETER :: nfactmax = 20
656      INTEGER :: nfact ! The no. of factors returned
657      INTEGER :: ierr  ! Error flag
658      INTEGER :: ji
659      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
660      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
661      !!----------------------------------------------------------------------
662      !
663      ierr = 0
664      !
665      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
666      !
667      IF( nfact <= 1 ) THEN
668         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
669         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
670         jpnj = 1
671         jpni = num_pes
672      ELSE
673         ! Search through factors for the pair that are closest in value
674         mindiff = 1000000
675         imin    = 1
676         DO ji = 1, nfact-1, 2
677            idiff = ABS( ifact(ji) - ifact(ji+1) )
678            IF( idiff < mindiff ) THEN
679               mindiff = idiff
680               imin = ji
681            ENDIF
682         END DO
683         jpnj = ifact(imin)
684         jpni = ifact(imin + 1)
685      ENDIF
686      !
687      jpnij = jpni*jpnj
688      !
689   END SUBROUTINE nemo_partition
690
691
692   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
693      !!----------------------------------------------------------------------
694      !!                     ***  ROUTINE factorise  ***
695      !!
696      !! ** Purpose :   return the prime factors of n.
697      !!                knfax factors are returned in array kfax which is of
698      !!                maximum dimension kmaxfax.
699      !! ** Method  :
700      !!----------------------------------------------------------------------
701      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
702      INTEGER                    , INTENT(  out) ::   kerr, knfax
703      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
704      !
705      INTEGER :: ifac, jl, inu
706      INTEGER, PARAMETER :: ntest = 14
707      INTEGER :: ilfax(ntest)
708      !
709      ! lfax contains the set of allowed factors.
710      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
711         &                            128,   64,   32,   16,    8,   4,   2  /
712      !!----------------------------------------------------------------------
713
714      ! Clear the error flag and initialise output vars
715      kerr = 0
716      kfax = 1
717      knfax = 0
718
719      ! Find the factors of n.
720      IF( kn == 1 )   GOTO 20
721
722      ! nu holds the unfactorised part of the number.
723      ! knfax holds the number of factors found.
724      ! l points to the allowed factor list.
725      ! ifac holds the current factor.
726
727      inu   = kn
728      knfax = 0
729
730      DO jl = ntest, 1, -1
731         !
732         ifac = ilfax(jl)
733         IF( ifac > inu )   CYCLE
734
735         ! Test whether the factor will divide.
736
737         IF( MOD(inu,ifac) == 0 ) THEN
738            !
739            knfax = knfax + 1            ! Add the factor to the list
740            IF( knfax > kmaxfax ) THEN
741               kerr = 6
742               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
743               return
744            ENDIF
745            kfax(knfax) = ifac
746            ! Store the other factor that goes with this one
747            knfax = knfax + 1
748            kfax(knfax) = inu / ifac
749            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
750         ENDIF
751         !
752      END DO
753
754   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
755      !
756   END SUBROUTINE factorise
757
758#if defined key_mpp_mpi
759
760   SUBROUTINE nemo_northcomms
761      !!======================================================================
762      !!                     ***  ROUTINE  nemo_northcomms  ***
763      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
764      !!                       point-to-point messaging
765      !!=====================================================================
766      !!----------------------------------------------------------------------
767      !!
768      !! ** Purpose :   Initialization of the northern neighbours lists.
769      !!----------------------------------------------------------------------
770      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
771      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
772      !!----------------------------------------------------------------------
773
774      INTEGER  ::   sxM, dxM, sxT, dxT, jn
775      INTEGER  ::   njmppmax
776
777      njmppmax = MAXVAL( njmppt )
778   
779      !initializes the north-fold communication variables
780      isendto(:) = 0
781      nsndto = 0
782
783      !if I am a process in the north
784      IF ( njmpp == njmppmax ) THEN
785          !sxM is the first point (in the global domain) needed to compute the
786          !north-fold for the current process
787          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
788          !dxM is the last point (in the global domain) needed to compute the
789          !north-fold for the current process
790          dxM = jpiglo - nimppt(narea) + 2
791
792          !loop over the other north-fold processes to find the processes
793          !managing the points belonging to the sxT-dxT range
794 
795          DO jn = 1, jpni
796                !sxT is the first point (in the global domain) of the jn
797                !process
798                sxT = nfiimpp(jn, jpnj)
799                !dxT is the last point (in the global domain) of the jn
800                !process
801                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
802                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
803                   nsndto = nsndto + 1
804                     isendto(nsndto) = jn
805                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
806                   nsndto = nsndto + 1
807                     isendto(nsndto) = jn
808                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
809                   nsndto = nsndto + 1
810                     isendto(nsndto) = jn
811                END IF
812          END DO
813          nfsloop = 1
814          nfeloop = nlci
815          DO jn = 2,jpni-1
816           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
817              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
818                 nfsloop = nldi
819              ENDIF
820              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
821                 nfeloop = nlei
822              ENDIF
823           ENDIF
824        END DO
825
826      ENDIF
827      l_north_nogather = .TRUE.
828   END SUBROUTINE nemo_northcomms
829#else
830   SUBROUTINE nemo_northcomms      ! Dummy routine
831      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
832   END SUBROUTINE nemo_northcomms
833#endif
834
835   !!======================================================================
836END MODULE nemogcm
837
838
Note: See TracBrowser for help on using the repository browser.