New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traqsr.F90 in branches/UKMO/dev_r5518_AMM15_package/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/dev_r5518_AMM15_package/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 10253

Last change on this file since 10253 was 10253, checked in by kingr, 5 years ago

Merged AMM15_v3_6_STABLE_package_collate@10237
File size: 33.4 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            4.0  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_qsr      : trend due to the solar radiation penetration
17   !!   tra_qsr_init : solar radiation penetration initialization
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and active tracers
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce         ! surface boundary condition: ocean
22   USE trc_oce         ! share SMS/Ocean variables
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! trends manager: tracers
25   USE in_out_manager  ! I/O manager
26   USE phycst          ! physical constants
27   USE prtctl          ! Print control
28   USE iom             ! I/O manager
29   USE fldread         ! read input fields
30   USE restart         ! ocean restart
31   USE lib_mpp         ! MPP library
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
39   PUBLIC   tra_qsr_init  ! routine called by nemogcm.F90
40
41   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
42   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
43   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag 
44   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
45   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
46   LOGICAL , PUBLIC ::   ln_qsr_ice   !: light penetration for ice-model LIM3 (clem)
47   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
48   INTEGER , PUBLIC ::   nn_kd490dta  !: use kd490dta data (=1) or not (=0)
49   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
50   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
51   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
52 
53   ! Module variables
54   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
55   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_kd490 ! structure of input kd490 (file informations, fields read)
58   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
59   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
60
61   !! * Substitutions
62#  include "domzgr_substitute.h90"
63#  include "vectopt_loop_substitute.h90"
64   !!----------------------------------------------------------------------
65   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
66   !! $Id$
67   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
68   !!----------------------------------------------------------------------
69CONTAINS
70
71   SUBROUTINE tra_qsr( kt )
72      !!----------------------------------------------------------------------
73      !!                  ***  ROUTINE tra_qsr  ***
74      !!
75      !! ** Purpose :   Compute the temperature trend due to the solar radiation
76      !!      penetration and add it to the general temperature trend.
77      !!
78      !! ** Method  : The profile of the solar radiation within the ocean is defined
79      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
80      !!      Considering the 2 wavebands case:
81      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
82      !!         The temperature trend associated with the solar radiation penetration
83      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
84      !!         At the bottom, boudary condition for the radiation is no flux :
85      !!      all heat which has not been absorbed in the above levels is put
86      !!      in the last ocean level.
87      !!         In z-coordinate case, the computation is only done down to the
88      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
89      !!      used for the computation are calculated one for once as they
90      !!      depends on k only.
91      !!
92      !! ** Action  : - update ta with the penetrative solar radiation trend
93      !!              - save the trend in ttrd ('key_trdtra')
94      !!
95      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
96      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
97      !!----------------------------------------------------------------------
98      !
99      INTEGER, INTENT(in) ::   kt     ! ocean time-step
100      !
101      INTEGER  ::   ji, jj, jk           ! dummy loop indices
102      INTEGER  ::   irgb                 ! local integers
103      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
104      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
105      REAL(wp) ::   zzc0, zzc1, zzc2, zzc3   !    -         -
106      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
107      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
108      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt
109      !!----------------------------------------------------------------------
110      !
111      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
112      !
113      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
114      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
115      !
116      IF( kt == nit000 ) THEN
117         IF(lwp) WRITE(numout,*)
118         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
119         IF(lwp) WRITE(numout,*) '~~~~~~~'
120         IF( .NOT.ln_traqsr )   RETURN
121      ENDIF
122
123      IF( l_trdtra ) THEN      ! Save ta and sa trends
124         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
125         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
126      ENDIF
127
128      !                                        Set before qsr tracer content field
129      !                                        ***********************************
130      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
131         !                                        ! -----------------------------------
132         qsr_hc(:,:,:) = 0.e0
133         !
134         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
135              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
136            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
137            zfact = 0.5e0
138            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
139         ELSE                                           ! No restart or restart not found: Euler forward time stepping
140            zfact = 1.e0
141            qsr_hc_b(:,:,:) = 0.e0
142         ENDIF
143      ELSE                                        ! Swap of forcing field
144         !                                        ! ---------------------
145         zfact = 0.5e0
146         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
147      ENDIF
148      !                                        Compute now qsr tracer content field
149      !                                        ************************************
150     
151      !                                           ! ============================================== !
152      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
153         !                                        ! ============================================== !
154         DO jk = 1, jpkm1
155            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
156         END DO
157         !                                        Add to the general trend
158         DO jk = 1, jpkm1
159            DO jj = 2, jpjm1 
160               DO ji = fs_2, fs_jpim1   ! vector opt.
161                  z1_e3t = zfact / fse3t(ji,jj,jk)
162                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
163               END DO
164            END DO
165         END DO
166         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
167         ! clem: store attenuation coefficient of the first ocean level
168         IF ( ln_qsr_ice ) THEN
169            DO jj = 1, jpj
170               DO ji = 1, jpi
171                  IF ( qsr(ji,jj) /= 0._wp ) THEN
172                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
173                  ELSE
174                     fraqsr_1lev(ji,jj) = 1.
175                  ENDIF
176               END DO
177            END DO
178         ENDIF
179         !                                        ! ============================================== !
180      ELSE                                        !  Ocean alone :
181         !                                        ! ============================================== !
182         !
183         !                                                ! ------------------------- !
184         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
185            !                                             ! ------------------------- !
186            ! Set chlorophyl concentration
187            IF( nn_chldta == 1 .OR. lk_vvl ) THEN            !*  Variable Chlorophyll or ocean volume
188               !
189               IF( nn_chldta == 1 ) THEN                             !*  Variable Chlorophyll
190                  !
191                  CALL fld_read( kt, 1, sf_chl )                         ! Read Chl data and provides it at the current time step
192                  !         
193!CDIR COLLAPSE
194!CDIR NOVERRCHK
195                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
196!CDIR NOVERRCHK
197                     DO ji = 1, jpi
198                        zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) )
199                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
200                        zekb(ji,jj) = rkrgb(1,irgb)
201                        zekg(ji,jj) = rkrgb(2,irgb)
202                        zekr(ji,jj) = rkrgb(3,irgb)
203                     END DO
204                  END DO
205               ELSE                                            ! Variable ocean volume but constant chrlorophyll
206                  zchl = 0.05                                     ! constant chlorophyll
207                  irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 )
208                  zekb(:,:) = rkrgb(1,irgb)                       ! Separation in R-G-B depending of the chlorophyll
209                  zekg(:,:) = rkrgb(2,irgb)
210                  zekr(:,:) = rkrgb(3,irgb)
211               ENDIF
212               !
213               zcoef  = ( 1. - rn_abs ) / 3.e0                        ! equi-partition in R-G-B
214               ze0(:,:,1) = rn_abs  * qsr(:,:)
215               ze1(:,:,1) = zcoef * qsr(:,:)
216               ze2(:,:,1) = zcoef * qsr(:,:)
217               ze3(:,:,1) = zcoef * qsr(:,:)
218               zea(:,:,1) =         qsr(:,:)
219               !
220               DO jk = 2, nksr+1
221!CDIR NOVERRCHK
222                  DO jj = 1, jpj
223!CDIR NOVERRCHK   
224                     DO ji = 1, jpi
225                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
226                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
227                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
228                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
229                        ze0(ji,jj,jk) = zc0
230                        ze1(ji,jj,jk) = zc1
231                        ze2(ji,jj,jk) = zc2
232                        ze3(ji,jj,jk) = zc3
233                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
234                     END DO
235                  END DO
236               END DO
237               ! clem: store attenuation coefficient of the first ocean level
238               IF ( ln_qsr_ice ) THEN
239                  DO jj = 1, jpj
240                     DO ji = 1, jpi
241                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
242                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
243                        zzc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
244                        zzc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
245                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 + zzc2  + zzc3  ) * tmask(ji,jj,2) 
246                     END DO
247                  END DO
248               ENDIF
249               !
250               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
251                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
252               END DO
253               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
254               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
255               !
256            ELSE                                                 !*  Constant Chlorophyll
257               DO jk = 1, nksr
258                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
259               END DO
260               ! clem: store attenuation coefficient of the first ocean level
261               IF ( ln_qsr_ice ) THEN
262                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
263               ENDIF
264           ENDIF
265
266         ENDIF
267         !                                                ! ------------------------- !
268         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
269            !                                             ! ------------------------- !
270            !
271            IF( lk_vvl ) THEN                                  !* variable volume
272               zz0   =        rn_abs   * r1_rau0_rcp
273               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
274               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
275                  DO jj = 1, jpj
276                     DO ji = 1, jpi
277                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
278                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
279                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
280                     END DO
281                  END DO
282               END DO
283               ! clem: store attenuation coefficient of the first ocean level
284               IF ( ln_qsr_ice ) THEN
285                  DO jj = 1, jpj
286                     DO ji = 1, jpi
287                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
288                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
289                        fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp
290                     END DO
291                  END DO
292               ENDIF
293            ELSE                                               !* constant volume: coef. computed one for all
294               DO jk = 1, nksr
295                  DO jj = 2, jpjm1
296                     DO ji = fs_2, fs_jpim1   ! vector opt.
297                        ! (ISF) no light penetration below the ice shelves         
298                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1)
299                     END DO
300                  END DO
301               END DO
302               ! clem: store attenuation coefficient of the first ocean level
303               IF ( ln_qsr_ice ) THEN
304                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
305               ENDIF
306               !
307            ENDIF
308            !
309         ENDIF
310! slwa
311         IF( nn_kd490dta == 1 ) THEN                      !  use KD490 data read in   !
312            !                                             ! ------------------------- !
313               nksr = jpk - 1
314               !
315               CALL fld_read( kt, 1, sf_kd490 )     ! Read kd490 data and provide it at the current time step
316               !
317               zcoef  = ( 1. - rn_abs )
318               ze0(:,:,1) = rn_abs  * qsr(:,:)
319               ze1(:,:,1) = zcoef * qsr(:,:)
320               zea(:,:,1) =         qsr(:,:)
321               !
322               DO jk = 2, nksr+1
323!CDIR NOVERRCHK
324                  DO jj = 1, jpj
325!CDIR NOVERRCHK   
326                     DO ji = 1, jpi
327                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
328                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * sf_kd490(1)%fnow(ji,jj,1) )
329                        ze0(ji,jj,jk) = zc0
330                        ze1(ji,jj,jk) = zc1
331                        zea(ji,jj,jk) = ( zc0 + zc1 ) * tmask(ji,jj,jk)
332                     END DO
333                  END DO
334               END DO
335               ! clem: store attenuation coefficient of the first ocean level
336               IF ( ln_qsr_ice ) THEN
337                  DO jj = 1, jpj
338                     DO ji = 1, jpi
339                        zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
340                        zzc1 = zcoef  * EXP( - fse3t(ji,jj,1) * sf_kd490(1)%fnow(ji,jj,1) )
341                        fraqsr_1lev(ji,jj) = 1.0 - ( zzc0 + zzc1 ) * tmask(ji,jj,2) 
342                     END DO
343                  END DO
344               ENDIF
345               !
346               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
347                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
348               END DO
349               zea(:,:,nksr+1:jpk) = 0.e0     !
350               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
351               !
352        ENDIF   ! use KD490 data
353!slwa
354         !
355         !                                        Add to the general trend
356         DO jk = 1, nksr
357            DO jj = 2, jpjm1 
358               DO ji = fs_2, fs_jpim1   ! vector opt.
359                  z1_e3t = zfact / fse3t(ji,jj,jk)
360                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
361               END DO
362            END DO
363         END DO
364         !
365      ENDIF
366      !
367      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
368         !                                     *******************************
369         IF(lwp) WRITE(numout,*)
370         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
371            &                    'at it= ', kt,' date= ', ndastp
372         IF(lwp) WRITE(numout,*) '~~~~'
373         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b'   , qsr_hc      )
374         CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev )   ! default definition in sbcssm
375         !
376      ENDIF
377
378      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
379         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
380         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
381         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
382      ENDIF
383      !                       ! print mean trends (used for debugging)
384      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
385      !
386      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
387      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
388      !
389      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
390      !
391   END SUBROUTINE tra_qsr
392
393
394   SUBROUTINE tra_qsr_init
395      !!----------------------------------------------------------------------
396      !!                  ***  ROUTINE tra_qsr_init  ***
397      !!
398      !! ** Purpose :   Initialization for the penetrative solar radiation
399      !!
400      !! ** Method  :   The profile of solar radiation within the ocean is set
401      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
402      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
403      !!      default values correspond to clear water (type I in Jerlov'
404      !!      (1968) classification.
405      !!         called by tra_qsr at the first timestep (nit000)
406      !!
407      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
408      !!
409      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
410      !!----------------------------------------------------------------------
411      !
412      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
413      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
414      INTEGER  ::   ios                          ! Local integer output status for namelist read
415      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
416      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
417      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
418      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
419      !
420      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
421      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
422      TYPE(FLD_N)        ::   sn_kd490 ! informations about the kd490 field to be read
423      !!
424      NAMELIST/namtra_qsr/  sn_chl, sn_kd490, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
425         &                  nn_chldta, rn_abs, rn_si0, rn_si1, nn_kd490dta
426      !!----------------------------------------------------------------------
427
428      !
429      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
430      !
431      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
432      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
433      !
434
435      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
436      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
437901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
438
439      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
440      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
441902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
442      IF(lwm) WRITE ( numond, namtra_qsr )
443      !
444      IF(lwp) THEN                ! control print
445         WRITE(numout,*)
446         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
447         WRITE(numout,*) '~~~~~~~~~~~~'
448         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
449         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
450         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
451         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
452         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
453         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
454         WRITE(numout,*) '      RGB : Chl data (=1) or cst value (=0)    nn_chldta  = ', nn_chldta
455         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
456         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
457         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
458         WRITE(numout,*) '      read in KD490 data                       nn_kd490dta  = ', nn_kd490dta
459      ENDIF
460
461      IF( ln_traqsr ) THEN     ! control consistency
462         !                     
463         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
464            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
465            ln_qsr_bio = .FALSE.
466         ENDIF
467         !
468         ioptio = 0                      ! Parameter control
469         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
470         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
471         IF( ln_qsr_bio  )   ioptio = ioptio + 1
472         IF( nn_kd490dta == 1 )   ioptio = ioptio + 1
473         !
474         IF( ioptio /= 1 ) &
475            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
476            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
477         !
478         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
479         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
480         IF( ln_qsr_2bd                      )   nqsr =  3
481         IF( ln_qsr_bio                      )   nqsr =  4
482         IF( nn_kd490dta == 1                )   nqsr =  5
483         !
484         IF(lwp) THEN                   ! Print the choice
485            WRITE(numout,*)
486            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
487            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - Chl data '
488            IF( nqsr ==  3 )   WRITE(numout,*) '         2 bands light penetration'
489            IF( nqsr ==  4 )   WRITE(numout,*) '         bio-model light penetration'
490            IF( nqsr ==  5 )   WRITE(numout,*) '         KD490 light penetration'
491         ENDIF
492         !
493      ENDIF
494      !                          ! ===================================== !
495      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
496         !                       ! ===================================== !
497         !
498         xsi0r = 1.e0 / rn_si0
499         xsi1r = 1.e0 / rn_si1
500         IF( nn_kd490dta == 1 ) THEN           !* KD490 data : set sf_kd490 structure
501            IF(lwp) WRITE(numout,*)
502            IF(lwp) WRITE(numout,*) '        KD490 read in a file'
503            ALLOCATE( sf_kd490(1), STAT=ierror )
504            IF( ierror > 0 ) THEN
505               CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_kd490 structure' )   ;   RETURN
506            ENDIF
507            ALLOCATE( sf_kd490(1)%fnow(jpi,jpj,1)   )
508            IF( sn_kd490%ln_tint )ALLOCATE( sf_kd490(1)%fdta(jpi,jpj,1,2) )
509            !                                        ! fill sf_kd490 with sn_kd490 and control print
510            CALL fld_fill( sf_kd490, (/ sn_kd490 /), cn_dir, 'tra_qsr_init',   &
511               &                                         'Solar penetration function of read KD490', 'namtra_qsr' )
512         !                                ! ---------------------------------- !
513         ELSEIF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
514            !                             ! ---------------------------------- !
515            !
516            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
517            !
518            !                                   !* level of light extinction
519            IF(  ln_sco ) THEN   ;   nksr = jpkm1
520            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
521            ENDIF
522
523            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
524            !
525            IF( nn_chldta == 1 ) THEN           !* Chl data : set sf_chl structure
526               IF(lwp) WRITE(numout,*)
527               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
528               ALLOCATE( sf_chl(1), STAT=ierror )
529               IF( ierror > 0 ) THEN
530                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
531               ENDIF
532               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
533               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
534               !                                        ! fill sf_chl with sn_chl and control print
535               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
536                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
537               !
538            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
539               IF(lwp) WRITE(numout,*)
540               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
541               IF( lk_vvl ) THEN                   ! variable volume
542                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
543               ELSE                                ! constant volume: computes one for all
544                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
545                  !
546                  zchl = 0.05                                 ! constant chlorophyll
547                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
548                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
549                  zekg(:,:) = rkrgb(2,irgb)
550                  zekr(:,:) = rkrgb(3,irgb)
551                  !
552                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
553                  ze0(:,:,1) = rn_abs
554                  ze1(:,:,1) = zcoef
555                  ze2(:,:,1) = zcoef 
556                  ze3(:,:,1) = zcoef
557                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
558               
559                  DO jk = 2, nksr+1
560!CDIR NOVERRCHK
561                     DO jj = 1, jpj
562!CDIR NOVERRCHK   
563                        DO ji = 1, jpi
564                           zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r     )
565                           zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) )
566                           zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) )
567                           zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) )
568                           ze0(ji,jj,jk) = zc0
569                           ze1(ji,jj,jk) = zc1
570                           ze2(ji,jj,jk) = zc2
571                           ze3(ji,jj,jk) = zc3
572                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
573                        END DO
574                     END DO
575                  END DO 
576                  !
577                  DO jk = 1, nksr
578                     ! (ISF) no light penetration below the ice shelves
579                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1)
580                  END DO
581                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
582               ENDIF
583            ENDIF
584            !
585         ENDIF
586            !                             ! ---------------------------------- !
587         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
588            !                             ! ---------------------------------- !
589            !
590            !                                ! level of light extinction
591            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
592            IF(lwp) THEN
593               WRITE(numout,*)
594            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
595            ENDIF
596            !
597            IF( lk_vvl ) THEN                   ! variable volume
598               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
599            ELSE                                ! constant volume: computes one for all
600               zz0 =        rn_abs   * r1_rau0_rcp
601               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
602               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
603                  DO jj = 1, jpj                              ! top 400 meters
604                     DO ji = 1, jpi
605                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
606                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
607                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) * tmask(ji,jj,1) 
608                     END DO
609                  END DO
610               END DO
611               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
612               !
613            ENDIF
614         ENDIF
615         !                       ! ===================================== !
616      ELSE                       !        No light penetration           !                   
617         !                       ! ===================================== !
618         IF(lwp) THEN
619            WRITE(numout,*)
620            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
621            WRITE(numout,*) '~~~~~~~~~~~~'
622         ENDIF
623      ENDIF
624      !
625      ! initialisation of fraqsr_1lev used in sbcssm
626      IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN
627         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev'  , fraqsr_1lev  )
628      ELSE
629         fraqsr_1lev(:,:) = 1._wp   ! default definition
630      ENDIF
631      !
632      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
633      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
634      !
635      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
636      !
637   END SUBROUTINE tra_qsr_init
638
639   !!======================================================================
640END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.