source: branches/UKMO/dev_r5518_GO6_package/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 6498

Last change on this file since 6498 was 6498, checked in by timgraham, 5 years ago

Merge head of nemo_v3_6_STABLE into package branch

File size: 9.9 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcrst          ! passive tracers restart
21   USE trcnam          ! Namelist read
22   USE trcini_cfc      ! CFC      initialisation
23   USE trcini_pisces   ! PISCES   initialisation
24   USE trcini_c14b     ! C14 bomb initialisation
25   USE trcini_my_trc   ! MY_TRC   initialisation
26   USE trcdta          ! initialisation from files
27   USE daymod          ! calendar manager
28   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
29   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
30   USE trcsub          ! variables to substep passive tracers
31   USE lib_mpp         ! distribued memory computing library
32   USE sbc_oce
33   USE trcice          ! tracers in sea ice
34 
35   IMPLICIT NONE
36   PRIVATE
37   
38   PUBLIC   trc_init   ! called by opa
39
40    !! * Substitutions
41#  include "domzgr_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48   
49   SUBROUTINE trc_init
50      !!---------------------------------------------------------------------
51      !!                     ***  ROUTINE trc_init  ***
52      !!
53      !! ** Purpose :   Initialization of the passive tracer fields
54      !!
55      !! ** Method  : - read namelist
56      !!              - control the consistancy
57      !!              - compute specific initialisations
58      !!              - set initial tracer fields (either read restart
59      !!                or read data or analytical formulation
60      !!---------------------------------------------------------------------
61      INTEGER ::   jk, jn, jl    ! dummy loop indices
62      CHARACTER (len=25) :: charout
63      !!---------------------------------------------------------------------
64      !
65      IF( nn_timing == 1 )   CALL timing_start('trc_init')
66      !
67      IF(lwp) WRITE(numout,*)
68      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
69      IF(lwp) WRITE(numout,*) '~~~~~~~'
70
71      CALL top_alloc()              ! allocate TOP arrays
72
73      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
74      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. lk_offline
75      IF( l_trcdm2dc .AND. lwp ) &
76         &   CALL ctl_warn(' Coupling with passive tracers and used of diurnal cycle. &
77         & Computation of a daily mean shortwave for some biogeochemical models) ')
78
79      IF( nn_cla == 1 )   &
80         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
81
82      CALL trc_nam      ! read passive tracers namelists
83      !
84      IF(lwp) WRITE(numout,*)
85      !
86      IF( ln_rsttr .AND. .NOT. lk_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
87      !
88      IF(lwp) WRITE(numout,*)
89                                                              ! masked grid volume
90      !                                                              ! masked grid volume
91      DO jk = 1, jpk
92         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
93      END DO
94      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
95      !                                                              ! total volume of the ocean
96      areatot = glob_sum( cvol(:,:,:) )
97
98      IF( lk_pisces  )       CALL trc_ini_pisces       ! PISCES  bio-model
99      IF( lk_cfc     )       CALL trc_ini_cfc          ! CFC     tracers
100      IF( lk_c14b    )       CALL trc_ini_c14b         ! C14 bomb  tracer
101      IF( lk_my_trc  )       CALL trc_ini_my_trc       ! MY_TRC  tracers
102
103      CALL trc_ice_ini                                 ! Tracers in sea ice
104
105      IF( lwp ) THEN
106         !
107         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
108         !
109      ENDIF
110
111      IF( ln_trcdta )      CALL trc_dta_init(jptra)
112
113
114      IF( ln_rsttr ) THEN
115        !
116        CALL trc_rst_read              ! restart from a file
117        !
118      ELSE
119        !
120        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
121            !
122            DO jn = 1, jptra
123               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
124                  jl = n_trc_index(jn) 
125                  CALL trc_dta( nit000, sf_trcdta(jl) )   ! read tracer data at nit000
126                  trn(:,:,:,jn) = sf_trcdta(jl)%fnow(:,:,:) * tmask(:,:,:) * rf_trfac(jl)
127                  !
128                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN      !== deallocate data structure   ==!
129                     !                                                    (data used only for initialisation)
130                     IF(lwp) WRITE(numout,*) 'trc_dta: deallocate data arrays as they are only used to initialize the run'
131                                                  DEALLOCATE( sf_trcdta(jl)%fnow )     !  arrays in the structure
132                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
133                     !
134                  ENDIF
135               ENDIF
136            ENDDO
137            !
138        ENDIF
139        !
140        trb(:,:,:,:) = trn(:,:,:,:)
141        !
142      ENDIF
143 
144      tra(:,:,:,:) = 0._wp
145      IF( ln_zps .AND. .NOT. lk_c1d .AND. .NOT. ln_isfcav )   &              ! Partial steps: before horizontal gradient of passive
146        &    CALL zps_hde    ( nit000, jptra, trn, gtru, gtrv  )  ! Partial steps: before horizontal gradient
147      IF( ln_zps .AND. .NOT. lk_c1d .AND.       ln_isfcav )   &
148        &    CALL zps_hde_isf( nit000, jptra, trn, pgtu=gtru, pgtv=gtrv, pgtui=gtrui, pgtvi=gtrvi )       ! tracers at the bottom ocean level
149
150
151      !
152      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
153      !
154
155      trai(:) = 0._wp                                                   ! initial content of all tracers
156      DO jn = 1, jptra
157         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
158      END DO
159
160      IF(lwp) THEN               ! control print
161         WRITE(numout,*)
162         WRITE(numout,*)
163         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
164         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
165         WRITE(numout,*) '          *** Total inital content of all tracers '
166         WRITE(numout,*)
167         DO jn = 1, jptra
168            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
169         ENDDO
170         WRITE(numout,*)
171      ENDIF
172      IF(lwp) WRITE(numout,*)
173      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
174         CALL prt_ctl_trc_init
175         WRITE(charout, FMT="('ini ')")
176         CALL prt_ctl_trc_info( charout )
177         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
178      ENDIF
1799000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
180      !
181      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
182      !
183   END SUBROUTINE trc_init
184
185
186   SUBROUTINE top_alloc
187      !!----------------------------------------------------------------------
188      !!                     ***  ROUTINE top_alloc  ***
189      !!
190      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
191      !!----------------------------------------------------------------------
192      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
193      USE trc           , ONLY:   trc_alloc
194      USE trcnxt        , ONLY:   trc_nxt_alloc
195      USE trczdf        , ONLY:   trc_zdf_alloc
196      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
197#if defined key_trdmxl_trc 
198      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
199#endif
200      !
201      INTEGER :: ierr
202      !!----------------------------------------------------------------------
203      !
204      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
205      ierr = ierr + trc_alloc    ()
206      ierr = ierr + trc_nxt_alloc()
207      ierr = ierr + trc_zdf_alloc()
208      ierr = ierr + trd_trc_oce_alloc()
209#if defined key_trdmxl_trc 
210      ierr = ierr + trd_mxl_trc_alloc()
211#endif
212      !
213      IF( lk_mpp    )   CALL mpp_sum( ierr )
214      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
215      !
216   END SUBROUTINE top_alloc
217
218#else
219   !!----------------------------------------------------------------------
220   !!  Empty module :                                     No passive tracer
221   !!----------------------------------------------------------------------
222CONTAINS
223   SUBROUTINE trc_init                      ! Dummy routine   
224   END SUBROUTINE trc_init
225#endif
226
227   !!======================================================================
228END MODULE trcini
Note: See TracBrowser for help on using the repository browser.