source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/TOP_SRC/TRP/trcrad.F90 @ 7203

Last change on this file since 7203 was 7203, checked in by timgraham, 4 years ago

Remove age tracer as this conflicts with changes for MEDUSA. This will need to be added as a separate branch in suites

File size: 9.4 KB
Line 
1MODULE trcrad
2   !!======================================================================
3   !!                       ***  MODULE  trcrad  ***
4   !! Ocean passive tracers:  correction of negative concentrations
5   !!======================================================================
6   !! History :   -   !  01-01  (O. Aumont & E. Kestenare)  Original code
7   !!            1.0  !  04-03  (C. Ethe)  free form F90
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_rad    : correction of negative concentrations
14   !!----------------------------------------------------------------------
15   USE oce_trc             ! ocean dynamics and tracers variables
16   USE trc                 ! ocean passive tracers variables
17   USE trd_oce
18   USE trdtra
19   USE prtctl_trc          ! Print control for debbuging
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC trc_rad         ! routine called by trcstp.F90
25
26   !! * Substitutions
27#  include "top_substitute.h90"
28   !!----------------------------------------------------------------------
29   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
30   !! $Id$
31   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
32   !!----------------------------------------------------------------------
33   
34CONTAINS
35
36   SUBROUTINE trc_rad( kt )
37      !!----------------------------------------------------------------------
38      !!                  ***  ROUTINE trc_rad  ***
39      !!
40      !! ** Purpose :   "crappy" routine to correct artificial negative
41      !!              concentrations due to isopycnal scheme
42      !!
43      !! ** Method  : - PISCES or LOBSTER: Set negative concentrations to zero
44      !!                while computing the corresponding tracer content that
45      !!                is added to the tracers. Then, adjust the tracer
46      !!                concentration using a multiplicative factor so that
47      !!                the total tracer concentration is preserved.
48      !!              - CFC: simply set to zero the negative CFC concentration
49      !!                (the total CFC content is not strictly preserved)
50      !!----------------------------------------------------------------------
51      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index     
52      CHARACTER (len=22) :: charout
53      !!----------------------------------------------------------------------
54      !
55      IF( nn_timing == 1 )  CALL timing_start('trc_rad')
56      !
57      IF( kt == nittrc000 ) THEN
58         IF(lwp) WRITE(numout,*)
59         IF(lwp) WRITE(numout,*) 'trc_rad : Correct artificial negative concentrations '
60         IF(lwp) WRITE(numout,*) '~~~~~~~ '
61      ENDIF
62
63      IF( lk_cfc     )   CALL trc_rad_sms( kt, trb, trn, jp_cfc0 , jp_cfc1               )  ! CFC model
64      IF( lk_c14b    )   CALL trc_rad_sms( kt, trb, trn, jp_c14b0, jp_c14b1              )  ! bomb C14
65      IF( lk_pisces  )   CALL trc_rad_sms( kt, trb, trn, jp_pcs0 , jp_pcs1, cpreserv='Y' )  ! PISCES model
66      IF( lk_my_trc  )   CALL trc_rad_sms( kt, trb, trn, jp_myt0 , jp_myt1               )  ! MY_TRC model
67
68      !
69      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
70         WRITE(charout, FMT="('rad')")
71         CALL prt_ctl_trc_info( charout )
72         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
73      ENDIF
74      !
75      IF( nn_timing == 1 )  CALL timing_stop('trc_rad')
76      !
77   END SUBROUTINE trc_rad
78
79   SUBROUTINE trc_rad_sms( kt, ptrb, ptrn, jp_sms0, jp_sms1, cpreserv )
80      !!-----------------------------------------------------------------------------
81      !!                  ***  ROUTINE trc_rad_sms  ***
82      !!
83      !! ** Purpose :   "crappy" routine to correct artificial negative
84      !!              concentrations due to isopycnal scheme
85      !!
86      !! ** Method  : 2 cases :
87      !!                - Set negative concentrations to zero while computing
88      !!                  the corresponding tracer content that is added to the
89      !!                  tracers. Then, adjust the tracer concentration using
90      !!                  a multiplicative factor so that the total tracer
91      !!                  concentration is preserved.
92      !!                - simply set to zero the negative CFC concentration
93      !!                  (the total content of concentration is not strictly preserved)
94      !!--------------------------------------------------------------------------------
95      !! Arguments
96      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
97      INTEGER  , INTENT( in ) ::  &
98         jp_sms0, &       !: First index of the passive tracer model
99         jp_sms1          !: Last  index of  the passive tracer model
100
101      REAL(wp), DIMENSION (jpi,jpj,jpk,jptra), INTENT( inout )  :: &
102         ptrb, ptrn       !: before and now traceur concentration
103
104      CHARACTER( len = 1) , INTENT(in), OPTIONAL  :: &
105         cpreserv          !: flag to preserve content or not
106     
107      ! Local declarations
108      INTEGER  :: ji, jj, jk, jn     ! dummy loop indices
109      REAL(wp) :: ztrcorb, ztrmasb   ! temporary scalars
110      REAL(wp) :: zcoef, ztrcorn, ztrmasn   !    "         "
111      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrtrdb, ztrtrdn   ! workspace arrays
112      REAL(wp) :: zs2rdt
113      LOGICAL ::   lldebug = .FALSE.
114      !!----------------------------------------------------------------------
115
116 
117      IF( l_trdtrc )  CALL wrk_alloc( jpi, jpj, jpk, ztrtrdb, ztrtrdn )
118     
119      IF( PRESENT( cpreserv )  ) THEN   !  total tracer concentration is preserved
120     
121         DO jn = jp_sms0, jp_sms1
122            !                                                        ! ===========
123            ztrcorb = 0.e0   ;   ztrmasb = 0.e0
124            ztrcorn = 0.e0   ;   ztrmasn = 0.e0
125
126            IF( l_trdtrc ) THEN
127               ztrtrdb(:,:,:) = ptrb(:,:,:,jn)                        ! save input trb for trend computation
128               ztrtrdn(:,:,:) = ptrn(:,:,:,jn)                        ! save input trn for trend computation
129            ENDIF
130            !                                                         ! sum over the global domain
131            ztrcorb = glob_sum( MIN( 0., ptrb(:,:,:,jn) ) * cvol(:,:,:) )
132            ztrcorn = glob_sum( MIN( 0., ptrn(:,:,:,jn) ) * cvol(:,:,:) )
133
134            ztrmasb = glob_sum( MAX( 0., ptrb(:,:,:,jn) ) * cvol(:,:,:) )
135            ztrmasn = glob_sum( MAX( 0., ptrn(:,:,:,jn) ) * cvol(:,:,:) )
136
137            IF( ztrcorb /= 0 ) THEN
138               zcoef = 1. + ztrcorb / ztrmasb
139               DO jk = 1, jpkm1
140                  ptrb(:,:,jk,jn) = MAX( 0., ptrb(:,:,jk,jn) )
141                  ptrb(:,:,jk,jn) = ptrb(:,:,jk,jn) * zcoef * tmask(:,:,jk)
142               END DO
143            ENDIF
144
145            IF( ztrcorn /= 0 ) THEN
146               zcoef = 1. + ztrcorn / ztrmasn
147               DO jk = 1, jpkm1
148                  ptrn(:,:,jk,jn) = MAX( 0., ptrn(:,:,jk,jn) )
149                  ptrn(:,:,jk,jn) = ptrn(:,:,jk,jn) * zcoef * tmask(:,:,jk)
150               END DO
151            ENDIF
152            !
153            IF( l_trdtrc ) THEN
154               !
155               zs2rdt = 1. / ( 2. * rdt )
156               ztrtrdb(:,:,:) = ( ptrb(:,:,:,jn) - ztrtrdb(:,:,:) ) * zs2rdt
157               ztrtrdn(:,:,:) = ( ptrn(:,:,:,jn) - ztrtrdn(:,:,:) ) * zs2rdt 
158               CALL trd_tra( kt, 'TRC', jn, jptra_radb, ztrtrdb )       ! Asselin-like trend handling
159               CALL trd_tra( kt, 'TRC', jn, jptra_radn, ztrtrdn )       ! standard     trend handling
160              !
161            ENDIF
162
163         END DO
164         !
165         !
166      ELSE  ! total CFC content is not strictly preserved
167
168         DO jn = jp_sms0, jp_sms1 
169
170           IF( l_trdtrc ) THEN
171              ztrtrdb(:,:,:) = ptrb(:,:,:,jn)                        ! save input trb for trend computation
172              ztrtrdn(:,:,:) = ptrn(:,:,:,jn)                        ! save input trn for trend computation
173           ENDIF
174
175            DO jk = 1, jpkm1
176               DO jj = 1, jpj
177                  DO ji = 1, jpi
178                     ptrn(ji,jj,jk,jn) = MAX( 0. , ptrn(ji,jj,jk,jn) )
179                     ptrb(ji,jj,jk,jn) = MAX( 0. , ptrb(ji,jj,jk,jn) )
180                  END DO
181               END DO
182            END DO
183         
184            IF( l_trdtrc ) THEN
185               !
186               zs2rdt = 1. / ( 2. * rdt * FLOAT( nn_dttrc ) )
187               ztrtrdb(:,:,:) = ( ptrb(:,:,:,jn) - ztrtrdb(:,:,:) ) * zs2rdt
188               ztrtrdn(:,:,:) = ( ptrn(:,:,:,jn) - ztrtrdn(:,:,:) ) * zs2rdt 
189               CALL trd_tra( kt, 'TRC', jn, jptra_radb, ztrtrdb )       ! Asselin-like trend handling
190               CALL trd_tra( kt, 'TRC', jn, jptra_radn, ztrtrdn )       ! standard     trend handling
191              !
192            ENDIF
193            !
194         ENDDO
195
196      ENDIF
197
198      IF( l_trdtrc )  CALL wrk_dealloc( jpi, jpj, jpk, ztrtrdb, ztrtrdn )
199
200   END SUBROUTINE trc_rad_sms
201#else
202   !!----------------------------------------------------------------------
203   !!   Dummy module :                                         NO TOP model
204   !!----------------------------------------------------------------------
205CONTAINS
206   SUBROUTINE trc_rad( kt )              ! Empty routine
207      INTEGER, INTENT(in) ::   kt
208      WRITE(*,*) 'trc_rad: You should not have seen this print! error?', kt
209   END SUBROUTINE trc_rad
210#endif
211   
212   !!======================================================================
213END MODULE trcrad
Note: See TracBrowser for help on using the repository browser.