| 1 | MODULE trcsbc |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE trcsbc *** |
|---|
| 4 | !! Ocean passive tracers: surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 8.2 ! 1998-10 (G. Madec, G. Roullet, M. Imbard) Original code |
|---|
| 7 | !! 8.2 ! 2001-02 (D. Ludicone) sea ice and free surface |
|---|
| 8 | !! 8.5 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 9 | !! 9.0 ! 2004-03 (C. Ethe) adapted for passive tracers |
|---|
| 10 | !! ! 2006-08 (C. Deltel) Diagnose ML trends for passive tracers |
|---|
| 11 | !!============================================================================== |
|---|
| 12 | #if defined key_top |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! 'key_top' TOP models |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! trc_sbc : update the tracer trend at ocean surface |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce_trc ! ocean dynamics and active tracers variables |
|---|
| 19 | USE trc ! ocean passive tracers variables |
|---|
| 20 | USE prtctl_trc ! Print control for debbuging |
|---|
| 21 | USE iom |
|---|
| 22 | USE trd_oce |
|---|
| 23 | USE trdtra |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC trc_sbc ! routine called by step.F90 |
|---|
| 29 | |
|---|
| 30 | REAL(wp) :: r2dt ! time-step at surface |
|---|
| 31 | |
|---|
| 32 | !! * Substitutions |
|---|
| 33 | # include "top_substitute.h90" |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 36 | !! $Id$ |
|---|
| 37 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 38 | !!---------------------------------------------------------------------- |
|---|
| 39 | CONTAINS |
|---|
| 40 | |
|---|
| 41 | SUBROUTINE trc_sbc ( kt ) |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | !! *** ROUTINE trc_sbc *** |
|---|
| 44 | !! |
|---|
| 45 | !! ** Purpose : Compute the tracer surface boundary condition trend of |
|---|
| 46 | !! (concentration/dilution effect) and add it to the general |
|---|
| 47 | !! trend of tracer equations. |
|---|
| 48 | !! |
|---|
| 49 | !! ** Method : |
|---|
| 50 | !! * concentration/dilution effect: |
|---|
| 51 | !! The surface freshwater flux modify the ocean volume |
|---|
| 52 | !! and thus the concentration of a tracer as : |
|---|
| 53 | !! tra = tra + emp * trn / e3t for k=1 |
|---|
| 54 | !! where emp, the surface freshwater budget (evaporation minus |
|---|
| 55 | !! precipitation ) given in kg/m2/s is divided |
|---|
| 56 | !! by 1035 kg/m3 (density of ocean water) to obtain m/s. |
|---|
| 57 | !! |
|---|
| 58 | !! ** Action : - Update the 1st level of tra with the trend associated |
|---|
| 59 | !! with the tracer surface boundary condition |
|---|
| 60 | !! |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | ! |
|---|
| 63 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
|---|
| 64 | ! |
|---|
| 65 | INTEGER :: ji, jj, jn ! dummy loop indices |
|---|
| 66 | REAL(wp) :: zse3t, zrtrn, zratio, zfact ! temporary scalars |
|---|
| 67 | REAL(wp) :: zswitch, zftra, zcd, zdtra, ztfx, ztra ! temporary scalars |
|---|
| 68 | CHARACTER (len=22) :: charout |
|---|
| 69 | REAL(wp), POINTER, DIMENSION(:,: ) :: zsfx |
|---|
| 70 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrtrd |
|---|
| 71 | |
|---|
| 72 | !!--------------------------------------------------------------------- |
|---|
| 73 | ! |
|---|
| 74 | IF( nn_timing == 1 ) CALL timing_start('trc_sbc') |
|---|
| 75 | ! |
|---|
| 76 | ! Allocate temporary workspace |
|---|
| 77 | CALL wrk_alloc( jpi, jpj, zsfx ) |
|---|
| 78 | IF( l_trdtrc ) CALL wrk_alloc( jpi, jpj, jpk, ztrtrd ) |
|---|
| 79 | ! |
|---|
| 80 | zrtrn = 1.e-15_wp |
|---|
| 81 | |
|---|
| 82 | SELECT CASE( nn_ice_embd ) ! levitating or embedded sea-ice option |
|---|
| 83 | CASE( 0 ) ; zswitch = 1 ! (0) standard levitating sea-ice : salt exchange only |
|---|
| 84 | CASE( 1, 2 ) ; zswitch = 0 ! (1) levitating sea-ice: salt and volume exchange but no pressure effect |
|---|
| 85 | ! (2) embedded sea-ice : salt and volume fluxes and pressure |
|---|
| 86 | END SELECT |
|---|
| 87 | |
|---|
| 88 | IF( ln_top_euler) THEN |
|---|
| 89 | r2dt = rdttrc(1) ! = rdttrc (use Euler time stepping) |
|---|
| 90 | ELSE |
|---|
| 91 | IF( neuler == 0 .AND. kt == nittrc000 ) THEN ! at nittrc000 |
|---|
| 92 | r2dt = rdttrc(1) ! = rdttrc (restarting with Euler time stepping) |
|---|
| 93 | ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN ! at nittrc000 or nittrc000+1 |
|---|
| 94 | r2dt = 2. * rdttrc(1) ! = 2 rdttrc (leapfrog) |
|---|
| 95 | ENDIF |
|---|
| 96 | ENDIF |
|---|
| 97 | |
|---|
| 98 | |
|---|
| 99 | IF( kt == nittrc000 ) THEN |
|---|
| 100 | IF(lwp) WRITE(numout,*) |
|---|
| 101 | IF(lwp) WRITE(numout,*) 'trc_sbc : Passive tracers surface boundary condition' |
|---|
| 102 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 103 | |
|---|
| 104 | !! JPALM -- 12-01-2016 -- problem after restart, maybe because of this... |
|---|
| 105 | !! -- set sbc_trc_b to 0 after restart, first, to check. |
|---|
| 106 | !!------------------------------------------------------------------------------ |
|---|
| 107 | ! IF( ln_rsttr .AND. & ! Restart: read in restart file |
|---|
| 108 | ! iom_varid( numrtr, 'sbc_'//TRIM(ctrcnm(1))//'_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 109 | ! IF(lwp) WRITE(numout,*) ' nittrc000-nn_dttrc surface tracer content forcing fields red in the restart file' |
|---|
| 110 | ! zfact = 0.5_wp |
|---|
| 111 | ! DO jn = 1, jptra |
|---|
| 112 | ! CALL iom_get( numrtr, jpdom_autoglo, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc_b(:,:,jn) ) ! before tracer content sbc |
|---|
| 113 | ! END DO |
|---|
| 114 | ! ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 115 | zfact = 1._wp |
|---|
| 116 | sbc_trc_b(:,:,:) = 0._wp |
|---|
| 117 | ! ENDIF |
|---|
| 118 | ELSE ! Swap of forcing fields |
|---|
| 119 | IF( ln_top_euler ) THEN |
|---|
| 120 | zfact = 1._wp |
|---|
| 121 | sbc_trc_b(:,:,:) = 0._wp |
|---|
| 122 | ELSE |
|---|
| 123 | zfact = 0.5_wp |
|---|
| 124 | sbc_trc_b(:,:,:) = sbc_trc(:,:,:) |
|---|
| 125 | ENDIF |
|---|
| 126 | ! |
|---|
| 127 | ENDIF |
|---|
| 128 | |
|---|
| 129 | ! Coupling online : river runoff is added to the horizontal divergence (hdivn) in the subroutine sbc_rnf_div |
|---|
| 130 | ! one only consider the concentration/dilution effect due to evaporation minus precipitation + freezing/melting of sea-ice |
|---|
| 131 | ! Coupling offline : runoff are in emp which contains E-P-R |
|---|
| 132 | ! |
|---|
| 133 | IF( .NOT. lk_offline .AND. lk_vvl ) THEN ! online coupling with vvl |
|---|
| 134 | zsfx(:,:) = 0._wp |
|---|
| 135 | ELSE ! online coupling free surface or offline with free surface |
|---|
| 136 | zsfx(:,:) = emp(:,:) |
|---|
| 137 | ENDIF |
|---|
| 138 | |
|---|
| 139 | ! 0. initialization |
|---|
| 140 | DO jn = 1, jptra |
|---|
| 141 | ! |
|---|
| 142 | IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn) ! save trends |
|---|
| 143 | ! ! add the trend to the general tracer trend |
|---|
| 144 | |
|---|
| 145 | IF ( nn_ice_tr == -1 ) THEN ! No tracers in sea ice (null concentration in sea ice) |
|---|
| 146 | |
|---|
| 147 | DO jj = 2, jpj |
|---|
| 148 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 149 | sbc_trc(ji,jj,jn) = zsfx(ji,jj) * r1_rau0 * trn(ji,jj,1,jn) |
|---|
| 150 | END DO |
|---|
| 151 | END DO |
|---|
| 152 | |
|---|
| 153 | ELSE |
|---|
| 154 | |
|---|
| 155 | DO jj = 2, jpj |
|---|
| 156 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 157 | zse3t = 1. / fse3t(ji,jj,1) |
|---|
| 158 | ! tracer flux at the ice/ocean interface (tracer/m2/s) |
|---|
| 159 | zftra = - trc_i(ji,jj,jn) * fmmflx(ji,jj) ! uptake of tracer in the sea ice |
|---|
| 160 | zcd = trc_o(ji,jj,jn) * fmmflx(ji,jj) ! concentration dilution due to freezing-melting, |
|---|
| 161 | ! only used in the levitating sea ice case |
|---|
| 162 | ! tracer flux only : add concentration dilution term in net tracer flux, no F-M in volume flux |
|---|
| 163 | ! tracer and mass fluxes : no concentration dilution term in net tracer flux, F-M term in volume flux |
|---|
| 164 | ztfx = zftra + zswitch * zcd ! net tracer flux (+C/D if no ice/ocean mass exchange) |
|---|
| 165 | |
|---|
| 166 | zdtra = r1_rau0 * ( ztfx + zsfx(ji,jj) * trn(ji,jj,1,jn) ) |
|---|
| 167 | IF ( zdtra < 0. ) THEN |
|---|
| 168 | zratio = -zdtra * zse3t * r2dt / ( trn(ji,jj,1,jn) + zrtrn ) |
|---|
| 169 | zdtra = MIN(1.0, zratio) * zdtra ! avoid negative concentrations to arise |
|---|
| 170 | ENDIF |
|---|
| 171 | sbc_trc(ji,jj,jn) = zdtra |
|---|
| 172 | END DO |
|---|
| 173 | END DO |
|---|
| 174 | ENDIF |
|---|
| 175 | ! |
|---|
| 176 | CALL lbc_lnk( sbc_trc(:,:,jn), 'T', 1. ) |
|---|
| 177 | ! Concentration dilution effect on tracers due to evaporation & precipitation |
|---|
| 178 | DO jj = 2, jpj |
|---|
| 179 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 180 | zse3t = zfact / fse3t(ji,jj,1) |
|---|
| 181 | tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + ( sbc_trc_b(ji,jj,jn) + sbc_trc(ji,jj,jn) ) * zse3t |
|---|
| 182 | END DO |
|---|
| 183 | END DO |
|---|
| 184 | ! |
|---|
| 185 | IF( l_trdtrc ) THEN |
|---|
| 186 | ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:) |
|---|
| 187 | CALL trd_tra( kt, 'TRC', jn, jptra_nsr, ztrtrd ) |
|---|
| 188 | END IF |
|---|
| 189 | ! ! =========== |
|---|
| 190 | END DO ! tracer loop |
|---|
| 191 | ! ! =========== |
|---|
| 192 | |
|---|
| 193 | ! Write in the tracer restar file |
|---|
| 194 | ! ******************************* |
|---|
| 195 | IF( lrst_trc ) THEN |
|---|
| 196 | IF(lwp) WRITE(numout,*) |
|---|
| 197 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface tracer content forcing fields written in tracer restart file ', & |
|---|
| 198 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 199 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 200 | DO jn = 1, jptra |
|---|
| 201 | CALL iom_rstput( kt, nitrst, numrtw, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc(:,:,jn) ) |
|---|
| 202 | END DO |
|---|
| 203 | ENDIF |
|---|
| 204 | ! |
|---|
| 205 | IF( ln_ctl ) THEN |
|---|
| 206 | WRITE(charout, FMT="('sbc ')") ; CALL prt_ctl_trc_info(charout) |
|---|
| 207 | CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' ) |
|---|
| 208 | ENDIF |
|---|
| 209 | CALL wrk_dealloc( jpi, jpj, zsfx ) |
|---|
| 210 | IF( l_trdtrc ) CALL wrk_dealloc( jpi, jpj, jpk, ztrtrd ) |
|---|
| 211 | ! |
|---|
| 212 | IF( nn_timing == 1 ) CALL timing_stop('trc_sbc') |
|---|
| 213 | ! |
|---|
| 214 | END SUBROUTINE trc_sbc |
|---|
| 215 | |
|---|
| 216 | #else |
|---|
| 217 | !!---------------------------------------------------------------------- |
|---|
| 218 | !! Dummy module : NO passive tracer |
|---|
| 219 | !!---------------------------------------------------------------------- |
|---|
| 220 | CONTAINS |
|---|
| 221 | SUBROUTINE trc_sbc (kt) ! Empty routine |
|---|
| 222 | INTEGER, INTENT(in) :: kt |
|---|
| 223 | WRITE(*,*) 'trc_sbc: You should not have seen this print! error?', kt |
|---|
| 224 | END SUBROUTINE trc_sbc |
|---|
| 225 | #endif |
|---|
| 226 | |
|---|
| 227 | !!====================================================================== |
|---|
| 228 | END MODULE trcsbc |
|---|
