New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 6755

Last change on this file since 6755 was 6755, checked in by davestorkey, 8 years ago

UKMO/dev_r5518_GO6_package branch: Merge back changes from UKMO/dev_r5518_GO6_package_MEDUSA_temporary
Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6749 cf. r6618 of /branches/UKMO/dev_r5518_GO6_package_MEDUSA_temporary/NEMOGCM@6754

File size: 24.4 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!                 !  2012-07  (J. Simeon, G. Madec, C. Ethe) Online coarsening of outputs
27   !!            3.7  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!----------------------------------------------------------------------
29
30   !!----------------------------------------------------------------------
31   !!   stp             : OPA system time-stepping
32   !!----------------------------------------------------------------------
33   USE step_oce         ! time stepping definition modules
34   USE iom
35   USE lbclnk
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   stp   ! called by opa.F90
41
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44!!gm   #  include "zdfddm_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52#if defined key_agrif
53   RECURSIVE SUBROUTINE stp( )
54      INTEGER             ::   kstp   ! ocean time-step index
55#else
56   SUBROUTINE stp( kstp )
57      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
58#endif
59      !!----------------------------------------------------------------------
60      !!                     ***  ROUTINE stp  ***
61      !!
62      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
63      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
64      !!              - Tme stepping  of TRC (passive tracer eqs.)
65      !!
66      !! ** Method  : -1- Update forcings and data
67      !!              -2- Update ocean physics
68      !!              -3- Compute the t and s trends
69      !!              -4- Update t and s
70      !!              -5- Compute the momentum trends
71      !!              -6- Update the horizontal velocity
72      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
73      !!              -8- Outputs and diagnostics
74      !!----------------------------------------------------------------------
75      INTEGER ::   jk       ! dummy loop indice
76      INTEGER ::   tind     ! tracer loop index
77      INTEGER ::   indic    ! error indicator if < 0
78      INTEGER ::   kcall    ! optional integer argument (dom_vvl_sf_nxt)
79      !! ---------------------------------------------------------------------
80
81#if defined key_agrif
82      kstp = nit000 + Agrif_Nb_Step()
83      IF ( lk_agrif_debug ) THEN
84         IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
85         IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp, 'int tstep',Agrif_NbStepint()
86      ENDIF
87
88      IF ( kstp == (nit000 + 1) ) lk_agrif_fstep = .FALSE.
89
90# if defined key_iomput
91      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
92# endif
93#endif
94                             indic = 0           ! reset to no error condition
95      IF( kstp == nit000 ) THEN
96         ! must be done after nemo_init for AGRIF+XIOS+OASIS
97                      CALL iom_init(      cxios_context          )  ! iom_put initialization
98         IF( ln_crs ) CALL iom_init( TRIM(cxios_context)//"_crs" )  ! initialize context for coarse grid
99      ENDIF
100
101      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
102                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell iom we are at time step kstp
103      IF( ln_crs     )       CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell iom we are at time step kstp
104
105      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
106      ! Update data, open boundaries, surface boundary condition (including sea-ice)
107      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
108      IF( lk_tide    )   CALL sbc_tide( kstp )
109      IF( lk_bdy     )  THEN
110         IF( ln_apr_dyn) CALL sbc_apr( kstp )   ! bdy_dta needs ssh_ib
111                         CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
112      ENDIF
113
114      ! We must ensure that tsb halos are up to date on EVERY timestep.
115      DO tind = 1, jpts
116         CALL lbc_lnk( tsb(:,:,:,tind), 'T', 1. )
117      END DO
118
119                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
120                                                      ! clem: moved here for bdy ice purpose
121      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
122      ! Update stochastic parameters and random T/S fluctuations
123      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
124       IF( ln_sto_eos ) CALL sto_par( kstp )          ! Stochastic parameters
125       IF( ln_sto_eos ) CALL sto_pts( tsn  )          ! Random T/S fluctuations
126
127      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
128      ! Ocean physics update                (ua, va, tsa used as workspace)
129      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
130      !  THERMODYNAMICS
131                         CALL eos_rab( tsb, rab_b )       ! before local thermal/haline expension ratio at T-points
132                         CALL eos_rab( tsn, rab_n )       ! now    local thermal/haline expension ratio at T-points
133                         CALL bn2    ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency
134                         CALL bn2    ( tsn, rab_n, rn2  ) ! now    Brunt-Vaisala frequency
135      !
136      !  VERTICAL PHYSICS
137                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
138      !                                               ! Vertical eddy viscosity and diffusivity coefficients
139      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
140      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
141      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
142      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
143      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
144         avt (:,:,:) = rn_avt0 * wmask (:,:,:)
145         avmu(:,:,:) = rn_avm0 * wumask(:,:,:)
146         avmv(:,:,:) = rn_avm0 * wvmask(:,:,:)
147      ENDIF
148      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
149         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
150      ENDIF
151      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
152
153      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
154
155      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
156         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
157
158                         CALL zdf_mxl( kstp )         ! mixed layer depth
159
160                                                      ! write TKE or GLS information in the restart file
161      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
162      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
163      !
164      !  LATERAL  PHYSICS
165      !
166      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
167                         CALL eos( tsb, rhd, gdept_0(:,:,:) )               ! before in situ density
168         IF( ln_zps .AND. .NOT. ln_isfcav)                               &
169            &            CALL zps_hde    ( kstp, jpts, tsb, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
170            &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
171         IF( ln_zps .AND.       ln_isfcav)                               &
172            &            CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
173            &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
174            &                                   gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the first ocean level
175         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
176                         CALL ldf_slp_grif( kstp )
177         ELSE
178                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
179         ENDIF
180      ENDIF
181#if defined key_traldf_c2d
182      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
183#endif
184#if defined key_traldf_c3d && defined key_traldf_smag
185                          CALL ldf_tra_smag( kstp )      ! eddy induced velocity coefficient
186#  endif
187#if defined key_dynldf_c3d && defined key_dynldf_smag
188                          CALL ldf_dyn_smag( kstp )      ! eddy induced velocity coefficient
189#  endif
190
191      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
192      !  Ocean dynamics : hdiv, rot, ssh, e3, wn
193      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
194                         CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_cur)
195      IF( lk_vvl     )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
196                         CALL wzv           ( kstp )  ! now cross-level velocity
197
198      IF( lk_dynspg_ts ) THEN 
199          ! In case the time splitting case, update almost all momentum trends here:
200          ! Note that the computation of vertical velocity above, hence "after" sea level
201          ! is necessary to compute momentum advection for the rhs of barotropic loop:
202                            CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation
203            IF( ln_zps .AND. .NOT. ln_isfcav)                               &
204               &            CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
205               &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
206            IF( ln_zps .AND.       ln_isfcav)                               &
207               &            CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
208               &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
209               &                                   gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
210
211                                  ua(:,:,:) = 0.e0             ! set dynamics trends to zero
212                                  va(:,:,:) = 0.e0
213          IF(  lk_asminc .AND. ln_asmiau .AND. &
214             & ln_dyninc       )  CALL dyn_asm_inc  ( kstp )   ! apply dynamics assimilation increment
215          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! subtract Neptune velocities (simplified)
216          IF( lk_bdy           )  CALL bdy_dyn3d_dmp( kstp )   ! bdy damping trends
217                                  CALL dyn_adv      ( kstp )   ! advection (vector or flux form)
218                                  CALL dyn_vor      ( kstp )   ! vorticity term including Coriolis
219                                  CALL dyn_ldf      ( kstp )   ! lateral mixing
220          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! add Neptune velocities (simplified)
221#if defined key_agrif
222          IF(.NOT. Agrif_Root())  CALL Agrif_Sponge_dyn        ! momentum sponge
223#endif
224                                  CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
225                                  CALL dyn_spg( kstp, indic )  ! surface pressure gradient
226
227                                  ua_sv(:,:,:) = ua(:,:,:)     ! Save trends (barotropic trend has been fully updated at this stage)
228                                  va_sv(:,:,:) = va(:,:,:)
229
230                                  CALL div_cur( kstp )         ! Horizontal divergence & Relative vorticity (2nd call in time-split case)
231          IF( lk_vvl     )        CALL dom_vvl_sf_nxt( kstp, kcall=2 )  ! after vertical scale factors (update depth average component)
232                                  CALL wzv           ( kstp )  ! now cross-level velocity
233      ENDIF
234
235      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
236      ! diagnostics and outputs             (ua, va, tsa used as workspace)
237      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
238      IF( lk_floats  )      CALL flo_stp( kstp )         ! drifting Floats
239      IF( lk_diahth  )      CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
240      IF( .NOT. ln_cpl )    CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
241      IF( lk_diadct  )      CALL dia_dct( kstp )         ! Transports
242      IF( lk_diaar5  )      CALL dia_ar5( kstp )         ! ar5 diag
243      IF( lk_diaharm )      CALL dia_harm( kstp )        ! Tidal harmonic analysis
244                            CALL dia_prod( kstp )        ! ocean model: product diagnostics
245                            CALL dia_wri( kstp )         ! ocean model: outputs
246      !
247      IF( ln_crs     )      CALL crs_fld( kstp )         ! ocean model: online field coarsening & output
248
249#if defined key_top
250      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
251      ! Passive Tracer Model
252      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
253                         CALL trc_stp( kstp )         ! time-stepping
254#endif
255
256
257      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
258      ! Active tracers                              (ua, va used as workspace)
259      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
260                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
261
262      IF(  lk_asminc .AND. ln_asmiau .AND. &
263         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
264                             CALL tra_sbc    ( kstp )       ! surface boundary condition
265      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
266      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
267      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
268      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
269      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
270                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
271      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
272                             CALL tra_ldf    ( kstp )       ! lateral mixing
273
274      IF( ln_diaptr      )   CALL dia_ptr                   ! Poleward adv/ldf TRansports diagnostics
275
276#if defined key_agrif
277      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
278#endif
279                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
280
281      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
282         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
283                             CALL tra_nxt( kstp )                ! tracer fields at next time step
284                             CALL eos    ( tsa, rhd, rhop, fsdept_n(:,:,:) )  ! Time-filtered in situ density for hpg computation
285            IF( ln_zps .AND. .NOT. ln_isfcav)                                &
286               &             CALL zps_hde    ( kstp, jpts, tsa, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
287               &                                           rhd, gru , grv    )  ! of t, s, rd at the last ocean level
288            IF( ln_zps .AND.       ln_isfcav)                                &
289               &             CALL zps_hde_isf( kstp, jpts, tsa, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
290               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
291               &                                    gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
292      ELSE                                                  ! centered hpg  (eos then time stepping)
293         IF ( .NOT. lk_dynspg_ts ) THEN                     ! eos already called in time-split case
294                             CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )  ! now in situ density for hpg computation
295         IF( ln_zps .AND. .NOT. ln_isfcav)                                   &
296               &             CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
297               &                                           rhd, gru , grv    )  ! of t, s, rd at the last ocean level
298         IF( ln_zps .AND.       ln_isfcav)                                   & 
299               &             CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
300               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
301               &                                    gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
302         ENDIF
303         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
304                             CALL tra_nxt( kstp )                ! tracer fields at next time step
305      ENDIF
306
307      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
308      ! Dynamics                                    (tsa used as workspace)
309      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
310      IF( lk_dynspg_ts   )  THEN
311                                                             ! revert to previously computed momentum tendencies
312                                                             ! (not using ua, va as temporary arrays during tracers' update could avoid that)
313                               ua(:,:,:) = ua_sv(:,:,:)
314                               va(:,:,:) = va_sv(:,:,:)
315                                                             ! Revert now divergence and rotational to previously computed ones
316                                                             !(needed because of the time swap in div_cur, at the beginning of each time step)
317                               hdivn(:,:,:) = hdivb(:,:,:)
318                               rotn(:,:,:)  = rotb(:,:,:) 
319
320                               CALL dyn_bfr( kstp )         ! bottom friction
321                               CALL dyn_zdf( kstp )         ! vertical diffusion
322      ELSE
323                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
324                               va(:,:,:) = 0.e0
325
326        IF(  lk_asminc .AND. ln_asmiau .AND. &
327           & ln_dyninc      )  CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
328        IF( ln_bkgwri )        CALL asm_bkg_wri( kstp )     ! output background fields
329        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
330        IF( lk_bdy          )  CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
331                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
332                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
333                               CALL dyn_ldf( kstp )         ! lateral mixing
334        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
335#if defined key_agrif
336        IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn        ! momemtum sponge
337#endif
338                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
339                               CALL dyn_bfr( kstp )         ! bottom friction
340                               CALL dyn_zdf( kstp )         ! vertical diffusion
341                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
342      ENDIF
343                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
344
345                               CALL ssh_swp( kstp )         ! swap of sea surface height
346      IF( lk_vvl           )   CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
347      !
348      IF( lrst_oce         )   CALL rst_write( kstp )       ! write output ocean restart file
349      IF( ln_sto_eos       )   CALL sto_rst_write( kstp )   ! write restart file for stochastic parameters
350
351#if defined key_agrif
352      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
353      ! AGRIF
354      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
355                               CALL Agrif_Integrate_ChildGrids( stp ) 
356
357      IF ( Agrif_NbStepint().EQ.0 ) THEN
358                               CALL Agrif_Update_Tra()      ! Update active tracers
359                               CALL Agrif_Update_Dyn()      ! Update momentum
360      ENDIF
361#endif
362      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
363      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
364
365      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
366      ! Control
367      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
368                               CALL stp_ctl( kstp, indic )
369      IF( indic < 0        )   THEN
370                               CALL ctl_stop( 'step: indic < 0' )
371                               CALL dia_wri_state( 'output.abort', kstp )
372      ENDIF
373      IF( kstp == nit000   )   THEN
374                 CALL iom_close( numror )     ! close input  ocean restart file
375         IF(lwm) CALL FLUSH    ( numond )     ! flush output namelist oce
376         IF( lwm.AND.numoni /= -1 ) CALL FLUSH    ( numoni )     ! flush output namelist ice
377      ENDIF
378
379      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
380      ! Coupled mode
381      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
382      IF( lk_oasis         )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
383      !
384#if defined key_iomput
385      IF( kstp == nitend .OR. indic < 0 ) THEN
386                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
387         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
388      ENDIF
389#endif
390      !
391      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
392      !     
393      !
394   END SUBROUTINE stp
395
396   !!======================================================================
397END MODULE step
Note: See TracBrowser for help on using the repository browser.