Context Navigation

restart.F90 @ 6491

Last change on this file since 6491 was 6491, checked in by davestorkey, 8 years ago

Commit remaining changes to UKMO/r5518_GO6_package branch from following branches:
UKMO/dev_r5021_nn_etau_revision@6238
UKMO/dev_r5107_mld_zint@5534
UKMO/dev_r5107_eorca025_closea@6390
UKMO/restart_datestamp@5539
UKMO/icebergs_latent_heat@5821
UKMO/icebergs_restart_single_file_corrected@6480
UKMO/product_diagnostics@5971
UKMO/antarctic_partial_slip@5961
Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r5961 cf. r5958 of /branches/UKMO/antarctic_partial_slip/NEMOGCM@6490

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6349 cf. r5962 of /branches/UKMO/product_diagnostics/NEMOGCM@6490

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6480 cf. r6479 of /branches/UKMO/icebergs_restart_single_file_corrected/NEMOGCM@6490

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r5986 cf. r5852 of /branches/UKMO/icebergs_restart_single_file/NEMOGCM@6490

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r5821 cf. r5808 of /branches/UKMO/icebergs_latent_heat/NEMOGCM@6490

File size: 16.3 KB

Line
1	MODULE restart
2	!!======================================================================
3	!! * MODULE restart *
4	!! Ocean restart : write the ocean restart file
5	!!======================================================================
6	!! History : OPA ! 1999-11 (M. Imbard) Original code
7	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form
8	!! 2.0 ! 2006-07 (S. Masson) use IOM for restart
9	!! 3.3 ! 2010-04 (M. Leclair, G. Madec) modified LF-RA
10	!! - - ! 2010-10 (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! rst_opn : open the ocean restart file
15	!! rst_write : write the ocean restart file
16	!! rst_read : read the ocean restart file
17	!!----------------------------------------------------------------------
18	USE oce ! ocean dynamics and tracers
19	USE dom_oce ! ocean space and time domain
20	USE phycst ! physical constants
21	USE in_out_manager ! I/O manager
22	USE iom ! I/O module
23	USE ioipsl, ONLY : ju2ymds ! for calendar
24	USE eosbn2 ! equation of state (eos bn2 routine)
25	USE trdmxl_oce ! ocean active mixed layer tracers trends variables
26	USE divcur ! hor. divergence and curl (div & cur routines)
27	USE sbc_oce ! for icesheet freshwater input variables
28
29	IMPLICIT NONE
30	PRIVATE
31
32	PUBLIC rst_opn ! routine called by step module
33	PUBLIC rst_write ! routine called by step module
34	PUBLIC rst_read ! routine called by istate module
35	PUBLIC rst_read_open ! routine called in rst_read and (possibly) in dom_vvl_init
36
37	!! * Substitutions
38	# include "domzgr_substitute.h90"
39	# include "vectopt_loop_substitute.h90"
40	!!----------------------------------------------------------------------
41	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
42	!! $Id$
43	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
44	!!----------------------------------------------------------------------
45	CONTAINS
46
47	SUBROUTINE rst_opn( kt )
48	!!---------------------------------------------------------------------
49	!! * ROUTINE rst_opn *
50	!!
51	!! ** Purpose : + initialization (should be read in the namelist) of nitrst
52	!! + open the restart when we are one time step before nitrst
53	!! - restart header is defined when kt = nitrst-1
54	!! - restart data are written when kt = nitrst
55	!! + define lrst_oce to .TRUE. when we need to define or write the restart
56	!!----------------------------------------------------------------------
57	INTEGER, INTENT(in) :: kt ! ocean time-step
58	INTEGER :: iyear, imonth, iday
59	REAL (wp) :: zsec
60	!!
61	CHARACTER(LEN=20) :: clkt ! ocean time-step deine as a character
62	CHARACTER(LEN=50) :: clname ! ocean output restart file name
63	CHARACTER(LEN=150) :: clpath ! full path to ocean output restart file
64	!!----------------------------------------------------------------------
65	!
66	IF( kt == nit000 ) THEN ! default definitions
67	lrst_oce = .FALSE.
68	IF( ln_rst_list ) THEN
69	nrst_lst = 1
70	nitrst = nstocklist( nrst_lst )
71	ELSE
72	nitrst = nitend
73	ENDIF
74	ENDIF
75
76	! frequency-based restart dumping (nn_stock)
77	IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN
78	! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
79	nitrst = kt + nstock - 1 ! define the next value of nitrst for restart writing
80	IF( nitrst > nitend ) nitrst = nitend ! make sure we write a restart at the end of the run
81	ENDIF
82	! to get better performances with NetCDF format:
83	! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
84	! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
85	IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
86	IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
87	IF ( ln_rstdate ) THEN
88	CALL ju2ymds( fjulday + rdttra(1) / rday, iyear, imonth, iday, zsec )
89	WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
90	ELSE
91	! beware of the format used to write kt (default is i8.8, that should be large enough...)
92	IF( nitrst > 999999999 ) THEN ; WRITE(clkt, * ) nitrst
93	ELSE ; WRITE(clkt, '(i8.8)') nitrst
94	ENDIF
95	ENDIF
96	! create the file
97	clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
98	clpath = TRIM(cn_ocerst_outdir)
99	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
100	IF(lwp) THEN
101	WRITE(numout,*)
102	SELECT CASE ( jprstlib )
103	CASE ( jprstdimg ) ; WRITE(numout,*) &
104	' open ocean restart binary file: ',TRIM(clpath)//clname
105	CASE DEFAULT ; WRITE(numout,*) &
106	' open ocean restart NetCDF file: ',TRIM(clpath)//clname
107	END SELECT
108	IF ( snc4set%luse ) WRITE(numout,*) ' opened for NetCDF4 chunking and compression'
109	IF( kt == nitrst - 1 ) THEN ; WRITE(numout,*) ' kt = nitrst - 1 = ', kt
110	ELSE ; WRITE(numout,*) ' kt = ' , kt
111	ENDIF
112	ENDIF
113	!
114	CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
115	lrst_oce = .TRUE.
116	ENDIF
117	ENDIF
118	!
119	END SUBROUTINE rst_opn
120
121
122	SUBROUTINE rst_write( kt )
123	!!---------------------------------------------------------------------
124	!! * ROUTINE rstwrite *
125	!!
126	!! ** Purpose : Write restart fields in the format corresponding to jprstlib
127	!!
128	!! ** Method : Write in numrow when kt == nitrst in NetCDF
129	!! file, save fields which are necessary for restart
130	!!----------------------------------------------------------------------
131	INTEGER, INTENT(in) :: kt ! ocean time-step
132	!!----------------------------------------------------------------------
133
134	CALL iom_rstput( kt, nitrst, numrow, 'rdt' , rdt ) ! dynamics time step
135	CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) ) ! surface tracer time step
136
137	CALL iom_rstput( kt, nitrst, numrow, 'ub' , ub ) ! before fields
138	CALL iom_rstput( kt, nitrst, numrow, 'vb' , vb )
139	CALL iom_rstput( kt, nitrst, numrow, 'tb' , tsb(:,:,:,jp_tem) )
140	CALL iom_rstput( kt, nitrst, numrow, 'sb' , tsb(:,:,:,jp_sal) )
141	CALL iom_rstput( kt, nitrst, numrow, 'rotb' , rotb )
142	CALL iom_rstput( kt, nitrst, numrow, 'hdivb' , hdivb )
143	CALL iom_rstput( kt, nitrst, numrow, 'sshb' , sshb )
144	!
145	CALL iom_rstput( kt, nitrst, numrow, 'un' , un ) ! now fields
146	CALL iom_rstput( kt, nitrst, numrow, 'vn' , vn )
147	CALL iom_rstput( kt, nitrst, numrow, 'tn' , tsn(:,:,:,jp_tem) )
148	CALL iom_rstput( kt, nitrst, numrow, 'sn' , tsn(:,:,:,jp_sal) )
149	CALL iom_rstput( kt, nitrst, numrow, 'rotn' , rotn )
150	CALL iom_rstput( kt, nitrst, numrow, 'hdivn' , hdivn )
151	CALL iom_rstput( kt, nitrst, numrow, 'sshn' , sshn )
152	CALL iom_rstput( kt, nitrst, numrow, 'rhop' , rhop )
153	#if defined key_zdfkpp
154	CALL iom_rstput( kt, nitrst, numrow, 'rhd' , rhd )
155	#endif
156	IF( lk_oasis) THEN
157	! ln_coupled_iceshelf_fluxes uninitialised unless lk_oasis=true
158	IF( ln_coupled_iceshelf_fluxes ) THEN
159	CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass', greenland_icesheet_mass )
160	CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
161	CALL iom_rstput( kt, nitrst, numrow, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
162	CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
163	CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
164	CALL iom_rstput( kt, nitrst, numrow, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
165	ENDIF
166	ENDIF
167
168	IF( kt == nitrst ) THEN
169	CALL iom_close( numrow ) ! close the restart file (only at last time step)
170	!!gm IF( .NOT. lk_trdmld ) lrst_oce = .FALSE.
171	!!gm not sure what to do here ===>>> ask to Sebastian
172	lrst_oce = .FALSE.
173	IF( ln_rst_list ) THEN
174	nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
175	nitrst = nstocklist( nrst_lst )
176	ENDIF
177	lrst_oce = .FALSE.
178	ENDIF
179	!
180	END SUBROUTINE rst_write
181
182
183	SUBROUTINE rst_read_open
184	!!----------------------------------------------------------------------
185	!! * ROUTINE rst_read_open *
186	!!
187	!! ** Purpose : Open read files for restart (format fixed by jprstlib )
188	!!
189	!! ** Method : Use a non-zero, positive value of numror to assess whether or not
190	!! the file has already been opened
191	!!----------------------------------------------------------------------
192	INTEGER :: jlibalt = jprstlib
193	LOGICAL :: llok
194	CHARACTER(lc) :: clpath ! full path to ocean output restart file
195	!!----------------------------------------------------------------------
196	!
197	IF( numror <= 0 ) THEN
198	IF(lwp) THEN ! Contol prints
199	WRITE(numout,*)
200	SELECT CASE ( jprstlib )
201	CASE ( jpnf90 ) ; WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
202	CASE ( jprstdimg ) ; WRITE(numout,*) 'rst_read : read oce binary restart file'
203	END SELECT
204	IF ( snc4set%luse ) WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
205	WRITE(numout,*) '~~~~~~~~'
206	ENDIF
207
208	clpath = TRIM(cn_ocerst_indir)
209	IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
210	IF ( jprstlib == jprstdimg ) THEN
211	! eventually read netcdf file (monobloc) for restarting on different number of processors
212	! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
213	INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
214	IF ( llok ) THEN ; jlibalt = jpnf90 ; ELSE ; jlibalt = jprstlib ; ENDIF
215	ENDIF
216	CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
217	ENDIF
218	END SUBROUTINE rst_read_open
219
220	SUBROUTINE rst_read
221	!!----------------------------------------------------------------------
222	!! * ROUTINE rst_read *
223	!!
224	!! ** Purpose : Read files for restart (format fixed by jprstlib )
225	!!
226	!! ** Method : Read in restart.nc file fields which are necessary for restart
227	!!----------------------------------------------------------------------
228	REAL(wp) :: zrdt, zrdttra1
229	INTEGER :: jk
230	LOGICAL :: llok
231	!!----------------------------------------------------------------------
232
233	CALL rst_read_open ! open restart for reading (if not already opened)
234
235	! Check dynamics and tracer time-step consistency and force Euler restart if changed
236	IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 ) THEN
237	CALL iom_get( numror, 'rdt', zrdt )
238	IF( zrdt /= rdt ) neuler = 0
239	ENDIF
240	IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 ) THEN
241	CALL iom_get( numror, 'rdttra1', zrdttra1 )
242	IF( zrdttra1 /= rdttra(1) ) neuler = 0
243	ENDIF
244	!
245	IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
246	CALL iom_get( numror, jpdom_autoglo, 'ub' , ub ) ! before fields
247	CALL iom_get( numror, jpdom_autoglo, 'vb' , vb )
248	CALL iom_get( numror, jpdom_autoglo, 'tb' , tsb(:,:,:,jp_tem) )
249	CALL iom_get( numror, jpdom_autoglo, 'sb' , tsb(:,:,:,jp_sal) )
250	CALL iom_get( numror, jpdom_autoglo, 'rotb' , rotb )
251	CALL iom_get( numror, jpdom_autoglo, 'hdivb' , hdivb )
252	CALL iom_get( numror, jpdom_autoglo, 'sshb' , sshb )
253	ELSE
254	neuler = 0
255	ENDIF
256	!
257	CALL iom_get( numror, jpdom_autoglo, 'un' , un ) ! now fields
258	CALL iom_get( numror, jpdom_autoglo, 'vn' , vn )
259	CALL iom_get( numror, jpdom_autoglo, 'tn' , tsn(:,:,:,jp_tem) )
260	CALL iom_get( numror, jpdom_autoglo, 'sn' , tsn(:,:,:,jp_sal) )
261	CALL iom_get( numror, jpdom_autoglo, 'sshn' , sshn )
262	IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
263	CALL iom_get( numror, jpdom_autoglo, 'rotn' , rotn )
264	CALL iom_get( numror, jpdom_autoglo, 'hdivn' , hdivn )
265	ELSE
266	CALL div_cur( 0 ) ! Horizontal divergence & Relative vorticity
267	ENDIF
268	IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
269	CALL iom_get( numror, jpdom_autoglo, 'rhop' , rhop ) ! now potential density
270	ELSE
271	CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) )
272	ENDIF
273	#if defined key_zdfkpp
274	IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
275	CALL iom_get( numror, jpdom_autoglo, 'rhd' , rhd ) ! now in situ density anomaly
276	ELSE
277	CALL eos( tsn, rhd, fsdept_n(:,:,:) ) ! compute rhd
278	ENDIF
279	#endif
280	!
281	IF( iom_varid( numror, 'greenland_icesheet_mass', ldstop = .FALSE. ) > 0 ) THEN
282	CALL iom_get( numror, 'greenland_icesheet_mass', greenland_icesheet_mass )
283	CALL iom_get( numror, 'greenland_icesheet_timelapsed', greenland_icesheet_timelapsed )
284	CALL iom_get( numror, 'greenland_icesheet_mass_roc', greenland_icesheet_mass_rate_of_change )
285	ELSE
286	greenland_icesheet_mass = 0.0
287	greenland_icesheet_mass_rate_of_change = 0.0
288	greenland_icesheet_timelapsed = 0.0
289	ENDIF
290	IF( iom_varid( numror, 'antarctica_icesheet_mass', ldstop = .FALSE. ) > 0 ) THEN
291	CALL iom_get( numror, 'antarctica_icesheet_mass', antarctica_icesheet_mass )
292	CALL iom_get( numror, 'antarctica_icesheet_timelapsed', antarctica_icesheet_timelapsed )
293	CALL iom_get( numror, 'antarctica_icesheet_mass_roc', antarctica_icesheet_mass_rate_of_change )
294	ELSE
295	antarctica_icesheet_mass = 0.0
296	antarctica_icesheet_mass_rate_of_change = 0.0
297	antarctica_icesheet_timelapsed = 0.0
298	ENDIF
299
300	IF( neuler == 0 ) THEN ! Euler restart (neuler=0)
301	tsb (:,:,:,:) = tsn (:,:,:,:) ! all before fields set to now values
302	ub (:,:,:) = un (:,:,:)
303	vb (:,:,:) = vn (:,:,:)
304	rotb (:,:,:) = rotn (:,:,:)
305	hdivb(:,:,:) = hdivn(:,:,:)
306	sshb (:,:) = sshn (:,:)
307
308	IF( lk_vvl ) THEN
309	DO jk = 1, jpk
310	fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
311	END DO
312	ENDIF
313
314	ENDIF
315	!
316	END SUBROUTINE rst_read
317
318	!!=====================================================================
319	END MODULE restart

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 6491

Download in other formats: