New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/UKMO/dev_r5518_GO6M_dev/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/UKMO/dev_r5518_GO6M_dev/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 8200

Last change on this file since 8200 was 8200, checked in by frrh, 7 years ago

Merge branches/UKMO/dev_r5518_GC3_couple_pkg@7985 using command:

svn merge -r 6574:7985 svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/UKMO/dev_r5518_GC3_couple_pkg

File size: 40.5 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!!----------------------------------------------------------------------
33
34	!!----------------------------------------------------------------------
35	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36	!! nemo_init : initialization of the NEMO system
37	!! nemo_ctl : initialisation of the contol print
38	!! nemo_closefile : close remaining open files
39	!! nemo_alloc : dynamical allocation
40	!! nemo_partition : calculate MPP domain decomposition
41	!! factorise : calculate the factors of the no. of MPI processes
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE bdyini ! open boundary cond. setting (bdy_init routine)
53	USE bdydta ! open boundary cond. setting (bdy_dta_init routine)
54	USE bdytides ! open boundary cond. setting (bdytide_init routine)
55	USE istate ! initial state setting (istate_init routine)
56	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
57	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
58	USE zdfini ! vertical physics setting (zdf_init routine)
59	USE phycst ! physical constant (par_cst routine)
60	USE trdini ! dyn/tra trends initialization (trd_init routine)
61	USE asminc ! assimilation increments
62	USE asmbkg ! writing out state trajectory
63	USE diaptr ! poleward transports (dia_ptr_init routine)
64	USE diadct ! sections transports (dia_dct_init routine)
65	USE diaobs ! Observation diagnostics (dia_obs_init routine)
66	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
67	USE step ! NEMO time-stepping (stp routine)
68	USE icbini ! handle bergs, initialisation
69	USE icbstp ! handle bergs, calving, themodynamics and transport
70	USE sbccpl
71	USE cpl_oasis3 ! OASIS3 coupling
72	USE c1d ! 1D configuration
73	USE step_c1d ! Time stepping loop for the 1D configuration
74	USE dyndmp ! Momentum damping
75	#if defined key_top
76	USE trcini ! passive tracer initialisation
77	#endif
78	USE lib_mpp ! distributed memory computing
79	#if defined key_iomput
80	USE xios
81	#endif
82	USE sbctide, ONLY: lk_tide
83	USE crsini ! initialise grid coarsening utility
84	USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
85	USE sbc_oce, ONLY: lk_oasis
86	USE stopar
87	USE stopts
88
89	IMPLICIT NONE
90	PRIVATE
91
92	PUBLIC nemo_gcm ! called by model.F90
93	PUBLIC nemo_init ! needed by AGRIF
94	PUBLIC nemo_alloc ! needed by TAM
95
96	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
97
98	!!----------------------------------------------------------------------
99	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
100	!! $Id$
101	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
102	!!----------------------------------------------------------------------
103	CONTAINS
104
105	SUBROUTINE nemo_gcm
106	!!----------------------------------------------------------------------
107	!! * ROUTINE nemo_gcm *
108	!!
109	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
110	!! curvilinear mesh on the sphere.
111	!!
112	!! ** Method : - model general initialization
113	!! - launch the time-stepping (stp routine)
114	!! - finalize the run by closing files and communications
115	!!
116	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
117	!! Madec, 2008, internal report, IPSL.
118	!!----------------------------------------------------------------------
119	INTEGER :: istp ! time step index
120	!!----------------------------------------------------------------------
121	!
122	#if defined key_agrif
123	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
124	#endif
125
126	! !-----------------------!
127	CALL nemo_init !== Initialisations ==!
128	! !-----------------------!
129	#if defined key_agrif
130	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
131	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
132	# if defined key_top
133	CALL Agrif_Declare_Var_top ! " " " " " TOP
134	# endif
135	# if defined key_lim2
136	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
137	# endif
138	#endif
139	! check that all process are still there... If some process have an error,
140	! they will never enter in step and other processes will wait until the end of the cpu time!
141	IF( lk_mpp ) CALL mpp_max( nstop )
142
143	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
144
145	! !-----------------------!
146	! !== time stepping ==!
147	! !-----------------------!
148	istp = nit000
149	#if defined key_c1d
150	DO WHILE ( istp <= nitend .AND. nstop == 0 )
151	CALL stp_c1d( istp )
152	istp = istp + 1
153	END DO
154	#else
155	IF( lk_asminc ) THEN
156	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
157	IF( ln_asmdin ) THEN ! Direct initialization
158	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
159	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
160	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
161	ENDIF
162	ENDIF
163
164	#if defined key_agrif
165	CALL Agrif_Regrid()
166	#endif
167
168	DO WHILE ( istp <= nitend .AND. nstop == 0 )
169	#if defined key_agrif
170	CALL stp ! AGRIF: time stepping
171	#else
172	IF (lk_oasis) CALL sbc_cpl_snd( istp ) ! Coupling to atmos
173	CALL stp( istp )
174	! We don't couple on the final timestep because
175	! our restart file has already been written
176	! and contains all the necessary data for a
177	! restart. sbc_cpl_snd could be called here
178	! but it would require
179	! a) A test to ensure it was not performed
180	! on the very last time-step
181	! b) the presence of another call to
182	! sbc_cpl_snd call prior to the main DO loop
183	! This solution produces identical results
184	! with fewer lines of code.
185	#endif
186	istp = istp + 1
187	IF( lk_mpp ) CALL mpp_max( nstop )
188	END DO
189	#endif
190
191	IF( lk_diaobs ) CALL dia_obs_wri
192	!
193	IF( ln_icebergs ) CALL icb_end( nitend )
194
195	! !------------------------!
196	! !== finalize the run ==!
197	! !------------------------!
198	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
199	!
200	IF( nstop /= 0 .AND. lwp ) THEN ! error print
201	WRITE(numout,cform_err)
202	WRITE(numout,*) nstop, ' error have been found'
203	ENDIF
204	!
205	#if defined key_agrif
206	IF( .NOT. Agrif_Root() ) THEN
207	CALL Agrif_ParentGrid_To_ChildGrid()
208	IF( lk_diaobs ) CALL dia_obs_wri
209	IF( nn_timing == 1 ) CALL timing_finalize
210	CALL Agrif_ChildGrid_To_ParentGrid()
211	ENDIF
212	#endif
213	IF( nn_timing == 1 ) CALL timing_finalize
214	!
215	CALL nemo_closefile
216	!
217	#if defined key_iomput
218	CALL xios_finalize ! end mpp communications with xios
219	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
220	#else
221	IF( lk_oasis ) THEN
222	CALL cpl_finalize ! end coupling and mpp communications with OASIS
223	ELSE
224	IF( lk_mpp ) CALL mppstop ! end mpp communications
225	ENDIF
226	#endif
227	!
228	END SUBROUTINE nemo_gcm
229
230
231	SUBROUTINE nemo_init
232	!!----------------------------------------------------------------------
233	!! * ROUTINE nemo_init *
234	!!
235	!! ** Purpose : initialization of the NEMO GCM
236	!!----------------------------------------------------------------------
237	INTEGER :: ji ! dummy loop indices
238	INTEGER :: ilocal_comm ! local integer
239	INTEGER :: ios
240	CHARACTER(len=80), DIMENSION(16) :: cltxt
241	!
242	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
243	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
244	& nn_bench, nn_timing
245	NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
246	& jpizoom, jpjzoom, jperio, ln_use_jattr
247	!!----------------------------------------------------------------------
248	!
249	cltxt = ''
250	cxios_context = 'nemo'
251	!
252	! ! Open reference namelist and configuration namelist files
253	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
254	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
255	!
256	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
257	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
258	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
259
260	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
261	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
262	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
263
264	!
265	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark
266	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
267	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
268
269	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
270	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
271	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
272
273	! Force values for AGRIF zoom (cf. agrif_user.F90)
274	#if defined key_agrif
275	IF( .NOT. Agrif_Root() ) THEN
276	jpiglo = nbcellsx + 2 + 2*nbghostcells
277	jpjglo = nbcellsy + 2 + 2*nbghostcells
278	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
279	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
280	jpidta = jpiglo
281	jpjdta = jpjglo
282	jpizoom = 1
283	jpjzoom = 1
284	nperio = 0
285	jperio = 0
286	ln_use_jattr = .false.
287	ENDIF
288	#endif
289	!
290	! !--------------------------------------------!
291	! ! set communicator & select the local node !
292	! ! NB: mynode also opens output.namelist.dyn !
293	! ! on unit number numond on first proc !
294	! !--------------------------------------------!
295	#if defined key_iomput
296	IF( Agrif_Root() ) THEN
297	IF( lk_oasis ) THEN
298	CALL cpl_init( "toyoce", ilocal_comm ) ! nemo local communicator given by oasis
299	CALL xios_initialize( "not used",local_comm=ilocal_comm ) ! send nemo communicator to xios
300	ELSE
301	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
302	ENDIF
303	ENDIF
304	! Nodes selection (control print return in cltxt)
305	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
306	#else
307	IF( lk_oasis ) THEN
308	IF( Agrif_Root() ) THEN
309	CALL cpl_init( "toyoce", ilocal_comm ) ! nemo local communicator given by oasis
310	ENDIF
311	! Nodes selection (control print return in cltxt)
312	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
313	ELSE
314	ilocal_comm = 0
315	! Nodes selection (control print return in cltxt)
316	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
317	ENDIF
318	#endif
319	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
320
321	lwm = (narea == 1) ! control of output namelists
322	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
323
324	IF(lwm) THEN
325	! write merged namelists from earlier to output namelist now that the
326	! file has been opened in call to mynode. nammpp has already been
327	! written in mynode (if lk_mpp_mpi)
328	WRITE( numond, namctl )
329	WRITE( numond, namcfg )
330	ENDIF
331
332	! If dimensions of processor grid weren't specified in the namelist file
333	! then we calculate them here now that we have our communicator size
334	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
335	#if defined key_mpp_mpi
336	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
337	#else
338	jpni = 1
339	jpnj = 1
340	jpnij = jpni*jpnj
341	#endif
342	END IF
343
344	! Calculate domain dimensions given calculated jpni and jpnj
345	! This used to be done in par_oce.F90 when they were parameters rather
346	! than variables
347	IF( Agrif_Root() ) THEN
348	#if defined key_nemocice_decomp
349	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
350	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
351	#else
352	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
353	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
354	#endif
355	ENDIF
356	jpk = jpkdta ! third dim
357	#if defined key_agrif
358	! simple trick to use same vertical grid as parent
359	! but different number of levels:
360	! Save maximum number of levels in jpkdta, then define all vertical grids
361	! with this number.
362	! Suppress once vertical online interpolation is ok
363	IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
364	#endif
365	jpim1 = jpi-1 ! inner domain indices
366	jpjm1 = jpj-1 ! " "
367	jpkm1 = jpk-1 ! " "
368	jpij = jpi*jpj ! jpi x j
369
370	IF(lwp) THEN ! open listing units
371	!
372	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
373	!
374	WRITE(numout,*)
375	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
376	WRITE(numout,*) ' NEMO team'
377	WRITE(numout,*) ' Ocean General Circulation Model'
378	WRITE(numout,*) ' version 3.6 (2015) '
379	WRITE(numout,*)
380	WRITE(numout,*)
381	DO ji = 1, SIZE(cltxt)
382	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
383	END DO
384	WRITE(numout,cform_aaa) ! Flag AAAAAAA
385	!
386	ENDIF
387
388	! Now we know the dimensions of the grid and numout has been set we can
389	! allocate arrays
390	CALL nemo_alloc()
391
392	! !-------------------------------!
393	! ! NEMO general initialization !
394	! !-------------------------------!
395
396	CALL nemo_ctl ! Control prints & Benchmark
397
398	! ! Domain decomposition
399	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
400	ELSE ; CALL mpp_init2 ! eliminate land processors
401	ENDIF
402	!
403	IF( nn_timing == 1 ) CALL timing_init
404	!
405	! ! General initialization
406	CALL phy_cst ! Physical constants
407	CALL eos_init ! Equation of state
408	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
409	CALL dom_cfg ! Domain configuration
410	CALL dom_init ! Domain
411
412	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
413
414	IF( ln_ctl ) CALL prt_ctl_init ! Print control
415
416	CALL istate_init ! ocean initial state (Dynamics and tracers)
417
418	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
419
420	CALL sbc_init ! Forcings : surface module (clem: moved here for bdy purpose)
421
422	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
423	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
424	IF( lk_bdy .AND. lk_tide ) &
425	& CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
426
427	CALL dyn_nept_init ! simplified form of Neptune effect
428	!
429	IF( ln_crs ) CALL crs_init ! Domain initialization of coarsened grid
430	!
431	! Ocean physics
432	! ! Vertical physics
433	CALL zdf_init ! namelist read
434	CALL zdf_bfr_init ! bottom friction
435	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
436	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
437	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
438	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
439	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
440	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
441	& CALL zdf_ddm_init ! double diffusive mixing
442	! ! Lateral physics
443	CALL ldf_tra_init ! Lateral ocean tracer physics
444	CALL ldf_dyn_init ! Lateral ocean momentum physics
445	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
446
447	! ! Active tracers
448	CALL tra_qsr_init ! penetrative solar radiation qsr
449	CALL tra_bbc_init ! bottom heat flux
450	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
451	CALL tra_dmp_init ! internal damping trends- tracers
452	CALL tra_adv_init ! horizontal & vertical advection
453	CALL tra_ldf_init ! lateral mixing
454	CALL tra_zdf_init ! vertical mixing and after tracer fields
455
456	! ! Dynamics
457	IF( lk_c1d ) CALL dyn_dmp_init ! internal damping trends- momentum
458	CALL dyn_adv_init ! advection (vector or flux form)
459	CALL dyn_vor_init ! vorticity term including Coriolis
460	CALL dyn_ldf_init ! lateral mixing
461	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
462	CALL dyn_zdf_init ! vertical diffusion
463	CALL dyn_spg_init ! surface pressure gradient
464
465	! ! Misc. options
466	IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 ) CALL cla_init ! Cross Land Advection
467	CALL icb_init( rdt, nit000) ! initialise icebergs instance
468	CALL sto_par_init ! Stochastic parametrization
469	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
470
471	#if defined key_top
472	! ! Passive tracers
473	CALL trc_init
474	#endif
475	! ! Diagnostics
476	IF( lk_floats ) CALL flo_init ! drifting Floats
477	CALL dia_ptr_init ! Poleward TRansports initialization
478	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
479	CALL dia_hsb_init ! heat content, salt content and volume budgets
480	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
481	IF( lk_diaobs ) THEN ! Observation & model comparison
482	CALL dia_obs_init ! Initialize observational data
483	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
484	ENDIF
485
486	! ! Assimilation increments
487	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
488	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
489
490	IF (nstop > 0) THEN
491	CALL CTL_STOP('STOP','Critical errors in NEMO initialisation')
492	END IF
493
494	!
495	END SUBROUTINE nemo_init
496
497
498	SUBROUTINE nemo_ctl
499	!!----------------------------------------------------------------------
500	!! * ROUTINE nemo_ctl *
501	!!
502	!! ** Purpose : control print setting
503	!!
504	!! ** Method : - print namctl information and check some consistencies
505	!!----------------------------------------------------------------------
506	!
507	IF(lwp) THEN ! control print
508	WRITE(numout,*)
509	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
510	WRITE(numout,*) '~~~~~~~ '
511	WRITE(numout,*) ' Namelist namctl'
512	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
513	WRITE(numout,*) ' level of print nn_print = ', nn_print
514	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
515	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
516	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
517	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
518	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
519	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
520	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
521	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
522	ENDIF
523	!
524	nprint = nn_print ! convert DOCTOR namelist names into OLD names
525	nictls = nn_ictls
526	nictle = nn_ictle
527	njctls = nn_jctls
528	njctle = nn_jctle
529	isplt = nn_isplt
530	jsplt = nn_jsplt
531	nbench = nn_bench
532
533	IF(lwp) THEN ! control print
534	WRITE(numout,*)
535	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
536	WRITE(numout,*) '~~~~~~~ '
537	WRITE(numout,*) ' Namelist namcfg'
538	WRITE(numout,*) ' configuration name cp_cfg = ', TRIM(cp_cfg)
539	WRITE(numout,*) ' configuration zoom name cp_cfz = ', TRIM(cp_cfz)
540	WRITE(numout,*) ' configuration resolution jp_cfg = ', jp_cfg
541	WRITE(numout,*) ' 1st lateral dimension ( >= jpi ) jpidta = ', jpidta
542	WRITE(numout,*) ' 2nd " " ( >= jpj ) jpjdta = ', jpjdta
543	WRITE(numout,*) ' 3nd " " jpkdta = ', jpkdta
544	WRITE(numout,*) ' 1st dimension of global domain in i jpiglo = ', jpiglo
545	WRITE(numout,*) ' 2nd - - in j jpjglo = ', jpjglo
546	WRITE(numout,*) ' left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
547	WRITE(numout,*) ' left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
548	WRITE(numout,*) ' lateral cond. type (between 0 and 6) jperio = ', jperio
549	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
550	ENDIF
551	! ! Parameter control
552	!
553	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
554	IF( lk_mpp .AND. jpnij > 1 ) THEN
555	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
556	ELSE
557	IF( isplt == 1 .AND. jsplt == 1 ) THEN
558	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
559	& ' - the print control will be done over the whole domain' )
560	ENDIF
561	ijsplt = isplt * jsplt ! total number of processors ijsplt
562	ENDIF
563	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
564	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
565	!
566	! ! indices used for the SUM control
567	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
568	lsp_area = .FALSE.
569	ELSE ! print control done over a specific area
570	lsp_area = .TRUE.
571	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
572	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
573	nictls = 1
574	ENDIF
575	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
576	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
577	nictle = jpiglo
578	ENDIF
579	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
580	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
581	njctls = 1
582	ENDIF
583	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
584	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
585	njctle = jpjglo
586	ENDIF
587	ENDIF
588	ENDIF
589	!
590	IF( nbench == 1 ) THEN ! Benchmark
591	SELECT CASE ( cp_cfg )
592	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
593	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
594	& ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
595	END SELECT
596	ENDIF
597	!
598	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
599	& 'f2003 standard. ' , &
600	& 'Compile with key_nosignedzero enabled' )
601	!
602	END SUBROUTINE nemo_ctl
603
604
605	SUBROUTINE nemo_closefile
606	!!----------------------------------------------------------------------
607	!! * ROUTINE nemo_closefile *
608	!!
609	!! ** Purpose : Close the files
610	!!----------------------------------------------------------------------
611	!
612	IF( lk_mpp ) CALL mppsync
613	!
614	CALL iom_close ! close all input/output files managed by iom_*
615	!
616	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
617	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
618	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
619	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
620	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
621	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
622	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
623	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
624	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
625	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
626	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
627	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
628	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
629
630	!
631	numout = 6 ! redefine numout in case it is used after this point...
632	!
633	END SUBROUTINE nemo_closefile
634
635
636	SUBROUTINE nemo_alloc
637	!!----------------------------------------------------------------------
638	!! * ROUTINE nemo_alloc *
639	!!
640	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
641	!!
642	!! ** Method :
643	!!----------------------------------------------------------------------
644	USE diawri , ONLY: dia_wri_alloc
645	USE dom_oce , ONLY: dom_oce_alloc
646	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
647	USE ldftra_oce, ONLY: ldftra_oce_alloc
648	USE trc_oce , ONLY: trc_oce_alloc
649	#if defined key_diadct
650	USE diadct , ONLY: diadct_alloc
651	#endif
652	#if defined key_bdy
653	USE bdy_oce , ONLY: bdy_oce_alloc
654	#endif
655	!
656	INTEGER :: ierr
657	!!----------------------------------------------------------------------
658	!
659	ierr = oce_alloc () ! ocean
660	ierr = ierr + dia_wri_alloc ()
661	ierr = ierr + dom_oce_alloc () ! ocean domain
662	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
663	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
664	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
665	!
666	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
667	!
668	#if defined key_diadct
669	ierr = ierr + diadct_alloc () !
670	#endif
671	#if defined key_bdy
672	ierr = ierr + bdy_oce_alloc () ! bdy masks (incl. initialization)
673	#endif
674	!
675	IF( lk_mpp ) CALL mpp_sum( ierr )
676	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
677	!
678	END SUBROUTINE nemo_alloc
679
680
681	SUBROUTINE nemo_partition( num_pes )
682	!!----------------------------------------------------------------------
683	!! * ROUTINE nemo_partition *
684	!!
685	!! ** Purpose :
686	!!
687	!! ** Method :
688	!!----------------------------------------------------------------------
689	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
690	!
691	INTEGER, PARAMETER :: nfactmax = 20
692	INTEGER :: nfact ! The no. of factors returned
693	INTEGER :: ierr ! Error flag
694	INTEGER :: ji
695	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
696	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
697	!!----------------------------------------------------------------------
698	!
699	ierr = 0
700	!
701	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
702	!
703	IF( nfact <= 1 ) THEN
704	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
705	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
706	jpnj = 1
707	jpni = num_pes
708	ELSE
709	! Search through factors for the pair that are closest in value
710	mindiff = 1000000
711	imin = 1
712	DO ji = 1, nfact-1, 2
713	idiff = ABS( ifact(ji) - ifact(ji+1) )
714	IF( idiff < mindiff ) THEN
715	mindiff = idiff
716	imin = ji
717	ENDIF
718	END DO
719	jpnj = ifact(imin)
720	jpni = ifact(imin + 1)
721	ENDIF
722	!
723	jpnij = jpni*jpnj
724	!
725	END SUBROUTINE nemo_partition
726
727
728	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
729	!!----------------------------------------------------------------------
730	!! * ROUTINE factorise *
731	!!
732	!! ** Purpose : return the prime factors of n.
733	!! knfax factors are returned in array kfax which is of
734	!! maximum dimension kmaxfax.
735	!! ** Method :
736	!!----------------------------------------------------------------------
737	INTEGER , INTENT(in ) :: kn, kmaxfax
738	INTEGER , INTENT( out) :: kerr, knfax
739	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
740	!
741	INTEGER :: ifac, jl, inu
742	INTEGER, PARAMETER :: ntest = 14
743	INTEGER, DIMENSION(ntest) :: ilfax
744	!
745	! ilfax contains the set of allowed factors.
746	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
747	!!----------------------------------------------------------------------
748	! ilfax contains the set of allowed factors.
749	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
750
751	! Clear the error flag and initialise output vars
752	kerr = 0
753	kfax = 1
754	knfax = 0
755
756	! Find the factors of n.
757	IF( kn == 1 ) GOTO 20
758
759	! nu holds the unfactorised part of the number.
760	! knfax holds the number of factors found.
761	! l points to the allowed factor list.
762	! ifac holds the current factor.
763
764	inu = kn
765	knfax = 0
766
767	DO jl = ntest, 1, -1
768	!
769	ifac = ilfax(jl)
770	IF( ifac > inu ) CYCLE
771
772	! Test whether the factor will divide.
773
774	IF( MOD(inu,ifac) == 0 ) THEN
775	!
776	knfax = knfax + 1 ! Add the factor to the list
777	IF( knfax > kmaxfax ) THEN
778	kerr = 6
779	write (,) 'FACTOR: insufficient space in factor array ', knfax
780	return
781	ENDIF
782	kfax(knfax) = ifac
783	! Store the other factor that goes with this one
784	knfax = knfax + 1
785	kfax(knfax) = inu / ifac
786	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
787	ENDIF
788	!
789	END DO
790
791	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
792	!
793	END SUBROUTINE factorise
794
795	#if defined key_mpp_mpi
796
797	SUBROUTINE nemo_northcomms
798	!!======================================================================
799	!! * ROUTINE nemo_northcomms *
800	!! nemo_northcomms : Setup for north fold exchanges with explicit
801	!! point-to-point messaging
802	!!=====================================================================
803	!!----------------------------------------------------------------------
804	!!
805	!! ** Purpose : Initialization of the northern neighbours lists.
806	!!----------------------------------------------------------------------
807	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
808	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
809	!!----------------------------------------------------------------------
810
811	INTEGER :: sxM, dxM, sxT, dxT, jn
812	INTEGER :: njmppmax
813
814	njmppmax = MAXVAL( njmppt )
815
816	!initializes the north-fold communication variables
817	isendto(:) = 0
818	nsndto = 0
819
820	!if I am a process in the north
821	IF ( njmpp == njmppmax ) THEN
822	!sxM is the first point (in the global domain) needed to compute the
823	!north-fold for the current process
824	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
825	!dxM is the last point (in the global domain) needed to compute the
826	!north-fold for the current process
827	dxM = jpiglo - nimppt(narea) + 2
828
829	!loop over the other north-fold processes to find the processes
830	!managing the points belonging to the sxT-dxT range
831
832	DO jn = 1, jpni
833	!sxT is the first point (in the global domain) of the jn
834	!process
835	sxT = nfiimpp(jn, jpnj)
836	!dxT is the last point (in the global domain) of the jn
837	!process
838	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
839	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
840	nsndto = nsndto + 1
841	isendto(nsndto) = jn
842	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
843	nsndto = nsndto + 1
844	isendto(nsndto) = jn
845	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
846	nsndto = nsndto + 1
847	isendto(nsndto) = jn
848	END IF
849	END DO
850	nfsloop = 1
851	nfeloop = nlci
852	DO jn = 2,jpni-1
853	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
854	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
855	nfsloop = nldi
856	ENDIF
857	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
858	nfeloop = nlei
859	ENDIF
860	ENDIF
861	END DO
862
863	ENDIF
864	l_north_nogather = .TRUE.
865	END SUBROUTINE nemo_northcomms
866	#else
867	SUBROUTINE nemo_northcomms ! Dummy routine
868	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
869	END SUBROUTINE nemo_northcomms
870	#endif
871
872	!!======================================================================
873	END MODULE nemogcm
874
875

Note: See TracBrowser for help on using the repository browser.

Download in other formats: