New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limhdf_2.F90 in branches/UKMO/dev_r5518_DMP_TOOLS/NEMOGCM/NEMO/LIM_SRC_2 – NEMO

source: branches/UKMO/dev_r5518_DMP_TOOLS/NEMOGCM/NEMO/LIM_SRC_2/limhdf_2.F90 @ 10198

Last change on this file since 10198 was 10198, checked in by jenniewaters, 5 years ago

Strip out SVN keywords.

File size: 7.2 KB
Line 
1MODULE limhdf_2
2   !!======================================================================
3   !!                    ***  MODULE limhdf_2   ***
4   !! LIM 2.0 ice model : horizontal diffusion of sea-ice quantities
5   !!======================================================================
6   !! History :  LIM  !  2000-01 (LIM) Original code
7   !!             -   !  2001-05 (G. Madec, R. Hordoir) opa norm
8   !!            1.0  !  2002-08 (C. Ethe)  F90, free form
9   !!----------------------------------------------------------------------
10#if defined key_lim2
11   !!----------------------------------------------------------------------
12   !!   'key_lim2'                                    LIM 2.0 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   lim_hdf_2  : diffusion trend on sea-ice variable
15   !!----------------------------------------------------------------------
16   USE dom_oce          ! ocean domain
17   USE ice_2            ! LIM-2: ice variables
18   USE lbclnk           ! lateral boundary condition - MPP exchanges
19   USE lib_mpp          ! MPP library
20   USE wrk_nemo         ! work arrays
21   USE prtctl           ! Print control
22   USE in_out_manager   ! I/O manager
23   USE lib_fortran      ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   lim_hdf_2         ! called by limtrp_2.F90
29
30   LOGICAL  ::   linit = .TRUE.   ! ! initialization flag (set to flase after the 1st call)
31   REAL(wp) ::   epsi04 = 1e-04   ! constant
32   
33   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   efact   ! metric coefficient
34
35   !! * Substitution
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/LIM2 4.0 , UCL - NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE lim_hdf_2( ptab )
45      !!-------------------------------------------------------------------
46      !!                  ***  ROUTINE lim_hdf_2  ***
47      !!
48      !! ** purpose :   Compute and add the diffusive trend on sea-ice variables
49      !!
50      !! ** method  :   Second order diffusive operator evaluated using a
51      !!              Cranck-Nicholson time Scheme.
52      !!
53      !! ** Action  :    update ptab with the diffusive contribution
54      !!-------------------------------------------------------------------
55      REAL(wp), DIMENSION(jpi,jpj), INTENT( inout ) ::   ptab   ! Field on which the diffusion is applied 
56      !
57      INTEGER  ::   ji, jj            ! dummy loop indices
58      INTEGER  ::   its, iter, ierr   ! local integers
59      REAL(wp) ::   zalfa, zrlxint, zconv, zeps   ! local scalars
60      REAL(wp), DIMENSION(:,:), POINTER :: zrlx, zflu, zflv, zdiv0, zdiv, ztab0 
61      CHARACTER (len=55) :: charout
62      !!-------------------------------------------------------------------
63
64      CALL wrk_alloc( jpi, jpj, zrlx, zflu, zflv, zdiv0, zdiv, ztab0 )
65
66      !                       !==  Initialisation  ==!
67      !
68      IF( linit ) THEN              ! Metric coefficient (compute at the first call and saved in efact)
69         ALLOCATE( efact(jpi,jpj) , STAT=ierr )
70         IF( lk_mpp    )   CALL mpp_sum( ierr )
71         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'lim_hdf_2 : unable to allocate standard arrays' )
72         DO jj = 2, jpjm1 
73            DO ji = fs_2 , fs_jpim1   ! vector opt.
74               efact(ji,jj) = ( e2u(ji,jj) + e2u(ji-1,jj) + e1v(ji,jj) + e1v(ji,jj-1) ) / ( e1t(ji,jj) * e2t(ji,jj) )
75            END DO
76         END DO
77         linit = .FALSE.
78      ENDIF
79      !
80      !                             ! Time integration parameters
81      zalfa = 0.5_wp                      ! =1.0/0.5/0.0 = implicit/Cranck-Nicholson/explicit
82      its   = 100                         ! Maximum number of iteration
83      zeps  =  2._wp * epsi04
84      !
85      ztab0(:, : ) = ptab(:,:)      ! Arrays initialization
86      zdiv0(:, 1 ) = 0._wp
87      zdiv0(:,jpj) = 0._wp
88      zflu (jpi,:) = 0._wp   
89      zflv (jpi,:) = 0._wp
90      zdiv0(1,  :) = 0._wp
91      zdiv0(jpi,:) = 0._wp
92
93      zconv = 1._wp           !==  horizontal diffusion using a Crant-Nicholson scheme  ==!
94      iter  = 0
95      !
96      DO WHILE (  zconv > zeps  .AND.  iter <= its  )    ! Sub-time step loop
97         !
98         iter = iter + 1                                       ! incrementation of the sub-time step number
99         !
100         DO jj = 1, jpjm1                                      ! diffusive fluxes in U- and V- direction
101            DO ji = 1 , fs_jpim1   ! vector opt.
102               zflu(ji,jj) = pahu(ji,jj) * e2u(ji,jj) / e1u(ji,jj) * ( ptab(ji+1,jj) - ptab(ji,jj) )
103               zflv(ji,jj) = pahv(ji,jj) * e1v(ji,jj) / e2v(ji,jj) * ( ptab(ji,jj+1) - ptab(ji,jj) )
104            END DO
105         END DO
106         !
107         DO jj= 2, jpjm1                                       ! diffusive trend : divergence of the fluxes
108            DO ji = fs_2 , fs_jpim1   ! vector opt.
109               zdiv (ji,jj) = (  zflu(ji,jj) - zflu(ji-1,jj  )   &
110                  &            + zflv(ji,jj) - zflv(ji  ,jj-1)  ) / ( e1t (ji,jj) * e2t (ji,jj) )
111            END DO
112         END DO
113         !
114         IF( iter == 1 )   zdiv0(:,:) = zdiv(:,:)              ! save the 1st evaluation of the diffusive trend in zdiv0
115         !
116         DO jj = 2, jpjm1                                      ! iterative evaluation
117            DO ji = fs_2 , fs_jpim1   ! vector opt.
118               zrlxint = (   ztab0(ji,jj)    &
119                  &       +  rdt_ice * (           zalfa   * ( zdiv(ji,jj) + efact(ji,jj) * ptab(ji,jj) )   &
120                  &                      + ( 1.0 - zalfa ) *   zdiv0(ji,jj) )  )                             & 
121                  &    / ( 1.0 + zalfa * rdt_ice * efact(ji,jj) )
122               zrlx(ji,jj) = ptab(ji,jj) + om * ( zrlxint - ptab(ji,jj) )
123            END DO
124         END DO
125         CALL lbc_lnk( zrlx, 'T', 1. )                         ! lateral boundary condition
126
127         zconv = 0._wp                                         ! convergence test
128
129         DO jj = 2, jpjm1
130            DO ji = 2, jpim1
131               zconv = MAX( zconv, ABS( zrlx(ji,jj) - ptab(ji,jj) )  )
132            END DO
133         END DO
134         IF( lk_mpp )   CALL mpp_max( zconv )                  ! max over the global domain
135
136         ptab(:,:) = zrlx(:,:)
137         !
138      END DO                                             ! end of sub-time step loop
139
140      IF(ln_ctl)   THEN
141         zrlx(:,:) = ptab(:,:) - ztab0(:,:)
142         WRITE(charout,FMT="(' lim_hdf  : zconv =',D23.16, ' iter =',I4,2X)") zconv, iter
143         CALL prt_ctl( tab2d_1=zrlx, clinfo1=charout )
144      ENDIF
145      !
146      CALL wrk_dealloc( jpi, jpj, zrlx, zflu, zflv, zdiv0, zdiv, ztab0 )
147      !
148   END SUBROUTINE lim_hdf_2
149
150#else
151   !!----------------------------------------------------------------------
152   !!   Default option          Dummy module       NO LIM 2.0 sea-ice model
153   !!----------------------------------------------------------------------
154CONTAINS
155   SUBROUTINE lim_hdf_2       ! Empty routine
156   END SUBROUTINE lim_hdf_2
157#endif
158
159   !!======================================================================
160END MODULE limhdf_2
Note: See TracBrowser for help on using the repository browser.