source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 9321

Last change on this file since 9321 was 9321, checked in by davestorkey, 3 years ago

UKMO/dev_r5518_GO6_package branch: allow timing of I/O and coupling only.
See GMED ticket 374.

File size: 40.9 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48#if defined key_nemocice_decomp
49   USE ice_domain_size, only: nx_global, ny_global
50#endif
51   USE tideini         ! tidal components initialization   (tide_ini routine)
52   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
53   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
54   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
55   USE istate          ! initial state setting          (istate_init routine)
56   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
57   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
58   USE zdfini          ! vertical physics setting          (zdf_init routine)
59   USE phycst          ! physical constant                  (par_cst routine)
60   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
61   USE asminc          ! assimilation increments     
62   USE asmbkg          ! writing out state trajectory
63   USE diaptr          ! poleward transports           (dia_ptr_init routine)
64   USE diadct          ! sections transports           (dia_dct_init routine)
65   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
66   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
67   USE step            ! NEMO time-stepping                 (stp     routine)
68   USE icbini          ! handle bergs, initialisation
69   USE icbstp          ! handle bergs, calving, themodynamics and transport
70   USE sbccpl 
71   USE cpl_oasis3      ! OASIS3 coupling
72   USE c1d             ! 1D configuration
73   USE step_c1d        ! Time stepping loop for the 1D configuration
74   USE dyndmp          ! Momentum damping
75#if defined key_top
76   USE trcini          ! passive tracer initialisation
77   USE trc, ONLY: numstr  ! tracer stats unit number
78#endif
79   USE lib_mpp         ! distributed memory computing
80#if defined key_iomput
81   USE xios
82#endif
83   USE sbctide, ONLY: lk_tide
84   USE crsini          ! initialise grid coarsening utility
85   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
86   USE sbc_oce, ONLY: lk_oasis
87   USE stopar
88   USE stopts
89
90   IMPLICIT NONE
91   PRIVATE
92
93   PUBLIC   nemo_gcm    ! called by model.F90
94   PUBLIC   nemo_init   ! needed by AGRIF
95   PUBLIC   nemo_alloc  ! needed by TAM
96
97   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
98
99   !!----------------------------------------------------------------------
100   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
101   !! $Id$
102   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
103   !!----------------------------------------------------------------------
104CONTAINS
105
106   SUBROUTINE nemo_gcm
107      !!----------------------------------------------------------------------
108      !!                     ***  ROUTINE nemo_gcm  ***
109      !!
110      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
111      !!              curvilinear mesh on the sphere.
112      !!
113      !! ** Method  : - model general initialization
114      !!              - launch the time-stepping (stp routine)
115      !!              - finalize the run by closing files and communications
116      !!
117      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
118      !!              Madec, 2008, internal report, IPSL.
119      !!----------------------------------------------------------------------
120      INTEGER ::   istp       ! time step index
121      !!----------------------------------------------------------------------
122      !
123#if defined key_agrif
124      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
125#endif
126
127      !                            !-----------------------!
128      CALL nemo_init               !==  Initialisations  ==!
129      !                            !-----------------------!
130#if defined key_agrif
131      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
132      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
133# if defined key_top
134      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
135# endif
136# if defined key_lim2
137      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
138# endif
139#endif
140      ! check that all process are still there... If some process have an error,
141      ! they will never enter in step and other processes will wait until the end of the cpu time!
142      IF( lk_mpp )   CALL mpp_max( nstop )
143
144      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
145
146      !                            !-----------------------!
147      !                            !==   time stepping   ==!
148      !                            !-----------------------!
149      istp = nit000
150#if defined key_c1d
151         DO WHILE ( istp <= nitend .AND. nstop == 0 )
152            CALL stp_c1d( istp )
153            istp = istp + 1
154         END DO
155#else
156          IF( lk_asminc ) THEN
157             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
158             IF( ln_asmdin ) THEN                        ! Direct initialization
159                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
160                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
161                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
162             ENDIF
163          ENDIF
164
165#if defined key_agrif
166          CALL Agrif_Regrid()
167#endif
168
169         DO WHILE ( istp <= nitend .AND. nstop == 0 )
170#if defined key_agrif
171            CALL stp                         ! AGRIF: time stepping
172#else
173            IF (lk_oasis) CALL sbc_cpl_snd( istp )  ! Coupling to atmos
174       CALL stp( istp )
175            ! We don't couple on the final timestep because
176            ! our restart file has already been written
177            ! and contains all the necessary data for a
178            ! restart. sbc_cpl_snd could be called here
179            ! but it would require
180            ! a) A test to ensure it was not performed
181            !    on the very last time-step
182            ! b) the presence of another call to
183            !    sbc_cpl_snd call prior to the main DO loop
184            ! This solution produces identical results
185            ! with fewer lines of code.
186#endif
187            istp = istp + 1
188            IF( lk_mpp )   CALL mpp_max( nstop )
189         END DO
190#endif
191
192      IF( lk_diaobs   )   CALL dia_obs_wri
193      !
194      IF( ln_icebergs )   CALL icb_end( nitend )
195
196      !                            !------------------------!
197      !                            !==  finalize the run  ==!
198      !                            !------------------------!
199      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
200      !
201      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
202         WRITE(numout,cform_err)
203         WRITE(numout,*) nstop, ' error have been found'
204      ENDIF
205      !
206#if defined key_agrif
207      IF( .NOT. Agrif_Root() ) THEN
208         CALL Agrif_ParentGrid_To_ChildGrid()
209         IF( lk_diaobs ) CALL dia_obs_wri
210         IF( nn_timing > 0 )   CALL timing_finalize
211         CALL Agrif_ChildGrid_To_ParentGrid()
212      ENDIF
213#endif
214      IF( nn_timing > 0 )   CALL timing_finalize
215      !
216      CALL nemo_closefile
217      !
218#if defined key_iomput
219      CALL xios_finalize                ! end mpp communications with xios
220      IF( lk_oasis ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
221#else
222      IF( lk_oasis ) THEN
223         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
224      ELSE
225         IF( lk_mpp )   CALL mppstop    ! end mpp communications
226      ENDIF
227#endif
228      !
229      ! Met Office addition: if failed, return non-zero exit code
230      IF( nstop /= 0 )  CALL exit( 9 ) 
231      !
232   END SUBROUTINE nemo_gcm
233
234
235   SUBROUTINE nemo_init
236      !!----------------------------------------------------------------------
237      !!                     ***  ROUTINE nemo_init  ***
238      !!
239      !! ** Purpose :   initialization of the NEMO GCM
240      !!----------------------------------------------------------------------
241      INTEGER ::   ji            ! dummy loop indices
242      INTEGER ::   ilocal_comm   ! local integer
243      INTEGER ::   ios
244      CHARACTER(len=80), DIMENSION(16) ::   cltxt
245      !
246      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
247         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
248         &             nn_bench, nn_timing
249      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
250         &             jpizoom, jpjzoom, jperio, ln_use_jattr
251      !!----------------------------------------------------------------------
252      !
253      cltxt = ''
254      cxios_context = 'nemo'
255      !
256      !                             ! Open reference namelist and configuration namelist files
257      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
258      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
259      !
260      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
261      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
262901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
263
264      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
265      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
266902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
267
268      !
269      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
270      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
271903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
272
273      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
274      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
275904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
276
277! Force values for AGRIF zoom (cf. agrif_user.F90)
278#if defined key_agrif
279   IF( .NOT. Agrif_Root() ) THEN
280      jpiglo  = nbcellsx + 2 + 2*nbghostcells
281      jpjglo  = nbcellsy + 2 + 2*nbghostcells
282      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
283      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
284      jpidta  = jpiglo
285      jpjdta  = jpjglo
286      jpizoom = 1
287      jpjzoom = 1
288      nperio  = 0
289      jperio  = 0
290      ln_use_jattr = .false.
291   ENDIF
292#endif
293      !
294      !                             !--------------------------------------------!
295      !                             !  set communicator & select the local node  !
296      !                             !  NB: mynode also opens output.namelist.dyn !
297      !                             !      on unit number numond on first proc   !
298      !                             !--------------------------------------------!
299#if defined key_iomput
300      IF( Agrif_Root() ) THEN
301         IF( lk_oasis ) THEN
302            CALL cpl_init( "toyoce", ilocal_comm )                     ! nemo local communicator given by oasis
303            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
304         ELSE
305            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
306         ENDIF
307      ENDIF
308      ! Nodes selection (control print return in cltxt)
309      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
310#else
311      IF( lk_oasis ) THEN
312         IF( Agrif_Root() ) THEN
313            CALL cpl_init( "toyoce", ilocal_comm )                      ! nemo local communicator given by oasis
314         ENDIF
315         ! Nodes selection (control print return in cltxt)
316         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
317      ELSE
318         ilocal_comm = 0
319         ! Nodes selection (control print return in cltxt)
320         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
321      ENDIF
322#endif
323      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
324
325      lwm = (narea == 1)                                    ! control of output namelists
326      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
327
328      IF(lwm) THEN
329         ! write merged namelists from earlier to output namelist now that the
330         ! file has been opened in call to mynode. nammpp has already been
331         ! written in mynode (if lk_mpp_mpi)
332         WRITE( numond, namctl )
333         WRITE( numond, namcfg )
334      ENDIF
335
336      ! If dimensions of processor grid weren't specified in the namelist file
337      ! then we calculate them here now that we have our communicator size
338      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
339#if   defined key_mpp_mpi
340         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
341#else
342         jpni  = 1
343         jpnj  = 1
344         jpnij = jpni*jpnj
345#endif
346      END IF
347
348      ! Calculate domain dimensions given calculated jpni and jpnj
349      ! This used to be done in par_oce.F90 when they were parameters rather
350      ! than variables
351      IF( Agrif_Root() ) THEN
352#if defined key_nemocice_decomp
353         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
354         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
355#else
356         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
357         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
358#endif
359      ENDIF         
360         jpk = jpkdta                                             ! third dim
361#if defined key_agrif
362         ! simple trick to use same vertical grid as parent
363         ! but different number of levels:
364         ! Save maximum number of levels in jpkdta, then define all vertical grids
365         ! with this number.
366         ! Suppress once vertical online interpolation is ok
367         IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
368#endif
369         jpim1 = jpi-1                                            ! inner domain indices
370         jpjm1 = jpj-1                                            !   "           "
371         jpkm1 = jpk-1                                            !   "           "
372         jpij  = jpi*jpj                                          !  jpi x j
373
374      IF(lwp) THEN                            ! open listing units
375         !
376         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
377         !
378         WRITE(numout,*)
379         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
380         WRITE(numout,*) '                       NEMO team'
381         WRITE(numout,*) '            Ocean General Circulation Model'
382         WRITE(numout,*) '                  version 3.6  (2015) '
383         WRITE(numout,*)
384         WRITE(numout,*)
385         DO ji = 1, SIZE(cltxt)
386            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
387         END DO
388         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
389         !
390      ENDIF
391
392      ! Now we know the dimensions of the grid and numout has been set we can
393      ! allocate arrays
394      CALL nemo_alloc()
395
396      !                             !-------------------------------!
397      !                             !  NEMO general initialization  !
398      !                             !-------------------------------!
399
400      CALL nemo_ctl                          ! Control prints & Benchmark
401
402      !                                      ! Domain decomposition
403      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
404      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
405      ENDIF
406      !
407      IF( nn_timing > 0 )  CALL timing_init
408      !
409      !                                      ! General initialization
410                            CALL     phy_cst    ! Physical constants
411                            CALL     eos_init   ! Equation of state
412      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
413                            CALL     dom_cfg    ! Domain configuration
414                            CALL     dom_init   ! Domain
415
416      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
417
418      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
419
420                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
421
422      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
423
424                            CALL     sbc_init   ! Forcings : surface module (clem: moved here for bdy purpose)
425
426      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
427      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
428      IF( lk_bdy .AND. lk_tide )   &
429         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
430
431                            CALL dyn_nept_init  ! simplified form of Neptune effect
432      !     
433      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
434      !
435                                ! Ocean physics
436      !                                         ! Vertical physics
437                            CALL     zdf_init      ! namelist read
438                            CALL zdf_bfr_init      ! bottom friction
439      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
440      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
441      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
442      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
443      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
444      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
445         &                  CALL zdf_ddm_init      ! double diffusive mixing
446      !                                         ! Lateral physics
447                            CALL ldf_tra_init      ! Lateral ocean tracer physics
448                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
449      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
450
451      !                                     ! Active tracers
452                            CALL tra_qsr_init   ! penetrative solar radiation qsr
453                            CALL tra_bbc_init   ! bottom heat flux
454      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
455                            CALL tra_dmp_init   ! internal damping trends- tracers
456                            CALL tra_adv_init   ! horizontal & vertical advection
457                            CALL tra_ldf_init   ! lateral mixing
458                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
459
460      !                                     ! Dynamics
461      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
462                            CALL dyn_adv_init   ! advection (vector or flux form)
463                            CALL dyn_vor_init   ! vorticity term including Coriolis
464                            CALL dyn_ldf_init   ! lateral mixing
465                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
466                            CALL dyn_zdf_init   ! vertical diffusion
467                            CALL dyn_spg_init   ! surface pressure gradient
468
469      !                                     ! Misc. options
470      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
471                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
472                            CALL sto_par_init   ! Stochastic parametrization
473      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
474     
475#if defined key_top
476      !                                     ! Passive tracers
477                            CALL     trc_init
478#endif
479      !                                     ! Diagnostics
480      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
481                            CALL dia_ptr_init   ! Poleward TRansports initialization
482      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
483                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
484                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
485                            CALL     bias_init  ! Pressure correction bias
486      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
487                            CALL dia_obs_init            ! Initialize observational data
488                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
489      ENDIF
490
491      !                                     ! Assimilation increments
492      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
493      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
494     
495      IF (nstop > 0) THEN
496        CALL CTL_STOP('STOP','Critical errors in NEMO initialisation')
497      END IF
498
499      !
500   END SUBROUTINE nemo_init
501
502
503   SUBROUTINE nemo_ctl
504      !!----------------------------------------------------------------------
505      !!                     ***  ROUTINE nemo_ctl  ***
506      !!
507      !! ** Purpose :   control print setting
508      !!
509      !! ** Method  : - print namctl information and check some consistencies
510      !!----------------------------------------------------------------------
511      !
512      IF(lwp) THEN                  ! control print
513         WRITE(numout,*)
514         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
515         WRITE(numout,*) '~~~~~~~ '
516         WRITE(numout,*) '   Namelist namctl'
517         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
518         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
519         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
520         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
521         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
522         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
523         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
524         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
525         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
526         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
527      ENDIF
528      !
529      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
530      nictls    = nn_ictls
531      nictle    = nn_ictle
532      njctls    = nn_jctls
533      njctle    = nn_jctle
534      isplt     = nn_isplt
535      jsplt     = nn_jsplt
536      nbench    = nn_bench
537
538      IF(lwp) THEN                  ! control print
539         WRITE(numout,*)
540         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
541         WRITE(numout,*) '~~~~~~~ '
542         WRITE(numout,*) '   Namelist namcfg'
543         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
544         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
545         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
546         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
547         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
548         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
549         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
550         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
551         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
552         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
553         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
554         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
555      ENDIF
556      !                             ! Parameter control
557      !
558      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
559         IF( lk_mpp .AND. jpnij > 1 ) THEN
560            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
561         ELSE
562            IF( isplt == 1 .AND. jsplt == 1  ) THEN
563               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
564                  &           ' - the print control will be done over the whole domain' )
565            ENDIF
566            ijsplt = isplt * jsplt            ! total number of processors ijsplt
567         ENDIF
568         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
569         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
570         !
571         !                              ! indices used for the SUM control
572         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
573            lsp_area = .FALSE.
574         ELSE                                             ! print control done over a specific  area
575            lsp_area = .TRUE.
576            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
577               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
578               nictls = 1
579            ENDIF
580            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
581               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
582               nictle = jpiglo
583            ENDIF
584            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
585               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
586               njctls = 1
587            ENDIF
588            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
589               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
590               njctle = jpjglo
591            ENDIF
592         ENDIF
593      ENDIF
594      !
595      IF( nbench == 1 ) THEN              ! Benchmark
596         SELECT CASE ( cp_cfg )
597         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
598         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
599            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
600         END SELECT
601      ENDIF
602      !
603      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
604         &                                               'f2003 standard. '                              ,  &
605         &                                               'Compile with key_nosignedzero enabled' )
606      !
607   END SUBROUTINE nemo_ctl
608
609
610   SUBROUTINE nemo_closefile
611      !!----------------------------------------------------------------------
612      !!                     ***  ROUTINE nemo_closefile  ***
613      !!
614      !! ** Purpose :   Close the files
615      !!----------------------------------------------------------------------
616      !
617      IF( lk_mpp )   CALL mppsync
618      !
619      CALL iom_close                                 ! close all input/output files managed by iom_*
620      !
621      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
622      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
623      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
624      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
625      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
626      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
627      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
628      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
629      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
630      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
631      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
632      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
633      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
634#if defined key_top
635      IF( numstr          /= -1 )   CLOSE( numstr          )   ! tracer statistics
636#endif
637      !
638      numout = 6                                     ! redefine numout in case it is used after this point...
639      !
640   END SUBROUTINE nemo_closefile
641
642
643   SUBROUTINE nemo_alloc
644      !!----------------------------------------------------------------------
645      !!                     ***  ROUTINE nemo_alloc  ***
646      !!
647      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
648      !!
649      !! ** Method  :
650      !!----------------------------------------------------------------------
651      USE diawri    , ONLY: dia_wri_alloc
652      USE insitu_tem, ONLY: insitu_tem_alloc
653      USE dom_oce   , ONLY: dom_oce_alloc
654      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
655      USE ldftra_oce, ONLY: ldftra_oce_alloc
656      USE trc_oce   , ONLY: trc_oce_alloc
657#if defined key_diadct 
658      USE diadct    , ONLY: diadct_alloc 
659#endif 
660#if defined key_bdy
661      USE bdy_oce   , ONLY: bdy_oce_alloc
662#endif
663      !
664      INTEGER :: ierr
665      !!----------------------------------------------------------------------
666      !
667      ierr =        oce_alloc       ()          ! ocean
668      ierr = ierr + dia_wri_alloc   ()
669      ierr = ierr + insitu_tem_alloc()
670      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
671      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
672      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
673      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
674      !
675      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
676      !
677#if defined key_diadct 
678      ierr = ierr + diadct_alloc    ()          !
679#endif 
680#if defined key_bdy
681      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
682#endif
683      !
684      IF( lk_mpp    )   CALL mpp_sum( ierr )
685      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
686      !
687   END SUBROUTINE nemo_alloc
688
689
690   SUBROUTINE nemo_partition( num_pes )
691      !!----------------------------------------------------------------------
692      !!                 ***  ROUTINE nemo_partition  ***
693      !!
694      !! ** Purpose :
695      !!
696      !! ** Method  :
697      !!----------------------------------------------------------------------
698      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
699      !
700      INTEGER, PARAMETER :: nfactmax = 20
701      INTEGER :: nfact ! The no. of factors returned
702      INTEGER :: ierr  ! Error flag
703      INTEGER :: ji
704      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
705      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
706      !!----------------------------------------------------------------------
707      !
708      ierr = 0
709      !
710      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
711      !
712      IF( nfact <= 1 ) THEN
713         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
714         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
715         jpnj = 1
716         jpni = num_pes
717      ELSE
718         ! Search through factors for the pair that are closest in value
719         mindiff = 1000000
720         imin    = 1
721         DO ji = 1, nfact-1, 2
722            idiff = ABS( ifact(ji) - ifact(ji+1) )
723            IF( idiff < mindiff ) THEN
724               mindiff = idiff
725               imin = ji
726            ENDIF
727         END DO
728         jpnj = ifact(imin)
729         jpni = ifact(imin + 1)
730      ENDIF
731      !
732      jpnij = jpni*jpnj
733      !
734   END SUBROUTINE nemo_partition
735
736
737   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
738      !!----------------------------------------------------------------------
739      !!                     ***  ROUTINE factorise  ***
740      !!
741      !! ** Purpose :   return the prime factors of n.
742      !!                knfax factors are returned in array kfax which is of
743      !!                maximum dimension kmaxfax.
744      !! ** Method  :
745      !!----------------------------------------------------------------------
746      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
747      INTEGER                    , INTENT(  out) ::   kerr, knfax
748      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
749      !
750      INTEGER :: ifac, jl, inu
751      INTEGER, PARAMETER :: ntest = 14
752      INTEGER, DIMENSION(ntest) :: ilfax
753      !
754      ! ilfax contains the set of allowed factors.
755      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
756      !!----------------------------------------------------------------------
757      ! ilfax contains the set of allowed factors.
758      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
759
760      ! Clear the error flag and initialise output vars
761      kerr = 0
762      kfax = 1
763      knfax = 0
764
765      ! Find the factors of n.
766      IF( kn == 1 )   GOTO 20
767
768      ! nu holds the unfactorised part of the number.
769      ! knfax holds the number of factors found.
770      ! l points to the allowed factor list.
771      ! ifac holds the current factor.
772
773      inu   = kn
774      knfax = 0
775
776      DO jl = ntest, 1, -1
777         !
778         ifac = ilfax(jl)
779         IF( ifac > inu )   CYCLE
780
781         ! Test whether the factor will divide.
782
783         IF( MOD(inu,ifac) == 0 ) THEN
784            !
785            knfax = knfax + 1            ! Add the factor to the list
786            IF( knfax > kmaxfax ) THEN
787               kerr = 6
788               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
789               return
790            ENDIF
791            kfax(knfax) = ifac
792            ! Store the other factor that goes with this one
793            knfax = knfax + 1
794            kfax(knfax) = inu / ifac
795            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
796         ENDIF
797         !
798      END DO
799
800   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
801      !
802   END SUBROUTINE factorise
803
804#if defined key_mpp_mpi
805
806   SUBROUTINE nemo_northcomms
807      !!======================================================================
808      !!                     ***  ROUTINE  nemo_northcomms  ***
809      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
810      !!                       point-to-point messaging
811      !!=====================================================================
812      !!----------------------------------------------------------------------
813      !!
814      !! ** Purpose :   Initialization of the northern neighbours lists.
815      !!----------------------------------------------------------------------
816      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
817      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
818      !!----------------------------------------------------------------------
819
820      INTEGER  ::   sxM, dxM, sxT, dxT, jn
821      INTEGER  ::   njmppmax
822
823      njmppmax = MAXVAL( njmppt )
824   
825      !initializes the north-fold communication variables
826      isendto(:) = 0
827      nsndto = 0
828
829      !if I am a process in the north
830      IF ( njmpp == njmppmax ) THEN
831          !sxM is the first point (in the global domain) needed to compute the
832          !north-fold for the current process
833          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
834          !dxM is the last point (in the global domain) needed to compute the
835          !north-fold for the current process
836          dxM = jpiglo - nimppt(narea) + 2
837
838          !loop over the other north-fold processes to find the processes
839          !managing the points belonging to the sxT-dxT range
840 
841          DO jn = 1, jpni
842                !sxT is the first point (in the global domain) of the jn
843                !process
844                sxT = nfiimpp(jn, jpnj)
845                !dxT is the last point (in the global domain) of the jn
846                !process
847                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
848                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
849                   nsndto = nsndto + 1
850                     isendto(nsndto) = jn
851                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
852                   nsndto = nsndto + 1
853                     isendto(nsndto) = jn
854                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
855                   nsndto = nsndto + 1
856                     isendto(nsndto) = jn
857                END IF
858          END DO
859          nfsloop = 1
860          nfeloop = nlci
861          DO jn = 2,jpni-1
862           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
863              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
864                 nfsloop = nldi
865              ENDIF
866              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
867                 nfeloop = nlei
868              ENDIF
869           ENDIF
870        END DO
871
872      ENDIF
873      l_north_nogather = .TRUE.
874   END SUBROUTINE nemo_northcomms
875#else
876   SUBROUTINE nemo_northcomms      ! Dummy routine
877      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
878   END SUBROUTINE nemo_northcomms
879#endif
880
881   !!======================================================================
882END MODULE nemogcm
883
884
Note: See TracBrowser for help on using the repository browser.