New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in branches/UKMO/dev_r5518_GO6_package_FOAMv14_STOPACK/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/dev_r5518_GO6_package_FOAMv14_STOPACK/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 11394

Last change on this file since 11394 was 11394, checked in by mattmartin, 5 years ago

First implementation of STOPACK in the GO6 package branch.
File size: 29.2 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf      : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init : runoffs initialisation
16   !!   rnf_mouth    : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce         ! ocean space and time domain
19   USE phycst          ! physical constants
20   USE sbc_oce         ! surface boundary condition variables
21   USE sbcisf          ! PM we could remove it I think
22   USE closea          ! closed seas
23   USE fldread         ! read input field at current time step
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O module
26   USE lib_mpp         ! MPP library
27   USE eosbn2
28   USE wrk_nemo        ! Memory allocation
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   sbc_rnf       ! routine call in sbcmod module
34   PUBLIC   sbc_rnf_div   ! routine called in divcurl module
35   PUBLIC   sbc_rnf_alloc ! routine call in sbcmod module
36   PUBLIC   sbc_rnf_init  ! (PUBLIC for TAM)
37   !                                                     !!* namsbc_rnf namelist *
38   CHARACTER(len=100)         ::   cn_dir          !: Root directory for location of rnf files
39   LOGICAL                    ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
40   LOGICAL                    ::   ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
41   REAL(wp)                   ::   rn_rnf_max        !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
42   REAL(wp)                   ::   rn_dep_max        !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
43   INTEGER                    ::   nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44   LOGICAL                    ::   ln_rnf_tem      !: temperature river runoffs attribute specified in a file
45   LOGICAL           , PUBLIC ::   ln_rnf_sal      !: salinity    river runoffs attribute specified in a file
46   TYPE(FLD_N)       , PUBLIC ::   sn_rnf          !: information about the runoff file to be read
47   TYPE(FLD_N)                ::   sn_cnf          !: information about the runoff mouth file to be read
48   TYPE(FLD_N)                ::   sn_s_rnf        !: information about the salinities of runoff file to be read
49   TYPE(FLD_N)                ::   sn_t_rnf        !: information about the temperatures of runoff file to be read
50   TYPE(FLD_N)                ::   sn_dep_rnf      !: information about the depth which river inflow affects
51   LOGICAL           , PUBLIC ::   ln_rnf_mouth    !: specific treatment in mouths vicinity
52   REAL(wp)                   ::   rn_hrnf         !: runoffs, depth over which enhanced vertical mixing is used
53   REAL(wp)          , PUBLIC ::   rn_avt_rnf      !: runoffs, value of the additional vertical mixing coef. [m2/s]
54   REAL(wp)          , PUBLIC ::   rn_rfact        !: multiplicative factor for runoff
55   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rn_avt_rnf0
56
57   LOGICAL           , PUBLIC ::   l_rnfcpl = .false.       ! runoffs recieved from oasis
58
59   INTEGER , PUBLIC  ::   nkrnf = 0         !: nb of levels over which Kz is increased at river mouths
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
63   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
64   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
65
66   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
67   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
68   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
69 
70   !! * Substitutions 
71#  include "domzgr_substitute.h90" 
72   !!----------------------------------------------------------------------
73   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
74   !! $Id$
75   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
76   !!----------------------------------------------------------------------
77CONTAINS
78
79   INTEGER FUNCTION sbc_rnf_alloc()
80      !!----------------------------------------------------------------------
81      !!                ***  ROUTINE sbc_rnf_alloc  ***
82      !!----------------------------------------------------------------------
83      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
84         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
85         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
86         !
87      IF( lk_mpp            )   CALL mpp_sum ( sbc_rnf_alloc )
88      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
89   END FUNCTION sbc_rnf_alloc
90
91
92   SUBROUTINE sbc_rnf( kt )
93      !!----------------------------------------------------------------------
94      !!                  ***  ROUTINE sbc_rnf  ***
95      !!
96      !! ** Purpose :   Introduce a climatological run off forcing
97      !!
98      !! ** Method  :   Set each river mouth with a monthly climatology
99      !!                provided from different data.
100      !!                CAUTION : upward water flux, runoff forced to be < 0
101      !!
102      !! ** Action  :   runoff updated runoff field at time-step kt
103      !!----------------------------------------------------------------------
104      INTEGER, INTENT(in) ::   kt          ! ocean time step
105      !
106      INTEGER  ::   ji, jj    ! dummy loop indices
107      INTEGER  ::   z_err = 0 ! dummy integer for error handling
108      !!----------------------------------------------------------------------
109      REAL(wp), DIMENSION(:,:), POINTER       ::   ztfrz   ! freezing point used for temperature correction
110      !
111      CALL wrk_alloc( jpi,jpj, ztfrz)
112      !
113      !                                            !-------------------!
114      !                                            !   Update runoff   !
115      !                                            !-------------------!
116      !
117      IF( .NOT. l_rnfcpl )   CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt
118      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
119      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
120      !
121      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
122         !
123         IF( .NOT. l_rnfcpl )   rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) )       ! updated runoff value at time step kt
124         CALL lbc_lnk(rnf(:,:), 'T', 1._wp)
125         !
126         !                                                     ! set temperature & salinity content of runoffs
127         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
128            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
129            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
130               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
131            END WHERE
132            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp )             ! where fwf comes from melting of ice shelves or iceberg
133               ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
134               rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
135            END WHERE
136         ELSE                                                        ! use SST as runoffs temperature
137            rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
138         ENDIF
139         !                                                           ! use runoffs salinity data
140         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
141         !                                                           ! else use S=0 for runoffs (done one for all in the init)
142         CALL iom_put( "runoffs", rnf )         ! output runoffs arrays
143      ENDIF
144      !
145      !                                                ! ---------------------------------------- !
146      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
147         !                                             ! ---------------------------------------- !
148         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
149            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
150            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file'
151            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b )     ! before runoff
152            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) )   ! before heat content of runoff
153            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) )   ! before salinity content of runoff
154         ELSE                                                   !* no restart: set from nit000 values
155            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
156            rnf_b    (:,:  ) = rnf    (:,:  )
157            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
158         ENDIF
159      ENDIF
160      !                                                ! ---------------------------------------- !
161      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
162         !                                             ! ---------------------------------------- !
163         IF(lwp) WRITE(numout,*)
164         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
165            &                    'at it= ', kt,' date= ', ndastp
166         IF(lwp) WRITE(numout,*) '~~~~'
167         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
168         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
169         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
170      ENDIF
171      !
172      CALL wrk_dealloc( jpi,jpj, ztfrz)
173      !
174   END SUBROUTINE sbc_rnf
175
176
177   SUBROUTINE sbc_rnf_div( phdivn )
178      !!----------------------------------------------------------------------
179      !!                  ***  ROUTINE sbc_rnf  ***
180      !!
181      !! ** Purpose :   update the horizontal divergence with the runoff inflow
182      !!
183      !! ** Method  :
184      !!                CAUTION : rnf is positive (inflow) decreasing the
185      !!                          divergence and expressed in m/s
186      !!
187      !! ** Action  :   phdivn   decreased by the runoff inflow
188      !!----------------------------------------------------------------------
189      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
190      !!
191      INTEGER  ::   ji, jj, jk   ! dummy loop indices
192      REAL(wp) ::   zfact     ! local scalar
193      !!----------------------------------------------------------------------
194      !
195      zfact = 0.5_wp
196      !
197      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
198         IF( lk_vvl ) THEN             ! variable volume case
199            DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
200               DO ji = 1, jpi
201                  h_rnf(ji,jj) = 0._wp
202                  DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
203                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)   ! to the bottom of the relevant grid box
204                  END DO
205                  !                          ! apply the runoff input flow
206                  DO jk = 1, nk_rnf(ji,jj)
207                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
208                  END DO
209               END DO
210            END DO
211         ELSE                          ! constant volume case : just apply the runoff input flow
212            DO jj = 1, jpj
213               DO ji = 1, jpi
214                  DO jk = 1, nk_rnf(ji,jj)
215                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
216                  END DO
217               END DO
218            END DO
219         ENDIF
220      ELSE                       !==   runoff put only at the surface   ==!
221         IF( lk_vvl ) THEN              ! variable volume case
222            h_rnf(:,:) = fse3t(:,:,1)   ! recalculate h_rnf to be depth of top box
223         ENDIF
224         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
225      ENDIF
226      !
227   END SUBROUTINE sbc_rnf_div
228
229
230   SUBROUTINE sbc_rnf_init
231      !!----------------------------------------------------------------------
232      !!                  ***  ROUTINE sbc_rnf_init  ***
233      !!
234      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
235      !!
236      !! ** Method  : - read the runoff namsbc_rnf namelist
237      !!
238      !! ** Action  : - read parameters
239      !!----------------------------------------------------------------------
240      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
241      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
242      INTEGER           ::   ierror, inum  ! temporary integer
243      INTEGER           ::   ios           ! Local integer output status for namelist read
244      INTEGER           ::   nbrec         ! temporary integer
245      REAL(wp)          ::   zacoef 
246      REAL(wp), DIMENSION(12)                 :: zrec             ! times records
247      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl   
248      REAL(wp), DIMENSION(:,:  ), ALLOCATABLE :: zrnf
249      !
250      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal,   &
251         &                 sn_rnf, sn_cnf    , sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
252         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
253         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
254      !!----------------------------------------------------------------------
255      !
256      !                                         !==  allocate runoff arrays
257      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
258      !
259      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
260         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
261         nkrnf         = 0
262         rnf     (:,:) = 0.0_wp
263         rnf_b   (:,:) = 0.0_wp
264         rnfmsk  (:,:) = 0.0_wp
265         rnfmsk_z(:)   = 0.0_wp
266         RETURN
267      ENDIF
268      !
269      !                                   ! ============
270      !                                   !   Namelist
271      !                                   ! ============
272      !
273      REWIND( numnam_ref )              ! Namelist namsbc_rnf in reference namelist : Runoffs
274      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
275901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
276
277      REWIND( numnam_cfg )              ! Namelist namsbc_rnf in configuration namelist : Runoffs
278      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
279902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
280      IF(lwm) WRITE ( numond, namsbc_rnf )
281      !
282      !                                         ! Control print
283      IF(lwp) THEN
284         WRITE(numout,*)
285         WRITE(numout,*) 'sbc_rnf : runoff '
286         WRITE(numout,*) '~~~~~~~ '
287         WRITE(numout,*) '   Namelist namsbc_rnf'
288         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
289         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
290         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
291         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
292      ENDIF
293      !                                   ! ==================
294      !                                   !   Type of runoff
295      !                                   ! ==================
296      !
297      IF( .NOT. l_rnfcpl ) THEN                   
298         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
299         IF(lwp) WRITE(numout,*)
300         IF(lwp) WRITE(numout,*) '          runoffs inflow read in a file'
301         IF( ierror > 0 ) THEN
302            CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' )   ;   RETURN
303         ENDIF
304         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
305         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
306         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
307      ENDIF
308      !
309      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
310         IF(lwp) WRITE(numout,*)
311         IF(lwp) WRITE(numout,*) '          runoffs temperatures read in a file'
312         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
313         IF( ierror > 0 ) THEN
314            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
315         ENDIF
316         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
317         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
318         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
319      ENDIF
320      !
321      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
322         IF(lwp) WRITE(numout,*)
323         IF(lwp) WRITE(numout,*) '          runoffs salinities read in a file'
324         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
325         IF( ierror > 0 ) THEN
326            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
327         ENDIF
328         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
329         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
330         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
331      ENDIF
332      !
333      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
334         IF(lwp) WRITE(numout,*)
335         IF(lwp) WRITE(numout,*) '          runoffs depth read in a file'
336         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
337         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
338            IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
339         ENDIF
340         CALL iom_open ( rn_dep_file, inum )                           ! open file
341         CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
342         CALL iom_close( inum )                                        ! close file
343         !
344         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
345         DO jj = 1, jpj
346            DO ji = 1, jpi
347               IF( h_rnf(ji,jj) > 0._wp ) THEN
348                  jk = 2
349                  DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
350                  END DO
351                  nk_rnf(ji,jj) = jk
352               ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
353               ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
354               ELSE
355                  CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
356                  WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
357               ENDIF
358            END DO
359         END DO
360         DO jj = 1, jpj                                ! set the associated depth
361            DO ji = 1, jpi
362               h_rnf(ji,jj) = 0._wp
363               DO jk = 1, nk_rnf(ji,jj)
364                  h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
365               END DO
366            END DO
367         END DO
368         !
369      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
370         !
371         IF(lwp) WRITE(numout,*)
372         IF(lwp) WRITE(numout,*) '    depth of runoff computed once from max value of runoff'
373         IF(lwp) WRITE(numout,*) '    max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
374         IF(lwp) WRITE(numout,*) '    depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
375         IF(lwp) WRITE(numout,*) '     create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
376
377         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
378         CALL iom_gettime( inum, zrec, kntime=nbrec)
379         ALLOCATE( zrnfcl(jpi,jpj,nbrec) )     ;      ALLOCATE( zrnf(jpi,jpj) )
380         DO jm = 1, nbrec
381            CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
382         END DO
383         CALL iom_close( inum )
384         zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 )   !  maximum value in time
385         DEALLOCATE( zrnfcl )
386         !
387         h_rnf(:,:) = 1.
388         !
389         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
390         !
391         WHERE( zrnf(:,:) > 0._wp )  h_rnf(:,:) = zacoef * zrnf(:,:)   ! compute depth for all runoffs
392         !
393         DO jj = 1, jpj                     ! take in account min depth of ocean rn_hmin
394            DO ji = 1, jpi
395               IF( zrnf(ji,jj) > 0._wp ) THEN
396                  jk = mbkt(ji,jj)
397                  h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
398               ENDIF
399            END DO
400         END DO
401         !
402         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
403         DO jj = 1, jpj
404            DO ji = 1, jpi
405               IF( zrnf(ji,jj) > 0._wp ) THEN
406                  jk = 2
407                  DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
408                  END DO
409                  nk_rnf(ji,jj) = jk
410               ELSE
411                  nk_rnf(ji,jj) = 1
412               ENDIF
413            END DO
414         END DO
415         !
416         DEALLOCATE( zrnf )
417         !
418         DO jj = 1, jpj                                ! set the associated depth
419            DO ji = 1, jpi
420               h_rnf(ji,jj) = 0._wp
421               DO jk = 1, nk_rnf(ji,jj)
422                  h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
423               END DO
424            END DO
425         END DO
426         !
427         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
428            IF(lwp) WRITE(numout,*) '              create runoff depht file'
429            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
430            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
431            CALL iom_close ( inum )
432         ENDIF
433      ELSE                                       ! runoffs applied at the surface
434         nk_rnf(:,:) = 1
435         h_rnf (:,:) = fse3t(:,:,1)
436      ENDIF
437      !
438      rnf(:,:) =  0._wp                         ! runoff initialisation
439      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
440      !
441      !                                   ! ========================
442      !                                   !   River mouth vicinity
443      !                                   ! ========================
444      !
445      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
446         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
447         !                                      !    - set to zero SSS damping (ln_ssr=T)
448         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
449         !
450         ALLOCATE ( rn_avt_rnf0(jpi,jpj) )
451         rn_avt_rnf0(:,:) = rn_avt_rnf
452         !
453         IF ( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
454            &                                              'be spread through depth by ln_rnf_depth'               )
455         !
456         nkrnf = 0                                  ! Number of level over which Kz increase
457         IF( rn_hrnf > 0._wp ) THEN
458            nkrnf = 2
459            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
460            END DO
461            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
462         ENDIF
463         IF(lwp) WRITE(numout,*)
464         IF(lwp) WRITE(numout,*) '          Specific treatment used in vicinity of river mouths :'
465         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
466         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
467         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
468         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
469         !
470         CALL rnf_mouth                             ! set river mouth mask
471         !
472      ELSE                                      ! No treatment at river mouths
473         IF(lwp) WRITE(numout,*)
474         IF(lwp) WRITE(numout,*) '          No specific treatment at river mouths'
475         rnfmsk  (:,:) = 0._wp
476         rnfmsk_z(:)   = 0._wp
477         nkrnf = 0
478      ENDIF
479      !
480   END SUBROUTINE sbc_rnf_init
481
482
483   SUBROUTINE rnf_mouth
484      !!----------------------------------------------------------------------
485      !!                  ***  ROUTINE rnf_mouth  ***
486      !!
487      !! ** Purpose :   define the river mouths mask
488      !!
489      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
490      !!                climatological file. Defined a given vertical structure.
491      !!                CAUTION, the vertical structure is hard coded on the
492      !!                first 5 levels.
493      !!                This fields can be used to:
494      !!                 - set an upstream advection scheme
495      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
496      !!                 - increase vertical on the top nn_krnf vertical levels
497      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
498      !!                 - set to zero SSS restoring flux at river mouth grid points
499      !!
500      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
501      !!                rnfmsk_z vertical structure
502      !!----------------------------------------------------------------------
503      INTEGER            ::   inum        ! temporary integers
504      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
505      !!----------------------------------------------------------------------
506      !
507      IF(lwp) WRITE(numout,*)
508      IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
509      IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
510      !
511      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
512      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
513         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
514      ENDIF
515      !
516      ! horizontal mask (read in NetCDF file)
517      CALL iom_open ( cl_rnfile, inum )                           ! open file
518      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
519      CALL iom_close( inum )                                      ! close file
520      !
521      IF( nn_closea == 1 )   CALL clo_rnf( rnfmsk )               ! closed sea inflow set as ruver mouth
522      !
523      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
524      rnfmsk_z(1)   = 1.0
525      rnfmsk_z(2)   = 1.0                                         ! **********
526      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
527      rnfmsk_z(4)   = 0.25                                        ! **********
528      rnfmsk_z(5)   = 0.125
529      !
530   END SUBROUTINE rnf_mouth
531
532   !!======================================================================
533END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.