New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
cpl_oasis3.F90 in branches/UKMO/dev_r5518_GO6_oasis3mct_vn4/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_r5518_GO6_oasis3mct_vn4/NEMOGCM/NEMO/OPA_SRC/SBC/cpl_oasis3.F90 @ 10018

Last change on this file since 10018 was 10018, checked in by frrh, 6 years ago

Corrections for consistency with OASIS3-MCT version 4.0
and backwards compatibility with earlier coupler releases.
File size: 26.4 KB
Line 
1MODULE cpl_oasis3
2   !!======================================================================
3   !!                    ***  MODULE cpl_oasis  ***
4   !! Coupled O/A : coupled ocean-atmosphere case using OASIS3-MCT
5   !!=====================================================================
6   !! History :   
7   !!   9.0  !  04-06  (R. Redler, NEC Laboratories Europe, Germany) Original code
8   !!   " "  !  04-11  (R. Redler, NEC Laboratories Europe; N. Keenlyside, W. Park, IFM-GEOMAR, Germany) revision
9   !!   " "  !  04-11  (V. Gayler, MPI M&D) Grid writing
10   !!   " "  !  05-08  (R. Redler, W. Park) frld initialization, paral(2) revision
11   !!   " "  !  05-09  (R. Redler) extended to allow for communication over root only
12   !!   " "  !  06-01  (W. Park) modification of physical part
13   !!   " "  !  06-02  (R. Redler, W. Park) buffer array fix for root exchange
14   !!   3.4  !  11-11  (C. Harris) Changes to allow mutiple category fields
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   'key_oasis3'                    coupled Ocean/Atmosphere via OASIS3-MCT
18   !!   'key_oa3mct_v3'                 to be added for OASIS3-MCT version 3
19   !!----------------------------------------------------------------------
20   !!   cpl_init     : initialization of coupled mode communication
21   !!   cpl_define   : definition of grid and fields
22   !!   cpl_snd     : snd out fields in coupled mode
23   !!   cpl_rcv     : receive fields in coupled mode
24   !!   cpl_finalize : finalize the coupled mode communication
25   !!----------------------------------------------------------------------
26#if defined key_oasis3
27   USE mod_oasis                    ! OASIS3-MCT module
28#endif
29   USE par_oce                      ! ocean parameters
30   USE dom_oce                      ! ocean space and time domain
31   USE in_out_manager               ! I/O manager
32   USE lbclnk                       ! ocean lateral boundary conditions (or mpp link)
33   
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   cpl_init
38   PUBLIC   cpl_define
39   PUBLIC   cpl_snd
40   PUBLIC   cpl_rcv
41   PUBLIC   cpl_freq
42   PUBLIC   cpl_finalize
43#if defined key_mpp_mpi
44   INCLUDE 'mpif.h'
45#endif
46   
47   INTEGER, PARAMETER         :: localRoot  = 0
48   LOGICAL                    :: commRank            ! true for ranks doing OASIS communication
49#if defined key_cpl_rootexchg
50   LOGICAL                    :: rootexchg =.true.   ! logical switch
51#else
52   LOGICAL                    :: rootexchg =.false.  ! logical switch
53#endif
54
55   INTEGER, PUBLIC            ::   OASIS_Rcv  = 1    !: return code if received field
56   INTEGER, PUBLIC            ::   OASIS_idle = 0    !: return code if nothing done by oasis
57   INTEGER                    ::   ncomp_id          ! id returned by oasis_init_comp
58   INTEGER                    ::   nerror            ! return error code
59#if ! defined key_oasis3
60   ! OASIS Variables not used. defined only for compilation purpose
61   INTEGER                    ::   OASIS_Out         = -1
62   INTEGER                    ::   OASIS_REAL        = -1
63   INTEGER                    ::   OASIS_Ok          = -1
64   INTEGER                    ::   OASIS_In          = -1
65   INTEGER                    ::   OASIS_Sent        = -1
66   INTEGER                    ::   OASIS_SentOut     = -1
67   INTEGER                    ::   OASIS_ToRest      = -1
68   INTEGER                    ::   OASIS_ToRestOut   = -1
69   INTEGER                    ::   OASIS_Recvd       = -1
70   INTEGER                    ::   OASIS_RecvOut     = -1
71   INTEGER                    ::   OASIS_FromRest    = -1
72   INTEGER                    ::   OASIS_FromRestOut = -1
73#endif
74
75   INTEGER                    ::   nrcv         ! total number of fields received
76   INTEGER                    ::   nsnd         ! total number of fields sent
77   INTEGER                    ::   ncplmodel    ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
78   INTEGER, PUBLIC, PARAMETER ::   nmaxfld=50   ! Maximum number of coupling fields
79   INTEGER, PUBLIC, PARAMETER ::   nmaxcat=5    ! Maximum number of coupling fields
80   INTEGER, PUBLIC, PARAMETER ::   nmaxcpl=5    ! Maximum number of coupling fields
81   
82   TYPE, PUBLIC ::   FLD_CPL               !: Type for coupling field information
83      LOGICAL               ::   laction   ! To be coupled or not
84      CHARACTER(len = 8)    ::   clname    ! Name of the coupling field   
85      CHARACTER(len = 1)    ::   clgrid    ! Grid type 
86      REAL(wp)              ::   nsgn      ! Control of the sign change
87      INTEGER, DIMENSION(nmaxcat,nmaxcpl) ::   nid   ! Id of the field (no more than 9 categories and 9 extrena models)
88      INTEGER               ::   nct       ! Number of categories in field
89      INTEGER               ::   ncplmodel ! Maximum number of models to/from which this variable may be sent/received
90   END TYPE FLD_CPL
91
92   TYPE(FLD_CPL), DIMENSION(nmaxfld), PUBLIC ::   srcv, ssnd   !: Coupling fields
93
94   REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   exfld   ! Temporary buffer for receiving
95   INTEGER, PUBLIC :: localComm 
96     
97   !!----------------------------------------------------------------------
98   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
99   !! $Id$
100   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
101   !!----------------------------------------------------------------------
102CONTAINS
103
104   SUBROUTINE cpl_init( cd_modname, kl_comm )
105      !!-------------------------------------------------------------------
106      !!             ***  ROUTINE cpl_init  ***
107      !!
108      !! ** Purpose :   Initialize coupled mode communication for ocean
109      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
110      !!
111      !! ** Method  :   OASIS3 MPI communication
112      !!--------------------------------------------------------------------
113      CHARACTER(len = *), INTENT(in) ::   cd_modname   ! model name as set in namcouple file
114      INTEGER          , INTENT(out) ::   kl_comm      ! local communicator of the model
115      !!--------------------------------------------------------------------
116
117      ! WARNING: No write in numout in this routine
118      !============================================
119
120      !------------------------------------------------------------------
121      ! 1st Initialize the OASIS system for the application
122      !------------------------------------------------------------------
123      CALL oasis_init_comp ( ncomp_id, TRIM(cd_modname), nerror )
124      IF ( nerror /= OASIS_Ok ) &
125         CALL oasis_abort (ncomp_id, 'cpl_init', 'Failure in oasis_init_comp')
126
127      !------------------------------------------------------------------
128      ! 3rd Get an MPI communicator for OPA local communication
129      !------------------------------------------------------------------
130
131      CALL oasis_get_localcomm ( kl_comm, nerror )
132      IF ( nerror /= OASIS_Ok ) &
133         CALL oasis_abort (ncomp_id, 'cpl_init','Failure in oasis_get_localcomm' )
134      localComm = kl_comm 
135      !
136   END SUBROUTINE cpl_init
137
138
139   SUBROUTINE cpl_define( krcv, ksnd, kcplmodel )
140      !!-------------------------------------------------------------------
141      !!             ***  ROUTINE cpl_define  ***
142      !!
143      !! ** Purpose :   Define grid and field information for ocean
144      !!    exchange between AGCM, OGCM and COUPLER. (OASIS3 software)
145      !!
146      !! ** Method  :   OASIS3 MPI communication
147      !!--------------------------------------------------------------------
148      INTEGER, INTENT(in) ::   krcv, ksnd     ! Number of received and sent coupling fields
149      INTEGER, INTENT(in) ::   kcplmodel      ! Maximum number of models to/from which NEMO is potentialy sending/receiving data
150      !
151      INTEGER :: id_part
152      INTEGER :: paral(5)       ! OASIS3 box partition
153      INTEGER :: ishape(4)    ! shape of arrays passed to PSMILe
154      INTEGER :: var_nodims(2)  ! Number of coupling field dimensions.
155                                ! var_nodims(1) is redundant with OASIS3-MCT vn4.0 but retained
156                                ! for backwards compatibility. var_nodims(2) is the number of
157                                ! fields in a bundle or 1 for unbundled fields.
158      INTEGER :: ji,jc,jm       ! local loop indicees
159      CHARACTER(LEN=64) :: zclname
160      CHARACTER(LEN=2) :: cli2
161      !!--------------------------------------------------------------------
162
163      IF(lwp) WRITE(numout,*)
164      IF(lwp) WRITE(numout,*) 'cpl_define : initialization in coupled ocean/atmosphere case'
165      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~~~'
166      IF(lwp) WRITE(numout,*)
167
168      ncplmodel = kcplmodel
169      IF( kcplmodel > nmaxcpl ) THEN
170         CALL oasis_abort ( ncomp_id, 'cpl_define', 'ncplmodel is larger than nmaxcpl, increase nmaxcpl')   ;   RETURN
171      ENDIF
172
173      nrcv = krcv
174      IF( nrcv > nmaxfld ) THEN
175         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nrcv is larger than nmaxfld, increase nmaxfld')   ;   RETURN
176      ENDIF
177
178      nsnd = ksnd
179      IF( nsnd > nmaxfld ) THEN
180         CALL oasis_abort ( ncomp_id, 'cpl_define', 'nsnd is larger than nmaxfld, increase nmaxfld')   ;   RETURN
181      ENDIF
182
183      !
184      ! ... Define the shape for the area that excludes the halo
185      !     For serial configuration (key_mpp_mpi not being active)
186      !     nl* is set to the global values 1 and jp*glo.
187      !
188      ishape(1) = 1
189      ishape(2) = nlei-nldi+1
190      ishape(3) = 1
191      ishape(4) = nlej-nldj+1
192
193
194      !
195      ! ... Allocate memory for data exchange
196      !
197      ALLOCATE(exfld(nlei-nldi+1, nlej-nldj+1), stat = nerror)
198      IF( nerror > 0 ) THEN
199         CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in allocating exfld')   ;   RETURN
200      ENDIF     
201      !
202      ! -----------------------------------------------------------------
203      ! ... Define the partition
204      ! -----------------------------------------------------------------
205           
206      paral(1) = 2                                              ! box partitioning
207      paral(2) = jpiglo * (nldj-1+njmpp-1) + (nldi-1+nimpp-1)   ! NEMO lower left corner global offset   
208      paral(3) = nlei-nldi+1                                    ! local extent in i
209      paral(4) = nlej-nldj+1                                    ! local extent in j
210      paral(5) = jpiglo                                         ! global extent in x
211     
212      IF( ln_ctl ) THEN
213         WRITE(numout,*) ' multiexchg: paral (1:5)', paral
214         WRITE(numout,*) ' multiexchg: jpi, jpj =', jpi, jpj
215         WRITE(numout,*) ' multiexchg: nldi, nlei, nimpp =', nldi, nlei, nimpp
216         WRITE(numout,*) ' multiexchg: nldj, nlej, njmpp =', nldj, nlej, njmpp
217      ENDIF
218     
219      CALL oasis_def_partition ( id_part, paral, nerror, jpiglo*jpjglo)
220      !
221      ! ... Announce send variables.
222      !
223      ssnd(:)%ncplmodel = kcplmodel
224      !
225      DO ji = 1, ksnd
226         IF ( ssnd(ji)%laction ) THEN
227
228            IF( ssnd(ji)%nct > nmaxcat ) THEN
229               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
230                  &              TRIM(ssnd(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
231               RETURN
232            ENDIF
233           
234            DO jc = 1, ssnd(ji)%nct
235               DO jm = 1, kcplmodel
236
237                  IF ( ssnd(ji)%nct .GT. 1 ) THEN
238                     WRITE(cli2,'(i2.2)') jc
239                     zclname = TRIM(ssnd(ji)%clname)//'_cat'//cli2
240                  ELSE
241                     zclname = ssnd(ji)%clname
242                  ENDIF
243                  IF ( kcplmodel  > 1 ) THEN
244                     WRITE(cli2,'(i2.2)') jm
245                     zclname = 'model'//cli2//'_'//TRIM(zclname)
246                  ENDIF
247#if defined key_agrif
248                  IF( agrif_fixed() /= 0 ) THEN
249                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
250                  END IF
251#endif
252                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_Out
253
254                  !
255                  ! ... Set the field dimension and bundle count
256                  var_nodims(1) = 2
257                  var_nodims(2) = 1 ! Make this variable to cater for bundled fields.   
258
259                  CALL oasis_def_var (ssnd(ji)%nid(jc,jm), zclname, id_part   , var_nodims,   &
260                     &                OASIS_Out          , ishape , OASIS_REAL, nerror )
261                  IF ( nerror /= OASIS_Ok ) THEN
262                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
263                     CALL oasis_abort ( ssnd(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
264                  ENDIF
265                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
266                  IF( ln_ctl .AND. ssnd(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
267               END DO
268            END DO
269         ENDIF
270      END DO     
271      !
272      ! ... Announce received variables.
273      !
274      srcv(:)%ncplmodel = kcplmodel
275      !
276      DO ji = 1, krcv
277         IF ( srcv(ji)%laction ) THEN
278           
279            IF( srcv(ji)%nct > nmaxcat ) THEN
280               CALL oasis_abort ( ncomp_id, 'cpl_define', 'Number of categories of '//   &
281                  &              TRIM(srcv(ji)%clname)//' is larger than nmaxcat, increase nmaxcat' )
282               RETURN
283            ENDIF
284           
285            DO jc = 1, srcv(ji)%nct
286               DO jm = 1, kcplmodel
287                 
288                  IF ( srcv(ji)%nct .GT. 1 ) THEN
289                     WRITE(cli2,'(i2.2)') jc
290                     zclname = TRIM(srcv(ji)%clname)//'_cat'//cli2
291                  ELSE
292                     zclname = srcv(ji)%clname
293                  ENDIF
294                  IF ( kcplmodel  > 1 ) THEN
295                     WRITE(cli2,'(i2.2)') jm
296                     zclname = 'model'//cli2//'_'//TRIM(zclname)
297                  ENDIF
298#if defined key_agrif
299                  IF( agrif_fixed() /= 0 ) THEN
300                     zclname=TRIM(Agrif_CFixed())//'_'//TRIM(zclname)
301                  END IF
302#endif
303                  IF( ln_ctl ) WRITE(numout,*) "Define", ji, jc, jm, " "//TRIM(zclname), " for ", OASIS_In
304
305                  ! ... Set the field dimension and bundle count
306                  var_nodims(1) = 2
307                  var_nodims(2) = 1 ! Make this variable to cater for bundled fields.   
308
309                  CALL oasis_def_var (srcv(ji)%nid(jc,jm), zclname, id_part   , var_nodims,   &
310                     &                OASIS_In           , ishape , OASIS_REAL, nerror )
311                  IF ( nerror /= OASIS_Ok ) THEN
312                     WRITE(numout,*) 'Failed to define transient ', ji, jc, jm, " "//TRIM(zclname)
313                     CALL oasis_abort ( srcv(ji)%nid(jc,jm), 'cpl_define', 'Failure in oasis_def_var' )
314                  ENDIF
315                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) /= -1 ) WRITE(numout,*) "variable defined in the namcouple"
316                  IF( ln_ctl .AND. srcv(ji)%nid(jc,jm) == -1 ) WRITE(numout,*) "variable NOT defined in the namcouple"
317
318               END DO
319            END DO
320         ENDIF
321      END DO
322     
323      !------------------------------------------------------------------
324      ! End of definition phase
325      !------------------------------------------------------------------
326     
327      CALL oasis_enddef(nerror)
328      IF( nerror /= OASIS_Ok )   CALL oasis_abort ( ncomp_id, 'cpl_define', 'Failure in oasis_enddef')
329      !
330   END SUBROUTINE cpl_define
331   
332   
333   SUBROUTINE cpl_snd( kid, kstep, pdata, kinfo )
334      !!---------------------------------------------------------------------
335      !!              ***  ROUTINE cpl_snd  ***
336      !!
337      !! ** Purpose : - At each coupling time-step,this routine sends fields
338      !!      like sst or ice cover to the coupler or remote application.
339      !!----------------------------------------------------------------------
340      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
341      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
342      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
343      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pdata
344      !!
345      INTEGER                                   ::   jc,jm     ! local loop index
346      !!--------------------------------------------------------------------
347      !
348      ! snd data to OASIS3
349      !
350      DO jc = 1, ssnd(kid)%nct
351         DO jm = 1, ssnd(kid)%ncplmodel
352       
353            IF( ssnd(kid)%nid(jc,jm) /= -1 ) THEN
354               CALL oasis_put ( ssnd(kid)%nid(jc,jm), kstep, pdata(nldi:nlei, nldj:nlej,jc), kinfo )
355               
356               IF ( ln_ctl ) THEN       
357                  IF ( kinfo == OASIS_Sent     .OR. kinfo == OASIS_ToRest .OR.   &
358                     & kinfo == OASIS_SentOut  .OR. kinfo == OASIS_ToRestOut ) THEN
359                     WRITE(numout,*) '****************'
360                     WRITE(numout,*) 'oasis_put: Outgoing ', ssnd(kid)%clname
361                     WRITE(numout,*) 'oasis_put: ivarid ', ssnd(kid)%nid(jc,jm)
362                     WRITE(numout,*) 'oasis_put:  kstep ', kstep
363                     WRITE(numout,*) 'oasis_put:   info ', kinfo
364                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
365                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
366                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
367                     WRITE(numout,*) '****************'
368                  ENDIF
369               ENDIF
370               
371            ENDIF
372           
373         ENDDO
374      ENDDO
375      !
376    END SUBROUTINE cpl_snd
377
378
379   SUBROUTINE cpl_rcv( kid, kstep, pdata, pmask, kinfo )
380      !!---------------------------------------------------------------------
381      !!              ***  ROUTINE cpl_rcv  ***
382      !!
383      !! ** Purpose : - At each coupling time-step,this routine receives fields
384      !!      like stresses and fluxes from the coupler or remote application.
385      !!----------------------------------------------------------------------
386      INTEGER                   , INTENT(in   ) ::   kid       ! variable index in the array
387      INTEGER                   , INTENT(in   ) ::   kstep     ! ocean time-step in seconds
388      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdata     ! IN to keep the value if nothing is done
389      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   pmask     ! coupling mask
390      INTEGER                   , INTENT(  out) ::   kinfo     ! OASIS3 info argument
391      !!
392      INTEGER                                   ::   jc,jm     ! local loop index
393      LOGICAL                                   ::   llaction, llfisrt
394      !!--------------------------------------------------------------------
395      !
396      ! receive local data from OASIS3 on every process
397      !
398      kinfo = OASIS_idle
399      !
400      DO jc = 1, srcv(kid)%nct
401         llfisrt = .TRUE.
402
403         DO jm = 1, srcv(kid)%ncplmodel
404
405            IF( srcv(kid)%nid(jc,jm) /= -1 ) THEN
406
407               CALL oasis_get ( srcv(kid)%nid(jc,jm), kstep, exfld, kinfo )   
408               
409               llaction =  kinfo == OASIS_Recvd   .OR. kinfo == OASIS_FromRest .OR.   &
410                  &        kinfo == OASIS_RecvOut .OR. kinfo == OASIS_FromRestOut
411               
412               IF ( ln_ctl )   WRITE(numout,*) "llaction, kinfo, kstep, ivarid: " , llaction, kinfo, kstep, srcv(kid)%nid(jc,jm)
413               
414               IF ( llaction ) THEN
415                 
416                  kinfo = OASIS_Rcv
417                  IF( llfisrt ) THEN
418                     pdata(nldi:nlei,nldj:nlej,jc) =                                 exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm) 
419                     llfisrt = .FALSE.
420                  ELSE
421                     pdata(nldi:nlei,nldj:nlej,jc) = pdata(nldi:nlei,nldj:nlej,jc) + exfld(:,:) * pmask(nldi:nlei,nldj:nlej,jm)
422                  ENDIF
423                 
424                  IF ( ln_ctl ) THEN       
425                     WRITE(numout,*) '****************'
426                     WRITE(numout,*) 'oasis_get: Incoming ', srcv(kid)%clname
427                     WRITE(numout,*) 'oasis_get: ivarid '  , srcv(kid)%nid(jc,jm)
428                     WRITE(numout,*) 'oasis_get:   kstep', kstep
429                     WRITE(numout,*) 'oasis_get:   info ', kinfo
430                     WRITE(numout,*) '     - Minimum value is ', MINVAL(pdata(:,:,jc))
431                     WRITE(numout,*) '     - Maximum value is ', MAXVAL(pdata(:,:,jc))
432                     WRITE(numout,*) '     -     Sum value is ', SUM(pdata(:,:,jc))
433                     WRITE(numout,*) '****************'
434                  ENDIF
435                 
436               ENDIF
437               
438            ENDIF
439           
440         ENDDO
441
442         !--- Fill the overlap areas and extra hallows (mpp)
443         !--- check periodicity conditions (all cases)
444         IF( .not. llfisrt )   CALL lbc_lnk( pdata(:,:,jc), srcv(kid)%clgrid, srcv(kid)%nsgn )   
445 
446      ENDDO
447      !
448   END SUBROUTINE cpl_rcv
449
450
451   INTEGER FUNCTION cpl_freq( cdfieldname ) 
452      !!---------------------------------------------------------------------
453      !!              ***  ROUTINE cpl_freq  ***
454      !!
455      !! ** Purpose : - send back the coupling frequency for a particular field
456      !!----------------------------------------------------------------------
457      CHARACTER(len = *), INTENT(in) ::   cdfieldname    ! field name as set in namcouple file
458      !!
459      INTEGER               :: id
460      INTEGER               :: info
461      INTEGER, DIMENSION(1) :: itmp
462      INTEGER               :: ji,jm     ! local loop index
463      INTEGER               :: mop
464      !!----------------------------------------------------------------------
465      cpl_freq = 0   ! defaut definition
466      id = -1        ! defaut definition
467      !
468      DO ji = 1, nsnd
469         IF (ssnd(ji)%laction ) THEN
470            DO jm = 1, ncplmodel
471               IF( ssnd(ji)%nid(1,jm) /= -1 ) THEN
472                  IF( TRIM(cdfieldname) == TRIM(ssnd(ji)%clname) ) THEN
473                     id = ssnd(ji)%nid(1,jm)
474                     mop = OASIS_Out
475                  ENDIF
476               ENDIF
477            ENDDO
478         ENDIF
479      ENDDO
480      DO ji = 1, nrcv
481         IF (srcv(ji)%laction ) THEN
482            DO jm = 1, ncplmodel
483               IF( srcv(ji)%nid(1,jm) /= -1 ) THEN
484                  IF( TRIM(cdfieldname) == TRIM(srcv(ji)%clname) ) THEN
485                     id = srcv(ji)%nid(1,jm)
486                     mop = OASIS_In
487                  ENDIF
488               ENDIF
489            ENDDO
490         ENDIF
491      ENDDO
492      !
493      IF( id /= -1 ) THEN
494#if defined key_oa3mct_v3
495         CALL oasis_get_freqs(id, mop, 1, itmp, info)
496#else
497#if defined key_oasis3 
498         itmp(1) = namflddti( id )
499#else
500         CALL oasis_get_freqs(id,      1, itmp, info)
501#endif
502#endif
503         cpl_freq = itmp(1)
504      ENDIF
505      !
506   END FUNCTION cpl_freq
507
508
509   SUBROUTINE cpl_finalize
510      !!---------------------------------------------------------------------
511      !!              ***  ROUTINE cpl_finalize  ***
512      !!
513      !! ** Purpose : - Finalizes the coupling. If MPI_init has not been
514      !!      called explicitly before cpl_init it will also close
515      !!      MPI communication.
516      !!----------------------------------------------------------------------
517      !
518      DEALLOCATE( exfld )
519      IF (nstop == 0) THEN
520         CALL oasis_terminate( nerror )         
521      ELSE
522         CALL oasis_abort( ncomp_id, "cpl_finalize", "NEMO ABORT STOP" )
523      ENDIF       
524      !
525   END SUBROUTINE cpl_finalize
526
527#if ! defined key_oasis3
528
529   !!----------------------------------------------------------------------
530   !!   No OASIS Library          OASIS3 Dummy module...
531   !!----------------------------------------------------------------------
532
533   SUBROUTINE oasis_init_comp(k1,cd1,k2)
534      CHARACTER(*), INTENT(in   ) ::  cd1
535      INTEGER     , INTENT(  out) ::  k1,k2
536      k1 = -1 ; k2 = -1
537      WRITE(numout,*) 'oasis_init_comp: Error you sould not be there...', cd1
538   END SUBROUTINE oasis_init_comp
539
540   SUBROUTINE oasis_abort(k1,cd1,cd2)
541      INTEGER     , INTENT(in   ) ::  k1
542      CHARACTER(*), INTENT(in   ) ::  cd1,cd2
543      WRITE(numout,*) 'oasis_abort: Error you sould not be there...', cd1, cd2
544   END SUBROUTINE oasis_abort
545
546   SUBROUTINE oasis_get_localcomm(k1,k2)
547      INTEGER     , INTENT(  out) ::  k1,k2
548      k1 = -1 ; k2 = -1
549      WRITE(numout,*) 'oasis_get_localcomm: Error you sould not be there...'
550   END SUBROUTINE oasis_get_localcomm
551
552   SUBROUTINE oasis_def_partition(k1,k2,k3,K4)
553      INTEGER     , INTENT(  out) ::  k1,k3
554      INTEGER     , INTENT(in   ) ::  k2(5)
555      INTEGER     , OPTIONAL, INTENT(in   ) ::  k4
556      k1 = k2(1) ; k3 = k2(5)
557      WRITE(numout,*) 'oasis_def_partition: Error you sould not be there...'
558   END SUBROUTINE oasis_def_partition
559
560   SUBROUTINE oasis_def_var(k1,cd1,k2,k3,k4,k5,k6,k7)
561      CHARACTER(*), INTENT(in   ) ::  cd1
562      INTEGER     , INTENT(in   ) ::  k2,k3(2),k4,k5(2,2),k6
563      INTEGER     , INTENT(  out) ::  k1,k7
564      k1 = -1 ; k7 = -1
565      WRITE(numout,*) 'oasis_def_var: Error you sould not be there...', cd1
566   END SUBROUTINE oasis_def_var
567
568   SUBROUTINE oasis_enddef(k1)
569      INTEGER     , INTENT(  out) ::  k1
570      k1 = -1
571      WRITE(numout,*) 'oasis_enddef: Error you sould not be there...'
572   END SUBROUTINE oasis_enddef
573 
574   SUBROUTINE oasis_put(k1,k2,p1,k3)
575      REAL(wp), DIMENSION(:,:), INTENT(in   ) ::  p1
576      INTEGER                 , INTENT(in   ) ::  k1,k2
577      INTEGER                 , INTENT(  out) ::  k3
578      k3 = -1
579      WRITE(numout,*) 'oasis_put: Error you sould not be there...'
580   END SUBROUTINE oasis_put
581
582   SUBROUTINE oasis_get(k1,k2,p1,k3)
583      REAL(wp), DIMENSION(:,:), INTENT(  out) ::  p1
584      INTEGER                 , INTENT(in   ) ::  k1,k2
585      INTEGER                 , INTENT(  out) ::  k3
586      p1(1,1) = -1. ; k3 = -1
587      WRITE(numout,*) 'oasis_get: Error you sould not be there...'
588   END SUBROUTINE oasis_get
589
590   SUBROUTINE oasis_get_freqs(k1,k2,k3,k4)
591      INTEGER              , INTENT(in   ) ::  k1,k2
592      INTEGER, DIMENSION(1), INTENT(  out) ::  k3
593      INTEGER              , INTENT(  out) ::  k4
594      k3(1) = k1 ; k4 = k2
595      WRITE(numout,*) 'oasis_get_freqs: Error you sould not be there...'
596   END SUBROUTINE oasis_get_freqs
597
598   SUBROUTINE oasis_terminate(k1)
599      INTEGER     , INTENT(  out) ::  k1
600      k1 = -1
601      WRITE(numout,*) 'oasis_terminate: Error you sould not be there...'
602   END SUBROUTINE oasis_terminate
603   
604#endif
605
606   !!=====================================================================
607END MODULE cpl_oasis3
Note: See TracBrowser for help on using the repository browser.