source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/TOP_SRC/TRP/trcdmp.F90 @ 6793

Last change on this file since 6793 was 6793, checked in by davestorkey, 4 years ago

Merge in changes r6482:6692 from the nemo_v3_6_STABLE branch. Only part that changes results for GO6 configurations is a bug fix for the TVD advection scheme put in at r6692.
Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6692 cf. r6688 of /branches/2015/nemo_v3_6_STABLE/NEMOGCM@6791

Custom merge into /branches/UKMO/dev_r5518_GO6_package/NEMOGCM: r6688 cf. r6482 of /branches/2015/nemo_v3_6_STABLE/NEMOGCM@6791

File size: 17.8 KB
Line 
1MODULE trcdmp
2   !!======================================================================
3   !!                       ***  MODULE  trcdmp  ***
4   !! Ocean physics: internal restoring trend on passive tracers
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (O. Marti, G. Madec)  Original code
7   !!                 !  1996-01  (G. Madec) statement function for e3
8   !!                 !  1997-05  (H. Loukos)  adapted for passive tracers
9   !!    NEMO    9.0  !  2004-03  (C. Ethe)    free form + modules
10   !!            3.2  !  2007-02  (C. Deltel)  Diagnose ML trends for passive tracers
11   !!            3.3  !  2010-06  (C. Ethe, G. Madec) merge TRA-TRC
12   !!----------------------------------------------------------------------
13#if  defined key_top 
14   !!----------------------------------------------------------------------
15   !!   trc_dmp      : update the tracer trend with the internal damping
16   !!   trc_dmp_init : initialization, namlist read, parameters control
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! ocean dynamics and tracers variables
19   USE trc             ! ocean passive tracers variables
20   USE trcnam_trp      ! passive tracers transport namelist variables
21   USE trcdta
22   USE tradmp
23   USE prtctl_trc      ! Print control for debbuging
24   USE trdtra
25   USE trd_oce
26   USE iom
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC trc_dmp            ! routine called by step.F90
32   PUBLIC trc_dmp_clo        ! routine called by step.F90
33   PUBLIC trc_dmp_alloc      ! routine called by nemogcm.F90
34
35   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   restotr   ! restoring coeff. on tracers (s-1)
36
37   INTEGER, PARAMETER           ::   npncts   = 8        ! number of closed sea
38   INTEGER, DIMENSION(npncts)   ::   nctsi1, nctsj1      ! south-west closed sea limits (i,j)
39   INTEGER, DIMENSION(npncts)   ::   nctsi2, nctsj2      ! north-east closed sea limits (i,j)
40
41   !! * Substitutions
42#  include "top_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   INTEGER FUNCTION trc_dmp_alloc()
51      !!----------------------------------------------------------------------
52      !!                   ***  ROUTINE trc_dmp_alloc  ***
53      !!----------------------------------------------------------------------
54      ALLOCATE( restotr(jpi,jpj,jpk) , STAT=trc_dmp_alloc )
55      !
56      IF( trc_dmp_alloc /= 0 )   CALL ctl_warn('trc_dmp_alloc: failed to allocate array')
57      !
58   END FUNCTION trc_dmp_alloc
59
60
61   SUBROUTINE trc_dmp( kt )
62      !!----------------------------------------------------------------------
63      !!                   ***  ROUTINE trc_dmp  ***
64      !!                 
65      !! ** Purpose :   Compute the passive tracer trend due to a newtonian damping
66      !!      of the tracer field towards given data field and add it to the
67      !!      general tracer trends.
68      !!
69      !! ** Method  :   Newtonian damping towards trdta computed
70      !!      and add to the general tracer trends:
71      !!                     trn = tra + restotr * (trdta - trb)
72      !!         The trend is computed either throughout the water column
73      !!      (nlmdmptr=0) or in area of weak vertical mixing (nlmdmptr=1) or
74      !!      below the well mixed layer (nlmdmptr=2)
75      !!
76      !! ** Action  : - update the tracer trends tra with the newtonian
77      !!                damping trends.
78      !!              - save the trends ('key_trdmxl_trc')
79      !!----------------------------------------------------------------------
80      !!
81      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index
82      !!
83      INTEGER  ::   ji, jj, jk, jn, jl       ! dummy loop indices
84      REAL(wp) ::   ztra                 ! temporary scalars
85      CHARACTER (len=22) :: charout
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrtrd
87      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrcdta   ! 3D  workspace
88      !!----------------------------------------------------------------------
89      !
90      IF( nn_timing == 1 )  CALL timing_start('trc_dmp')
91      !
92      ! 0. Initialization (first time-step only)
93      !    --------------
94      IF( kt == nittrc000 ) CALL trc_dmp_init
95
96      IF( l_trdtrc )   CALL wrk_alloc( jpi, jpj, jpk, ztrtrd )   ! temporary save of trends
97      !
98      IF( nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
99         !
100         CALL wrk_alloc( jpi, jpj, jpk, ztrcdta )    ! Memory allocation
101         !                                                          ! ===========
102         DO jn = 1, jptra                                           ! tracer loop
103            !                                                       ! ===========
104            IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn)    ! save trends
105            !
106            IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
107               
108               jl = n_trc_index(jn) 
109               CALL trc_dta( kt, sf_trcdta(jl), rf_trfac(jl), ztrcdta )   ! read tracer data at nit000
110
111               SELECT CASE ( nn_zdmp_tr )
112               !
113               CASE( 0 )                !==  newtonian damping throughout the water column  ==!
114                  DO jk = 1, jpkm1
115                     DO jj = 2, jpjm1
116                        DO ji = fs_2, fs_jpim1   ! vector opt.
117                           ztra = restotr(ji,jj,jk) * ( ztrcdta(ji,jj,jk) - trb(ji,jj,jk,jn) )
118                           tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra
119                        END DO
120                     END DO
121                  END DO
122               !
123               CASE ( 1 )                !==  no damping in the turbocline (avt > 5 cm2/s)  ==!
124                  DO jk = 1, jpkm1
125                     DO jj = 2, jpjm1
126                        DO ji = fs_2, fs_jpim1   ! vector opt.
127                           IF( avt(ji,jj,jk) <= 5.e-4_wp )  THEN
128                              ztra = restotr(ji,jj,jk) * ( ztrcdta(ji,jj,jk) - trb(ji,jj,jk,jn) )
129                              tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra
130                           ENDIF
131                        END DO
132                     END DO
133                  END DO
134               !
135               CASE ( 2 )               !==  no damping in the mixed layer   ==!
136                  DO jk = 1, jpkm1
137                     DO jj = 2, jpjm1
138                        DO ji = fs_2, fs_jpim1   ! vector opt.
139                           IF( fsdept(ji,jj,jk) >= hmlp (ji,jj) ) THEN
140                              ztra = restotr(ji,jj,jk) * ( ztrcdta(ji,jj,jk) - trb(ji,jj,jk,jn) )
141                              tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + ztra
142                           END IF
143                        END DO
144                     END DO
145                  END DO
146               
147               END SELECT
148               !
149            ENDIF
150            !
151            IF( l_trdtrc ) THEN
152               ztrtrd(:,:,:) = tra(:,:,:,jn) -  ztrtrd(:,:,:)
153               CALL trd_tra( kt, 'TRC', jn, jptra_dmp, ztrtrd )
154            END IF
155            !                                                       ! ===========
156         END DO                                                     ! tracer loop
157         !                                                          ! ===========
158         CALL wrk_dealloc( jpi, jpj, jpk, ztrcdta )
159      ENDIF
160      !
161      IF( l_trdtrc )  CALL wrk_dealloc( jpi, jpj, jpk, ztrtrd )
162      !                                          ! print mean trends (used for debugging)
163      IF( ln_ctl )   THEN
164         WRITE(charout, FMT="('dmp ')") ;  CALL prt_ctl_trc_info(charout)
165                                           CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
166      ENDIF
167      !
168      IF( nn_timing == 1 )  CALL timing_stop('trc_dmp')
169      !
170   END SUBROUTINE trc_dmp
171
172   SUBROUTINE trc_dmp_clo( kt )
173      !!---------------------------------------------------------------------
174      !!                  ***  ROUTINE trc_dmp_clo  ***
175      !!
176      !! ** Purpose :   Closed sea domain initialization
177      !!
178      !! ** Method  :   if a closed sea is located only in a model grid point
179      !!                we restore to initial data
180      !!
181      !! ** Action  :   nctsi1(), nctsj1() : south-west closed sea limits (i,j)
182      !!                nctsi2(), nctsj2() : north-east Closed sea limits (i,j)
183      !!----------------------------------------------------------------------
184      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index
185      !
186      INTEGER :: ji , jj, jk, jn, jl, jc                     ! dummy loop indicesa
187      INTEGER :: isrow                                      ! local index
188      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrcdta       ! 3D  workspace
189
190      !!----------------------------------------------------------------------
191
192      IF( kt == nit000 ) THEN
193         ! initial values
194         nctsi1(:) = 1  ;  nctsi2(:) = 1
195         nctsj1(:) = 1  ;  nctsj2(:) = 1
196
197         ! set the closed seas (in data domain indices)
198         ! -------------------
199
200         IF( cp_cfg == "orca" ) THEN
201            !
202            SELECT CASE ( jp_cfg )
203            !                                           ! =======================
204            CASE ( 1 )                                  ! eORCA_R1 configuration
205            !                                           ! =======================
206            isrow = 332 - jpjglo
207            !
208                                                        ! Caspian Sea
209            nctsi1(1)   = 333  ; nctsj1(1)   = 243 - isrow
210            nctsi2(1)   = 342  ; nctsj2(1)   = 274 - isrow
211            !                                           ! Lake Superior
212            nctsi1(2)   = 198  ; nctsj1(2)   = 258 - isrow
213            nctsi2(2)   = 204  ; nctsj2(2)   = 262 - isrow
214            !                                           ! Lake Michigan
215            nctsi1(3)   = 201  ; nctsj1(3)   = 250 - isrow
216            nctsi2(3)   = 203  ; nctsj2(3)   = 256 - isrow
217            !                                           ! Lake Huron
218            nctsi1(4)   = 204  ; nctsj1(4)   = 252 - isrow
219            nctsi2(4)   = 209  ; nctsj2(4)   = 256 - isrow
220            !                                           ! Lake Erie
221            nctsi1(5)   = 206  ; nctsj1(5)   = 249 - isrow
222            nctsi2(5)   = 209  ; nctsj2(5)   = 251 - isrow
223            !                                           ! Lake Ontario
224            nctsi1(6)   = 210  ; nctsj1(6)   = 252 - isrow
225            nctsi2(6)   = 212  ; nctsj2(6)   = 252 - isrow
226            !                                           ! Victoria Lake
227            nctsi1(7)   = 321  ; nctsj1(7)   = 180 - isrow
228            nctsi2(7)   = 322  ; nctsj2(7)   = 189 - isrow
229            !                                           ! Baltic Sea
230            nctsi1(8)   = 297  ; nctsj1(8)   = 270 - isrow
231            nctsi2(8)   = 308  ; nctsj2(8)   = 293 - isrow
232            !                                       
233            !                                           ! =======================
234            CASE ( 2 )                                  !  ORCA_R2 configuration
235               !                                        ! =======================
236               !                                            ! Caspian Sea
237               nctsi1(1)   =  11  ;  nctsj1(1)   = 103
238               nctsi2(1)   =  17  ;  nctsj2(1)   = 112
239               !                                            ! Great North American Lakes
240               nctsi1(2)   =  97  ;  nctsj1(2)   = 107
241               nctsi2(2)   = 103  ;  nctsj2(2)   = 111
242               !                                            ! Black Sea 1 : west part of the Black Sea
243               nctsi1(3)   = 174  ;  nctsj1(3)   = 107
244               nctsi2(3)   = 181  ;  nctsj2(3)   = 112
245              !                                            ! Black Sea 2 : est part of the Black Sea
246               nctsi1(4)   =   2  ;  nctsj1(4)   = 107
247               nctsi2(4)   =   6  ;  nctsj2(4)   = 112
248               !                                            ! Baltic Sea
249               nctsi1(5)   =  145 ;  nctsj1(5)   = 116
250               nctsi2(5)   =  150 ;  nctsj2(5)   = 126
251               !                                        ! =======================
252            CASE ( 4 )                                  !  ORCA_R4 configuration
253               !                                        ! =======================
254               !                                            ! Caspian Sea
255               nctsi1(1)   =  4  ;  nctsj1(1)   = 53
256               nctsi2(1)   =  4  ;  nctsj2(1)   = 56
257               !                                            ! Great North American Lakes
258               nctsi1(2)   = 49  ;  nctsj1(2)   = 55
259               nctsi2(2)   = 51  ;  nctsj2(2)   = 56
260               !                                            ! Black Sea
261               nctsi1(3)   = 88  ;  nctsj1(3)   = 55
262               nctsi2(3)   = 91  ;  nctsj2(3)   = 56
263               !                                            ! Baltic Sea
264               nctsi1(4)   = 75  ;  nctsj1(4)   = 59
265               nctsi2(4)   = 76  ;  nctsj2(4)   = 61
266               !                                        ! =======================
267            CASE ( 025 )                                ! ORCA_R025 configuration
268               !                                        ! =======================
269                                                     ! Caspian + Aral sea
270               nctsi1(1)   = 1330 ; nctsj1(1)   = 645
271               nctsi2(1)   = 1400 ; nctsj2(1)   = 795
272               !                                        ! Azov Sea
273               nctsi1(2)   = 1284 ; nctsj1(2)   = 722
274               nctsi2(2)   = 1304 ; nctsj2(2)   = 747
275               !
276            END SELECT
277            !
278         ENDIF
279         !
280
281         ! convert the position in local domain indices
282         ! --------------------------------------------
283         DO jc = 1, npncts
284            nctsi1(jc)   = mi0( nctsi1(jc) )
285            nctsj1(jc)   = mj0( nctsj1(jc) )
286
287            nctsi2(jc)   = mi1( nctsi2(jc) )
288            nctsj2(jc)   = mj1( nctsj2(jc) )
289         END DO
290         !
291      ENDIF
292
293      ! Restore close seas values to initial data
294      IF( ln_trcdta .AND. nb_trcdta > 0 )  THEN   ! Initialisation of tracer from a file that may also be used for damping
295         !
296         IF(lwp)  WRITE(numout,*)
297         IF(lwp)  WRITE(numout,*) ' trc_dmp_clo : Restoring of nutrients on close seas at time-step kt = ', kt
298         IF(lwp)  WRITE(numout,*)
299         !
300         CALL wrk_alloc( jpi, jpj, jpk, ztrcdta )   ! Memory allocation
301         !
302         DO jn = 1, jptra
303            IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
304                jl = n_trc_index(jn)
305                CALL trc_dta( kt, sf_trcdta(jl), rf_trfac(jl), ztrcdta )   ! read tracer data at nit000
306                DO jc = 1, npncts
307                   DO jk = 1, jpkm1
308                      DO jj = nctsj1(jc), nctsj2(jc)
309                         DO ji = nctsi1(jc), nctsi2(jc)
310                            trn(ji,jj,jk,jn) = ztrcdta(ji,jj,jk)
311                            trb(ji,jj,jk,jn) = trn(ji,jj,jk,jn)
312                         ENDDO
313                      ENDDO
314                   ENDDO
315                ENDDO
316             ENDIF
317          ENDDO
318          CALL wrk_dealloc( jpi, jpj, jpk, ztrcdta )
319      ENDIF
320      !
321   END SUBROUTINE trc_dmp_clo
322
323
324   SUBROUTINE trc_dmp_init
325      !!----------------------------------------------------------------------
326      !!                  ***  ROUTINE trc_dmp_init  ***
327      !!
328      !! ** Purpose :   Initialization for the newtonian damping
329      !!
330      !! ** Method  :   read the nammbf namelist and check the parameters
331      !!              called by trc_dmp at the first timestep (nittrc000)
332      !!----------------------------------------------------------------------
333      !
334      INTEGER :: imask  !local file handle
335
336      IF( nn_timing == 1 )  CALL timing_start('trc_dmp_init')
337      !
338      !Allocate arrays
339      IF( trc_dmp_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'trc_dmp_init: unable to allocate arrays' )
340
341      IF( lzoom )   nn_zdmp_tr = 0           ! restoring to climatology at closed north or south boundaries
342      SELECT CASE ( nn_zdmp_tr )
343      CASE ( 0 )   ;   IF(lwp) WRITE(numout,*) '   tracer damping throughout the water column'
344      CASE ( 1 )   ;   IF(lwp) WRITE(numout,*) '   no tracer damping in the turbocline (avt > 5 cm2/s)'
345      CASE ( 2 )   ;   IF(lwp) WRITE(numout,*) '   no tracer damping in the mixed layer'
346      CASE DEFAULT
347         WRITE(ctmp1,*) 'bad flag value for nn_zdmp_tr = ', nn_zdmp_tr
348         CALL ctl_stop(ctmp1)
349      END SELECT
350
351      IF( .NOT. ln_tradmp )   &
352         &   CALL ctl_stop( 'passive trace damping need key_tradmp to compute damping coef.' )
353      !
354      !                          ! Read damping coefficients from file
355      !Read in mask from file
356      CALL iom_open ( cn_resto_tr, imask)
357      CALL iom_get  ( imask, jpdom_autoglo, 'resto', restotr)
358      CALL iom_close( imask )
359      !
360      IF( nn_timing == 1 )  CALL timing_stop('trc_dmp_init')
361      !
362   END SUBROUTINE trc_dmp_init
363
364#else
365   !!----------------------------------------------------------------------
366   !!  Dummy module :                                     No passive tracer
367   !!----------------------------------------------------------------------
368CONTAINS
369   SUBROUTINE trc_dmp( kt )        ! Empty routine
370      INTEGER, INTENT(in) :: kt
371      WRITE(*,*) 'trc_dmp: You should not have seen this print! error?', kt
372   END SUBROUTINE trc_dmp
373#endif
374
375
376   !!======================================================================
377END MODULE trcdmp
Note: See TracBrowser for help on using the repository browser.