New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/UKMO/dev_r5518_GO6_fix_cpp_keys/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/dev_r5518_GO6_fix_cpp_keys/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 10004

Last change on this file since 10004 was 10004, checked in by frrh, 6 years ago

Various fixes

File size: 35.0 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE diaptr         ! poleward transport diagnostics
29   !
30   USE lib_mpp        ! MPP library
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE in_out_manager ! I/O manager
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE phycst         ! Physical constants
36   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
37   USE iom
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
43   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
44
45   LOGICAL ::   l_trd   ! flag to compute trends
46   LOGICAL ::   l_trans   ! flag to output vertically integrated transports
47
48   !! * Substitutions
49#  include "domzgr_substitute.h90"
50#  include "vectopt_loop_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
59      &                                       ptb, ptn, pta, kjpt )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE tra_adv_tvd  ***
62      !!
63      !! **  Purpose :   Compute the now trend due to total advection of
64      !!       tracers and add it to the general trend of tracer equations
65      !!
66      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
67      !!       corrected flux (monotonic correction)
68      !!       note: - this advection scheme needs a leap-frog time scheme
69      !!
70      !! ** Action : - update (pta) with the now advective tracer trends
71      !!             - save the trends
72      !!----------------------------------------------------------------------
73      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
74      !
75      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
77      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
78      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
79      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
80      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
83      !
84      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
85      INTEGER  ::   ik 
86      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
87      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
88      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
89      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zwi, zwz
90      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz, zptry
91      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   :: z2d
92      !!----------------------------------------------------------------------
93      !
94      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
95      !
96      ALLOCATE(zwi(1:jpi, 1:jpj, 1:jpk))
97      ALLOCATE(zwz(1:jpi, 1:jpj, 1:jpk))
98
99      !
100      IF( kt == kit000 )  THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
103         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
104         !
105      ENDIF
106      l_trd = .FALSE.
107      l_trans = .FALSE.
108      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
109      IF( cdtype == 'TRA' .AND. (iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") ) ) l_trans = .TRUE.
110      !
111      IF( l_trd .OR. l_trans )  THEN
112         ALLOCATE(ztrdx(1:jpi, 1:jpj, 1:jpk))
113         ALLOCATE(ztrdy(1:jpi, 1:jpj, 1:jpk))
114         ALLOCATE(ztrdz(1:jpi, 1:jpj, 1:jpk))
115         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
116         ALLOCATE(z2d(1:jpi, 1:jpj))
117      ENDIF
118      !
119      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
120         ALLOCATE(zptry(1:jpi, 1:jpj, 1:jpk))
121         zptry(:,:,:) = 0._wp
122      ENDIF
123      !
124      zwi(:,:,:) = 0.e0 ; 
125      !
126      !                                                          ! ===========
127      DO jn = 1, kjpt                                            ! tracer loop
128         !                                                       ! ===========
129         ! 1. Bottom and k=1 value : flux set to zero
130         ! ----------------------------------
131         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
132         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
133         
134         zwz(:,:,1  ) = 0._wp
135         ! 2. upstream advection with initial mass fluxes & intermediate update
136         ! --------------------------------------------------------------------
137         ! upstream tracer flux in the i and j direction
138         DO jk = 1, jpkm1
139            DO jj = 1, jpjm1
140               DO ji = 1, fs_jpim1   ! vector opt.
141                  ! upstream scheme
142                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
143                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
144                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
145                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
146                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
147                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
148               END DO
149            END DO
150         END DO
151
152         ! upstream tracer flux in the k direction
153         ! Interior value
154         DO jk = 2, jpkm1
155            DO jj = 1, jpj
156               DO ji = 1, jpi
157                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
158                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
159                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
160               END DO
161            END DO
162         END DO
163         ! Surface value
164         IF( lk_vvl ) THEN   
165            IF ( ln_isfcav ) THEN
166               DO jj = 1, jpj
167                  DO ji = 1, jpi
168                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable
169                  END DO
170               END DO
171            ELSE
172               zwz(:,:,1) = 0.e0          ! volume variable
173            END IF
174         ELSE               
175            IF ( ln_isfcav ) THEN
176               DO jj = 1, jpj
177                  DO ji = 1, jpi
178                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
179                  END DO
180               END DO   
181            ELSE
182               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
183            END IF
184         ENDIF
185
186         ! total advective trend
187         DO jk = 1, jpkm1
188            z2dtt = p2dt(jk)
189            DO jj = 2, jpjm1
190               DO ji = fs_2, fs_jpim1   ! vector opt.
191                  ! total intermediate advective trends
192                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
193                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
194                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) / e1e2t(ji,jj)
195                  ! update and guess with monotonic sheme
196                  pta(ji,jj,jk,jn) =                       pta(ji,jj,jk,jn) +         ztra   / fse3t_n(ji,jj,jk) * tmask(ji,jj,jk)
197                  zwi(ji,jj,jk)    = ( fse3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + z2dtt * ztra ) / fse3t_a(ji,jj,jk) * tmask(ji,jj,jk)
198               END DO
199            END DO
200         END DO
201         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
202         CALL lbc_lnk( zwi, 'T', 1. ) 
203
204         !                                 ! trend diagnostics (contribution of upstream fluxes)
205         IF( l_trd .OR. l_trans )  THEN 
206            ! store intermediate advective trends
207            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
208         END IF
209         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
210         IF( cdtype == 'TRA' .AND. ln_diaptr )    zptry(:,:,:) = zwy(:,:,:) 
211
212         ! 3. antidiffusive flux : high order minus low order
213         ! --------------------------------------------------
214         ! antidiffusive flux on i and j
215         DO jk = 1, jpkm1
216            DO jj = 1, jpjm1
217               DO ji = 1, fs_jpim1   ! vector opt.
218                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
219                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
220               END DO
221            END DO
222         END DO
223     
224         ! antidiffusive flux on k
225         ! Interior value
226         DO jk = 2, jpkm1                   
227            DO jj = 1, jpj
228               DO ji = 1, jpi
229                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
230               END DO
231            END DO
232         END DO
233         ! surface value
234         IF ( ln_isfcav ) THEN
235            DO jj = 1, jpj
236               DO ji = 1, jpi
237                  zwz(ji,jj,mikt(ji,jj)) = 0.e0
238               END DO
239            END DO
240         ELSE
241            zwz(:,:,1) = 0.e0
242         END IF
243         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
244         CALL lbc_lnk( zwz, 'W',  1. )
245
246         ! 4. monotonicity algorithm
247         ! -------------------------
248         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
249
250
251         ! 5. final trend with corrected fluxes
252         ! ------------------------------------
253         DO jk = 1, jpkm1
254            DO jj = 2, jpjm1
255               DO ji = fs_2, fs_jpim1   ! vector opt. 
256                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
257                  ! total advective trends
258                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
259                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
260                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
261                  ! add them to the general tracer trends
262                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
263               END DO
264            END DO
265         END DO
266
267         !                                 ! trend diagnostics (contribution of upstream fluxes)
268         IF( l_trd .OR. l_trans )  THEN
269            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
270            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
271            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
272         ENDIF
273         
274         IF( l_trd ) THEN
275            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
276            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
277            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
278         END IF
279
280         IF( l_trans .AND. jn==jp_tem ) THEN
281            z2d(:,:) = 0._wp 
282            DO jk = 1, jpkm1
283               DO jj = 2, jpjm1
284                  DO ji = fs_2, fs_jpim1   ! vector opt.
285                     z2d(ji,jj) = z2d(ji,jj) + ztrdx(ji,jj,jk) 
286                  END DO
287               END DO
288            END DO
289            CALL lbc_lnk( z2d, 'U', -1. )
290            CALL iom_put( "uadv_heattr", rau0_rcp * z2d )       ! heat transport in i-direction
291              !
292            z2d(:,:) = 0._wp 
293            DO jk = 1, jpkm1
294               DO jj = 2, jpjm1
295                  DO ji = fs_2, fs_jpim1   ! vector opt.
296                     z2d(ji,jj) = z2d(ji,jj) + ztrdy(ji,jj,jk) 
297                  END DO
298               END DO
299            END DO
300            CALL lbc_lnk( z2d, 'V', -1. )
301            CALL iom_put( "vadv_heattr", rau0_rcp * z2d )       ! heat transport in j-direction
302         ENDIF
303         ! "Poleward" heat and salt transports (contribution of upstream fluxes)
304         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
305            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
306            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
307         ENDIF
308         !
309      END DO
310      !
311      DEALLOCATE( zwi )
312      DEALLOCATE( zwz )
313      IF( l_trd .OR. l_trans )  THEN
314         DEALLOCATE( ztrdx )
315         DEALLOCATE( ztrdy )
316         DEALLOCATE( ztrdz )
317         DEALLOCATE( z2d )
318      ENDIF
319      IF( cdtype == 'TRA' .AND. ln_diaptr ) DEALLOCATE( zptry )
320      !
321      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
322      !
323   END SUBROUTINE tra_adv_tvd
324
325   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
326      &                                       ptb, ptn, pta, kjpt )
327      !!----------------------------------------------------------------------
328      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
329      !!
330      !! **  Purpose :   Compute the now trend due to total advection of
331      !!       tracers and add it to the general trend of tracer equations
332      !!
333      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
334      !!       corrected flux (monotonic correction). This version use sub-
335      !!       timestepping for the vertical advection which increases stability
336      !!       when vertical metrics are small.
337      !!       note: - this advection scheme needs a leap-frog time scheme
338      !!
339      !! ** Action : - update (pta) with the now advective tracer trends
340      !!             - save the trends
341      !!----------------------------------------------------------------------
342      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
343      !
344      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
345      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
346      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
347      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
348      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
349      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
350      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
351      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
352      !
353      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
354      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
355      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
356      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
357      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
358      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
359      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
360      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
361      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
362      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
363      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
364      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
365      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
366      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zptry
367      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) :: ztrs
368      !!----------------------------------------------------------------------
369      !
370      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
371      !
372      ALLOCATE(zwx_sav(1:jpi, 1:jpj))
373      ALLOCATE(zwy_sav(1:jpi, 1:jpj))
374      ALLOCATE(zwi(1:jpi, 1:jpj, 1:jpk))
375      ALLOCATE(zwz(1:jpi, 1:jpj, 1:jpk))       
376      ALLOCATE(zhdiv(1:jpi, 1:jpj, 1:jpk))       
377      ALLOCATE(zwz_sav(1:jpi, 1:jpj, 1:jpk))       
378      ALLOCATE(zwzts(1:jpi, 1:jpj, 1:jpk)) 
379      ALLOCATE(ztrs(1:jpi, 1:jpj, 1:jpk, 1:kjpt+1))
380      !
381      IF( kt == kit000 )  THEN
382         IF(lwp) WRITE(numout,*)
383         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
384         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
385      ENDIF
386      !
387      l_trd = .FALSE.
388      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
389      !
390      IF( l_trd )  THEN
391         ALLOCATE(ztrdx(1:jpi, 1:jpj, 1:jpk))       
392         ALLOCATE(ztrdy(1:jpi, 1:jpj, 1:jpk))       
393         ALLOCATE(ztrdz(1:jpi, 1:jpj, 1:jpk))       
394         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
395      ENDIF
396      !
397      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
398         ALLOCATE(zptry(1:jpi, 1:jpj, 1:jpk))       
399         zptry(:,:,:) = 0._wp
400      ENDIF
401      !
402      zwi(:,:,:) = 0._wp
403      z_rzts = 1._wp / REAL( jnzts, wp )
404      zr_p2dt(:) = 1._wp / p2dt(:)
405      !
406      !                                                          ! ===========
407      DO jn = 1, kjpt                                            ! tracer loop
408         !                                                       ! ===========
409         ! 1. Bottom value : flux set to zero
410         ! ----------------------------------
411         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
412         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
413
414         ! 2. upstream advection with initial mass fluxes & intermediate update
415         ! --------------------------------------------------------------------
416         ! upstream tracer flux in the i and j direction
417         DO jk = 1, jpkm1
418            DO jj = 1, jpjm1
419               DO ji = 1, fs_jpim1   ! vector opt.
420                  ! upstream scheme
421                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
422                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
423                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
424                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
425                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
426                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
427               END DO
428            END DO
429         END DO
430
431         ! upstream tracer flux in the k direction
432         ! Interior value
433         DO jk = 2, jpkm1
434            DO jj = 1, jpj
435               DO ji = 1, jpi
436                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
437                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
438                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
439               END DO
440            END DO
441         END DO
442         ! Surface value
443         IF( lk_vvl ) THEN
444            IF ( ln_isfcav ) THEN
445               DO jj = 1, jpj
446                  DO ji = 1, jpi
447                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable +    isf
448                  END DO
449               END DO
450            ELSE
451               zwz(:,:,1) = 0.e0                              ! volume variable + no isf
452            END IF
453         ELSE
454            IF ( ln_isfcav ) THEN
455               DO jj = 1, jpj
456                  DO ji = 1, jpi
457                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface +    isf
458                  END DO
459               END DO
460            ELSE
461               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)                                               ! linear free surface + no isf
462            END IF
463         ENDIF
464
465         ! total advective trend
466         DO jk = 1, jpkm1
467            z2dtt = p2dt(jk)
468            DO jj = 2, jpjm1
469               DO ji = fs_2, fs_jpim1   ! vector opt.
470                  ! total intermediate advective trends
471                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
472                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
473                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) / e1e2t(ji,jj)
474                  ! update and guess with monotonic sheme
475                  pta(ji,jj,jk,jn) =                       pta(ji,jj,jk,jn) +         ztra   / fse3t_n(ji,jj,jk) * tmask(ji,jj,jk)
476                  zwi(ji,jj,jk)    = ( fse3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + z2dtt * ztra ) / fse3t_a(ji,jj,jk) * tmask(ji,jj,jk)
477               END DO
478            END DO
479         END DO
480         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
481         CALL lbc_lnk( zwi, 'T', 1. ) 
482
483         !                                 ! trend diagnostics (contribution of upstream fluxes)
484         IF( l_trd )  THEN 
485            ! store intermediate advective trends
486            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
487         END IF
488         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
489         IF( cdtype == 'TRA' .AND. ln_diaptr )  zptry(:,:,:) = zwy(:,:,:)
490
491         ! 3. antidiffusive flux : high order minus low order
492         ! --------------------------------------------------
493         ! antidiffusive flux on i and j
494         !
495         DO jk = 1, jpkm1
496            !
497            DO jj = 1, jpjm1
498               DO ji = 1, fs_jpim1   ! vector opt.
499                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
500                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
501
502                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
503                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
504               END DO
505            END DO
506
507            DO jj = 2, jpjm1         ! partial horizontal divergence
508               DO ji = fs_2, fs_jpim1
509                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
510                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
511               END DO
512            END DO
513
514            DO jj = 1, jpjm1
515               DO ji = 1, fs_jpim1   ! vector opt.
516                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
517                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
518               END DO
519            END DO
520         END DO
521     
522         ! antidiffusive flux on k
523         zwz(:,:,1) = 0._wp        ! Surface value
524         zwz_sav(:,:,:) = zwz(:,:,:)
525         !
526         ztrs(:,:,:,1) = ptb(:,:,:,jn)
527         ztrs(:,:,1,2) = ptb(:,:,1,jn)
528         ztrs(:,:,1,3) = ptb(:,:,1,jn)
529         zwzts(:,:,:) = 0._wp
530
531         DO jl = 1, jnzts                   ! Start of sub timestepping loop
532
533            IF( jl == 1 ) THEN              ! Euler forward to kick things off
534              jtb = 1   ;   jtn = 1   ;   jta = 2
535              zts(:) = p2dt(:) * z_rzts
536              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
537                                            ! starting at jl =1 if jnzts is odd;
538                                            ! starting at jl =2 otherwise
539            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
540              jtb = 1   ;   jtn = 2   ;   jta = 3
541              zts(:) = 2._wp * p2dt(:) * z_rzts
542            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
543              jtb = MOD(jtb,3) + 1
544              jtn = MOD(jtn,3) + 1
545              jta = MOD(jta,3) + 1
546            ENDIF
547            DO jk = 2, jpkm1          ! Interior value
548               DO jj = 2, jpjm1
549                  DO ji = fs_2, fs_jpim1
550                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
551                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
552                  END DO
553               END DO
554            END DO
555
556            jtaken = MOD( jtaken + 1 , 2 )
557
558            DO jk = 2, jpkm1          ! Interior value
559               DO jj = 2, jpjm1
560                  DO ji = fs_2, fs_jpim1
561                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
562                     ! total advective trends
563                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
564                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
565                  END DO
566               END DO
567            END DO
568
569         END DO
570
571         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
572            DO jj = 2, jpjm1
573               DO ji = fs_2, fs_jpim1
574                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
575               END DO
576            END DO
577         END DO
578         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
579         CALL lbc_lnk( zwz, 'W',  1. )
580
581         ! 4. monotonicity algorithm
582         ! -------------------------
583         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
584
585
586         ! 5. final trend with corrected fluxes
587         ! ------------------------------------
588         DO jk = 1, jpkm1
589            DO jj = 2, jpjm1
590               DO ji = fs_2, fs_jpim1   ! vector opt. 
591                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
592                  ! total advective trends
593                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
594                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
595                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
596                  ! add them to the general tracer trends
597                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
598               END DO
599            END DO
600         END DO
601
602         !                                 ! trend diagnostics (contribution of upstream fluxes)
603         IF( l_trd )  THEN
604            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
605            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
606            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
607           
608            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
609            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
610            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
611         END IF
612         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
613         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
614            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:) 
615            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
616         ENDIF
617         !
618      END DO
619      !
620      DEALLOCATE(zwi) 
621      DEALLOCATE(zwz) 
622      DEALLOCATE(zhdiv) 
623      DEALLOCATE(zwz_sav) 
624      DEALLOCATE(zwzts)
625      DEALLOCATE(ztrs )
626      DEALLOCATE(zwx_sav) 
627      DEALLOCATE(zwy_sav )
628
629      IF( l_trd )  THEN
630          DEALLOCATE(ztrdx) 
631          DEALLOCATE(ztrdy) 
632          DEALLOCATE(ztrdz)
633      END IF
634
635      IF( cdtype == 'TRA' .AND. ln_diaptr ) DEALLOCATE(zptry )
636      !
637      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
638      !
639   END SUBROUTINE tra_adv_tvd_zts
640
641
642   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
643      !!---------------------------------------------------------------------
644      !!                    ***  ROUTINE nonosc  ***
645      !!     
646      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
647      !!       scheme and the before field by a nonoscillatory algorithm
648      !!
649      !! **  Method  :   ... ???
650      !!       warning : pbef and paft must be masked, but the boundaries
651      !!       conditions on the fluxes are not necessary zalezak (1979)
652      !!       drange (1995) multi-dimensional forward-in-time and upstream-
653      !!       in-space based differencing for fluid
654      !!----------------------------------------------------------------------
655      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
656      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
657      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
658      !
659      INTEGER  ::   ji, jj, jk   ! dummy loop indices
660      INTEGER  ::   ikm1         ! local integer
661      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
662      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
663      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
664      !!----------------------------------------------------------------------
665      !
666      IF( nn_timing == 1 )  CALL timing_start('nonosc')
667      !
668      ALLOCATE(zbetup(1:jpi, 1:jpj, 1:jpk))
669      ALLOCATE(zbetdo(1:jpi, 1:jpj, 1:jpk))
670      ALLOCATE(zbup(1:jpi, 1:jpj, 1:jpk))
671      ALLOCATE(zbdo(1:jpi, 1:jpj, 1:jpk))
672      !
673      zbig  = 1.e+40_wp
674      zrtrn = 1.e-15_wp
675      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
676
677      ! Search local extrema
678      ! --------------------
679      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
680      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
681         &        paft * tmask - zbig * ( 1._wp - tmask )  )
682      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
683         &        paft * tmask + zbig * ( 1._wp - tmask )  )
684
685      DO jk = 1, jpkm1
686         ikm1 = MAX(jk-1,1)
687         z2dtt = p2dt(jk)
688         DO jj = 2, jpjm1
689            DO ji = fs_2, fs_jpim1   ! vector opt.
690
691               ! search maximum in neighbourhood
692               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
693                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
694                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
695                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
696
697               ! search minimum in neighbourhood
698               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
699                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
700                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
701                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
702
703               ! positive part of the flux
704               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
705                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
706                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
707
708               ! negative part of the flux
709               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
710                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
711                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
712
713               ! up & down beta terms
714               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
715               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
716               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
717            END DO
718         END DO
719      END DO
720      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
721
722      ! 3. monotonic flux in the i & j direction (paa & pbb)
723      ! ----------------------------------------
724      DO jk = 1, jpkm1
725         DO jj = 2, jpjm1
726            DO ji = fs_2, fs_jpim1   ! vector opt.
727               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
728               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
729               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
730               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
731
732               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
733               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
734               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
735               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
736
737      ! monotonic flux in the k direction, i.e. pcc
738      ! -------------------------------------------
739               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
740               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
741               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
742               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
743            END DO
744         END DO
745      END DO
746      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
747      !
748      DEALLOCATE(zbetup)
749      DEALLOCATE(zbetdo) 
750      DEALLOCATE(zbup)
751      DEALLOCATE(zbdo)
752      !
753      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
754      !
755   END SUBROUTINE nonosc
756
757   !!======================================================================
758END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.