Context Navigation

← Previous Revision
Latest Revision
Next Revision →
Blame
Revision Log

dynhpg.F90 @ 11556

Last change on this file since 11556 was 11556, checked in by mattmartin, 5 years ago
Commit changes to bias pressure correction from ticket https://code.metoffice.gov.uk/trac/utils/ticket/262.
File size: 75.3 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!! 3.6 ! 2019-08 (M. Bell) Revisions to bias pressure correction
20	!!----------------------------------------------------------------------
21
22	!!----------------------------------------------------------------------
23	!! dyn_hpg : update the momentum trend with the now horizontal
24	!! gradient of the hydrostatic pressure
25	!! dyn_hpg_init : initialisation and control of options
26	!! hpg_zco : z-coordinate scheme
27	!! hpg_zps : z-coordinate plus partial steps (interpolation)
28	!! hpg_sco : s-coordinate (standard jacobian formulation)
29	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
30	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
31	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
32	!!----------------------------------------------------------------------
33	USE oce ! ocean dynamics and tracers
34	USE sbc_oce ! surface variable (only for the flag with ice shelf)
35	USE dom_oce ! ocean space and time domain
36	USE phycst ! physical constants
37	USE trd_oce ! trends: ocean variables
38	USE trddyn ! trend manager: dynamics
39	!
40	USE in_out_manager ! I/O manager
41	USE prtctl ! Print control
42	USE lbclnk ! lateral boundary condition
43	USE lib_mpp ! MPP library
44	USE eosbn2 ! compute density
45	USE wrk_nemo ! Memory Allocation
46	USE timing ! Timing
47	USE biaspar ! bias correction variables
48
49	IMPLICIT NONE
50	PRIVATE
51
52	PUBLIC dyn_hpg ! routine called by step module
53	PUBLIC dyn_hpg_init ! routine called by opa module
54
55	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56	LOGICAL , PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
57	LOGICAL , PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
58	LOGICAL , PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
59	LOGICAL , PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
60	LOGICAL , PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
61	LOGICAL , PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
62	LOGICAL , PUBLIC :: ln_dynhpg_imp !: semi-implicite hpg flag
63
64	INTEGER , PUBLIC :: nhpg = 0 ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
65
66	!! * Substitutions
67	# include "domzgr_substitute.h90"
68	# include "vectopt_loop_substitute.h90"
69	!!----------------------------------------------------------------------
70	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
71	!! $Id$
72	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
73	!!----------------------------------------------------------------------
74	CONTAINS
75
76	SUBROUTINE dyn_hpg( kt )
77	!!---------------------------------------------------------------------
78	!! * ROUTINE dyn_hpg *
79	!!
80	!! ** Method : Call the hydrostatic pressure gradient routine
81	!! using the scheme defined in the namelist
82	!!
83	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
84	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
85	!!----------------------------------------------------------------------
86	INTEGER, INTENT(in) :: kt ! ocean time-step index
87	INTEGER :: ji, jj, jk ! dummy loop indices
88	INTEGER :: iku, ikv ! k indices for bottom level at u and v points
89	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv
90	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: z_rhd_st ! tmp density storage for pressure corr
91	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: z_ua, z_va ! tmp store for ua and va including hpg but not pressure correction
92	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: z_ua_bpc, z_va_bpc ! ua calculated with bias pressure correction
93	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z_gru_st, z_grv_st ! tmp ua and va trends storage for pressure corr
94	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z_ua_bpc_bot, z_va_bpc_bot ! bias pc fields calculated at the ocean bottom
95
96	!!----------------------------------------------------------------------
97	!
98	IF( nn_timing == 1 ) CALL timing_start('dyn_hpg')
99	!
100	IF( l_trddyn ) THEN ! Temporary saving of ua and va trends (l_trddyn)
101	CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
102	ztrdu(:,:,:) = ua(:,:,:)
103	ztrdv(:,:,:) = va(:,:,:)
104	ENDIF
105	!
106
107	IF ( ln_bias .AND. ln_bias_pc_app ) THEN
108
109	! allocate space for tempory variables for the bias pressure correction (bpc)
110	ALLOCATE( z_rhd_st(jpi,jpj,jpk), &
111	& z_gru_st(jpi,jpj), &
112	& z_grv_st(jpi,jpj), &
113	& z_ua(jpi,jpj,jpk), &
114	& z_va(jpi,jpj,jpk), &
115	& z_ua_bpc(jpi,jpj,jpk), &
116	& z_va_bpc(jpi,jpj,jpk), &
117	& z_ua_bpc_bot(jpi,jpj), &
118	& z_va_bpc_bot(jpi,jpj) &
119	& )
120
121	! save the original acceleration trends
122	! (z_ua_bpc, z_va_bpc are used as temporary storage)
123	z_ua_bpc(:,:,:) = ua(:,:,:)
124	z_va_bpc(:,:,:) = va(:,:,:)
125
126	END IF
127
128	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
129	CASE ( 0 ) ; CALL hpg_zco ( kt ) ! z-coordinate
130	CASE ( 1 ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
131	CASE ( 2 ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
132	CASE ( 3 ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
133	CASE ( 4 ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
134	CASE ( 5 ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
135	END SELECT
136	!
137
138	IF ( ln_bias .AND. ln_bias_pc_app ) THEN
139
140	! The aim here is to calculate the contribution of the bpc to the acceleration terms.
141	! This is done so that the effect of the bpc on the hpg at the bottom can be removed.
142	! In order to do that:
143	! 1. The hpg calculation is done again, but with the contributions of the bpc included.
144	! 2. The difference between the acceleration terms (w and w/o bpc) is then calculated.
145	! 3. The effect of the bpc on the bottom hpg is then removed.
146	! 4. The total change to the acceleration terms is then calculated.
147
148	! The original density fields etc (without the bpc) are stored.
149	z_rhd_st(:,:,:) = rhd(:,:,:)
150	z_gru_st(:,:) = gru(:,:)
151	z_grv_st(:,:) = grv(:,:)
152
153	! Set the density etc used in the hpc calculations to the value including the effect of the bpc.
154	rhd(:,:,:) = rhd_pc(:,:,:)
155	gru(:,:) = gru_pc(:,:)
156	grv(:,:) = grv_pc(:,:)
157
158	! save the acceleration trends including hpg field but calculated without the bpc fields
159	z_ua(:,:,:) = ua(:,:,:)
160	z_va(:,:,:) = va(:,:,:)
161
162	! reset the acceleration trends to their original values
163	ua(:,:,:) = z_ua_bpc(:,:,:)
164	va(:,:,:) = z_va_bpc(:,:,:)
165
166	! re-calculate the horizontal pressure gradients with the bpc fields
167	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
168	CASE ( 0 ) ; CALL hpg_zco ( kt ) ! z-coordinate
169	CASE ( 1 ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
170	CASE ( 2 ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
171	CASE ( 3 ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
172	CASE ( 4 ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
173	CASE ( 5 ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
174	END SELECT
175
176	! calculate the bpc contribution to ua and va
177	z_ua_bpc(:,:,:) = ua(:,:,:) - z_ua(:,:,:)
178	z_va_bpc(:,:,:) = va(:,:,:) - z_va(:,:,:)
179
180	! calculate the bpc contribution to ua and va at the bottom
181	DO jj = 2, jpjm1
182	DO ji = 2, jpim1
183	iku = mbku(ji,jj)
184	ikv = mbkv(ji,jj)
185	z_ua_bpc_bot(ji,jj) = z_ua_bpc(ji,jj,iku)
186	z_va_bpc_bot(ji,jj) = z_va_bpc(ji,jj,ikv)
187	END DO ! ji
188	END DO ! jj
189
190	! subtract off the bottom values of bpc contribution to ua and va
191	DO jk = 1, jpk - 1
192	z_ua_bpc(:,:,jk) = z_ua_bpc(:,:,jk) - z_ua_bpc_bot(:,:)
193	z_va_bpc(:,:,jk) = z_va_bpc(:,:,jk) - z_va_bpc_bot(:,:)
194	END DO
195
196	! calculate ua using the original hpg (z_ua) and the bias hpg
197	! with the bottom pressure gradients subtracted off
198	ua(:,:,:) = z_ua(:,:,:) + z_ua_bpc(:,:,:)
199	va(:,:,:) = z_va(:,:,:) + z_va_bpc(:,:,:)
200
201	! restore original density, gru and grv fields
202	rhd(:,:,:) = z_rhd_st(:,:,:)
203	gru(:,:) = z_gru_st(:,:)
204	grv(:,:) = z_grv_st(:,:)
205
206	! deallocate tempory variables
207	DEALLOCATE( z_rhd_st, z_gru_st, z_grv_st, &
208	& z_ua, z_va, z_ua_bpc, z_va_bpc, &
209	& z_ua_bpc_bot, z_va_bpc_bot &
210	& )
211
212	ENDIF ! ln_bias .AND. ln_bias_pc_app
213
214
215	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
216	ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
217	ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
218	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
219	CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
220	ENDIF
221	!
222	IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg - Ua: ', mask1=umask, &
223	& tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
224	!
225	IF( nn_timing == 1 ) CALL timing_stop('dyn_hpg')
226	!
227	END SUBROUTINE dyn_hpg
228
229
230	SUBROUTINE dyn_hpg_init
231	!!----------------------------------------------------------------------
232	!! * ROUTINE dyn_hpg_init *
233	!!
234	!! ** Purpose : initializations for the hydrostatic pressure gradient
235	!! computation and consistency control
236	!!
237	!! ** Action : Read the namelist namdyn_hpg and check the consistency
238	!! with the type of vertical coordinate used (zco, zps, sco)
239	!!----------------------------------------------------------------------
240	INTEGER :: ioptio = 0 ! temporary integer
241	INTEGER :: ios ! Local integer output status for namelist read
242	!!
243	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
244	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
245	!!----------------------------------------------------------------------
246	!
247	REWIND( numnam_ref ) ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
248	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
249	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
250
251	REWIND( numnam_cfg ) ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
252	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
253	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
254	IF(lwm) WRITE ( numond, namdyn_hpg )
255	!
256	IF(lwp) THEN ! Control print
257	WRITE(numout,*)
258	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
259	WRITE(numout,*) '~~~~~~~~~~~~'
260	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
261	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
262	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
263	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
264	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
265	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
266	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
267	WRITE(numout,*) ' time stepping: centered (F) or semi-implicit (T) ln_dynhpg_imp = ', ln_dynhpg_imp
268	ENDIF
269	!
270	IF( ln_hpg_djc ) &
271	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
272	& currently disabled (bugs under investigation). Please select &
273	& either ln_hpg_sco or ln_hpg_prj instead')
274	!
275	IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
276	& CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
277	& the standard jacobian formulation hpg_sco or &
278	& the pressure jacobian formulation hpg_prj')
279
280	IF( ln_hpg_isf .AND. .NOT. ln_isfcav ) &
281	& CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
282	IF( .NOT. ln_hpg_isf .AND. ln_isfcav ) &
283	& CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
284	!
285	! ! Set nhpg from ln_hpg_... flags
286	IF( ln_hpg_zco ) nhpg = 0
287	IF( ln_hpg_zps ) nhpg = 1
288	IF( ln_hpg_sco ) nhpg = 2
289	IF( ln_hpg_djc ) nhpg = 3
290	IF( ln_hpg_prj ) nhpg = 4
291	IF( ln_hpg_isf ) nhpg = 5
292	!
293	! ! Consistency check
294	ioptio = 0
295	IF( ln_hpg_zco ) ioptio = ioptio + 1
296	IF( ln_hpg_zps ) ioptio = ioptio + 1
297	IF( ln_hpg_sco ) ioptio = ioptio + 1
298	IF( ln_hpg_djc ) ioptio = ioptio + 1
299	IF( ln_hpg_prj ) ioptio = ioptio + 1
300	IF( ln_hpg_isf ) ioptio = ioptio + 1
301	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
302	!
303	! initialisation of ice load
304	riceload(:,:)=0.0
305	!
306	END SUBROUTINE dyn_hpg_init
307
308
309	SUBROUTINE hpg_zco( kt )
310	!!---------------------------------------------------------------------
311	!! * ROUTINE hpg_zco *
312	!!
313	!! ** Method : z-coordinate case, levels are horizontal surfaces.
314	!! The now hydrostatic pressure gradient at a given level, jk,
315	!! is computed by taking the vertical integral of the in-situ
316	!! density gradient along the model level from the suface to that
317	!! level: zhpi = grav .....
318	!! zhpj = grav .....
319	!! add it to the general momentum trend (ua,va).
320	!! ua = ua - 1/e1u * zhpi
321	!! va = va - 1/e2v * zhpj
322	!!
323	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
324	!!----------------------------------------------------------------------
325	INTEGER, INTENT(in) :: kt ! ocean time-step index
326	!!
327	INTEGER :: ji, jj, jk ! dummy loop indices
328	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
329	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
330	!!----------------------------------------------------------------------
331	!
332	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
333	!
334	IF( kt == nit000 ) THEN
335	IF(lwp) WRITE(numout,*)
336	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
337	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
338	ENDIF
339
340	zcoef0 = - grav * 0.5_wp ! Local constant initialization
341
342	! Surface value
343	DO jj = 2, jpjm1
344	DO ji = fs_2, fs_jpim1 ! vector opt.
345	zcoef1 = zcoef0 * fse3w(ji,jj,1)
346	! hydrostatic pressure gradient
347	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
348	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
349	! add to the general momentum trend
350	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
351	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
352	END DO
353	END DO
354
355	!
356	! interior value (2=<jk=<jpkm1)
357	DO jk = 2, jpkm1
358	DO jj = 2, jpjm1
359	DO ji = fs_2, fs_jpim1 ! vector opt.
360	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
361	! hydrostatic pressure gradient
362	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
363	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
364	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
365
366	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
367	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
368	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
369	! add to the general momentum trend
370	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
371	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
372	END DO
373	END DO
374	END DO
375	!
376	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
377	!
378	END SUBROUTINE hpg_zco
379
380
381	SUBROUTINE hpg_zps( kt )
382	!!---------------------------------------------------------------------
383	!! * ROUTINE hpg_zps *
384	!!
385	!! ** Method : z-coordinate plus partial steps case. blahblah...
386	!!
387	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
388	!!----------------------------------------------------------------------
389	INTEGER, INTENT(in) :: kt ! ocean time-step index
390	!!
391	INTEGER :: ji, jj, jk ! dummy loop indices
392	INTEGER :: iku, ikv ! temporary integers
393	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
394	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
395	!!----------------------------------------------------------------------
396	!
397	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
398	!
399	IF( kt == nit000 ) THEN
400	IF(lwp) WRITE(numout,*)
401	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
402	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
403	ENDIF
404
405
406	! Local constant initialization
407	zcoef0 = - grav * 0.5_wp
408
409	! Surface value (also valid in partial step case)
410	DO jj = 2, jpjm1
411	DO ji = fs_2, fs_jpim1 ! vector opt.
412	zcoef1 = zcoef0 * fse3w(ji,jj,1)
413	! hydrostatic pressure gradient
414	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
415	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
416	! add to the general momentum trend
417	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
418	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
419	END DO
420	END DO
421
422
423	! interior value (2=<jk=<jpkm1)
424	DO jk = 2, jpkm1
425	DO jj = 2, jpjm1
426	DO ji = fs_2, fs_jpim1 ! vector opt.
427	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
428	! hydrostatic pressure gradient
429	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
430	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
431	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
432
433	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
434	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
435	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
436	! add to the general momentum trend
437	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
438	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
439	END DO
440	END DO
441	END DO
442
443
444	! partial steps correction at the last level (use gru & grv computed in zpshde.F90)
445	DO jj = 2, jpjm1
446	DO ji = 2, jpim1
447	iku = mbku(ji,jj)
448	ikv = mbkv(ji,jj)
449	zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj ,iku) )
450	zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji ,jj+1,ikv) )
451	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
452	ua (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) ! subtract old value
453	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
454	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
455	ua (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
456	ENDIF
457	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
458	va (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) ! subtract old value
459	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
460	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
461	va (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
462	ENDIF
463	END DO
464	END DO
465	!
466	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
467	!
468	END SUBROUTINE hpg_zps
469
470	SUBROUTINE hpg_sco( kt )
471	!!---------------------------------------------------------------------
472	!! * ROUTINE hpg_sco *
473	!!
474	!! ** Method : s-coordinate case. Jacobian scheme.
475	!! The now hydrostatic pressure gradient at a given level, jk,
476	!! is computed by taking the vertical integral of the in-situ
477	!! density gradient along the model level from the suface to that
478	!! level. s-coordinates (ln_sco): a corrective term is added
479	!! to the horizontal pressure gradient :
480	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
481	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
482	!! add it to the general momentum trend (ua,va).
483	!! ua = ua - 1/e1u * zhpi
484	!! va = va - 1/e2v * zhpj
485	!!
486	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
487	!!----------------------------------------------------------------------
488	INTEGER, INTENT(in) :: kt ! ocean time-step index
489	!!
490	INTEGER :: ji, jj, jk ! dummy loop indices
491	REAL(wp) :: zcoef0, zuap, zvap, znad ! temporary scalars
492	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
493	!!----------------------------------------------------------------------
494	!
495	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
496	!
497	IF( kt == nit000 ) THEN
498	IF(lwp) WRITE(numout,*)
499	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
500	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
501	ENDIF
502
503	! Local constant initialization
504	zcoef0 = - grav * 0.5_wp
505	! To use density and not density anomaly
506	IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
507	ELSE ; znad = 0._wp ! Fixed volume
508	ENDIF
509
510	! Surface value
511	DO jj = 2, jpjm1
512	DO ji = fs_2, fs_jpim1 ! vector opt.
513	! hydrostatic pressure gradient along s-surfaces
514	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj ,1) * ( znad + rhd(ji+1,jj ,1) ) &
515	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
516	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji ,jj+1,1) * ( znad + rhd(ji ,jj+1,1) ) &
517	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
518	! s-coordinate pressure gradient correction
519	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
520	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
521	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
522	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
523	! add to the general momentum trend
524	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
525	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
526	END DO
527	END DO
528
529	! interior value (2=<jk=<jpkm1)
530	DO jk = 2, jpkm1
531	DO jj = 2, jpjm1
532	DO ji = fs_2, fs_jpim1 ! vector opt.
533	! hydrostatic pressure gradient along s-surfaces
534	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
535	& * ( fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
536	& - fse3w(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
537	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
538	& * ( fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
539	& - fse3w(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
540	! s-coordinate pressure gradient correction
541	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
542	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
543	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
544	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
545	! add to the general momentum trend
546	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
547	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
548	END DO
549	END DO
550	END DO
551	!
552	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
553	!
554	END SUBROUTINE hpg_sco
555
556	SUBROUTINE hpg_isf( kt )
557	!!---------------------------------------------------------------------
558	!! * ROUTINE hpg_sco *
559	!!
560	!! ** Method : s-coordinate case. Jacobian scheme.
561	!! The now hydrostatic pressure gradient at a given level, jk,
562	!! is computed by taking the vertical integral of the in-situ
563	!! density gradient along the model level from the suface to that
564	!! level. s-coordinates (ln_sco): a corrective term is added
565	!! to the horizontal pressure gradient :
566	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
567	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
568	!! add it to the general momentum trend (ua,va).
569	!! ua = ua - 1/e1u * zhpi
570	!! va = va - 1/e2v * zhpj
571	!! iceload is added and partial cell case are added to the top and bottom
572	!!
573	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
574	!!----------------------------------------------------------------------
575	INTEGER, INTENT(in) :: kt ! ocean time-step index
576	!!
577	INTEGER :: ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j ! dummy loop indices
578	REAL(wp) :: zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1 ! temporary scalars
579	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj, zrhd
580	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztstop
581	REAL(wp), POINTER, DIMENSION(:,:) :: ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
582	!!----------------------------------------------------------------------
583	!
584	CALL wrk_alloc( jpi,jpj, 2, ztstop)
585	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
586	CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
587	!
588	IF( kt == nit000 ) THEN
589	IF(lwp) WRITE(numout,*)
590	IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
591	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
592	ENDIF
593
594	! Local constant initialization
595	zcoef0 = - grav * 0.5_wp
596	! To use density and not density anomaly
597	! IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
598	! ELSE ; znad = 0._wp ! Fixed volume
599	! ENDIF
600	znad=1._wp
601	! iniitialised to 0. zhpi zhpi
602	zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
603
604	!==================================================================================
605	!=====Compute iceload and contribution of the half first wet layer =================
606	!===================================================================================
607
608	! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
609	ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
610
611	! compute density of the water displaced by the ice shelf
612	zrhd = rhd ! save rhd
613	DO jk = 1, jpk
614	zdept(:,:)=gdept_1d(jk)
615	CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
616	END DO
617	WHERE ( tmask(:,:,:) == 1._wp)
618	rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
619	END WHERE
620
621	! compute rhd at the ice/oce interface (ice shelf side)
622	CALL eos(ztstop,risfdep,zrhdtop_isf)
623
624	! compute rhd at the ice/oce interface (ocean side)
625	DO ji=1,jpi
626	DO jj=1,jpj
627	ikt=mikt(ji,jj)
628	ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
629	ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
630	END DO
631	END DO
632	CALL eos(ztstop,risfdep,zrhdtop_oce)
633	!
634	! Surface value + ice shelf gradient
635	! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
636	ziceload = 0._wp
637	DO jj = 1, jpj
638	DO ji = 1, jpi ! vector opt.
639	ikt=mikt(ji,jj)
640	ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
641	DO jk=2,ikt-1
642	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
643	& * (1._wp - tmask(ji,jj,jk))
644	END DO
645	IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
646	& * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
647	END DO
648	END DO
649	riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:) ! need to be saved for diaar5
650	! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
651	DO jj = 2, jpjm1
652	DO ji = fs_2, fs_jpim1 ! vector opt.
653	ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
654	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
655	! we assume ISF is in isostatic equilibrium
656	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj ,iktp1i) &
657	& * ( 2._wp * znad + rhd(ji+1,jj ,iktp1i) + zrhdtop_oce(ji+1,jj ) ) &
658	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
659	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
660	& + ( ziceload(ji+1,jj) - ziceload(ji,jj)) )
661	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji ,jj+1,iktp1j) &
662	& * ( 2._wp * znad + rhd(ji ,jj+1,iktp1j) + zrhdtop_oce(ji ,jj+1) ) &
663	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
664	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
665	& + ( ziceload(ji,jj+1) - ziceload(ji,jj) ) )
666	! s-coordinate pressure gradient correction (=0 if z coordinate)
667	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
668	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
669	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
670	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
671	! add to the general momentum trend
672	ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
673	va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
674	END DO
675	END DO
676	!==================================================================================
677	!===== Compute partial cell contribution for the top cell =========================
678	!==================================================================================
679	DO jj = 2, jpjm1
680	DO ji = fs_2, fs_jpim1 ! vector opt.
681	iku = miku(ji,jj) ;
682	zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
683	ze3wu = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
684	! u direction
685	IF ( iku .GT. 1 ) THEN
686	! case iku
687	zhpi(ji,jj,iku) = zcoef0 / e1u(ji,jj) * ze3wu &
688	& * ( rhd (ji+1,jj,iku) + rhd (ji,jj,iku) &
689	& + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
690	! corrective term ( = 0 if z coordinate )
691	zuap = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
692	! zhpi will be added in interior loop
693	ua(ji,jj,iku) = ua(ji,jj,iku) + zuap
694	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
695	IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj) = zhpi(ji,jj,iku)
696
697	! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
698	zhpiint = zcoef0 / e1u(ji,jj) &
699	& * ( fse3w(ji+1,jj ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad) &
700	& + (rhd(ji+1,jj,iku ) + znad) ) * tmask(ji+1,jj,iku) &
701	& - fse3w(ji ,jj ,iku+1) * ( (rhd(ji ,jj,iku+1) + znad) &
702	& + (rhd(ji ,jj,iku ) + znad) ) * tmask(ji ,jj,iku) )
703	zhpi(ji,jj,iku+1) = zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint
704	END IF
705
706	! v direction
707	ikv = mikv(ji,jj)
708	ze3wv = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
709	IF ( ikv .GT. 1 ) THEN
710	! case ikv
711	zhpj(ji,jj,ikv) = zcoef0 / e2v(ji,jj) * ze3wv &
712	& * ( rhd(ji,jj+1,ikv) + rhd (ji,jj,ikv) &
713	& + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
714	! corrective term ( = 0 if z coordinate )
715	zvap = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
716	! zhpi will be added in interior loop
717	va(ji,jj,ikv) = va(ji,jj,ikv) + zvap
718	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
719	IF (mbkv(ji,jj) == ikv + 1) zpshpj(ji,jj) = zhpj(ji,jj,ikv)
720
721	! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
722	zhpjint = zcoef0 / e2v(ji,jj) &
723	& * ( fse3w(ji ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad) &
724	& + (rhd(ji,jj+1,ikv ) + znad) ) * tmask(ji,jj+1,ikv) &
725	& - fse3w(ji ,jj ,ikv+1) * ( (rhd(ji,jj ,ikv+1) + znad) &
726	& + (rhd(ji,jj ,ikv ) + znad) ) * tmask(ji,jj ,ikv) )
727	zhpj(ji,jj,ikv+1) = zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
728	END IF
729	END DO
730	END DO
731
732	!==================================================================================
733	!===== Compute interior value =====================================================
734	!==================================================================================
735
736	DO jj = 2, jpjm1
737	DO ji = fs_2, fs_jpim1 ! vector opt.
738	iku=miku(ji,jj); ikv=mikv(ji,jj)
739	DO jk = 2, jpkm1
740	! hydrostatic pressure gradient along s-surfaces
741	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
742	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1) &
743	& + zcoef0 / e1u(ji,jj) &
744	& * ( fse3w(ji+1,jj ,jk) * ( (rhd(ji+1,jj,jk ) + znad) &
745	& + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1) &
746	& - fse3w(ji ,jj ,jk) * ( (rhd(ji ,jj,jk ) + znad) &
747	& + (rhd(ji ,jj,jk-1) + znad) ) * tmask(ji ,jj,jk-1) )
748	! s-coordinate pressure gradient correction
749	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
750	zuap = - zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
751	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
752	ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
753
754	! hydrostatic pressure gradient along s-surfaces
755	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
756	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1) &
757	& + zcoef0 / e2v(ji,jj) &
758	& * ( fse3w(ji ,jj+1,jk) * ( (rhd(ji,jj+1,jk ) + znad) &
759	& + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1) &
760	& - fse3w(ji ,jj ,jk) * ( (rhd(ji,jj ,jk ) + znad) &
761	& + (rhd(ji,jj ,jk-1) + znad) ) * tmask(ji,jj ,jk-1) )
762	! s-coordinate pressure gradient correction
763	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
764	zvap = - zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
765	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
766	! add to the general momentum trend
767	va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
768	END DO
769	END DO
770	END DO
771
772	!==================================================================================
773	!===== Compute bottom cell contribution (partial cell) ============================
774	!==================================================================================
775
776	DO jj = 2, jpjm1
777	DO ji = 2, jpim1
778	iku = mbku(ji,jj)
779	ikv = mbkv(ji,jj)
780
781	IF (iku .GT. 1) THEN
782	! remove old value (interior case)
783	zuap = -zcoef0 * ( rhd (ji+1,jj ,iku) + rhd (ji,jj,iku) + 2._wp * znad ) &
784	& * ( fsde3w(ji+1,jj ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
785	ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
786	! put new value
787	! -zpshpi to avoid double contribution of the partial step in the top layer
788	zuap = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj) / e1u(ji,jj)
789	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj)
790	ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
791	END IF
792	! v direction
793	IF (ikv .GT. 1) THEN
794	! remove old value (interior case)
795	zvap = -zcoef0 * ( rhd (ji ,jj+1,ikv) + rhd (ji,jj,ikv) + 2._wp * znad ) &
796	& * ( fsde3w(ji ,jj+1,ikv) - fsde3w(ji,jj,ikv) ) / e2v(ji,jj)
797	va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
798	! put new value
799	! -zpshpj to avoid double contribution of the partial step in the top layer
800	zvap = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj) / e2v(ji,jj)
801	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)
802	va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
803	END IF
804	END DO
805	END DO
806
807	! set back to original density value into the ice shelf cell (maybe useless because it is masked)
808	rhd = zrhd
809	!
810	CALL wrk_dealloc( jpi,jpj,2, ztstop)
811	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
812	CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
813	!
814	END SUBROUTINE hpg_isf
815
816
817	SUBROUTINE hpg_djc( kt )
818	!!---------------------------------------------------------------------
819	!! * ROUTINE hpg_djc *
820	!!
821	!! ** Method : Density Jacobian with Cubic polynomial scheme
822	!!
823	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
824	!!----------------------------------------------------------------------
825	INTEGER, INTENT(in) :: kt ! ocean time-step index
826	!!
827	INTEGER :: ji, jj, jk ! dummy loop indices
828	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
829	REAL(wp) :: z1_10, cffu, cffx ! " "
830	REAL(wp) :: z1_12, cffv, cffy ! " "
831	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
832	REAL(wp), POINTER, DIMENSION(:,:,:) :: dzx, dzy, dzz, dzu, dzv, dzw
833	REAL(wp), POINTER, DIMENSION(:,:,:) :: drhox, drhoy, drhoz, drhou, drhov, drhow
834	REAL(wp), POINTER, DIMENSION(:,:,:) :: rho_i, rho_j, rho_k
835	!!----------------------------------------------------------------------
836	!
837	CALL wrk_alloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
838	CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
839	CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
840	!
841
842	IF( kt == nit000 ) THEN
843	IF(lwp) WRITE(numout,*)
844	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
845	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
846	ENDIF
847
848	! Local constant initialization
849	zcoef0 = - grav * 0.5_wp
850	z1_10 = 1._wp / 10._wp
851	z1_12 = 1._wp / 12._wp
852
853	!----------------------------------------------------------------------------------------
854	! compute and store in provisional arrays elementary vertical and horizontal differences
855	!----------------------------------------------------------------------------------------
856
857	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
858
859	DO jk = 2, jpkm1
860	DO jj = 2, jpjm1
861	DO ji = fs_2, fs_jpim1 ! vector opt.
862	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
863	dzz (ji,jj,jk) = fsde3w(ji ,jj ,jk) - fsde3w(ji,jj,jk-1)
864	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
865	dzx (ji,jj,jk) = fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk )
866	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
867	dzy (ji,jj,jk) = fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk )
868	END DO
869	END DO
870	END DO
871
872	!-------------------------------------------------------------------------
873	! compute harmonic averages using eq. 5.18
874	!-------------------------------------------------------------------------
875	zep = 1.e-15
876
877	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
878	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
879
880	DO jk = 2, jpkm1
881	DO jj = 2, jpjm1
882	DO ji = fs_2, fs_jpim1 ! vector opt.
883	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
884
885	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
886	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
887
888	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
889	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
890
891	IF( cffw > zep) THEN
892	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
893	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
894	ELSE
895	drhow(ji,jj,jk) = 0._wp
896	ENDIF
897
898	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
899	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
900
901	IF( cffu > zep ) THEN
902	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
903	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
904	ELSE
905	drhou(ji,jj,jk ) = 0._wp
906	ENDIF
907
908	IF( cffx > zep ) THEN
909	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
910	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
911	ELSE
912	dzu(ji,jj,jk) = 0._wp
913	ENDIF
914
915	IF( cffv > zep ) THEN
916	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
917	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
918	ELSE
919	drhov(ji,jj,jk) = 0._wp
920	ENDIF
921
922	IF( cffy > zep ) THEN
923	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
924	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
925	ELSE
926	dzv(ji,jj,jk) = 0._wp
927	ENDIF
928
929	END DO
930	END DO
931	END DO
932
933	!----------------------------------------------------------------------------------
934	! apply boundary conditions at top and bottom using 5.36-5.37
935	!----------------------------------------------------------------------------------
936	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
937	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
938	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
939
940	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
941	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
942	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
943
944
945	!--------------------------------------------------------------
946	! Upper half of top-most grid box, compute and store
947	!-------------------------------------------------------------
948
949	!!bug gm : e3w-de3w = 0.5*e3w .... and de3w(2)-de3w(1)=e3w(2) .... to be verified
950	! true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
951
952	DO jj = 2, jpjm1
953	DO ji = fs_2, fs_jpim1 ! vector opt.
954	rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) ) &
955	& * ( rhd(ji,jj,1) &
956	& + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) ) &
957	& * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) ) &
958	& / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) ) )
959	END DO
960	END DO
961
962	!!bug gm : here also, simplification is possible
963	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
964
965	DO jk = 2, jpkm1
966	DO jj = 2, jpjm1
967	DO ji = fs_2, fs_jpim1 ! vector opt.
968
969	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
970	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) ) &
971	& - grav * z1_10 * ( &
972	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
973	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
974	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
975	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
976	& )
977
978	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
979	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) ) &
980	& - grav* z1_10 * ( &
981	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
982	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
983	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
984	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
985	& )
986
987	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
988	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) ) &
989	& - grav* z1_10 * ( &
990	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
991	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
992	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
993	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
994	& )
995
996	END DO
997	END DO
998	END DO
999	CALL lbc_lnk(rho_k,'W',1.)
1000	CALL lbc_lnk(rho_i,'U',1.)
1001	CALL lbc_lnk(rho_j,'V',1.)
1002
1003
1004	! ---------------
1005	! Surface value
1006	! ---------------
1007	DO jj = 2, jpjm1
1008	DO ji = fs_2, fs_jpim1 ! vector opt.
1009	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
1010	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
1011	! add to the general momentum trend
1012	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
1013	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
1014	END DO
1015	END DO
1016
1017	! ----------------
1018	! interior value (2=<jk=<jpkm1)
1019	! ----------------
1020	DO jk = 2, jpkm1
1021	DO jj = 2, jpjm1
1022	DO ji = fs_2, fs_jpim1 ! vector opt.
1023	! hydrostatic pressure gradient along s-surfaces
1024	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
1025	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
1026	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) / e1u(ji,jj)
1027	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
1028	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
1029	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) / e2v(ji,jj)
1030	! add to the general momentum trend
1031	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
1032	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
1033	END DO
1034	END DO
1035	END DO
1036	!
1037	CALL wrk_dealloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
1038	CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
1039	CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
1040	!
1041	END SUBROUTINE hpg_djc
1042
1043
1044	SUBROUTINE hpg_prj( kt )
1045	!!---------------------------------------------------------------------
1046	!! * ROUTINE hpg_prj *
1047	!!
1048	!! ** Method : s-coordinate case.
1049	!! A Pressure-Jacobian horizontal pressure gradient method
1050	!! based on the constrained cubic-spline interpolation for
1051	!! all vertical coordinate systems
1052	!!
1053	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
1054	!!----------------------------------------------------------------------
1055	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
1056	INTEGER, INTENT(in) :: kt ! ocean time-step index
1057	!!
1058	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
1059	REAL(wp) :: zcoef0, znad ! temporary scalars
1060	!!
1061	!! The local variables for the correction term
1062	INTEGER :: jk1, jis, jid, jjs, jjd
1063	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
1064	REAL(wp) :: zrhdt1
1065	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
1066	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdept, zrhh
1067	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
1068	REAL(wp), POINTER, DIMENSION(:,:) :: zsshu_n, zsshv_n
1069	!!----------------------------------------------------------------------
1070	!
1071	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1072	CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
1073	CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
1074	!
1075	IF( kt == nit000 ) THEN
1076	IF(lwp) WRITE(numout,*)
1077	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
1078	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
1079	ENDIF
1080
1081	!!----------------------------------------------------------------------
1082	! Local constant initialization
1083	zcoef0 = - grav
1084	znad = 0.0_wp
1085	IF( lk_vvl ) znad = 1._wp
1086
1087	! Clean 3-D work arrays
1088	zhpi(:,:,:) = 0._wp
1089	zrhh(:,:,:) = rhd(:,:,:)
1090
1091	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1092	DO jj = 1, jpj
1093	DO ji = 1, jpi
1094	jk = mbathy(ji,jj)
1095	IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1096	ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1097	ELSE IF(jk < jpkm1) THEN
1098	DO jkk = jk+1, jpk
1099	zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk), fsde3w(ji,jj,jkk-1), &
1100	fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1101	END DO
1102	ENDIF
1103	END DO
1104	END DO
1105
1106	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1107	DO jj = 1, jpj
1108	DO ji = 1, jpi
1109	zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1110	END DO
1111	END DO
1112
1113	DO jk = 2, jpk
1114	DO jj = 1, jpj
1115	DO ji = 1, jpi
1116	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1117	END DO
1118	END DO
1119	END DO
1120
1121	fsp(:,:,:) = zrhh (:,:,:)
1122	xsp(:,:,:) = zdept(:,:,:)
1123
1124	! Construct the vertical density profile with the
1125	! constrained cubic spline interpolation
1126	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1127	CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1128
1129	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1130	DO jj = 2, jpj
1131	DO ji = 2, jpi
1132	zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1133	bsp(ji,jj,1), csp(ji,jj,1), &
1134	dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1135
1136	! assuming linear profile across the top half surface layer
1137	zhpi(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) * zrhdt1
1138	END DO
1139	END DO
1140
1141	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1142	DO jk = 2, jpkm1
1143	DO jj = 2, jpj
1144	DO ji = 2, jpi
1145	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1146	integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1147	asp(ji,jj,jk-1), bsp(ji,jj,jk-1), &
1148	csp(ji,jj,jk-1), dsp(ji,jj,jk-1))
1149	END DO
1150	END DO
1151	END DO
1152
1153	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1154
1155	! Prepare zsshu_n and zsshv_n
1156	DO jj = 2, jpjm1
1157	DO ji = 2, jpim1
1158	zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1159	& r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1160	zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1161	& r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1162	END DO
1163	END DO
1164
1165	DO jj = 2, jpjm1
1166	DO ji = 2, jpim1
1167	zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad)
1168	zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1169	END DO
1170	END DO
1171
1172	DO jk = 2, jpkm1
1173	DO jj = 2, jpjm1
1174	DO ji = 2, jpim1
1175	zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1176	zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1177	END DO
1178	END DO
1179	END DO
1180
1181	DO jk = 1, jpkm1
1182	DO jj = 2, jpjm1
1183	DO ji = 2, jpim1
1184	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1185	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1186	END DO
1187	END DO
1188	END DO
1189
1190	DO jk = 1, jpkm1
1191	DO jj = 2, jpjm1
1192	DO ji = 2, jpim1
1193	zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1194	zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1195	zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1196	zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1197	END DO
1198	END DO
1199	END DO
1200
1201
1202	DO jk = 1, jpkm1
1203	DO jj = 2, jpjm1
1204	DO ji = 2, jpim1
1205	zpwes = 0._wp; zpwed = 0._wp
1206	zpnss = 0._wp; zpnsd = 0._wp
1207	zuijk = zu(ji,jj,jk)
1208	zvijk = zv(ji,jj,jk)
1209
1210	!!!!! for u equation
1211	IF( jk <= mbku(ji,jj) ) THEN
1212	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1213	jis = ji + 1; jid = ji
1214	ELSE
1215	jis = ji; jid = ji +1
1216	ENDIF
1217
1218	! integrate the pressure on the shallow side
1219	jk1 = jk
1220	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1221	IF( jk1 == mbku(ji,jj) ) THEN
1222	zuijk = -zdept(jis,jj,jk1)
1223	EXIT
1224	ENDIF
1225	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1226	zpwes = zpwes + &
1227	integ_spline(zdept(jis,jj,jk1), zdeps, &
1228	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1229	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1230	jk1 = jk1 + 1
1231	END DO
1232
1233	! integrate the pressure on the deep side
1234	jk1 = jk
1235	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1236	IF( jk1 == 1 ) THEN
1237	zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1238	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1239	bsp(jid,jj,1), csp(jid,jj,1), &
1240	dsp(jid,jj,1)) * zdeps
1241	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1242	EXIT
1243	ENDIF
1244	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1245	zpwed = zpwed + &
1246	integ_spline(zdeps, zdept(jid,jj,jk1), &
1247	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1248	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1249	jk1 = jk1 - 1
1250	END DO
1251
1252	! update the momentum trends in u direction
1253
1254	zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1255	IF( lk_vvl ) THEN
1256	zdpdx2 = zcoef0 / e1u(ji,jj) * &
1257	( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1258	ELSE
1259	zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1260	ENDIF
1261
1262	ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1263	& umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1264	ENDIF
1265
1266	!!!!! for v equation
1267	IF( jk <= mbkv(ji,jj) ) THEN
1268	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1269	jjs = jj + 1; jjd = jj
1270	ELSE
1271	jjs = jj ; jjd = jj + 1
1272	ENDIF
1273
1274	! integrate the pressure on the shallow side
1275	jk1 = jk
1276	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1277	IF( jk1 == mbkv(ji,jj) ) THEN
1278	zvijk = -zdept(ji,jjs,jk1)
1279	EXIT
1280	ENDIF
1281	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1282	zpnss = zpnss + &
1283	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1284	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1285	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1286	jk1 = jk1 + 1
1287	END DO
1288
1289	! integrate the pressure on the deep side
1290	jk1 = jk
1291	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1292	IF( jk1 == 1 ) THEN
1293	zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1294	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1295	bsp(ji,jjd,1), csp(ji,jjd,1), &
1296	dsp(ji,jjd,1) ) * zdeps
1297	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1298	EXIT
1299	ENDIF
1300	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1301	zpnsd = zpnsd + &
1302	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1303	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1304	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1305	jk1 = jk1 - 1
1306	END DO
1307
1308
1309	! update the momentum trends in v direction
1310
1311	zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1312	IF( lk_vvl ) THEN
1313	zdpdy2 = zcoef0 / e2v(ji,jj) * &
1314	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1315	ELSE
1316	zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1317	ENDIF
1318
1319	va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1320	& vmask(ji,jj,jk)tmask(ji,jj,jk)tmask(ji,jj+1,jk)
1321	ENDIF
1322
1323
1324	END DO
1325	END DO
1326	END DO
1327	!
1328	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1329	CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1330	CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1331	!
1332	END SUBROUTINE hpg_prj
1333
1334
1335	SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1336	!!----------------------------------------------------------------------
1337	!! * ROUTINE cspline *
1338	!!
1339	!! ** Purpose : constrained cubic spline interpolation
1340	!!
1341	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1342	!!
1343	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1344	!!----------------------------------------------------------------------
1345	IMPLICIT NONE
1346	REAL(wp), DIMENSION(:,:,:), INTENT(in) :: fsp, xsp ! value and coordinate
1347	REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1348	! the interpoated function
1349	INTEGER, INTENT(in) :: polynomial_type ! 1: cubic spline
1350	! 2: Linear
1351	!
1352	INTEGER :: ji, jj, jk ! dummy loop indices
1353	INTEGER :: jpi, jpj, jpkm1
1354	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1355	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1356	REAL(wp) :: zdf(size(fsp,3))
1357	!!----------------------------------------------------------------------
1358
1359	jpi = size(fsp,1)
1360	jpj = size(fsp,2)
1361	jpkm1 = size(fsp,3) - 1
1362
1363
1364	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1365	DO ji = 1, jpi
1366	DO jj = 1, jpj
1367	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1368	! DO jk = 2, jpkm1-1
1369	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1370	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1371	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1372	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1373	!
1374	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1375	!
1376	! IF(zdf1 * zdf2 <= 0._wp) THEN
1377	! zdf(jk) = 0._wp
1378	! ELSE
1379	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1380	! ENDIF
1381	! END DO
1382
1383	!!Simply geometric average
1384	DO jk = 2, jpkm1-1
1385	zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1386	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1387
1388	IF(zdf1 * zdf2 <= 0._wp) THEN
1389	zdf(jk) = 0._wp
1390	ELSE
1391	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1392	ENDIF
1393	END DO
1394
1395	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1396	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1397	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1398	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1399	& 0.5_wp * zdf(jpkm1 - 1)
1400
1401	DO jk = 1, jpkm1 - 1
1402	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1403	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1404	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1405	zddf1 = -2._wp * ztmp1 + ztmp2
1406	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1407	zddf2 = 2._wp * ztmp1 - ztmp2
1408
1409	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1410	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1411	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1412	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1413	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1414	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1415	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1416	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1417	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1418	END DO
1419	END DO
1420	END DO
1421
1422	ELSE IF (polynomial_type == 2) THEN ! Linear
1423	DO ji = 1, jpi
1424	DO jj = 1, jpj
1425	DO jk = 1, jpkm1-1
1426	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1427	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1428
1429	dsp(ji,jj,jk) = 0._wp
1430	csp(ji,jj,jk) = 0._wp
1431	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1432	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1433	END DO
1434	END DO
1435	END DO
1436
1437	ELSE
1438	CALL ctl_stop( 'invalid polynomial type in cspline' )
1439	ENDIF
1440
1441	END SUBROUTINE cspline
1442
1443
1444	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1445	!!----------------------------------------------------------------------
1446	!! * ROUTINE interp1 *
1447	!!
1448	!! ** Purpose : 1-d linear interpolation
1449	!!
1450	!! ** Method : interpolation is straight forward
1451	!! extrapolation is also permitted (no value limit)
1452	!!----------------------------------------------------------------------
1453	IMPLICIT NONE
1454	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1455	REAL(wp) :: f ! result of the interpolation (extrapolation)
1456	REAL(wp) :: zdeltx
1457	!!----------------------------------------------------------------------
1458
1459	zdeltx = xr - xl
1460	IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1461	f = 0.5_wp * (fl + fr)
1462	ELSE
1463	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1464	ENDIF
1465
1466	END FUNCTION interp1
1467
1468
1469	FUNCTION interp2(x, a, b, c, d) RESULT(f)
1470	!!----------------------------------------------------------------------
1471	!! * ROUTINE interp1 *
1472	!!
1473	!! ** Purpose : 1-d constrained cubic spline interpolation
1474	!!
1475	!! ** Method : cubic spline interpolation
1476	!!
1477	!!----------------------------------------------------------------------
1478	IMPLICIT NONE
1479	REAL(wp), INTENT(in) :: x, a, b, c, d
1480	REAL(wp) :: f ! value from the interpolation
1481	!!----------------------------------------------------------------------
1482
1483	f = a + x* ( b + x * ( c + d * x ) )
1484
1485	END FUNCTION interp2
1486
1487
1488	FUNCTION interp3(x, a, b, c, d) RESULT(f)
1489	!!----------------------------------------------------------------------
1490	!! * ROUTINE interp1 *
1491	!!
1492	!! ** Purpose : Calculate the first order of deriavtive of
1493	!! a cubic spline function y=a+bx+cx^2+d*x^3
1494	!!
1495	!! ** Method : f=dy/dx=b+2cx+3dx^2
1496	!!
1497	!!----------------------------------------------------------------------
1498	IMPLICIT NONE
1499	REAL(wp), INTENT(in) :: x, a, b, c, d
1500	REAL(wp) :: f ! value from the interpolation
1501	!!----------------------------------------------------------------------
1502
1503	f = b + x * ( 2._wp * c + 3._wp * d * x)
1504
1505	END FUNCTION interp3
1506
1507
1508	FUNCTION integ_spline(xl, xr, a, b, c, d) RESULT(f)
1509	!!----------------------------------------------------------------------
1510	!! * ROUTINE interp1 *
1511	!!
1512	!! ** Purpose : 1-d constrained cubic spline integration
1513	!!
1514	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1515	!!
1516	!!----------------------------------------------------------------------
1517	IMPLICIT NONE
1518	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1519	REAL(wp) :: za1, za2, za3
1520	REAL(wp) :: f ! integration result
1521	!!----------------------------------------------------------------------
1522
1523	za1 = 0.5_wp * b
1524	za2 = c / 3.0_wp
1525	za3 = 0.25_wp * d
1526
1527	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1528	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1529
1530	END FUNCTION integ_spline
1531
1532	!!======================================================================
1533	END MODULE dynhpg
1534

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/dev_r5518_GO6_package_FOAMv14/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 11556

Download in other formats: