New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

diaptr.F90 in branches/UKMO/dev_r5518_GC3p0_package_v2/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

Context Navigation

source: branches/UKMO/dev_r5518_GC3p0_package_v2/NEMOGCM/NEMO/OPA_SRC/DIA/diaptr.F90 @ 6463

Last change on this file since 6463 was 6463, checked in by dancopsey, 8 years ago
Merged in diaptr changes from v3_6_extra_CMIP6_diagnostics up to revision 6433.
File size: 21.8 KB

Line
1	MODULE diaptr
2	!!======================================================================
3	!! * MODULE diaptr *
4	!! Ocean physics: Computes meridonal transports and zonal means
5	!!=====================================================================
6	!! History : 1.0 ! 2003-09 (C. Talandier, G. Madec) Original code
7	!! 2.0 ! 2006-01 (A. Biastoch) Allow sub-basins computation
8	!! 3.2 ! 2010-03 (O. Marti, S. Flavoni) Add fields
9	!! 3.3 ! 2010-10 (G. Madec) dynamical allocation
10	!! 3.6 ! 2014-12 (C. Ethe) use of IOM
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! dia_ptr : Poleward Transport Diagnostics module
15	!! dia_ptr_init : Initialization, namelist read
16	!! ptr_sjk : "zonal" mean computation of a field - tracer or flux array
17	!! ptr_sj : "zonal" and vertical sum computation of a "meridional" flux array
18	!! (Generic interface to ptr_sj_3d, ptr_sj_2d)
19	!!----------------------------------------------------------------------
20	USE oce ! ocean dynamics and active tracers
21	USE dom_oce ! ocean space and time domain
22	USE phycst ! physical constants
23	!
24	USE iom ! IOM library
25	USE in_out_manager ! I/O manager
26	USE lib_mpp ! MPP library
27	USE timing ! preformance summary
28
29	IMPLICIT NONE
30	PRIVATE
31
32	INTERFACE ptr_sj
33	MODULE PROCEDURE ptr_sj_3d, ptr_sj_2d
34	END INTERFACE
35
36	PUBLIC ptr_sj ! call by tra_ldf & tra_adv routines
37	PUBLIC ptr_sjk !
38	PUBLIC dia_ptr_init ! call in step module
39	PUBLIC dia_ptr ! call in step module
40	PUBLIC dia_ptr_ohst_components ! called from tra_ldf/tra_adv routines
41
42	! !! namelist namptr
43	REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) :: htr_adv, htr_ldf !: Heat TRansports (adv, diff, overturn.)
44	REAL(wp), ALLOCATABLE, SAVE, PUBLIC, DIMENSION(:,:) :: str_adv, str_ldf !: Salt TRansports (adv, diff, overturn.)
45
46
47	LOGICAL, PUBLIC :: ln_diaptr ! Poleward transport flag (T) or not (F)
48	LOGICAL, PUBLIC :: ln_subbas ! Atlantic/Pacific/Indian basins calculation
49	INTEGER, PUBLIC :: nptr ! = 1 (l_subbas=F) or = 5 (glo, atl, pac, ind, ipc) (l_subbas=T)
50
51	REAL(wp) :: rc_sv = 1.e-6_wp ! conversion from m3/s to Sverdrup
52	REAL(wp) :: rc_pwatt = 1.e-15_wp ! conversion from W to PW (further x rau0 x Cp)
53	REAL(wp) :: rc_ggram = 1.e-6_wp ! conversion from g to Pg
54
55	CHARACTER(len=3), ALLOCATABLE, SAVE, DIMENSION(:) :: clsubb
56	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: btmsk ! T-point basin interior masks
57	REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: btm30 ! mask out Southern Ocean (=0 south of 30°S)
58
59	REAL(wp), TARGET, ALLOCATABLE, SAVE, DIMENSION(:) :: p_fval1d
60	REAL(wp), TARGET, ALLOCATABLE, SAVE, DIMENSION(:,:) :: p_fval2d
61
62
63	!! * Substitutions
64	# include "domzgr_substitute.h90"
65	# include "vectopt_loop_substitute.h90"
66	!!----------------------------------------------------------------------
67	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
68	!! $Id$
69	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
70	!!----------------------------------------------------------------------
71	CONTAINS
72
73	SUBROUTINE dia_ptr( pvtr )
74	!!----------------------------------------------------------------------
75	!! * ROUTINE dia_ptr *
76	!!----------------------------------------------------------------------
77	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL :: pvtr ! j-effective transport
78	!
79	INTEGER :: ji, jj, jk, jn ! dummy loop indices
80	REAL(wp) :: zv, zsfc ! local scalar
81	REAL(wp), DIMENSION(jpi,jpj) :: z2d ! 2D workspace
82	REAL(wp), DIMENSION(jpi,jpj,jpk) :: z3d ! 3D workspace
83	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmask ! 3D workspace
84	REAL(wp), DIMENSION(jpi,jpj,jpk,jpts) :: zts ! 3D workspace
85	CHARACTER( len = 12 ) :: cl1
86	!!----------------------------------------------------------------------
87	!
88	IF( nn_timing == 1 ) CALL timing_start('dia_ptr')
89
90	!
91	IF( PRESENT( pvtr ) ) THEN
92	IF( iom_use("zomsfglo") ) THEN ! effective MSF
93	z3d(1,:,:) = ptr_sjk( pvtr(:,:,:) ) ! zonal cumulative effective transport
94	DO jk = 2, jpkm1
95	z3d(1,:,jk) = z3d(1,:,jk-1) + z3d(1,:,jk) ! effective j-Stream-Function (MSF)
96	END DO
97	DO ji = 1, jpi
98	z3d(ji,:,:) = z3d(1,:,:)
99	ENDDO
100	cl1 = TRIM('zomsf'//clsubb(1) )
101	CALL iom_put( cl1, z3d * rc_sv )
102	DO jn = 2, nptr ! by sub-basins
103	z3d(1,:,:) = ptr_sjk( pvtr(:,:,:), btmsk(:,:,jn)*btm30(:,:) )
104	DO jk = 2, jpkm1
105	z3d(1,:,jk) = z3d(1,:,jk-1) + z3d(1,:,jk) ! effective j-Stream-Function (MSF)
106	END DO
107	DO ji = 1, jpi
108	z3d(ji,:,:) = z3d(1,:,:)
109	ENDDO
110	cl1 = TRIM('zomsf'//clsubb(jn) )
111	CALL iom_put( cl1, z3d * rc_sv )
112	END DO
113	ENDIF
114	!
115	ELSE
116	!
117	IF( iom_use("zotemglo") ) THEN ! i-mean i-k-surface
118	DO jk = 1, jpkm1
119	DO jj = 1, jpj
120	DO ji = 1, jpi
121	zsfc = e1t(ji,jj) * fse3t(ji,jj,jk)
122	zmask(ji,jj,jk) = tmask(ji,jj,jk) * zsfc
123	zts(ji,jj,jk,jp_tem) = tsn(ji,jj,jk,jp_tem) * zsfc
124	zts(ji,jj,jk,jp_sal) = tsn(ji,jj,jk,jp_sal) * zsfc
125	ENDDO
126	ENDDO
127	ENDDO
128	DO jn = 1, nptr
129	zmask(1,:,:) = ptr_sjk( zmask(:,:,:), btmsk(:,:,jn) )
130	cl1 = TRIM('zosrf'//clsubb(jn) )
131	CALL iom_put( cl1, zmask )
132	!
133	z3d(1,:,:) = ptr_sjk( zts(:,:,:,jp_tem), btmsk(:,:,jn) ) &
134	& / MAX( zmask(1,:,:), 10.e-15 )
135	DO ji = 1, jpi
136	z3d(ji,:,:) = z3d(1,:,:)
137	ENDDO
138	cl1 = TRIM('zotem'//clsubb(jn) )
139	CALL iom_put( cl1, z3d )
140	!
141	z3d(1,:,:) = ptr_sjk( zts(:,:,:,jp_sal), btmsk(:,:,jn) ) &
142	& / MAX( zmask(1,:,:), 10.e-15 )
143	DO ji = 1, jpi
144	z3d(ji,:,:) = z3d(1,:,:)
145	ENDDO
146	cl1 = TRIM('zosal'//clsubb(jn) )
147	CALL iom_put( cl1, z3d )
148	END DO
149	ENDIF
150	!
151	! ! Advective and diffusive heat and salt transport
152	IF( iom_use("sophtadv") .OR. iom_use("sopstadv") ) THEN
153	z2d(1,:) = htr_adv(:,1) * rc_pwatt ! (conversion in PW)
154	DO ji = 1, jpi
155	z2d(ji,:) = z2d(1,:)
156	ENDDO
157	cl1 = 'sophtadv'
158	CALL iom_put( TRIM(cl1), z2d )
159	z2d(1,:) = str_adv(:,1) * rc_ggram ! (conversion in Gg)
160	DO ji = 1, jpi
161	z2d(ji,:) = z2d(1,:)
162	ENDDO
163	cl1 = 'sopstadv'
164	CALL iom_put( TRIM(cl1), z2d )
165	IF( ln_subbas ) THEN
166	DO jn=2,nptr
167	z2d(1,:) = htr_adv(:,jn) * rc_pwatt ! (conversion in PW)
168	DO ji = 1, jpi
169	z2d(ji,:) = z2d(1,:)
170	ENDDO
171	cl1 = TRIM('sophtadv_'//clsubb(jn))
172	CALL iom_put( cl1, z2d )
173	z2d(1,:) = str_adv(:,jn) * rc_ggram ! (conversion in Gg)
174	DO ji = 1, jpi
175	z2d(ji,:) = z2d(1,:)
176	ENDDO
177	cl1 = TRIM('sopstadv_'//clsubb(jn))
178	CALL iom_put( cl1, z2d )
179	ENDDO
180	ENDIF
181	ENDIF
182	!
183	IF( iom_use("sophtldf") .OR. iom_use("sopstldf") ) THEN
184	z2d(1,:) = htr_ldf(:,1) * rc_pwatt ! (conversion in PW)
185	DO ji = 1, jpi
186	z2d(ji,:) = z2d(1,:)
187	ENDDO
188	cl1 = 'sophtldf'
189	CALL iom_put( TRIM(cl1), z2d )
190	z2d(1,:) = str_ldf(:,1) * rc_ggram ! (conversion in Gg)
191	DO ji = 1, jpi
192	z2d(ji,:) = z2d(1,:)
193	ENDDO
194	cl1 = 'sopstldf'
195	CALL iom_put( TRIM(cl1), z2d )
196	IF( ln_subbas ) THEN
197	DO jn=2,nptr
198	z2d(1,:) = htr_ldf(:,jn) * rc_pwatt ! (conversion in PW)
199	DO ji = 1, jpi
200	z2d(ji,:) = z2d(1,:)
201	ENDDO
202	cl1 = TRIM('sophtldf_'//clsubb(jn))
203	CALL iom_put( cl1, z2d )
204	z2d(1,:) = str_ldf(:,jn) * rc_ggram ! (conversion in Gg)
205	DO ji = 1, jpi
206	z2d(ji,:) = z2d(1,:)
207	ENDDO
208	cl1 = TRIM('sopstldf_'//clsubb(jn))
209	CALL iom_put( cl1, z2d )
210	ENDDO
211	ENDIF
212
213	ENDIF
214	!
215	ENDIF
216	!
217	IF( nn_timing == 1 ) CALL timing_stop('dia_ptr')
218	!
219	END SUBROUTINE dia_ptr
220
221
222	SUBROUTINE dia_ptr_init
223	!!----------------------------------------------------------------------
224	!! * ROUTINE dia_ptr_init *
225	!!
226	!! ** Purpose : Initialization, namelist read
227	!!----------------------------------------------------------------------
228	INTEGER :: jn ! local integers
229	INTEGER :: inum, ierr ! local integers
230	INTEGER :: ios ! Local integer output status for namelist read
231	!!
232	NAMELIST/namptr/ ln_diaptr, ln_subbas
233	!!----------------------------------------------------------------------
234
235	REWIND( numnam_ref ) ! Namelist namptr in reference namelist : Poleward transport
236	READ ( numnam_ref, namptr, IOSTAT = ios, ERR = 901)
237	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namptr in reference namelist', lwp )
238
239	REWIND( numnam_cfg ) ! Namelist namptr in configuration namelist : Poleward transport
240	READ ( numnam_cfg, namptr, IOSTAT = ios, ERR = 902 )
241	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namptr in configuration namelist', lwp )
242	IF(lwm) WRITE ( numond, namptr )
243
244	IF(lwp) THEN ! Control print
245	WRITE(numout,*)
246	WRITE(numout,*) 'dia_ptr_init : poleward transport and msf initialization'
247	WRITE(numout,*) '~~~~~~~~~~~~'
248	WRITE(numout,*) ' Namelist namptr : set ptr parameters'
249	WRITE(numout,*) ' Poleward heat & salt transport (T) or not (F) ln_diaptr = ', ln_diaptr
250	WRITE(numout,*) ' Global (F) or glo/Atl/Pac/Ind/Indo-Pac basins ln_subbas = ', ln_subbas
251	ENDIF
252
253	IF( ln_diaptr ) THEN
254	!
255	IF( ln_subbas ) THEN
256	nptr = 5 ! Global, Atlantic, Pacific, Indian, Indo-Pacific
257	ALLOCATE( clsubb(nptr) )
258	clsubb(1) = 'glo' ; clsubb(2) = 'atl' ; clsubb(3) = 'pac' ; clsubb(4) = 'ind' ; clsubb(5) = 'ipc'
259	ELSE
260	nptr = 1 ! Global only
261	ALLOCATE( clsubb(nptr) )
262	clsubb(1) = 'glo'
263	ENDIF
264
265	! ! allocate dia_ptr arrays
266	IF( dia_ptr_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'dia_ptr_init : unable to allocate arrays' )
267
268	rc_pwatt = rc_pwatt * rau0_rcp ! conversion from K.s-1 to PetaWatt
269
270	IF( lk_mpp ) CALL mpp_ini_znl( numout ) ! Define MPI communicator for zonal sum
271
272	IF( ln_subbas ) THEN ! load sub-basin mask
273	CALL iom_open( 'subbasins', inum, ldstop = .FALSE. )
274	CALL iom_get( inum, jpdom_data, 'atlmsk', btmsk(:,:,2) ) ! Atlantic basin
275	CALL iom_get( inum, jpdom_data, 'pacmsk', btmsk(:,:,3) ) ! Pacific basin
276	CALL iom_get( inum, jpdom_data, 'indmsk', btmsk(:,:,4) ) ! Indian basin
277	CALL iom_close( inum )
278	btmsk(:,:,5) = MAX ( btmsk(:,:,3), btmsk(:,:,4) ) ! Indo-Pacific basin
279	WHERE( gphit(:,:) < -30._wp) ; btm30(:,:) = 0._wp ! mask out Southern Ocean
280	ELSE WHERE ; btm30(:,:) = ssmask(:,:)
281	END WHERE
282	ENDIF
283
284	btmsk(:,:,1) = tmask_i(:,:) ! global ocean
285
286	DO jn = 1, nptr
287	btmsk(:,:,jn) = btmsk(:,:,jn) * tmask_i(:,:) ! interior domain only
288	END DO
289
290	! Initialise arrays to zero because diatpr is called before they are first calculated
291	! Note that this means diagnostics will not be exactly correct when model run is restarted.
292	htr_adv(:,:) = 0._wp ; str_adv(:,:) = 0._wp
293	htr_ldf(:,:) = 0._wp ; str_ldf(:,:) = 0._wp
294	!
295	ENDIF
296	!
297	END SUBROUTINE dia_ptr_init
298
299	SUBROUTINE dia_ptr_ohst_components( ktra, cptr, pva )
300	!!----------------------------------------------------------------------
301	!! * ROUTINE dia_ptr_ohst_components *
302	!!----------------------------------------------------------------------
303	!! Wrapper for heat and salt transport calculations to calculate them for each basin
304	!! Called from all advection and/or diffusion routines
305	!!----------------------------------------------------------------------
306	INTEGER , INTENT(in ) :: ktra ! tracer index
307	CHARACTER(len=3) , INTENT(in) :: cptr ! transport type 'adv'/'ldf'
308	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in) :: pva ! 3D input array of advection/diffusion
309	INTEGER :: jn !
310
311
312	IF( cptr == 'adv' ) THEN
313	IF( ktra == jp_tem ) htr_adv(:,1) = ptr_sj( pva(:,:,:) )
314	IF( ktra == jp_sal ) str_adv(:,1) = ptr_sj( pva(:,:,:) )
315	ENDIF
316	IF( cptr == 'ldf' ) THEN
317	IF( ktra == jp_tem ) htr_ldf(:,1) = ptr_sj( pva(:,:,:) )
318	IF( ktra == jp_sal ) str_ldf(:,1) = ptr_sj( pva(:,:,:) )
319	ENDIF
320	!
321	IF( ln_subbas ) THEN
322	!
323	IF( cptr == 'adv' ) THEN
324	IF( ktra == jp_tem ) THEN
325	DO jn = 2, nptr
326	htr_adv(:,jn) = ptr_sj( pva(:,:,:), btmsk(:,:,jn) )
327	END DO
328	ENDIF
329	IF( ktra == jp_sal ) THEN
330	DO jn = 2, nptr
331	str_adv(:,jn) = ptr_sj( pva(:,:,:), btmsk(:,:,jn) )
332	END DO
333	ENDIF
334	ENDIF
335	IF( cptr == 'ldf' ) THEN
336	IF( ktra == jp_tem ) THEN
337	DO jn = 2, nptr
338	htr_ldf(:,jn) = ptr_sj( pva(:,:,:), btmsk(:,:,jn) )
339	END DO
340	ENDIF
341	IF( ktra == jp_sal ) THEN
342	DO jn = 2, nptr
343	str_ldf(:,jn) = ptr_sj( pva(:,:,:), btmsk(:,:,jn) )
344	END DO
345	ENDIF
346	ENDIF
347	!
348	ENDIF
349
350	END SUBROUTINE
351
352
353	FUNCTION dia_ptr_alloc()
354	!!----------------------------------------------------------------------
355	!! * ROUTINE dia_ptr_alloc *
356	!!----------------------------------------------------------------------
357	INTEGER :: dia_ptr_alloc ! return value
358	INTEGER, DIMENSION(3) :: ierr
359	!!----------------------------------------------------------------------
360	ierr(:) = 0
361	!
362	ALLOCATE( btmsk(jpi,jpj,nptr) , &
363	& htr_adv(jpj,nptr) , str_adv(jpj,nptr) , &
364	& htr_ldf(jpj,nptr) , str_ldf(jpj,nptr) , STAT=ierr(1) )
365	!
366	ALLOCATE( p_fval1d(jpj), p_fval2d(jpj,jpk), Stat=ierr(2))
367	!
368	ALLOCATE( btm30(jpi,jpj), STAT=ierr(3) )
369
370	!
371	dia_ptr_alloc = MAXVAL( ierr )
372	IF(lk_mpp) CALL mpp_sum( dia_ptr_alloc )
373	!
374	END FUNCTION dia_ptr_alloc
375
376
377	FUNCTION ptr_sj_3d( pva, pmsk ) RESULT ( p_fval )
378	!!----------------------------------------------------------------------
379	!! * ROUTINE ptr_sj_3d *
380	!!
381	!! ** Purpose : i-k sum computation of a j-flux array
382	!!
383	!! ** Method : - i-k sum of pva using the interior 2D vmask (vmask_i).
384	!! pva is supposed to be a masked flux (i.e. * vmaske1ve3v)
385	!!
386	!! ** Action : - p_fval: i-k-mean poleward flux of pva
387	!!----------------------------------------------------------------------
388	REAL(wp), INTENT(in), DIMENSION(jpi,jpj,jpk) :: pva ! mask flux array at V-point
389	REAL(wp), INTENT(in), DIMENSION(jpi,jpj), OPTIONAL :: pmsk ! Optional 2D basin mask
390	!
391	INTEGER :: ji, jj, jk ! dummy loop arguments
392	INTEGER :: ijpj ! ???
393	REAL(wp), POINTER, DIMENSION(:) :: p_fval ! function value
394	!!--------------------------------------------------------------------
395	!
396	p_fval => p_fval1d
397
398	ijpj = jpj
399	p_fval(:) = 0._wp
400	IF( PRESENT( pmsk ) ) THEN
401	DO jk = 1, jpkm1
402	DO jj = 2, jpjm1
403	DO ji = fs_2, fs_jpim1 ! Vector opt.
404	p_fval(jj) = p_fval(jj) + pva(ji,jj,jk) * tmask_i(ji,jj) * pmsk(ji,jj)
405	END DO
406	END DO
407	END DO
408	ELSE
409	DO jk = 1, jpkm1
410	DO jj = 2, jpjm1
411	DO ji = fs_2, fs_jpim1 ! Vector opt.
412	p_fval(jj) = p_fval(jj) + pva(ji,jj,jk) * tmask_i(ji,jj)
413	END DO
414	END DO
415	END DO
416	ENDIF
417	#if defined key_mpp_mpi
418	IF(lk_mpp) CALL mpp_sum( p_fval, ijpj, ncomm_znl)
419	#endif
420	!
421	END FUNCTION ptr_sj_3d
422
423
424	FUNCTION ptr_sj_2d( pva, pmsk ) RESULT ( p_fval )
425	!!----------------------------------------------------------------------
426	!! * ROUTINE ptr_sj_2d *
427	!!
428	!! ** Purpose : "zonal" and vertical sum computation of a i-flux array
429	!!
430	!! ** Method : - i-k sum of pva using the interior 2D vmask (vmask_i).
431	!! pva is supposed to be a masked flux (i.e. * vmaske1ve3v)
432	!!
433	!! ** Action : - p_fval: i-k-mean poleward flux of pva
434	!!----------------------------------------------------------------------
435	REAL(wp) , INTENT(in), DIMENSION(jpi,jpj) :: pva ! mask flux array at V-point
436	REAL(wp) , INTENT(in), DIMENSION(jpi,jpj), OPTIONAL :: pmsk ! Optional 2D basin mask
437	!
438	INTEGER :: ji,jj ! dummy loop arguments
439	INTEGER :: ijpj ! ???
440	REAL(wp), POINTER, DIMENSION(:) :: p_fval ! function value
441	!!--------------------------------------------------------------------
442	!
443	p_fval => p_fval1d
444
445	ijpj = jpj
446	p_fval(:) = 0._wp
447	IF( PRESENT( pmsk ) ) THEN
448	DO jj = 2, jpjm1
449	DO ji = nldi, nlei ! No vector optimisation here. Better use a mask ?
450	p_fval(jj) = p_fval(jj) + pva(ji,jj) * tmask_i(ji,jj) * pmsk(ji,jj)
451	END DO
452	END DO
453	ELSE
454	DO jj = 2, jpjm1
455	DO ji = nldi, nlei ! No vector optimisation here. Better use a mask ?
456	p_fval(jj) = p_fval(jj) + pva(ji,jj) * tmask_i(ji,jj)
457	END DO
458	END DO
459	ENDIF
460	#if defined key_mpp_mpi
461	CALL mpp_sum( p_fval, ijpj, ncomm_znl )
462	#endif
463	!
464	END FUNCTION ptr_sj_2d
465
466
467	FUNCTION ptr_sjk( pta, pmsk ) RESULT ( p_fval )
468	!!----------------------------------------------------------------------
469	!! * ROUTINE ptr_sjk *
470	!!
471	!! ** Purpose : i-sum computation of an array
472	!!
473	!! ** Method : - i-sum of pva using the interior 2D vmask (vmask_i).
474	!!
475	!! ** Action : - p_fval: i-mean poleward flux of pva
476	!!----------------------------------------------------------------------
477	!!
478	IMPLICIT none
479	REAL(wp) , INTENT(in), DIMENSION(jpi,jpj,jpk) :: pta ! mask flux array at V-point
480	REAL(wp) , INTENT(in), DIMENSION(jpi,jpj) , OPTIONAL :: pmsk ! Optional 2D basin mask
481	!!
482	INTEGER :: ji, jj, jk ! dummy loop arguments
483	REAL(wp), POINTER, DIMENSION(:,:) :: p_fval ! return function value
484	#if defined key_mpp_mpi
485	INTEGER, DIMENSION(1) :: ish
486	INTEGER, DIMENSION(2) :: ish2
487	INTEGER :: ijpjjpk
488	REAL(wp), DIMENSION(jpj*jpk) :: zwork ! mask flux array at V-point
489	#endif
490	!!--------------------------------------------------------------------
491	!
492	p_fval => p_fval2d
493
494	p_fval(:,:) = 0._wp
495	!
496	IF( PRESENT( pmsk ) ) THEN
497	DO jk = 1, jpkm1
498	DO jj = 2, jpjm1
499	!!gm here, use of tmask_i ==> no need of loop over nldi, nlei....
500	DO ji = nldi, nlei ! No vector optimisation here. Better use a mask ?
501	p_fval(jj,jk) = p_fval(jj,jk) + pta(ji,jj,jk) * pmsk(ji,jj)
502	END DO
503	END DO
504	END DO
505	ELSE
506	DO jk = 1, jpkm1
507	DO jj = 2, jpjm1
508	DO ji = nldi, nlei ! No vector optimisation here. Better use a mask ?
509	p_fval(jj,jk) = p_fval(jj,jk) + pta(ji,jj,jk) * tmask_i(ji,jj)
510	END DO
511	END DO
512	END DO
513	END IF
514	!
515	#if defined key_mpp_mpi
516	ijpjjpk = jpj*jpk
517	ish(1) = ijpjjpk ; ish2(1) = jpj ; ish2(2) = jpk
518	zwork(1:ijpjjpk) = RESHAPE( p_fval, ish )
519	CALL mpp_sum( zwork, ijpjjpk, ncomm_znl )
520	p_fval(:,:) = RESHAPE( zwork, ish2 )
521	#endif
522	!
523	END FUNCTION ptr_sjk
524
525
526	!!======================================================================
527	END MODULE diaptr

Note: See TracBrowser for help on using the repository browser.

Download in other formats: