New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 6793

Last change on this file since 6793 was 6793, checked in by davestorkey, 8 years ago

Merge in changes r6482:6692 from the nemo_v3_6_STABLE branch. Only part that changes results for GO6 configurations is a bug fix for the TVD advection scheme put in at r6692.
Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6692 cf. r6688 of /branches/2015/nemo_v3_6_STABLE/NEMOGCM@6791

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6688 cf. r6482 of /branches/2015/nemo_v3_6_STABLE/NEMOGCM@6791

File size: 32.8 KB
RevLine 
[3]1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
[2528]4   !! Ocean  tracers:  horizontal & vertical advective trend
[3]5   !!==============================================================================
[2528]6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
[503]16   !!----------------------------------------------------------------------
[3]17
18   !!----------------------------------------------------------------------
[3625]19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
[3]21   !!----------------------------------------------------------------------
[3625]22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
[4990]24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
[3625]26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
[4990]28   USE diaptr         ! poleward transport diagnostics
29   !
[3625]30   USE lib_mpp        ! MPP library
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
[4990]32   USE in_out_manager ! I/O manager
[3625]33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
[3]36
37   IMPLICIT NONE
38   PRIVATE
39
[4990]40   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
41   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
[3]42
[2715]43   LOGICAL ::   l_trd   ! flag to compute trends
[2528]44
[3]45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
[2528]49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
[1152]50   !! $Id$
[2528]51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[3]52   !!----------------------------------------------------------------------
53CONTAINS
54
[3294]55   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
[2528]56      &                                       ptb, ptn, pta, kjpt )
[3]57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_tvd  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of
61      !!       tracers and add it to the general trend of tracer equations
62      !!
63      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
64      !!       corrected flux (monotonic correction)
65      !!       note: - this advection scheme needs a leap-frog time scheme
66      !!
[2528]67      !! ** Action : - update (pta) with the now advective tracer trends
68      !!             - save the trends
[503]69      !!----------------------------------------------------------------------
[2715]70      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
71      !
[2528]72      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
[3294]73      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
[2528]74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
76      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
[2715]80      !
[4990]81      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
82      INTEGER  ::   ik 
[2528]83      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
84      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
85      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
[3294]86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
[3]88      !!----------------------------------------------------------------------
[3294]89      !
90      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
91      !
92      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
93      !
94      IF( kt == kit000 )  THEN
[2528]95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
[4990]98         !
99         l_trd = .FALSE.
100         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
[3]101      ENDIF
[2528]102      !
103      IF( l_trd )  THEN
[3294]104         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
105         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
106      ENDIF
[2528]107      !
[5120]108      zwi(:,:,:) = 0.e0 ; 
[2528]109      !
110      !                                                          ! ===========
111      DO jn = 1, kjpt                                            ! tracer loop
112         !                                                       ! ===========
[5120]113         ! 1. Bottom and k=1 value : flux set to zero
[2528]114         ! ----------------------------------
115         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
116         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
[5120]117         
118         zwz(:,:,1  ) = 0._wp
[2528]119         ! 2. upstream advection with initial mass fluxes & intermediate update
120         ! --------------------------------------------------------------------
121         ! upstream tracer flux in the i and j direction
122         DO jk = 1, jpkm1
123            DO jj = 1, jpjm1
124               DO ji = 1, fs_jpim1   ! vector opt.
125                  ! upstream scheme
126                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
127                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
128                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
129                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
130                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
131                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
132               END DO
[3]133            END DO
134         END DO
135
[2528]136         ! upstream tracer flux in the k direction
[5120]137         ! Interior value
138         DO jk = 2, jpkm1
[4990]139            DO jj = 1, jpj
140               DO ji = 1, jpi
[2528]141                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
142                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
[5120]143                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
[2528]144               END DO
[3]145            END DO
146         END DO
[5120]147         ! Surface value
148         IF( lk_vvl ) THEN   
149            IF ( ln_isfcav ) THEN
150               DO jj = 1, jpj
151                  DO ji = 1, jpi
152                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable
153                  END DO
154               END DO
155            ELSE
156               zwz(:,:,1) = 0.e0          ! volume variable
157            END IF
158         ELSE               
159            IF ( ln_isfcav ) THEN
160               DO jj = 1, jpj
161                  DO ji = 1, jpi
162                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
163                  END DO
164               END DO   
165            ELSE
166               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
167            END IF
168         ENDIF
[3]169
[2528]170         ! total advective trend
[216]171         DO jk = 1, jpkm1
[2528]172            z2dtt = p2dt(jk)
[216]173            DO jj = 2, jpjm1
174               DO ji = fs_2, fs_jpim1   ! vector opt.
[2528]175                  ! total intermediate advective trends
[6793]176                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
177                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
178                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) / e1e2t(ji,jj)
[2528]179                  ! update and guess with monotonic sheme
[6793]180                  pta(ji,jj,jk,jn) =                       pta(ji,jj,jk,jn) +         ztra   / fse3t_n(ji,jj,jk) * tmask(ji,jj,jk)
181                  zwi(ji,jj,jk)    = ( fse3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + z2dtt * ztra ) / fse3t_a(ji,jj,jk) * tmask(ji,jj,jk)
[216]182               END DO
183            END DO
184         END DO
[2528]185         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
186         CALL lbc_lnk( zwi, 'T', 1. ) 
187
188         !                                 ! trend diagnostics (contribution of upstream fluxes)
189         IF( l_trd )  THEN 
190            ! store intermediate advective trends
191            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
192         END IF
193         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
[5147]194         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
195           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
196           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
[2528]197         ENDIF
198
199         ! 3. antidiffusive flux : high order minus low order
200         ! --------------------------------------------------
201         ! antidiffusive flux on i and j
[503]202         DO jk = 1, jpkm1
[2528]203            DO jj = 1, jpjm1
204               DO ji = 1, fs_jpim1   ! vector opt.
205                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
206                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
[503]207               END DO
208            END DO
209         END DO
[2528]210     
211         ! antidiffusive flux on k
[5120]212         ! Interior value
213         DO jk = 2, jpkm1                   
214            DO jj = 1, jpj
215               DO ji = 1, jpi
[2528]216                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
[503]217               END DO
218            END DO
219         END DO
[5120]220         ! surface value
221         IF ( ln_isfcav ) THEN
222            DO jj = 1, jpj
223               DO ji = 1, jpi
224                  zwz(ji,jj,mikt(ji,jj)) = 0.e0
225               END DO
226            END DO
227         ELSE
228            zwz(:,:,1) = 0.e0
229         END IF
[2528]230         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
231         CALL lbc_lnk( zwz, 'W',  1. )
[216]232
[2528]233         ! 4. monotonicity algorithm
234         ! -------------------------
235         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
[3]236
237
[2528]238         ! 5. final trend with corrected fluxes
239         ! ------------------------------------
[216]240         DO jk = 1, jpkm1
241            DO jj = 2, jpjm1
[2528]242               DO ji = fs_2, fs_jpim1   ! vector opt. 
[503]243                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
[2528]244                  ! total advective trends
245                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
246                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
247                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
248                  ! add them to the general tracer trends
[4990]249                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
[216]250               END DO
251            END DO
252         END DO
[2528]253
254         !                                 ! trend diagnostics (contribution of upstream fluxes)
255         IF( l_trd )  THEN
256            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
257            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
258            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
259           
[4990]260            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
261            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
262            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
[2528]263         END IF
264         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
[5147]265         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
266           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
267           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
[2528]268         ENDIF
[503]269         !
[2715]270      END DO
[503]271      !
[3294]272                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
273      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
[2528]274      !
[3294]275      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
[2715]276      !
[3]277   END SUBROUTINE tra_adv_tvd
278
[4990]279   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
280      &                                       ptb, ptn, pta, kjpt )
281      !!----------------------------------------------------------------------
282      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
283      !!
284      !! **  Purpose :   Compute the now trend due to total advection of
285      !!       tracers and add it to the general trend of tracer equations
286      !!
287      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
288      !!       corrected flux (monotonic correction). This version use sub-
289      !!       timestepping for the vertical advection which increases stability
290      !!       when vertical metrics are small.
291      !!       note: - this advection scheme needs a leap-frog time scheme
292      !!
293      !! ** Action : - update (pta) with the now advective tracer trends
294      !!             - save the trends
295      !!----------------------------------------------------------------------
296      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
297      !
298      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
299      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
300      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
301      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
302      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
303      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
304      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
305      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
306      !
307      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
308      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
309      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
310      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
311      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
312      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
313      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
314      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
315      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
316      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
317      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
318      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
319      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
320      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
321      !!----------------------------------------------------------------------
322      !
323      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
324      !
325      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
326      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
[6487]327      CALL wrk_alloc( jpi, jpj, jpk, kjpt+1, ztrs )
[4990]328      !
329      IF( kt == kit000 )  THEN
330         IF(lwp) WRITE(numout,*)
331         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
332         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
333      ENDIF
334      !
335      l_trd = .FALSE.
336      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
337      !
338      IF( l_trd )  THEN
339         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
340         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
341      ENDIF
342      !
343      zwi(:,:,:) = 0._wp
344      z_rzts = 1._wp / REAL( jnzts, wp )
345      zr_p2dt(:) = 1._wp / p2dt(:)
346      !
347      !                                                          ! ===========
348      DO jn = 1, kjpt                                            ! tracer loop
349         !                                                       ! ===========
350         ! 1. Bottom value : flux set to zero
351         ! ----------------------------------
352         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
353         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
[3]354
[4990]355         ! 2. upstream advection with initial mass fluxes & intermediate update
356         ! --------------------------------------------------------------------
357         ! upstream tracer flux in the i and j direction
358         DO jk = 1, jpkm1
359            DO jj = 1, jpjm1
360               DO ji = 1, fs_jpim1   ! vector opt.
361                  ! upstream scheme
362                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
363                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
364                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
365                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
366                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
367                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
368               END DO
369            END DO
370         END DO
371
372         ! upstream tracer flux in the k direction
373         ! Interior value
374         DO jk = 2, jpkm1
375            DO jj = 1, jpj
376               DO ji = 1, jpi
377                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
378                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
379                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
380               END DO
381            END DO
382         END DO
[5120]383         ! Surface value
384         IF( lk_vvl ) THEN
385            IF ( ln_isfcav ) THEN
386               DO jj = 1, jpj
387                  DO ji = 1, jpi
388                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable +    isf
389                  END DO
390               END DO
391            ELSE
392               zwz(:,:,1) = 0.e0                              ! volume variable + no isf
393            END IF
394         ELSE
395            IF ( ln_isfcav ) THEN
396               DO jj = 1, jpj
397                  DO ji = 1, jpi
398                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface +    isf
399                  END DO
400               END DO
401            ELSE
402               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)                                               ! linear free surface + no isf
403            END IF
404         ENDIF
[4990]405
406         ! total advective trend
407         DO jk = 1, jpkm1
408            z2dtt = p2dt(jk)
409            DO jj = 2, jpjm1
410               DO ji = fs_2, fs_jpim1   ! vector opt.
411                  ! total intermediate advective trends
[6793]412                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
413                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
414                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) / e1e2t(ji,jj)
[4990]415                  ! update and guess with monotonic sheme
[6793]416                  pta(ji,jj,jk,jn) =                       pta(ji,jj,jk,jn) +         ztra   / fse3t_n(ji,jj,jk) * tmask(ji,jj,jk)
417                  zwi(ji,jj,jk)    = ( fse3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + z2dtt * ztra ) / fse3t_a(ji,jj,jk) * tmask(ji,jj,jk)
[4990]418               END DO
419            END DO
420         END DO
421         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
422         CALL lbc_lnk( zwi, 'T', 1. ) 
423
424         !                                 ! trend diagnostics (contribution of upstream fluxes)
425         IF( l_trd )  THEN 
426            ! store intermediate advective trends
427            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
428         END IF
429         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
[5147]430         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
431           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
432           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
[4990]433         ENDIF
434
435         ! 3. antidiffusive flux : high order minus low order
436         ! --------------------------------------------------
437         ! antidiffusive flux on i and j
[6793]438         !
[4990]439         DO jk = 1, jpkm1
[6793]440            !
[4990]441            DO jj = 1, jpjm1
442               DO ji = 1, fs_jpim1   ! vector opt.
443                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
444                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
445
446                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
447                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
448               END DO
449            END DO
450
451            DO jj = 2, jpjm1         ! partial horizontal divergence
452               DO ji = fs_2, fs_jpim1
453                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
454                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
455               END DO
456            END DO
457
458            DO jj = 1, jpjm1
459               DO ji = 1, fs_jpim1   ! vector opt.
460                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
461                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
462               END DO
463            END DO
464         END DO
465     
466         ! antidiffusive flux on k
467         zwz(:,:,1) = 0._wp        ! Surface value
468         zwz_sav(:,:,:) = zwz(:,:,:)
469         !
470         ztrs(:,:,:,1) = ptb(:,:,:,jn)
471         zwzts(:,:,:) = 0._wp
472
473         DO jl = 1, jnzts                   ! Start of sub timestepping loop
474
475            IF( jl == 1 ) THEN              ! Euler forward to kick things off
476              jtb = 1   ;   jtn = 1   ;   jta = 2
477              zts(:) = p2dt(:) * z_rzts
478              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
479                                            ! starting at jl =1 if jnzts is odd;
480                                            ! starting at jl =2 otherwise
481            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
482              jtb = 1   ;   jtn = 2   ;   jta = 3
483              zts(:) = 2._wp * p2dt(:) * z_rzts
484            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
485              jtb = MOD(jtb,3) + 1
486              jtn = MOD(jtn,3) + 1
487              jta = MOD(jta,3) + 1
488            ENDIF
489            DO jk = 2, jpkm1          ! Interior value
490               DO jj = 2, jpjm1
491                  DO ji = fs_2, fs_jpim1
492                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
493                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
494                  END DO
495               END DO
496            END DO
497
498            jtaken = MOD( jtaken + 1 , 2 )
499
500            DO jk = 2, jpkm1          ! Interior value
501               DO jj = 2, jpjm1
502                  DO ji = fs_2, fs_jpim1
503                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
504                     ! total advective trends
505                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
506                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
507                  END DO
508               END DO
509            END DO
510
511         END DO
512
513         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
514            DO jj = 2, jpjm1
515               DO ji = fs_2, fs_jpim1
516                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
517               END DO
518            END DO
519         END DO
520         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
521         CALL lbc_lnk( zwz, 'W',  1. )
522
523         ! 4. monotonicity algorithm
524         ! -------------------------
525         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
526
527
528         ! 5. final trend with corrected fluxes
529         ! ------------------------------------
530         DO jk = 1, jpkm1
531            DO jj = 2, jpjm1
532               DO ji = fs_2, fs_jpim1   ! vector opt. 
533                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
534                  ! total advective trends
535                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
536                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
537                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
538                  ! add them to the general tracer trends
539                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
540               END DO
541            END DO
542         END DO
543
544         !                                 ! trend diagnostics (contribution of upstream fluxes)
545         IF( l_trd )  THEN
546            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
547            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
548            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
549           
550            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
551            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
552            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
553         END IF
554         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
[5147]555         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
556           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
557           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
[4990]558         ENDIF
559         !
560      END DO
561      !
562                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
[6487]563                   CALL wrk_dealloc( jpi, jpj, jpk, kjpt+1, ztrs )
[4990]564                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
565      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
566      !
567      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
568      !
569   END SUBROUTINE tra_adv_tvd_zts
570
[6793]571
[2528]572   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
[3]573      !!---------------------------------------------------------------------
574      !!                    ***  ROUTINE nonosc  ***
575      !!     
576      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
577      !!       scheme and the before field by a nonoscillatory algorithm
578      !!
579      !! **  Method  :   ... ???
580      !!       warning : pbef and paft must be masked, but the boundaries
581      !!       conditions on the fluxes are not necessary zalezak (1979)
582      !!       drange (1995) multi-dimensional forward-in-time and upstream-
583      !!       in-space based differencing for fluid
584      !!----------------------------------------------------------------------
[2528]585      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
586      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
587      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
[2715]588      !
[4990]589      INTEGER  ::   ji, jj, jk   ! dummy loop indices
590      INTEGER  ::   ikm1         ! local integer
[2715]591      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
592      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
[3294]593      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
[3]594      !!----------------------------------------------------------------------
[3294]595      !
596      IF( nn_timing == 1 )  CALL timing_start('nonosc')
597      !
598      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
599      !
[2715]600      zbig  = 1.e+40_wp
601      zrtrn = 1.e-15_wp
[4990]602      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
[785]603
[3]604      ! Search local extrema
605      ! --------------------
[785]606      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
[4990]607      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
608         &        paft * tmask - zbig * ( 1._wp - tmask )  )
609      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
610         &        paft * tmask + zbig * ( 1._wp - tmask )  )
[785]611
[5120]612      DO jk = 1, jpkm1
613         ikm1 = MAX(jk-1,1)
614         z2dtt = p2dt(jk)
615         DO jj = 2, jpjm1
616            DO ji = fs_2, fs_jpim1   ! vector opt.
617
[785]618               ! search maximum in neighbourhood
619               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
620                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
621                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
622                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
[3]623
[785]624               ! search minimum in neighbourhood
625               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
626                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
627                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
628                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
[3]629
[785]630               ! positive part of the flux
[3]631               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
632                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
633                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
[785]634
635               ! negative part of the flux
[3]636               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
637                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
638                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
[785]639
[3]640               ! up & down beta terms
641               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
[785]642               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
643               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
[3]644            END DO
645         END DO
646      END DO
[2528]647      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
[3]648
[237]649      ! 3. monotonic flux in the i & j direction (paa & pbb)
650      ! ----------------------------------------
[3]651      DO jk = 1, jpkm1
652         DO jj = 2, jpjm1
653            DO ji = fs_2, fs_jpim1   ! vector opt.
[4990]654               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
655               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
[785]656               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
[4990]657               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
[3]658
[4990]659               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
660               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
[785]661               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
[4990]662               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
[3]663
664      ! monotonic flux in the k direction, i.e. pcc
665      ! -------------------------------------------
[785]666               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
667               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
668               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
[4990]669               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
[3]670            END DO
671         END DO
672      END DO
[2528]673      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
[503]674      !
[3294]675      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
[2715]676      !
[3294]677      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
678      !
[3]679   END SUBROUTINE nonosc
680
681   !!======================================================================
682END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.