source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/TRA/traqsr.F90 @ 6498

Last change on this file since 6498 was 6498, checked in by timgraham, 4 years ago

Merge head of nemo_v3_6_STABLE into package branch

File size: 32.3 KB
Line 
1MODULE traqsr
2   !!======================================================================
3   !!                       ***  MODULE  traqsr  ***
4   !! Ocean physics: solar radiation penetration in the top ocean levels
5   !!======================================================================
6   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
7   !!            7.0  !  1991-11  (G. Madec)
8   !!                 !  1996-01  (G. Madec)  s-coordinates
9   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
10   !!             -   !  2005-11  (G. Madec) zco, zps, sco coordinate
11   !!            3.2  !  2009-04  (G. Madec & NEMO team)
12   !!            3.4  !  2012-05  (C. Rousset) store attenuation coef for use in ice model
13   !!            3.6  !  2015-12  (O. Aumont, J. Jouanno, C. Ethe) use vertical profile of chlorophyll
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   tra_qsr      : trend due to the solar radiation penetration
18   !!   tra_qsr_init : solar radiation penetration initialization
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and active tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_oce         ! surface boundary condition: ocean
23   USE trc_oce         ! share SMS/Ocean variables
24   USE trd_oce        ! trends: ocean variables
25   USE trdtra         ! trends manager: tracers
26   USE in_out_manager  ! I/O manager
27   USE phycst          ! physical constants
28   USE prtctl          ! Print control
29   USE iom             ! I/O manager
30   USE fldread         ! read input fields
31   USE restart         ! ocean restart
32   USE lib_mpp         ! MPP library
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_qsr       ! routine called by step.F90 (ln_traqsr=T)
40   PUBLIC   tra_qsr_init  ! routine called by nemogcm.F90
41
42   !                                 !!* Namelist namtra_qsr: penetrative solar radiation
43   LOGICAL , PUBLIC ::   ln_traqsr    !: light absorption (qsr) flag
44   LOGICAL , PUBLIC ::   ln_qsr_rgb   !: Red-Green-Blue light absorption flag 
45   LOGICAL , PUBLIC ::   ln_qsr_2bd   !: 2 band         light absorption flag
46   LOGICAL , PUBLIC ::   ln_qsr_bio   !: bio-model      light absorption flag
47   LOGICAL , PUBLIC ::   ln_qsr_ice   !: light penetration for ice-model LIM3 (clem)
48   INTEGER , PUBLIC ::   nn_chldta    !: use Chlorophyll data (=1) or not (=0)
49   REAL(wp), PUBLIC ::   rn_abs       !: fraction absorbed in the very near surface (RGB & 2 bands)
50   REAL(wp), PUBLIC ::   rn_si0       !: very near surface depth of extinction      (RGB & 2 bands)
51   REAL(wp), PUBLIC ::   rn_si1       !: deepest depth of extinction (water type I)       (2 bands)
52 
53   ! Module variables
54   REAL(wp) ::   xsi0r                           !: inverse of rn_si0
55   REAL(wp) ::   xsi1r                           !: inverse of rn_si1
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_chl   ! structure of input Chl (file informations, fields read)
57   INTEGER, PUBLIC ::   nksr              ! levels below which the light cannot penetrate ( depth larger than 391 m)
58   REAL(wp), DIMENSION(3,61) ::   rkrgb   !: tabulated attenuation coefficients for RGB absorption
59
60   !! * Substitutions
61#  include "domzgr_substitute.h90"
62#  include "vectopt_loop_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   SUBROUTINE tra_qsr( kt )
71      !!----------------------------------------------------------------------
72      !!                  ***  ROUTINE tra_qsr  ***
73      !!
74      !! ** Purpose :   Compute the temperature trend due to the solar radiation
75      !!      penetration and add it to the general temperature trend.
76      !!
77      !! ** Method  : The profile of the solar radiation within the ocean is defined
78      !!      through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs
79      !!      Considering the 2 wavebands case:
80      !!         I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) )
81      !!         The temperature trend associated with the solar radiation penetration
82      !!         is given by : zta = 1/e3t dk[ I ] / (rau0*Cp)
83      !!         At the bottom, boudary condition for the radiation is no flux :
84      !!      all heat which has not been absorbed in the above levels is put
85      !!      in the last ocean level.
86      !!         In z-coordinate case, the computation is only done down to the
87      !!      level where I(k) < 1.e-15 W/m2. In addition, the coefficients
88      !!      used for the computation are calculated one for once as they
89      !!      depends on k only.
90      !!
91      !! ** Action  : - update ta with the penetrative solar radiation trend
92      !!              - save the trend in ttrd ('key_trdtra')
93      !!
94      !! Reference  : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
95      !!              Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516.
96      !!              Morel, A. et Berthon, JF, 1989, Limnol Oceanogr 34(8), 1545-1562
97      !!----------------------------------------------------------------------
98      !
99      INTEGER, INTENT(in) ::   kt     ! ocean time-step
100      !
101      INTEGER  ::   ji, jj, jk           ! dummy loop indices
102      INTEGER  ::   irgb                 ! local integers
103      REAL(wp) ::   zchl, zcoef, zfact   ! local scalars
104      REAL(wp) ::   zc0, zc1, zc2, zc3   !    -         -
105      REAL(wp) ::   zz0, zz1, z1_e3t     !    -         -
106      REAL(wp) ::   zCb, zCmax, zze, zpsi, zpsimax, zdelpsi, zCtot, zCze
107      REAL(wp) ::   zlogc, zlogc2, zlogc3 
108      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
109      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt, zchl3d
110      !!--------------------------------------------------------------------------
111      !
112      IF( nn_timing == 1 )  CALL timing_start('tra_qsr')
113      !
114      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
115      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) 
116      !
117      IF( kt == nit000 ) THEN
118         IF(lwp) WRITE(numout,*)
119         IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation'
120         IF(lwp) WRITE(numout,*) '~~~~~~~'
121         IF( .NOT.ln_traqsr )   RETURN
122      ENDIF
123
124      IF( l_trdtra ) THEN      ! Save ta and sa trends
125         CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) 
126         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
127      ENDIF
128
129      !                                        Set before qsr tracer content field
130      !                                        ***********************************
131      IF( kt == nit000 ) THEN                     ! Set the forcing field at nit000 - 1
132         !                                        ! -----------------------------------
133         qsr_hc(:,:,:) = 0.e0
134         !
135         IF( ln_rstart .AND.    &                    ! Restart: read in restart file
136              & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN
137            IF(lwp) WRITE(numout,*) '          nit000-1 qsr tracer content forcing field red in the restart file'
138            zfact = 0.5e0
139            CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b )   ! before heat content trend due to Qsr flux
140         ELSE                                           ! No restart or restart not found: Euler forward time stepping
141            zfact = 1.e0
142            qsr_hc_b(:,:,:) = 0.e0
143         ENDIF
144      ELSE                                        ! Swap of forcing field
145         !                                        ! ---------------------
146         zfact = 0.5e0
147         qsr_hc_b(:,:,:) = qsr_hc(:,:,:)
148      ENDIF
149      !                                        Compute now qsr tracer content field
150      !                                        ************************************
151     
152      !                                           ! ============================================== !
153      IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN      !  bio-model fluxes  : all vertical coordinates  !
154         !                                        ! ============================================== !
155         DO jk = 1, jpkm1
156            qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) )
157         END DO
158         !                                        Add to the general trend
159         DO jk = 1, jpkm1
160            DO jj = 2, jpjm1 
161               DO ji = fs_2, fs_jpim1   ! vector opt.
162                  z1_e3t = zfact / fse3t(ji,jj,jk)
163                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
164               END DO
165            END DO
166         END DO
167         CALL iom_put( 'qsr3d', etot3 )   ! Shortwave Radiation 3D distribution
168         ! clem: store attenuation coefficient of the first ocean level
169         IF ( ln_qsr_ice ) THEN
170            DO jj = 1, jpj
171               DO ji = 1, jpi
172                  IF ( qsr(ji,jj) /= 0._wp ) THEN
173                     fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) )
174                  ELSE
175                     fraqsr_1lev(ji,jj) = 1.
176                  ENDIF
177               END DO
178            END DO
179         ENDIF
180         !                                        ! ============================================== !
181      ELSE                                        !  Ocean alone :
182         !                                        ! ============================================== !
183         !
184         !                                                ! ------------------------- !
185         IF( ln_qsr_rgb) THEN                             !  R-G-B  light penetration !
186            !                                             ! ------------------------- !
187            ! Set chlorophyl concentration
188            IF( nn_chldta == 1 .OR. nn_chldta == 2 .OR. lk_vvl ) THEN    !*  Variable Chlorophyll or ocean volume
189               !
190               IF( nn_chldta == 1 ) THEN        !*  2D Variable Chlorophyll
191                  !
192                  CALL fld_read( kt, 1, sf_chl )            ! Read Chl data and provides it at the current time step
193                  DO jk = 1, nksr + 1
194                     zchl3d(:,:,jk) = sf_chl(1)%fnow(:,:,1) 
195                  ENDDO
196                  !
197               ELSE IF( nn_chldta == 2 ) THEN    !*   -3-D Variable Chlorophyll
198                  !
199                  CALL fld_read( kt, 1, sf_chl )            ! Read Chl data and provides it at the current time step
200!CDIR NOVERRCHK   !
201                  DO jj = 1, jpj
202!CDIR NOVERRCHK
203                     DO ji = 1, jpi
204                        zchl    = sf_chl(1)%fnow(ji,jj,1)
205                        zCtot   = 40.6  * zchl**0.459
206                        zze     = 568.2 * zCtot**(-0.746)
207                        IF( zze > 102. ) zze = 200.0 * zCtot**(-0.293)
208                        zlogc   = LOG( zchl )
209                        zlogc2  = zlogc * zlogc
210                        zlogc3  = zlogc * zlogc * zlogc
211                        zCb     = 0.768 + 0.087 * zlogc - 0.179 * zlogc2 - 0.025 * zlogc3
212                        zCmax   = 0.299 - 0.289 * zlogc + 0.579 * zlogc2
213                        zpsimax = 0.6   - 0.640 * zlogc + 0.021 * zlogc2 + 0.115 * zlogc3
214                        zdelpsi = 0.710 + 0.159 * zlogc + 0.021 * zlogc2
215                        zCze    = 1.12  * (zchl)**0.803 
216                        DO jk = 1, nksr + 1
217                           zpsi = fsdept(ji,jj,jk) / zze
218                           zchl3d(ji,jj,jk) = zCze * ( zCb + zCmax * EXP( -( (zpsi - zpsimax) / zdelpsi )**2 ) )
219                        END DO
220                        !
221                      END DO
222                   END DO
223                     !
224               ELSE                              !* Variable ocean volume but constant chrlorophyll
225                  DO jk = 1, nksr + 1
226                     zchl3d(:,:,jk) = 0.05 
227                  ENDDO
228               ENDIF
229               !
230               zcoef  = ( 1. - rn_abs ) / 3.e0                        !  equi-partition in R-G-B
231               ze0(:,:,1) = rn_abs  * qsr(:,:)
232               ze1(:,:,1) = zcoef * qsr(:,:)
233               ze2(:,:,1) = zcoef * qsr(:,:)
234               ze3(:,:,1) = zcoef * qsr(:,:)
235               zea(:,:,1) =         qsr(:,:)
236               !
237               DO jk = 2, nksr+1
238                  !
239                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of vertical profile of Chl
240!CDIR NOVERRCHK
241                     DO ji = 1, jpi
242                        zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,jk) ) )
243                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
244                        zekb(ji,jj) = rkrgb(1,irgb)
245                        zekg(ji,jj) = rkrgb(2,irgb)
246                        zekr(ji,jj) = rkrgb(3,irgb)
247                     END DO
248                  END DO
249!CDIR NOVERRCHK
250                  DO jj = 1, jpj
251!CDIR NOVERRCHK   
252                     DO ji = 1, jpi
253                        zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r     )
254                        zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) )
255                        zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) )
256                        zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) )
257                        ze0(ji,jj,jk) = zc0
258                        ze1(ji,jj,jk) = zc1
259                        ze2(ji,jj,jk) = zc2
260                        ze3(ji,jj,jk) = zc3
261                        zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
262                     END DO
263                  END DO
264               END DO
265               !
266               DO jk = 1, nksr                                        ! compute and add qsr trend to ta
267                  qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) )
268               END DO
269               zea(:,:,nksr+1:jpk) = 0.e0     ! below 400m set to zero
270               CALL iom_put( 'qsr3d', zea )   ! Shortwave Radiation 3D distribution
271               !
272               IF ( ln_qsr_ice ) THEN    ! store attenuation coefficient of the first ocean level
273!CDIR NOVERRCHK
274                  DO jj = 1, jpj                                         ! Separation in R-G-B depending of the surface Chl
275!CDIR NOVERRCHK
276                     DO ji = 1, jpi
277                        zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,1) ) )
278                        irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
279                        zekb(ji,jj) = rkrgb(1,irgb)
280                        zekg(ji,jj) = rkrgb(2,irgb)
281                        zekr(ji,jj) = rkrgb(3,irgb)
282                     END DO
283                  END DO
284                  !
285                  DO jj = 1, jpj
286                     DO ji = 1, jpi
287                        zc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r     )
288                        zc1 = zcoef  * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) )
289                        zc2 = zcoef  * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) )
290                        zc3 = zcoef  * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) )
291                        fraqsr_1lev(ji,jj) = 1.0 - ( zc0 + zc1 + zc2  + zc3  ) * tmask(ji,jj,2) 
292                     END DO
293                  END DO
294                  !
295               ENDIF
296               !
297            ELSE                                                 !*  Constant Chlorophyll
298               DO jk = 1, nksr
299                  qsr_hc(:,:,jk) =  etot3(:,:,jk) * qsr(:,:)
300               END DO
301               !  store attenuation coefficient of the first ocean level
302               IF( ln_qsr_ice ) THEN
303                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
304               ENDIF
305           ENDIF
306
307         ENDIF
308         !                                                ! ------------------------- !
309         IF( ln_qsr_2bd ) THEN                            !  2 band light penetration !
310            !                                             ! ------------------------- !
311            !
312            IF( lk_vvl ) THEN                                  !* variable volume
313               zz0   =        rn_abs   * r1_rau0_rcp
314               zz1   = ( 1. - rn_abs ) * r1_rau0_rcp
315               DO jk = 1, nksr                    ! solar heat absorbed at T-point in the top 400m
316                  DO jj = 1, jpj
317                     DO ji = 1, jpi
318                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
319                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
320                        qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) 
321                     END DO
322                  END DO
323               END DO
324               ! clem: store attenuation coefficient of the first ocean level
325               IF ( ln_qsr_ice ) THEN
326                  DO jj = 1, jpj
327                     DO ji = 1, jpi
328                        zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r )
329                        zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r )
330                        fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp
331                     END DO
332                  END DO
333               ENDIF
334            ELSE                                               !* constant volume: coef. computed one for all
335               DO jk = 1, nksr
336                  DO jj = 2, jpjm1
337                     DO ji = fs_2, fs_jpim1   ! vector opt.
338                        ! (ISF) no light penetration below the ice shelves         
339                        qsr_hc(ji,jj,jk) =  etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1)
340                     END DO
341                  END DO
342               END DO
343               ! clem: store attenuation coefficient of the first ocean level
344               IF ( ln_qsr_ice ) THEN
345                  fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp
346               ENDIF
347               !
348            ENDIF
349            !
350         ENDIF
351         !
352         !                                        Add to the general trend
353         DO jk = 1, nksr
354            DO jj = 2, jpjm1 
355               DO ji = fs_2, fs_jpim1   ! vector opt.
356                  z1_e3t = zfact / fse3t(ji,jj,jk)
357                  tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t
358               END DO
359            END DO
360         END DO
361         !
362      ENDIF
363      !
364      IF( lrst_oce ) THEN   !                  Write in the ocean restart file
365         !                                     *******************************
366         IF(lwp) WRITE(numout,*)
367         IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ',   &
368            &                    'at it= ', kt,' date= ', ndastp
369         IF(lwp) WRITE(numout,*) '~~~~'
370         CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b'   , qsr_hc      )
371         CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev )   ! default definition in sbcssm
372         !
373      ENDIF
374
375      IF( l_trdtra ) THEN     ! qsr tracers trends saved for diagnostics
376         ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:)
377         CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt )
378         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) 
379      ENDIF
380      !                       ! print mean trends (used for debugging)
381      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr  - Ta: ', mask1=tmask, clinfo3='tra-ta' )
382      !
383      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
384      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) 
385      !
386      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr')
387      !
388   END SUBROUTINE tra_qsr
389
390
391   SUBROUTINE tra_qsr_init
392      !!----------------------------------------------------------------------
393      !!                  ***  ROUTINE tra_qsr_init  ***
394      !!
395      !! ** Purpose :   Initialization for the penetrative solar radiation
396      !!
397      !! ** Method  :   The profile of solar radiation within the ocean is set
398      !!      from two length scale of penetration (rn_si0,rn_si1) and a ratio
399      !!      (rn_abs). These parameters are read in the namtra_qsr namelist. The
400      !!      default values correspond to clear water (type I in Jerlov'
401      !!      (1968) classification.
402      !!         called by tra_qsr at the first timestep (nit000)
403      !!
404      !! ** Action  : - initialize rn_si0, rn_si1 and rn_abs
405      !!
406      !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp.
407      !!----------------------------------------------------------------------
408      !
409      INTEGER  ::   ji, jj, jk                   ! dummy loop indices
410      INTEGER  ::   irgb, ierror, ioptio, nqsr   ! local integer
411      INTEGER  ::   ios                          ! Local integer output status for namelist read
412      REAL(wp) ::   zz0, zc0  , zc1, zcoef       ! local scalars
413      REAL(wp) ::   zz1, zc2  , zc3, zchl        !   -      -
414      REAL(wp), POINTER, DIMENSION(:,:  ) :: zekb, zekg, zekr
415      REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea
416      !
417      CHARACTER(len=100) ::   cn_dir   ! Root directory for location of ssr files
418      TYPE(FLD_N)        ::   sn_chl   ! informations about the chlorofyl field to be read
419      !!
420      NAMELIST/namtra_qsr/  sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice,  &
421         &                  nn_chldta, rn_abs, rn_si0, rn_si1
422      !!----------------------------------------------------------------------
423
424      !
425      IF( nn_timing == 1 )  CALL timing_start('tra_qsr_init')
426      !
427      CALL wrk_alloc( jpi, jpj,      zekb, zekg, zekr        ) 
428      CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
429      !
430
431      REWIND( numnam_ref )              ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration
432      READ  ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901)
433901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp )
434
435      REWIND( numnam_cfg )              !  Namelist namtra_qsr in configuration namelist : Ratio and length of penetration
436      READ  ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 )
437902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp )
438      IF(lwm) WRITE ( numond, namtra_qsr )
439      !
440      IF(lwp) THEN                ! control print
441         WRITE(numout,*)
442         WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation'
443         WRITE(numout,*) '~~~~~~~~~~~~'
444         WRITE(numout,*) '   Namelist namtra_qsr : set the parameter of penetration'
445         WRITE(numout,*) '      Light penetration (T) or not (F)         ln_traqsr  = ', ln_traqsr
446         WRITE(numout,*) '      RGB (Red-Green-Blue) light penetration   ln_qsr_rgb = ', ln_qsr_rgb
447         WRITE(numout,*) '      2 band               light penetration   ln_qsr_2bd = ', ln_qsr_2bd
448         WRITE(numout,*) '      bio-model            light penetration   ln_qsr_bio = ', ln_qsr_bio
449         WRITE(numout,*) '      light penetration for ice-model LIM3     ln_qsr_ice = ', ln_qsr_ice
450         WRITE(numout,*) '      RGB : Chl data (=1/2) or cst value (=0)  nn_chldta  = ', nn_chldta
451         WRITE(numout,*) '      RGB & 2 bands: fraction of light (rn_si1)    rn_abs = ', rn_abs
452         WRITE(numout,*) '      RGB & 2 bands: shortess depth of extinction  rn_si0 = ', rn_si0
453         WRITE(numout,*) '      2 bands: longest depth of extinction         rn_si1 = ', rn_si1
454      ENDIF
455
456      IF( ln_traqsr ) THEN     ! control consistency
457         !                     
458         IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio )   THEN
459            CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' )
460            ln_qsr_bio = .FALSE.
461         ENDIF
462         !
463         ioptio = 0                      ! Parameter control
464         IF( ln_qsr_rgb  )   ioptio = ioptio + 1
465         IF( ln_qsr_2bd  )   ioptio = ioptio + 1
466         IF( ln_qsr_bio  )   ioptio = ioptio + 1
467         !
468         IF( ioptio /= 1 ) &
469            CALL ctl_stop( '          Choose ONE type of light penetration in namelist namtra_qsr',  &
470            &              ' 2 bands, 3 RGB bands or bio-model light penetration' )
471         !
472         IF( ln_qsr_rgb .AND. nn_chldta == 0 )   nqsr =  1 
473         IF( ln_qsr_rgb .AND. nn_chldta == 1 )   nqsr =  2
474         IF( ln_qsr_rgb .AND. nn_chldta == 2 )   nqsr =  3
475         IF( ln_qsr_2bd                      )   nqsr =  4
476         IF( ln_qsr_bio                      )   nqsr =  5
477         !
478         IF(lwp) THEN                   ! Print the choice
479            WRITE(numout,*)
480            IF( nqsr ==  1 )   WRITE(numout,*) '         R-G-B   light penetration - Constant Chlorophyll'
481            IF( nqsr ==  2 )   WRITE(numout,*) '         R-G-B   light penetration - 2D Chl data '
482            IF( nqsr ==  3 )   WRITE(numout,*) '         R-G-B   light penetration - 3D Chl data '
483            IF( nqsr ==  4 )   WRITE(numout,*) '         2 bands light penetration'
484            IF( nqsr ==  5 )   WRITE(numout,*) '         bio-model light penetration'
485         ENDIF
486         !
487      ENDIF
488      !                          ! ===================================== !
489      IF( ln_traqsr  ) THEN      !  Initialisation of Light Penetration  ! 
490         !                       ! ===================================== !
491         !
492         xsi0r = 1.e0 / rn_si0
493         xsi1r = 1.e0 / rn_si1
494         !                                ! ---------------------------------- !
495         IF( ln_qsr_rgb ) THEN            !  Red-Green-Blue light penetration  !
496            !                             ! ---------------------------------- !
497            !
498            CALL trc_oce_rgb( rkrgb )           !* tabulated attenuation coef.
499            !
500            !                                   !* level of light extinction
501            IF(  ln_sco ) THEN   ;   nksr = jpkm1
502            ELSE                 ;   nksr = trc_oce_ext_lev( r_si2, 0.33e2 )
503            ENDIF
504
505            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
506            !
507            IF( nn_chldta == 1  .OR. nn_chldta == 2 ) THEN           !* Chl data : set sf_chl structure
508               IF(lwp) WRITE(numout,*)
509               IF(lwp) WRITE(numout,*) '        Chlorophyll read in a file'
510               ALLOCATE( sf_chl(1), STAT=ierror )
511               IF( ierror > 0 ) THEN
512                  CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' )   ;   RETURN
513               ENDIF
514               ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1)   )
515               IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) )
516               !                                        ! fill sf_chl with sn_chl and control print
517               CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init',   &
518                  &                                         'Solar penetration function of read chlorophyll', 'namtra_qsr' )
519               !
520            ELSE                                !* constant Chl : compute once for all the distribution of light (etot3)
521               IF(lwp) WRITE(numout,*)
522               IF(lwp) WRITE(numout,*) '        Constant Chlorophyll concentration = 0.05'
523               IF( lk_vvl ) THEN                   ! variable volume
524                  IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
525               ELSE                                ! constant volume: computes one for all
526                  IF(lwp) WRITE(numout,*) '        fixed volume: light distribution computed one for all'
527                  !
528                  zchl = 0.05                                 ! constant chlorophyll
529                  irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 )
530                  zekb(:,:) = rkrgb(1,irgb)                   ! Separation in R-G-B depending of the chlorophyll
531                  zekg(:,:) = rkrgb(2,irgb)
532                  zekr(:,:) = rkrgb(3,irgb)
533                  !
534                  zcoef = ( 1. - rn_abs ) / 3.e0              ! equi-partition in R-G-B
535                  ze0(:,:,1) = rn_abs
536                  ze1(:,:,1) = zcoef
537                  ze2(:,:,1) = zcoef 
538                  ze3(:,:,1) = zcoef
539                  zea(:,:,1) = tmask(:,:,1)                   ! = ( ze0+ze1+z2+ze3 ) * tmask
540               
541                  DO jk = 2, nksr+1
542!CDIR NOVERRCHK
543                     DO jj = 1, jpj
544!CDIR NOVERRCHK   
545                        DO ji = 1, jpi
546                           zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r     )
547                           zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) )
548                           zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) )
549                           zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) )
550                           ze0(ji,jj,jk) = zc0
551                           ze1(ji,jj,jk) = zc1
552                           ze2(ji,jj,jk) = zc2
553                           ze3(ji,jj,jk) = zc3
554                           zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk)
555                        END DO
556                     END DO
557                  END DO 
558                  !
559                  DO jk = 1, nksr
560                     ! (ISF) no light penetration below the ice shelves
561                     etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1)
562                  END DO
563                  etot3(:,:,nksr+1:jpk) = 0.e0                ! below 400m set to zero
564               ENDIF
565            ENDIF
566            !
567         ENDIF
568            !                             ! ---------------------------------- !
569         IF( ln_qsr_2bd ) THEN            !    2 bands    light penetration    !
570            !                             ! ---------------------------------- !
571            !
572            !                                ! level of light extinction
573            nksr = trc_oce_ext_lev( rn_si1, 1.e2 )
574            IF(lwp) THEN
575               WRITE(numout,*)
576            IF(lwp) WRITE(numout,*) '        level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m'
577            ENDIF
578            !
579            IF( lk_vvl ) THEN                   ! variable volume
580               IF(lwp) WRITE(numout,*) '        key_vvl: light distribution will be computed at each time step'
581            ELSE                                ! constant volume: computes one for all
582               zz0 =        rn_abs   * r1_rau0_rcp
583               zz1 = ( 1. - rn_abs ) * r1_rau0_rcp
584               DO jk = 1, nksr                    !*  solar heat absorbed at T-point computed once for all
585                  DO jj = 1, jpj                              ! top 400 meters
586                     DO ji = 1, jpi
587                        zc0 = zz0 * EXP( -fsdepw(ji,jj,jk  )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk  )*xsi1r )
588                        zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r )
589                        etot3(ji,jj,jk) = (  zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1)  ) * tmask(ji,jj,1) 
590                     END DO
591                  END DO
592               END DO
593               etot3(:,:,nksr+1:jpk) = 0.e0                   ! below 400m set to zero
594               !
595            ENDIF
596         ENDIF
597         !                       ! ===================================== !
598      ELSE                       !        No light penetration           !                   
599         !                       ! ===================================== !
600         IF(lwp) THEN
601            WRITE(numout,*)
602            WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration'
603            WRITE(numout,*) '~~~~~~~~~~~~'
604         ENDIF
605      ENDIF
606      !
607      ! initialisation of fraqsr_1lev used in sbcssm
608      IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN
609         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev'  , fraqsr_1lev  )
610      ELSE
611         fraqsr_1lev(:,:) = 1._wp   ! default definition
612      ENDIF
613      !
614      CALL wrk_dealloc( jpi, jpj,      zekb, zekg, zekr        ) 
615      CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) 
616      !
617      IF( nn_timing == 1 )  CALL timing_stop('tra_qsr_init')
618      !
619   END SUBROUTINE tra_qsr_init
620
621   !!======================================================================
622END MODULE traqsr
Note: See TracBrowser for help on using the repository browser.