source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 10149

Last change on this file since 10149 was 10149, checked in by frrh, 23 months ago

Met Office GMED ticket 379: Merged David Ford's MEDUSA assimilation changes
using command:

svn merge -r 10054:10141 svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/UKMO/dev_r5518_GO6_package_asm_3d_bgc_v3

File size: 15.1 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!             -   ! 2014-06 (A. Yool, J. Palmieri) adding MEDUSA-2
11   !!----------------------------------------------------------------------
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_init  :   Initialization for passive tracer
17   !!   top_alloc :   allocate the TOP arrays
18   !!----------------------------------------------------------------------
19   USE oce_trc         ! shared variables between ocean and passive tracers
20   USE trc             ! passive tracers common variables
21   USE trcrst          ! passive tracers restart
22   USE trcnam          ! Namelist read
23   USE trcini_cfc      ! CFC      initialisation
24   USE trcini_pisces   ! PISCES   initialisation
25   USE trcini_c14b     ! C14 bomb initialisation
26   USE trcini_age      ! AGE      initialisation
27   USE trcini_my_trc   ! MY_TRC   initialisation
28   USE trcini_idtra    ! idealize tracer initialisation
29   USE trcini_medusa   ! MEDUSA   initialisation
30   USE par_medusa      ! MEDUSA   parameters (needed for elemental cycles)
31   USE trcdta          ! initialisation from files
32   USE daymod          ! calendar manager
33   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
34   USE trcsub          ! variables to substep passive tracers
35   USE lib_mpp         ! distribued memory computing library
36   USE sbc_oce
37   USE trcice          ! tracers in sea ice
38# if defined key_medusa
39   USE sms_medusa      ! MEDUSA   initialisation
40# endif
41   IMPLICIT NONE
42   PRIVATE
43   
44   PUBLIC   trc_init   ! called by opa
45
46    !! * Substitutions
47#  include "domzgr_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54   
55   SUBROUTINE trc_init
56      !!---------------------------------------------------------------------
57      !!                     ***  ROUTINE trc_init  ***
58      !!
59      !! ** Purpose :   Initialization of the passive tracer fields
60      !!
61      !! ** Method  : - read namelist
62      !!              - control the consistancy
63      !!              - compute specific initialisations
64      !!              - set initial tracer fields (either read restart
65      !!                or read data or analytical formulation
66      !!---------------------------------------------------------------------
67      INTEGER ::   ji, jj, jk, jn, jl    ! dummy loop indices
68# if defined key_medusa && defined key_roam
69      !! AXY (23/11/2017)
70      REAL(wp)                         :: zsum3d, zsum2d
71      REAL(wp)                         :: zq1, zq2, loc_vol, loc_area
72      REAL(wp), DIMENSION(6)           :: loc_cycletot3, loc_cycletot2
73      REAL(wp), DIMENSION(jpi,jpj,jpk) :: ztot3d
74      REAL(wp), DIMENSION(jpi,jpj)     :: ztot2d, carea
75# endif
76      CHARACTER (len=25) :: charout
77      !!---------------------------------------------------------------------
78      !
79      IF( nn_timing == 1 )   CALL timing_start('trc_init')
80      !
81      IF(lwp) WRITE(numout,*)
82      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
83      IF(lwp) WRITE(numout,*) '~~~~~~~'
84
85      CALL top_alloc()              ! allocate TOP arrays
86
87      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
88      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
89      IF( l_trcdm2dc .AND. lwp ) &
90         &   CALL ctl_warn(' Coupling with passive tracers and used of diurnal cycle. &
91         & Computation of a daily mean shortwave for some biogeochemical models) ')
92
93      IF( nn_cla == 1 )   &
94         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
95
96      CALL trc_nam      ! read passive tracers namelists
97      !
98      IF(lwp) WRITE(numout,*)
99      !
100      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
101      !
102      IF(lwp) WRITE(numout,*)
103                                                              ! masked grid volume
104      !                                                              ! masked grid volume
105      DO jk = 1, jpk
106         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
107      END DO
108      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
109      !                                                              ! total volume of the ocean
110      areatot = glob_sum( cvol(:,:,:) )
111# if defined key_medusa && defined key_roam
112      carea(:,:) = e1e2t(:,:) * tmask(:,:,1) 
113# endif
114
115      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
116      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
117      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
118      IF( lk_age     )       CALL trc_ini_age          ! AGE       tracer
119      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
120      IF( lk_idtra   )       CALL trc_ini_idtra        ! Idealize tracers
121      IF( lk_medusa  )       CALL trc_ini_medusa       ! MEDUSA  tracers
122
123      CALL trc_ice_ini                                 ! Tracers in sea ice
124
125      IF( ln_ctl ) THEN
126         !
127         IF (narea == 1) THEN 
128            ! The tracer.stat file only contains global tracer sum values, if
129            ! it contains anything at all. Hence it only needs to be opened
130            ! and written to on the master PE, not on all PEs. 
131            CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE','FORMATTED',  & 
132                          'SEQUENTIAL', -1, numout, lwp , narea ) 
133         ENDIF 
134         !
135      ENDIF
136
137      IF( ln_trcdta ) THEN
138         CALL trc_dta_init(jptra)
139      ENDIF
140
141      IF( ln_rsttr ) THEN
142        !
143        CALL trc_rst_read              ! restart from a file
144        !
145      ELSE
146        !
147        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
148            !
149            DO jn = 1, jptra
150               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
151                  jl = n_trc_index(jn) 
152                  CALL trc_dta( nit000, sf_trcdta(jl), rf_trfac(jl) )   ! read tracer data at nit000
153                  trn(:,:,:,jn) = sf_trcdta(jl)%fnow(:,:,:) 
154                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
155                     !                                                    (data used only for initialisation)
156                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
157                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
158                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
159                     !
160                  ENDIF
161               ENDIF
162            ENDDO
163            !
164        ENDIF
165        !
166        trb(:,:,:,:) = trn(:,:,:,:)
167        !
168      ENDIF
169 
170      tra(:,:,:,:) = 0._wp
171      !
172      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
173      !
174
175      trai(:) = 0._wp                                                   ! initial content of all tracers
176      DO jn = 1, jptra
177         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
178      END DO
179
180      IF(lwp) THEN               ! control print
181         WRITE(numout,*)
182         WRITE(numout,*)
183         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
184         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
185         WRITE(numout,*) '          *** Total inital content of all tracers '
186         WRITE(numout,*)
187# if defined key_debug_medusa
188         CALL flush(numout)
189# endif
190         !
191# if defined key_debug_medusa
192         WRITE(numout,*) ' litle check :  ', ctrcnm(1)
193         CALL flush(numout)
194# endif
195         DO jn = 1, jptra
196            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
197         ENDDO
198         WRITE(numout,*)
199      ENDIF
200      IF(lwp) WRITE(numout,*)
201      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
202         CALL prt_ctl_trc_init
203         WRITE(charout, FMT="('ini ')")
204         CALL prt_ctl_trc_info( charout )
205         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
206      ENDIF
207
208# if defined key_medusa && defined key_roam
209      ! AXY (17/11/2017): calculate initial totals of elemental cycles
210      !
211      ! This is done in a very hard-wired way here; in future, this could be
212      ! replaced with loops and using a 2D array; one dimension would cover
213      ! the tracers, the other would be for the elements; each tracer would
214      ! have a factor for each element to say how much of that element was
215      ! in that tracer; for example, PHN would be 1.0 for N, xrfn for Fe and
216      ! xthetapn for C, with the other elements 0.0; the array entry for PHN
217      ! would then be (1. 0. xrfn xthetapn 0. 0.) for (N, Si, Fe, C, A, O2);
218      ! saving this for the next iteration
219      !
220      cycletot(:) = 0._wp
221      ! report elemental totals at initialisation as we go along
222      IF ( lwp ) WRITE(numout,*)
223      IF ( lwp ) WRITE(numout,*)    ' Elemental cycle totals: '
224      ! nitrogen
225      ztot3d(:,:,:) = trn(:,:,:,jpphn) + trn(:,:,:,jpphd) + trn(:,:,:,jpzmi) + &
226                      trn(:,:,:,jpzme) + trn(:,:,:,jpdet) + trn(:,:,:,jpdin)
227      ztot2d(:,:)   = zn_sed_n(:,:)
228      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
229      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
230      cycletot(1)   = zsum3d + zsum2d
231      IF ( lwp ) WRITE(numout,9010) 'nitrogen', zsum3d, zsum2d, cycletot(1)
232      ! silicon
233      ztot3d(:,:,:) = trn(:,:,:,jppds) + trn(:,:,:,jpsil)
234      ztot2d(:,:)   = zn_sed_si(:,:)
235      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
236      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
237      cycletot(2)   = zsum3d + zsum2d
238      IF ( lwp ) WRITE(numout,9010) 'silicon', zsum3d, zsum2d, cycletot(2)
239      ! iron
240      ztot3d(:,:,:) = ((trn(:,:,:,jpphn) + trn(:,:,:,jpphd) + trn(:,:,:,jpzmi) + &
241                      trn(:,:,:,jpzme) + trn(:,:,:,jpdet)) * xrfn) + trn(:,:,:,jpfer)
242      ztot2d(:,:)   = zn_sed_fe(:,:)
243      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
244      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
245      cycletot(3)   = zsum3d + zsum2d
246      IF ( lwp ) WRITE(numout,9010) 'iron', zsum3d, zsum2d, cycletot(3)
247      ! carbon (uses fixed C:N ratios on plankton tracers)
248      ztot3d(:,:,:) = (trn(:,:,:,jpphn) * xthetapn)  + (trn(:,:,:,jpphd) * xthetapd)  +  &
249                      (trn(:,:,:,jpzmi) * xthetazmi) + (trn(:,:,:,jpzme) * xthetazme) +  &
250                      trn(:,:,:,jpdtc) + trn(:,:,:,jpdic)
251      ztot2d(:,:)   = zn_sed_c(:,:) + zn_sed_ca(:,:)
252      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
253      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
254      cycletot(4)   = zsum3d + zsum2d
255      IF ( lwp ) WRITE(numout,9010) 'carbon', zsum3d, zsum2d, cycletot(4)
256      ! alkalinity (note benthic correction)
257      ztot3d(:,:,:) = trn(:,:,:,jpalk)
258      ztot2d(:,:)   = zn_sed_ca(:,:) * 2._wp
259      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
260      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
261      cycletot(5)   = zsum3d + zsum2d
262      IF ( lwp ) WRITE(numout,9010) 'alkalinity', zsum3d, zsum2d, cycletot(5)
263      ! oxygen (note no benthic)
264      ztot3d(:,:,:) = trn(:,:,:,jpoxy)
265      ztot2d(:,:)   = 0._wp
266      zsum3d        = glob_sum( ztot3d(:,:,:) * cvol(:,:,:) )
267      zsum2d        = glob_sum( ztot2d(:,:) * carea(:,:) )
268      cycletot(6)   = zsum3d + zsum2d
269      IF ( lwp ) WRITE(numout,9010) 'oxygen', zsum3d, zsum2d, cycletot(6)
270      ! Check
271      zsum3d        = glob_sum( cvol(:,:,:) )
272      zsum2d        = glob_sum( carea(:,:) )     
273      IF ( lwp ) THEN
274         WRITE(numout,*)
275         WRITE(numout,*) ' check : cvol    : ', zsum3d
276         WRITE(numout,*) ' check : carea   : ', zsum2d
277         WRITE(numout,*)
278      ENDIF
279      !
280# endif
281
282      IF(lwp) THEN
283          WRITE(numout,*)
284          WRITE(numout,*) 'trc_init : passive tracer set up completed'
285          WRITE(numout,*) '~~~~~~~'
286      ENDIF 
287# if defined key_debug_medusa
288         CALL trc_rst_stat
289         CALL flush(numout)
290# endif
291
2929000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
2939010  FORMAT(' element:',a10,                     &
294             ' 3d sum:',e18.10,' 2d sum:',e18.10, &
295             ' total:',e18.10)
296      !
297      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
298      !
299   END SUBROUTINE trc_init
300
301
302   SUBROUTINE top_alloc
303      !!----------------------------------------------------------------------
304      !!                     ***  ROUTINE top_alloc  ***
305      !!
306      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
307      !!----------------------------------------------------------------------
308      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
309      USE trc           , ONLY:   trc_alloc
310      USE trcnxt        , ONLY:   trc_nxt_alloc
311      USE trczdf        , ONLY:   trc_zdf_alloc
312      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
313#if defined key_trdmxl_trc 
314      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
315#endif
316# if defined key_medusa
317      USE bio_medusa_mod, ONLY:   bio_medusa_alloc
318# endif
319
320      !
321      INTEGER :: ierr
322      !!----------------------------------------------------------------------
323      !
324      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
325      ierr = ierr + trc_alloc    ()
326      ierr = ierr + trc_nxt_alloc()
327      ierr = ierr + trc_zdf_alloc()
328      ierr = ierr + trd_trc_oce_alloc()
329#if defined key_trdmxl_trc 
330      ierr = ierr + trd_mxl_trc_alloc()
331#endif
332#if defined key_medusa
333      ierr = ierr + bio_medusa_alloc()
334#endif
335      !
336      IF( lk_mpp    )   CALL mpp_sum( ierr )
337      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
338      !
339   END SUBROUTINE top_alloc
340
341#else
342   !!----------------------------------------------------------------------
343   !!  Empty module :                                     No passive tracer
344   !!----------------------------------------------------------------------
345CONTAINS
346   SUBROUTINE trc_init                      ! Dummy routine   
347   END SUBROUTINE trc_init
348#endif
349
350   !!======================================================================
351END MODULE trcini
Note: See TracBrowser for help on using the repository browser.