source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/LDF/ldfeiv.F90 @ 6793

Last change on this file since 6793 was 6793, checked in by davestorkey, 4 years ago

Merge in changes r6482:6692 from the nemo_v3_6_STABLE branch. Only part that changes results for GO6 configurations is a bug fix for the TVD advection scheme put in at r6692.
Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6692 cf. r6688 of /branches/2015/nemo_v3_6_STABLE/NEMOGCM@6791

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6688 cf. r6482 of /branches/2015/nemo_v3_6_STABLE/NEMOGCM@6791

File size: 9.8 KB
Line 
1MODULE ldfeiv
2   !!======================================================================
3   !!                     ***  MODULE  ldfeiv  ***
4   !! Ocean physics:  variable eddy induced velocity coefficients
5   !!======================================================================
6   !! History :  OPA  ! 1999-03  (G. Madec, A. Jouzeau)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  Free form, F90
8   !!----------------------------------------------------------------------
9#if   defined key_traldf_eiv   &&   defined key_traldf_c2d
10   !!----------------------------------------------------------------------
11   !!   'key_traldf_eiv'      and                     eddy induced velocity
12   !!   'key_traldf_c2d'                    2D tracer lateral  mixing coef.
13   !!----------------------------------------------------------------------
14   !!   ldf_eiv      : compute the eddy induced velocity coefficients
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! surface boundary condition: ocean
19   USE sbcrnf          ! river runoffs
20   USE ldftra_oce      ! ocean tracer   lateral physics
21   USE phycst          ! physical constants
22   USE ldfslp          ! iso-neutral slopes
23   USE in_out_manager  ! I/O manager
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE prtctl          ! Print control
26   USE iom             ! I/O library
27   USE wrk_nemo        ! work arrays
28   USE timing          ! Timing
29
30   IMPLICIT NONE
31   PRIVATE
32   
33   PUBLIC   ldf_eiv    ! routine called by step.F90
34   
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ldf_eiv( kt )
46      !!----------------------------------------------------------------------
47      !!                  ***  ROUTINE ldf_eiv  ***
48      !!
49      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
50      !!              growth rate of baroclinic instability.
51      !!
52      !! ** Method :
53      !!
54      !! ** Action : - uslp , vslp  : i- and j-slopes of neutral surfaces at u- & v-points
55      !!             - wslpi, wslpj : i- and j-slopes of neutral surfaces at w-points.
56      !!----------------------------------------------------------------------
57      INTEGER, INTENT(in) ::   kt   ! ocean time-step inedx
58      !
59      INTEGER  ::   ji, jj, jk   ! dummy loop indices
60      REAL(wp) ::   zfw, ze3w, zn2, zf20, zaht, zaht_min      ! temporary scalars
61      REAL(wp), DIMENSION(:,:), POINTER ::   zn, zah, zhw, zross   ! 2D workspace
62      !!----------------------------------------------------------------------
63      !
64      IF( nn_timing == 1 )  CALL timing_start('ldf_eiv')
65      !
66      CALL wrk_alloc( jpi,jpj, zn, zah, zhw, zross )
67
68      IF( kt == nit000 ) THEN
69         IF(lwp) WRITE(numout,*)
70         IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients'
71         IF(lwp) WRITE(numout,*) '~~~~~~~'
72      ENDIF
73     
74      ! 0. Local initialization
75      ! -----------------------
76      zn   (:,:) = 0._wp
77      zhw  (:,:) = 5._wp
78      zah  (:,:) = 0._wp
79      zross(:,:) = 0._wp
80
81
82      ! 1. Compute lateral diffusive coefficient
83      ! ----------------------------------------
84      IF( ln_traldf_grif ) THEN
85         DO jk = 1, jpk
86            DO jj = 2, jpjm1
87               DO ji = 2, jpim1
88                  ! Take the max of N^2 and zero then take the vertical sum
89                  ! of the square root of the resulting N^2 ( required to compute
90                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
91                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
92                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
93                  ! Compute elements required for the inverse time scale of baroclinic
94                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
95                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
96                  ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
97                  zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w
98                  zhw(ji,jj) = zhw(ji,jj) + ze3w
99               END DO
100            END DO
101         END DO
102      ELSE
103         DO jk = 1, jpk
104            DO jj = 2, jpjm1
105               DO ji = 2, jpim1
106                  ! Take the max of N^2 and zero then take the vertical sum
107                  ! of the square root of the resulting N^2 ( required to compute
108                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
109                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
110                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk)
111                  ! Compute elements required for the inverse time scale of baroclinic
112                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
113                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
114                  ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk)
115                  zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
116                     &                            + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w
117                  zhw(ji,jj) = zhw(ji,jj) + ze3w
118               END DO
119            END DO
120         END DO
121      END IF
122
123      DO jj = 2, jpjm1
124         DO ji = fs_2, fs_jpim1   ! vector opt.
125            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
126            ! Rossby radius at w-point taken < 40km and  > 2km
127            zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 )
128            ! Compute aeiw by multiplying Ro^2 and T^-1
129            aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * ssmask(ji,jj)
130         END DO
131      END DO
132
133      IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN   ! ORCA R2
134         DO jj = 2, jpjm1
135!CDIR NOVERRCHK
136            DO ji = fs_2, fs_jpim1   ! vector opt.
137               ! Take the minimum between aeiw and 1000 m2/s over shelves (depth shallower than 650 m)
138               IF( mbkt(ji,jj) <= 20 )   aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. )
139            END DO
140         END DO
141      ENDIF
142
143      ! Decrease the coefficient in the tropics (20N-20S)
144      zf20 = 2._wp * omega * sin( rad * 20._wp )
145      DO jj = 2, jpjm1
146         DO ji = fs_2, fs_jpim1   ! vector opt.
147            aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj)
148         END DO
149      END DO
150
151      ! ORCA R05: Take the minimum between aeiw  and aeiv0
152      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
153         DO jj = 2, jpjm1
154            DO ji = fs_2, fs_jpim1   ! vector opt.
155               aeiw(ji,jj) = MIN( aeiw(ji,jj), aeiv0 )
156            END DO
157         END DO
158      ENDIF
159
160      ! ORCA R1: Take the minimum between aeiw  and aeiv0
161      IF( cp_cfg == "orca" .AND. jp_cfg == 1 ) THEN
162         DO jj = 2, jpjm1
163            DO ji = fs_2, fs_jpim1   ! vector opt.
164               aeiw(ji,jj) = MIN( aeiw(ji,jj), aeiv0 )
165            END DO
166         END DO
167      ENDIF
168
169      CALL lbc_lnk( aeiw, 'W', 1. )      ! lateral boundary condition on aeiw
170
171
172      ! Average the diffusive coefficient at u- v- points
173      DO jj = 2, jpjm1
174         DO ji = fs_2, fs_jpim1   ! vector opt.
175            aeiu(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji+1,jj  ) )
176            aeiv(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji  ,jj+1) )
177         END DO
178      END DO
179      CALL lbc_lnk( aeiu, 'U', 1. )   ;   CALL lbc_lnk( aeiv, 'V', 1. )      ! lateral boundary condition
180
181
182      IF(ln_ctl) THEN
183         CALL prt_ctl(tab2d_1=aeiu, clinfo1=' eiv  - u: ', ovlap=1)
184         CALL prt_ctl(tab2d_1=aeiv, clinfo1=' eiv  - v: ', ovlap=1)
185      ENDIF
186
187      ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth)
188      IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN
189         zf20     = 2._wp * omega * SIN( rad * 20._wp )
190         zaht_min = 100._wp                           ! minimum value for aht
191         DO jj = 1, jpj
192            DO ji = 1, jpi
193               zaht      = ( 1._wp -  MIN( 1._wp , ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min )  &
194                  &      + aht0 * rnfmsk(ji,jj)                          ! enhanced near river mouths
195               ahtu(ji,jj) = MAX( MAX( zaht_min, aeiu(ji,jj) ) + zaht, aht0 )
196               ahtv(ji,jj) = MAX( MAX( zaht_min, aeiv(ji,jj) ) + zaht, aht0 )
197               ahtw(ji,jj) = MAX( MAX( zaht_min, aeiw(ji,jj) ) + zaht, aht0 )
198            END DO
199         END DO
200         IF(ln_ctl) THEN
201            CALL prt_ctl(tab2d_1=ahtu, clinfo1=' aht  - u: ', ovlap=1)
202            CALL prt_ctl(tab2d_1=ahtv, clinfo1=' aht  - v: ', ovlap=1)
203            CALL prt_ctl(tab2d_1=ahtw, clinfo1=' aht  - w: ', ovlap=1)
204         ENDIF
205      ENDIF
206
207      IF( aeiv0 == 0._wp ) THEN
208         aeiu(:,:) = 0._wp
209         aeiv(:,:) = 0._wp
210         aeiw(:,:) = 0._wp
211      ENDIF
212
213      CALL iom_put( "aht2d"    , ahtw )   ! lateral eddy diffusivity
214      CALL iom_put( "aht2d_eiv", aeiw )   ! EIV lateral eddy diffusivity
215     
216      CALL wrk_dealloc( jpi,jpj, zn, zah, zhw, zross )
217      !
218      IF( nn_timing == 1 )  CALL timing_stop('ldf_eiv')
219      !
220   END SUBROUTINE ldf_eiv
221
222#else
223   !!----------------------------------------------------------------------
224   !!   Default option                                         Dummy module
225   !!----------------------------------------------------------------------
226CONTAINS
227   SUBROUTINE ldf_eiv( kt )       ! Empty routine
228      INTEGER :: kt
229      WRITE(*,*) 'ldf_eiv: You should not have seen this print! error?', kt
230   END SUBROUTINE ldf_eiv
231#endif
232
233   !!======================================================================
234END MODULE ldfeiv
Note: See TracBrowser for help on using the repository browser.