source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlim.F90 @ 8356

Last change on this file since 8356 was 8356, checked in by davestorkey, 3 years ago

UKMO/dev_r5518_GO6_package branch: merge in changes from rev 6917 to 6959 of the 3.6_stable branch.

File size: 15.7 KB
Line 
1MODULE p4zlim
2   !!======================================================================
3   !!                         ***  MODULE p4zlim  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-04  (O. Aumont, C. Ethe) Limitation for iron modelled in quota
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_lim        :   Compute the nutrients limitation terms
15   !!   p4z_lim_init   :   Read the namelist
16   !!----------------------------------------------------------------------
17   USE oce_trc         ! Shared ocean-passive tracers variables
18   USE trc             ! Tracers defined
19   USE sms_pisces      ! PISCES variables
20   USE p4zopt          ! Optical
21   USE iom             !  I/O manager
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC p4z_lim   
27   PUBLIC p4z_lim_init   
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC ::  concnno3    !:  NO3, PO4 half saturation   
31   REAL(wp), PUBLIC ::  concdno3    !:  Phosphate half saturation for diatoms 
32   REAL(wp), PUBLIC ::  concnnh4    !:  NH4 half saturation for phyto 
33   REAL(wp), PUBLIC ::  concdnh4    !:  NH4 half saturation for diatoms
34   REAL(wp), PUBLIC ::  concnfer    !:  Iron half saturation for nanophyto
35   REAL(wp), PUBLIC ::  concdfer    !:  Iron half saturation for diatoms 
36   REAL(wp), PUBLIC ::  concbno3    !:  NO3 half saturation  for bacteria
37   REAL(wp), PUBLIC ::  concbnh4    !:  NH4 half saturation for bacteria
38   REAL(wp), PUBLIC ::  xsizedia    !:  Minimum size criteria for diatoms
39   REAL(wp), PUBLIC ::  xsizephy    !:  Minimum size criteria for nanophyto
40   REAL(wp), PUBLIC ::  xsizern     !:  Size ratio for nanophytoplankton
41   REAL(wp), PUBLIC ::  xsizerd     !:  Size ratio for diatoms
42   REAL(wp), PUBLIC ::  xksi1       !:  half saturation constant for Si uptake
43   REAL(wp), PUBLIC ::  xksi2       !:  half saturation constant for Si/C
44   REAL(wp), PUBLIC ::  xkdoc       !:  2nd half-sat. of DOC remineralization 
45   REAL(wp), PUBLIC ::  concbfe     !:  Fe half saturation for bacteria
46   REAL(wp), PUBLIC ::  oxymin      !:  half saturation constant for anoxia
47   REAL(wp), PUBLIC ::  qnfelim     !:  optimal Fe quota for nanophyto
48   REAL(wp), PUBLIC ::  qdfelim     !:  optimal Fe quota for diatoms
49   REAL(wp), PUBLIC ::  caco3r      !:  mean rainratio
50
51   ! Coefficient for iron limitation
52   REAL(wp) ::  xcoef1   = 0.0016  / 55.85 
53   REAL(wp) ::  xcoef2   = 1.21E-5 * 14. / 55.85 / 7.625 * 0.5 * 1.5
54   REAL(wp) ::  xcoef3   = 1.15E-4 * 14. / 55.85 / 7.625 * 0.5 
55   !!* Substitution
56#  include "top_substitute.h90"
57   !!----------------------------------------------------------------------
58   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
59   !! $Id$
60   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
61   !!----------------------------------------------------------------------
62
63CONTAINS
64
65   SUBROUTINE p4z_lim( kt, knt )
66      !!---------------------------------------------------------------------
67      !!                     ***  ROUTINE p4z_lim  ***
68      !!
69      !! ** Purpose :   Compute the co-limitations by the various nutrients
70      !!              for the various phytoplankton species
71      !!
72      !! ** Method  : - ???
73      !!---------------------------------------------------------------------
74      !
75      INTEGER, INTENT(in)  :: kt, knt
76      !
77      INTEGER  ::   ji, jj, jk
78      REAL(wp) ::   zlim1, zlim2, zlim3, zlim4, zno3, zferlim
79      REAL(wp) ::   zconcd, zconcd2, zconcn, zconcn2
80      REAL(wp) ::   z1_trbdia, z1_trbphy, ztem1, ztem2, zetot1, zetot2
81      REAL(wp) ::   zdenom, zratio, zironmin
82      REAL(wp) ::   zconc1d, zconc1dnh4, zconc0n, zconc0nnh4   
83      !!---------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('p4z_lim')
86      !
87      DO jk = 1, jpkm1
88         DO jj = 1, jpj
89            DO ji = 1, jpi
90               
91               ! Tuning of the iron concentration to a minimum level that is set to the detection limit
92               !-------------------------------------
93               zno3    = trb(ji,jj,jk,jpno3) / 40.e-6
94               zferlim = MAX( 3e-11 * zno3 * zno3, 5e-12 )
95               zferlim = MIN( zferlim, 7e-11 )
96               trb(ji,jj,jk,jpfer) = MAX( trb(ji,jj,jk,jpfer), zferlim )
97
98               ! Computation of a variable Ks for iron on diatoms taking into account
99               ! that increasing biomass is made of generally bigger cells
100               !------------------------------------------------
101               zconcd   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
102               zconcd2  = trb(ji,jj,jk,jpdia) - zconcd
103               zconcn   = MAX( 0.e0 , trb(ji,jj,jk,jpphy) - xsizephy )
104               zconcn2  = trb(ji,jj,jk,jpphy) - zconcn
105               z1_trbphy   = 1. / ( trb(ji,jj,jk,jpphy) + rtrn )
106               z1_trbdia   = 1. / ( trb(ji,jj,jk,jpdia) + rtrn )
107
108               concdfe(ji,jj,jk) = MAX( concdfer, ( zconcd2 * concdfer + concdfer * xsizerd * zconcd ) * z1_trbdia )
109               zconc1d           = MAX( concdno3, ( zconcd2 * concdno3 + concdno3 * xsizerd * zconcd ) * z1_trbdia )
110               zconc1dnh4        = MAX( concdnh4, ( zconcd2 * concdnh4 + concdnh4 * xsizerd * zconcd ) * z1_trbdia )
111
112               concnfe(ji,jj,jk) = MAX( concnfer, ( zconcn2 * concnfer + concnfer * xsizern * zconcn ) * z1_trbphy )
113               zconc0n           = MAX( concnno3, ( zconcn2 * concnno3 + concnno3 * xsizern * zconcn ) * z1_trbphy )
114               zconc0nnh4        = MAX( concnnh4, ( zconcn2 * concnnh4 + concnnh4 * xsizern * zconcn ) * z1_trbphy )
115
116               ! Michaelis-Menten Limitation term for nutrients Small bacteria
117               ! -------------------------------------------------------------
118               zdenom = 1. /  ( concbno3 * concbnh4 + concbnh4 * trb(ji,jj,jk,jpno3) + concbno3 * trb(ji,jj,jk,jpnh4) )
119               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * concbnh4 * zdenom
120               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * concbno3 * zdenom
121               !
122               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
123               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concbnh4 )
124               zlim3    = biron(ji,jj,jk)     / ( concbfe + biron(ji,jj,jk) )
125               zlim4    = trb(ji,jj,jk,jpdoc) / ( xkdoc   + trb(ji,jj,jk,jpdoc) )
126               xlimbacl(ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
127               xlimbac (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 ) * zlim4
128
129               ! Michaelis-Menten Limitation term for nutrients Small flagellates
130               ! -----------------------------------------------
131               zdenom = 1. /  ( zconc0n * zconc0nnh4 + zconc0nnh4 * trb(ji,jj,jk,jpno3) + zconc0n * trb(ji,jj,jk,jpnh4) )
132               xnanono3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc0nnh4 * zdenom
133               xnanonh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc0n    * zdenom
134               !
135               zlim1    = xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk)
136               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc0nnh4 )
137               zratio   = trb(ji,jj,jk,jpnfe) * z1_trbphy 
138               zironmin = xcoef1 * trb(ji,jj,jk,jpnch) * z1_trbphy + xcoef2 * zlim1 + xcoef3 * xnanono3(ji,jj,jk)
139               zlim3    = MAX( 0.,( zratio - zironmin ) / qnfelim )
140               xnanopo4(ji,jj,jk) = zlim2
141               xlimnfe (ji,jj,jk) = MIN( 1., zlim3 )
142               xlimphy (ji,jj,jk) = MIN( zlim1, zlim2, zlim3 )
143               !
144               !   Michaelis-Menten Limitation term for nutrients Diatoms
145               !   ----------------------------------------------
146               zdenom   = 1. / ( zconc1d * zconc1dnh4 + zconc1dnh4 * trb(ji,jj,jk,jpno3) + zconc1d * trb(ji,jj,jk,jpnh4) )
147               xdiatno3(ji,jj,jk) = trb(ji,jj,jk,jpno3) * zconc1dnh4 * zdenom
148               xdiatnh4(ji,jj,jk) = trb(ji,jj,jk,jpnh4) * zconc1d    * zdenom
149               !
150               zlim1    = xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk)
151               zlim2    = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + zconc1dnh4  )
152               zlim3    = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi(ji,jj) )
153               zratio   = trb(ji,jj,jk,jpdfe) * z1_trbdia
154               zironmin = xcoef1 * trb(ji,jj,jk,jpdch) * z1_trbdia + xcoef2 * zlim1 + xcoef3 * xdiatno3(ji,jj,jk)
155               zlim4    = MAX( 0., ( zratio - zironmin ) / qdfelim )
156               xdiatpo4(ji,jj,jk) = zlim2
157               xlimdfe (ji,jj,jk) = MIN( 1., zlim4 )
158               xlimdia (ji,jj,jk) = MIN( zlim1, zlim2, zlim3, zlim4 )
159               xlimsi  (ji,jj,jk) = MIN( zlim1, zlim2, zlim4 )
160           END DO
161         END DO
162      END DO
163
164      ! Compute the fraction of nanophytoplankton that is made of calcifiers
165      ! --------------------------------------------------------------------
166      DO jk = 1, jpkm1
167         DO jj = 1, jpj
168            DO ji = 1, jpi
169               zlim1 =  ( trb(ji,jj,jk,jpno3) * concnnh4 + trb(ji,jj,jk,jpnh4) * concnno3 )    &
170                  &   / ( concnno3 * concnnh4 + concnnh4 * trb(ji,jj,jk,jpno3) + concnno3 * trb(ji,jj,jk,jpnh4) ) 
171               zlim2  = trb(ji,jj,jk,jppo4) / ( trb(ji,jj,jk,jppo4) + concnnh4 )
172               zlim3  = trb(ji,jj,jk,jpfer) / ( trb(ji,jj,jk,jpfer) +  5.E-11   )
173               ztem1  = MAX( 0., tsn(ji,jj,jk,jp_tem) )
174               ztem2  = tsn(ji,jj,jk,jp_tem) - 10.
175               zetot1 = MAX( 0., etot_ndcy(ji,jj,jk) - 1.) / ( 4. + etot_ndcy(ji,jj,jk) ) 
176               zetot2 = 30. / ( 30. + etot_ndcy(ji,jj,jk) ) 
177
178               xfracal(ji,jj,jk) = caco3r * MIN( zlim1, zlim2, zlim3 )                  &
179                  &                       * ztem1 / ( 0.1 + ztem1 )                     &
180                  &                       * MAX( 1., trb(ji,jj,jk,jpphy) * 1.e6 / 2. )  &
181                  &                       * zetot1 * zetot2               &
182                  &                       * ( 1. + EXP(-ztem2 * ztem2 / 25. ) )         &
183                  &                       * MIN( 1., 50. / ( hmld(ji,jj) + rtrn ) )
184               xfracal(ji,jj,jk) = MIN( 0.8 , xfracal(ji,jj,jk) )
185               xfracal(ji,jj,jk) = MAX( 0.02, xfracal(ji,jj,jk) )
186            END DO
187         END DO
188      END DO
189      !
190      DO jk = 1, jpkm1
191         DO jj = 1, jpj
192            DO ji = 1, jpi
193               ! denitrification factor computed from O2 levels
194               nitrfac(ji,jj,jk) = MAX(  0.e0, 0.4 * ( 6.e-6  - trb(ji,jj,jk,jpoxy) )    &
195                  &                                / ( oxymin + trb(ji,jj,jk,jpoxy) )  )
196               nitrfac(ji,jj,jk) = MIN( 1., nitrfac(ji,jj,jk) )
197            END DO
198         END DO
199      END DO
200      !
201      IF( lk_iomput .AND. knt == nrdttrc ) THEN        ! save output diagnostics
202        IF( iom_use( "xfracal" ) ) CALL iom_put( "xfracal", xfracal(:,:,:) * tmask(:,:,:) )  ! euphotic layer deptht
203        IF( iom_use( "LNnut"   ) ) CALL iom_put( "LNnut"  , xlimphy(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
204        IF( iom_use( "LDnut"   ) ) CALL iom_put( "LDnut"  , xlimdia(:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
205        IF( iom_use( "LNFe"    ) ) CALL iom_put( "LNFe"   , xlimnfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
206        IF( iom_use( "LDFe"    ) ) CALL iom_put( "LDFe"   , xlimdfe(:,:,:) * tmask(:,:,:) )  ! Iron limitation term
207      ENDIF
208      !
209      IF( nn_timing == 1 )  CALL timing_stop('p4z_lim')
210      !
211   END SUBROUTINE p4z_lim
212
213   SUBROUTINE p4z_lim_init
214
215      !!----------------------------------------------------------------------
216      !!                  ***  ROUTINE p4z_lim_init  ***
217      !!
218      !! ** Purpose :   Initialization of nutrient limitation parameters
219      !!
220      !! ** Method  :   Read the nampislim namelist and check the parameters
221      !!      called at the first timestep (nittrc000)
222      !!
223      !! ** input   :   Namelist nampislim
224      !!
225      !!----------------------------------------------------------------------
226
227      NAMELIST/nampislim/ concnno3, concdno3, concnnh4, concdnh4, concnfer, concdfer, concbfe,   &
228         &                concbno3, concbnh4, xsizedia, xsizephy, xsizern, xsizerd,          & 
229         &                xksi1, xksi2, xkdoc, qnfelim, qdfelim, caco3r, oxymin
230      INTEGER :: ios                 ! Local integer output status for namelist read
231
232      REWIND( numnatp_ref )              ! Namelist nampislim in reference namelist : Pisces nutrient limitation parameters
233      READ  ( numnatp_ref, nampislim, IOSTAT = ios, ERR = 901)
234901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in reference namelist', lwp )
235
236      REWIND( numnatp_cfg )              ! Namelist nampislim in configuration namelist : Pisces nutrient limitation parameters
237      READ  ( numnatp_cfg, nampislim, IOSTAT = ios, ERR = 902 )
238902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampislim in configuration namelist', lwp )
239      IF(lwm) WRITE ( numonp, nampislim )
240
241      IF(lwp) THEN                         ! control print
242         WRITE(numout,*) ' '
243         WRITE(numout,*) ' Namelist parameters for nutrient limitations, nampislim'
244         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
245         WRITE(numout,*) '    mean rainratio                           caco3r    = ', caco3r
246         WRITE(numout,*) '    NO3 half saturation of nanophyto         concnno3  = ', concnno3
247         WRITE(numout,*) '    NO3 half saturation of diatoms           concdno3  = ', concdno3
248         WRITE(numout,*) '    NH4 half saturation for phyto            concnnh4  = ', concnnh4
249         WRITE(numout,*) '    NH4 half saturation for diatoms          concdnh4  = ', concdnh4
250         WRITE(numout,*) '    half saturation constant for Si uptake   xksi1     = ', xksi1
251         WRITE(numout,*) '    half saturation constant for Si/C        xksi2     = ', xksi2
252         WRITE(numout,*) '    half-sat. of DOC remineralization        xkdoc     = ', xkdoc
253         WRITE(numout,*) '    Iron half saturation for nanophyto       concnfer  = ', concnfer
254         WRITE(numout,*) '    Iron half saturation for diatoms         concdfer  = ', concdfer
255         WRITE(numout,*) '    size ratio for nanophytoplankton         xsizern   = ', xsizern
256         WRITE(numout,*) '    size ratio for diatoms                   xsizerd   = ', xsizerd
257         WRITE(numout,*) '    NO3 half saturation of bacteria          concbno3  = ', concbno3
258         WRITE(numout,*) '    NH4 half saturation for bacteria         concbnh4  = ', concbnh4
259         WRITE(numout,*) '    Minimum size criteria for diatoms        xsizedia  = ', xsizedia
260         WRITE(numout,*) '    Minimum size criteria for nanophyto      xsizephy  = ', xsizephy
261         WRITE(numout,*) '    Fe half saturation for bacteria          concbfe   = ', concbfe
262         WRITE(numout,*) '    halk saturation constant for anoxia       oxymin   =' , oxymin
263         WRITE(numout,*) '    optimal Fe quota for nano.               qnfelim   = ', qnfelim
264         WRITE(numout,*) '    Optimal Fe quota for diatoms             qdfelim   = ', qdfelim
265      ENDIF
266      !
267      nitrfac (:,:,:) = 0._wp
268      !
269   END SUBROUTINE p4z_lim_init
270
271#else
272   !!======================================================================
273   !!  Dummy module :                                   No PISCES bio-model
274   !!======================================================================
275CONTAINS
276   SUBROUTINE p4z_lim                   ! Empty routine
277   END SUBROUTINE p4z_lim
278#endif 
279
280   !!======================================================================
281END MODULE p4zlim
Note: See TracBrowser for help on using the repository browser.